WOLFRAM

Wolfram 语言与系统参考资料中心

DiscreteConvolve[f,g,n,m]

表达式 f 和 g 的关于 n 的卷积.

DiscreteConvolve[f,g,{n1,n2,…},{m1,m2,…}]

给出多维卷积.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
一元卷积  
多元卷积  
推广和延伸  
选项  
Assumptions  
GenerateConditions  
应用  
属性和关系  
互动范例  
参见
相关指南
相关链接
历史
按以下格式引用：

DiscreteConvolve

DiscreteConvolve[f,g,n,m]

表达式 f 和 g 的关于 n 的卷积.

DiscreteConvolve[f,g,{n1,n2,…},{m1,m2,…}]

给出多维卷积.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

计算序列与 DiscreteDelta 的卷积：

Wolfram Language code: DiscreteConvolve[DiscreteDelta[n], Sin[n], n, m]

计算两个指数序列的卷积：

Wolfram Language code: DiscreteConvolve[(1 / 2) ^ n UnitStep[n], (1 / 2) ^ n UnitStep[n], n, m]

计算两个 UnitBox 序列的卷积，并绘制结果：

Wolfram Language code: DiscreteConvolve[UnitBox[n / 5], UnitBox[n / 5], n, m];
Wolfram Language code: DiscretePlot[%, {m, -8, 8}, PlotRange -> All]

范围  (4)

一元卷积  (3)

卷积给出转化的乘积积分：

Wolfram Language code: f[n_] := UnitBox[n / 7]
Wolfram Language code: g[n_] := 2 UnitBox[n / 3 + 1]
Wolfram Language code: GraphicsRow@Table[DiscretePlot[{f[x], g[x - i]}, {x, -10, 10}, ImageSize -> 110, Ticks -> None, PlotRange -> All], {i, -1, 2}]
Wolfram Language code: DiscreteConvolve[f[n], g[n], n, m]
Wolfram Language code: DiscretePlot[%, {m, -10, 10}]

基本序列的卷积：

Wolfram Language code: DiscreteConvolve[1 / (2n + 1) ^ 2, 1 / (3n - 1) ^ 2, n, m]

分段序列的卷积：

Wolfram Language code: DiscreteConvolve[4 ^ (-n) UnitStep[n], 7 ^ n UnitStep[n], n, m]

多元卷积  (1)

Wolfram Language code: DiscreteConvolve[UnitBox[m / 4, n / 7 + 1], m ^ 2 + n, {m, n}, {r, s}]

推广和延伸  (1)

UnitStep 的乘法实际上给出有限区间上的卷积：

Wolfram Language code: DiscreteConvolve[2 ^ n UnitStep[n], n UnitStep[n], n, m]
Wolfram Language code: Sum[2 ^ n (m - n), {n, 0, m}]

选项  (2)

Assumptions  (1)

指定关于一个变量或参数的假设：

Wolfram Language code: DiscreteConvolve[UnitStep[n] / 3 ^ n, 2 ^ n UnitStep[-n], n, m, Assumptions -> m > 0]
Wolfram Language code: DiscreteConvolve[UnitStep[n] / 3 ^ n, 2 ^ n UnitStep[-n], n, m, Assumptions -> m < 0]

GenerateConditions  (1)

生成关于参数范围的条件：

Wolfram Language code: DiscreteConvolve[E ^ (-a Abs[n]), 1, n, m, GenerateConditions -> True]

应用  (2)

得到一个线性微分方程的特解:

Wolfram Language code: y[n] /. RSolve[{y[n] - 2y[n - 1] == n, y[0] == 0}, y, n][[1]]
Wolfram Language code: DiscreteConvolve[2 ^ k UnitStep[k], k UnitStep[k], k, n, Assumptions -> n > 0]

给定一个线性时不变系统的冲击响应 h，计算系统的阶跃响应：

Wolfram Language code: h = (4 / 5) ^ n UnitStep[n];
Wolfram Language code: DiscretePlot[h, {n, 0, 20}]

系统的阶跃响应：

Wolfram Language code: DiscreteConvolve[h, UnitStep[n], n, m]
Wolfram Language code: DiscretePlot[%, {m, -5, 20}]

属性和关系  (7)

DiscreteConvolve 在整数集上计算一个和:

Wolfram Language code: DiscreteConvolve[1 / (3n + 1) ^ 2, UnitStep[n], n, m, Assumptions -> m > 0]
Wolfram Language code: Sum[UnitStep[m - n] / (3n + 1) ^ 2, {n, -Infinity, Infinity}, Assumptions -> Element[m, Integers] && m > 0]

有 DiscreteDelta 的卷积给出在 m 的序列的值：

Wolfram Language code: DiscreteConvolve[f[n], DiscreteDelta[n], n, m]

缩放：

Wolfram Language code: DiscreteConvolve[a r[n], s[n], n, m]
Wolfram Language code: DiscreteConvolve[r[n], a s[n], n, m]

交换性：

Wolfram Language code: f[n_] := 2 ^ n UnitStep[n]
Wolfram Language code: g[n_] := UnitStep[n]
Wolfram Language code: DiscreteConvolve[f[n], g[n], n, m]
Wolfram Language code: DiscreteConvolve[g[n], f[n], n, m]

分配性：

Wolfram Language code: DiscreteConvolve[h[n] + i[n], j[n], n, m]
Wolfram Language code: DiscreteConvolve[h[n], i[n] + j[n], n, m]

一个因果卷积的 ZTransform 是单个转换的乘积：

Wolfram Language code: f[n_] := 2 ^ n UnitStep[n]
Wolfram Language code: g[n_] := UnitStep[n]
Wolfram Language code: ZTransform[DiscreteConvolve[f[n], g[n], n, m], m, z]
Wolfram Language code: Simplify[ZTransform[f[n], n, z]ZTransform[g[n], n, z]]

GeneratingFunction 相似：

Wolfram Language code: GeneratingFunction[DiscreteConvolve[f[n], g[n], n, m], m, z]
Wolfram Language code: GeneratingFunction[f[n], n, z]GeneratingFunction[g[n], n, z]
Wolfram Language code: %% - %//Simplify

一个卷积的 FourierSequenceTransform 是单个转换的乘积：

Wolfram Language code: f[n_] := 3 ^ (-n) UnitStep[n]
Wolfram Language code: g[n_] := 2 ^ (n)UnitStep[-n]
Wolfram Language code: DiscreteConvolve[f[n], g[n], n, m]
Wolfram Language code: Together[FourierSequenceTransform[%, m, w]]
Wolfram Language code: Simplify[FourierSequenceTransform[f[n], n, w] FourierSequenceTransform[g[n], n, w]]

互动范例  (1)

下面演示了离散时间卷积运算 ：

Wolfram Language code: DynamicModule[{f, g, h}, f[n_] := (3 / 4) ^ n UnitStep[n]; g[n_] := UnitBox[n / 5]; h[n_] = DiscreteConvolve[f[m], g[m], m, n]; Manipulate[GraphicsRow[{DiscretePlot[{f[m], g[n - m]}, {m, -5, 12}, ...], DiscretePlot[f[m]g[n - m], {m, -5, 12}, ...], DiscretePlot[h[m], {m, -5, n}, ...]}, ImageSize -> 480], {{n, 1}, -4, 11, 1}]]
Wolfram Research (2008)，DiscreteConvolve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscreteConvolve.html.

文本

Wolfram Research (2008)，DiscreteConvolve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscreteConvolve.html.

CMS

Wolfram 语言. 2008. "DiscreteConvolve." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DiscreteConvolve.html.

APA

Wolfram 语言. (2008). DiscreteConvolve. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DiscreteConvolve.html 年

BibTeX

@misc{reference.wolfram_2026_discreteconvolve, author="Wolfram Research", title="{DiscreteConvolve}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/DiscreteConvolve.html}", note=[Accessed: 14-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_discreteconvolve, organization={Wolfram Research}, title={DiscreteConvolve}, year={2008}, url={https://reference.wolfram.com/language/ref/DiscreteConvolve.html}, note=[Accessed: 14-October-2026]}