WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DiscreteConvolve[f,g,n,m]

n についての式 fと g のたたみ込みを与える．

DiscreteConvolve[f,g,{n1,n2,…},{m1,m2,…}]

多次元たたみ込みを与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一変数たたみ込み  
多変数たたみ込み  
一般化と拡張  
オプション  
Assumptions  
GenerateConditions  
アプリケーション  
特性と関係  
インタラクティブな例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

DiscreteConvolve

DiscreteConvolve[f,g,n,m]

n についての式 fと g のたたみ込みを与える．

DiscreteConvolve[f,g,{n1,n2,…},{m1,m2,…}]

多次元たたみ込みを与える．

詳細とオプション

例題

すべて開く すべて閉じる

例  (3)

DiscreteDeltaで数列をたたみ込む：

Wolfram Language code: DiscreteConvolve[DiscreteDelta[n], Sin[n], n, m]

2つの指数数列をたたみ込む：

Wolfram Language code: DiscreteConvolve[(1 / 2) ^ n UnitStep[n], (1 / 2) ^ n UnitStep[n], n, m]

2つのUnitBox数列をたたみ込み，結果をプロットする：

Wolfram Language code: DiscreteConvolve[UnitBox[n / 5], UnitBox[n / 5], n, m];
Wolfram Language code: DiscretePlot[%, {m, -8, 8}, PlotRange -> All]

スコープ  (4)

一変数たたみ込み  (3)

たたみ込みは平行移動の積を合計する：

Wolfram Language code: f[n_] := UnitBox[n / 7]
Wolfram Language code: g[n_] := 2 UnitBox[n / 3 + 1]
Wolfram Language code: GraphicsRow@Table[DiscretePlot[{f[x], g[x - i]}, {x, -10, 10}, ImageSize -> 110, Ticks -> None, PlotRange -> All], {i, -1, 2}]
Wolfram Language code: DiscreteConvolve[f[n], g[n], n, m]
Wolfram Language code: DiscretePlot[%, {m, -10, 10}]

初等数列のたたみ込み：

Wolfram Language code: DiscreteConvolve[1 / (2n + 1) ^ 2, 1 / (3n - 1) ^ 2, n, m]

区分数列のたたみ込み：

Wolfram Language code: DiscreteConvolve[4 ^ (-n) UnitStep[n], 7 ^ n UnitStep[n], n, m]

多変数たたみ込み  (1)

単位ボックスを用いて離散たたみ込みを実行する：

Wolfram Language code: DiscreteConvolve[UnitBox[m / 4, n / 7 + 1], m ^ 2 + n, {m, n}, {r, s}]

一般化と拡張  (1)

UnitStepによる乗算は，事実上有限区間でのたたみ込みを与える：

Wolfram Language code: DiscreteConvolve[2 ^ n UnitStep[n], n UnitStep[n], n, m]
Wolfram Language code: Sum[2 ^ n (m - n), {n, 0, m}]

オプション  (2)

Assumptions  (1)

変数すなわちパラメータについての仮定を指定する：

Wolfram Language code: DiscreteConvolve[UnitStep[n] / 3 ^ n, 2 ^ n UnitStep[-n], n, m, Assumptions -> m > 0]
Wolfram Language code: DiscreteConvolve[UnitStep[n] / 3 ^ n, 2 ^ n UnitStep[-n], n, m, Assumptions -> m < 0]

GenerateConditions  (1)

パラメータの範囲についての条件を生成する：

Wolfram Language code: DiscreteConvolve[E ^ (-a Abs[n]), 1, n, m, GenerateConditions -> True]

アプリケーション  (2)

線形微分方程式の特殊解を求める：

Wolfram Language code: y[n] /. RSolve[{y[n] - 2y[n - 1] == n, y[0] == 0}, y, n][[1]]
Wolfram Language code: DiscreteConvolve[2 ^ k UnitStep[k], k UnitStep[k], k, n, Assumptions -> n > 0]

インパルス応答 h が与えられた線形時不変系のステップ応答を得る：

Wolfram Language code: h = (4 / 5) ^ n UnitStep[n];
Wolfram Language code: DiscretePlot[h, {n, 0, 20}]

この系に対応するステップ応答：

Wolfram Language code: DiscreteConvolve[h, UnitStep[n], n, m]
Wolfram Language code: DiscretePlot[%, {m, -5, 20}]

特性と関係  (7)

DiscreteConvolveは整数の集合上で総和を計算する：

Wolfram Language code: DiscreteConvolve[1 / (3n + 1) ^ 2, UnitStep[n], n, m, Assumptions -> m > 0]
Wolfram Language code: Sum[UnitStep[m - n] / (3n + 1) ^ 2, {n, -Infinity, Infinity}, Assumptions -> Element[m, Integers] && m > 0]

DiscreteDeltaを伴うたたみ込みは m における数列の値を与える：

Wolfram Language code: DiscreteConvolve[f[n], DiscreteDelta[n], n, m]

スケーリング：

Wolfram Language code: DiscreteConvolve[a r[n], s[n], n, m]
Wolfram Language code: DiscreteConvolve[r[n], a s[n], n, m]

交換性：

Wolfram Language code: f[n_] := 2 ^ n UnitStep[n]
Wolfram Language code: g[n_] := UnitStep[n]
Wolfram Language code: DiscreteConvolve[f[n], g[n], n, m]
Wolfram Language code: DiscreteConvolve[g[n], f[n], n, m]

分配性：

Wolfram Language code: DiscreteConvolve[h[n] + i[n], j[n], n, m]
Wolfram Language code: DiscreteConvolve[h[n], i[n] + j[n], n, m]

Causal ConvolutionのZTransformは個々の変換の積である：

Wolfram Language code: f[n_] := 2 ^ n UnitStep[n]
Wolfram Language code: g[n_] := UnitStep[n]
Wolfram Language code: ZTransform[DiscreteConvolve[f[n], g[n], n, m], m, z]
Wolfram Language code: Simplify[ZTransform[f[n], n, z]ZTransform[g[n], n, z]]

GeneratingFunctionの類似性：

Wolfram Language code: GeneratingFunction[DiscreteConvolve[f[n], g[n], n, m], m, z]
Wolfram Language code: GeneratingFunction[f[n], n, z]GeneratingFunction[g[n], n, z]
Wolfram Language code: %% - %//Simplify

たたみ込みのFourierSequenceTransformは個々の変換の積である：

Wolfram Language code: f[n_] := 3 ^ (-n) UnitStep[n]
Wolfram Language code: g[n_] := 2 ^ (n)UnitStep[-n]
Wolfram Language code: DiscreteConvolve[f[n], g[n], n, m]
Wolfram Language code: Together[FourierSequenceTransform[%, m, w]]
Wolfram Language code: Simplify[FourierSequenceTransform[f[n], n, w] FourierSequenceTransform[g[n], n, w]]

インタラクティブな例題  (1)

次は，離散時間たたみ込み演算 を示す：

Wolfram Language code: DynamicModule[{f, g, h}, f[n_] := (3 / 4) ^ n UnitStep[n]; g[n_] := UnitBox[n / 5]; h[n_] = DiscreteConvolve[f[m], g[m], m, n]; Manipulate[GraphicsRow[{DiscretePlot[{f[m], g[n - m]}, {m, -5, 12}, ...], DiscretePlot[f[m]g[n - m], {m, -5, 12}, ...], DiscretePlot[h[m], {m, -5, n}, ...]}, ImageSize -> 480], {{n, 1}, -4, 11, 1}]]
Wolfram Research (2008), DiscreteConvolve, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiscreteConvolve.html.

テキスト

Wolfram Research (2008), DiscreteConvolve, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiscreteConvolve.html.

CMS

Wolfram Language. 2008. "DiscreteConvolve." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DiscreteConvolve.html.

APA

Wolfram Language. (2008). DiscreteConvolve. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DiscreteConvolve.html

BibTeX

@misc{reference.wolfram_2026_discreteconvolve, author="Wolfram Research", title="{DiscreteConvolve}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/DiscreteConvolve.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_discreteconvolve, organization={Wolfram Research}, title={DiscreteConvolve}, year={2008}, url={https://reference.wolfram.com/language/ref/DiscreteConvolve.html}, note=[Accessed: 11-September-2026]}