WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DiscreteMinLimit[f,k∞]

k が ∞ に近付くときの数列 f の最小極限k∞f(k)を整数上で与える．

DiscreteMinLimit[f,{k1,…,kn}]

ネストした最小極限⋯ f(k1,…,kn)を整数上で与える．

DiscreteMinLimit[f,{k1,…,kn}{,…,}]

多変量最小極限f(k1,…,kn)を整数上で与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
初等関数数列  
整数関数数列  
Show More Show More
周期数列  
区分関数数列  
整数論の数列  
多変量数列  
オプション  
Assumptions  
GenerateConditions  
Method  
PerformanceGoal  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

DiscreteMinLimit

DiscreteMinLimit[f,k∞]

k が ∞ に近付くときの数列 f の最小極限k∞f(k)を整数上で与える．

DiscreteMinLimit[f,{k1,…,kn}]

ネストした最小極限⋯ f(k1,…,kn)を整数上で与える．

DiscreteMinLimit[f,{k1,…,kn}{,…,}]

多変量最小極限f(k1,…,kn)を整数上で与える．

詳細とオプション

  • DiscreteMinLimitは，下極限としても知られている．
  • DiscreteMinLimitは極限の最大下界を計算し，常に実数値数列について定義される．収束条件や実際に極限が存在するかどうかに依存しないその他の漸近的特性を与えるためにしばしば使われる．
  • DiscreteMinLimit[f,k∞]はf として入力することができる．テンプレートはdmlimで入力し，を使ってカーソルを真下付き文字から本体に移動する．
  • DiscreteMinLimit[f,{k1,…,kn}{,…,}]は…f として入力できる．
  • 可能な極限点 は±∞である．
  • 最小極限は最小包絡線数列min[ω]の極限として定義される．
  • DiscreteMinLimit[f,k∞]DiscreteLimit[min[ω],ω∞]
    DiscreteMinLimit[f,{k1,…,kn}{∞,…,∞}]DiscreteLimit[min[ω],ω∞]
  • DiscreteMinLimit[f[k],k-∞]はDiscreteMinLimit[f[-l],l∞]等と等価である．
  • この定義は，一変量の f[k]については最小包絡線 min[ω]MinValue[{f[k],k≥ω∧k∈},k]を，多変量のf[k1,…,kn]についてはmin[ω]MinValue[{f[k1,…,kn],k1≥ω∧⋯∧kn≥ω∧ki∈},{k1,…,kn}]を使う．数列min[ω]は ω∞のとき単調増加であるので，常に極限を持つ．それは±∞である可能性がある．
  • 次の図ではmin[k]とmin[Min[k1,k2]]が青で示されている．
  • 最小極限が求まらなかったとき，DiscreteMinLimitは未評価で返される．
  • 次は使用可能なオプションである．
  • Assumptions $Assumptionsパラメータについての仮定
    GenerateConditions Automaticパラメータについての条件を生成するかどうか
    Method Automatic使用するメソッド
    PerformanceGoal "Quality"パフォーマンスのどの面について最適化するか
  • 次はGenerateConditionsの可能な設定である．
  • Automatic一般的ではない条件のみ
    Trueすべての条件
    False条件なし
    None条件が必要な場合は未評価で返す
  • PerformanceGoalの可能な設定には，$PerformanceGoal，"Quality"，"Speed"がある．"Quality"設定のとき，DiscreteMinLimitは，一般に，より多くの問題を解いたりより簡単な結果を生成したりするが，より多くの時間とメモリが必要になる可能性がある．

例題

すべて開く すべて閉じる

例  (4)

数列の最小極限：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n, n -> ∞]

積の最小極限：

Wolfram Language code: DiscretePlot[{(3 + (24 / 25) ^ n) Sin[Pi(n / 20)]}, {n, 1, 200, 3}, PlotRange -> {-4, 4}]
Wolfram Language code: DiscreteMinLimit[(3 + (24 / 25) ^ n) * Sin[Pi(n / 20)], n -> ∞]

dmlim を使ってテンプレートを入力し，を使って真下付き文字から本体に移動する：

Wolfram Language code: Underscript[, nUnderscript[ -> , ℤ]∞]Sin[n]

TraditionalFormによる表示：

Wolfram Language code: DiscreteMinLimit[f[n], n -> Infinity]//TraditionalForm

スコープ  (22)

基本的な用法  (4)

n がInfinityに近付くときの数列の最小極限を計算する：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n 3n ^ 2 / (n ^ 2 + 5), n -> ∞]

n が-Infinityに近付くときの数列の最小極限を計算する：

Wolfram Language code: DiscreteMinLimit[Sin[n π / 2](5 + 3 ^ n), n -> -∞]

多変量数列のネストした極限を計算する：

Wolfram Language code: DiscreteMinLimit[Cos[m + 1 / (n + 1)], {m -> ∞, n -> ∞}]

数列のリストの極限を計算する：

Wolfram Language code: DiscreteMinLimit[{(2) ^ (-n), Cos[n π]}, n -> ∞]

初等関数数列  (6)

有理指数数列の最小極限を求める：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n(3n) / (1 + 6n), n -> ∞]
Wolfram Language code: DiscretePlot[{(-1) ^ n(3n) / (1 + 6n), -1 / 2}, {n, 0, 50}]

収束等比数列：

Wolfram Language code: DiscreteMinLimit[(-9 / 10) ^ n, n -> ∞]
Wolfram Language code: DiscretePlot[{(-9 / 10) ^ n}, {n, 10, 40}]

振動等比数列：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n, n -> ∞]
Wolfram Language code: DiscretePlot[{(-1) ^ n}, {n, 10, 30}]

発散振動等比数列：

Wolfram Language code: DiscreteMinLimit[(-10 / 9) ^ n, n -> ∞]
Wolfram Language code: DiscretePlot[{(-10 / 9) ^ n}, {n, 10, 50}]

指数数列：

Wolfram Language code: DiscreteMinLimit[E ^ ((-1) ^ n(n) / (n + 2)), n -> ∞]
Wolfram Language code: DiscretePlot[{E ^ ((-1) ^ n(n) / (n + 2)), 1 / E}, {n, 1, 50}]

ベキ数列：

Wolfram Language code: DiscreteMinLimit[2 ^ Sin[n], n -> ∞]

三角数列：

Wolfram Language code: DiscreteMinLimit[Sin[n], n -> ∞]
Wolfram Language code: DiscretePlot[{Sin[n], -1}, {n, 1, 150}]
Wolfram Language code: DiscreteMinLimit[(3n / (n + 1) + (14 / 17) ^ n)Cos[Pi(n / 20)], n -> ∞]
Wolfram Language code: DiscretePlot[{(3 n / (n + 1) + (14 / 17) ^ n) * Cos[Pi(n / 20)], -3}, {n, 1, 200, 3}, PlotRange -> {-4, 4}]

逆三角数列：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n ArcTan[n], n -> ∞]
Wolfram Language code: DiscretePlot[{(-1) ^ n ArcTan[n], -Pi / 2}, {n, 1, 30}]

対数数列：

Wolfram Language code: DiscreteMinLimit[Log[1 + n / (n + 1)] Sin[n Pi / 5], n -> ∞]
Wolfram Language code: DiscretePlot[{Log[1 + n / (n + 1)] Sin[n Pi / 5], %}, {n, 1, 50}]

整数関数数列  (3)

Factorialを含む数列：

Wolfram Language code: DiscreteMinLimit[(k!/(-1)^kk^9), k -> ∞]
Wolfram Language code: DiscretePlot[(k!/(-1)^kk^9), {k, 15}, PlotRange -> {-5, 5}, PlotStyle -> PointSize[Large]]

FactorialPowerを含む数列：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n * (FactorialPower[n, 2] / (7n ^ 2 + 1)), n -> ∞]

Fibonacciを含む数列の極限を計算する：

Wolfram Language code: DiscreteMinLimit[Fibonacci[n]Sin[n Pi / 2] / GoldenRatio ^ n, n -> ∞]

周期数列  (3)

周期数列の極限：

Wolfram Language code: DiscreteMinLimit[Mod[n, 5], n -> ∞]
Wolfram Language code: DiscretePlot[Mod[n, 5], {n, 1, 50}]
Wolfram Language code: DiscreteMinLimit[Sin[n Pi / 4], n -> ∞]
Wolfram Language code: DiscretePlot[Sin[n Pi / 4], {n, 1, 40}]
Wolfram Language code: DiscreteMinLimit[Cos[Pi n / 10], n -> Infinity]
Wolfram Language code: DiscretePlot[Cos[Pi n / 10], {n, 1, 20}]

最終的に周期的になる数列：

Wolfram Language code: Table[Mod[Factorial[n] + (-1) ^ n, 5], {n, 12}]
Wolfram Language code: DiscreteMinLimit[Mod[Factorial[n] + (-1) ^ n, 5], n -> Infinity]
Wolfram Language code: DiscretePlot[Mod[Factorial[n] + (-1) ^ n, 5], {n, 1, 20}]

密に非周期的な数列：

Wolfram Language code: DiscreteMinLimit[Sin[n], n -> Infinity]
Wolfram Language code: DiscretePlot[{Sin[n], -1}, {n, 1, 150}]
Wolfram Language code: DiscreteMinLimit[Exp[Sin[2n] ^ 2 / (2 + Cos[n])], n -> Infinity]
Wolfram Language code: DiscretePlot[Exp[Sin[2n] ^ 2 / (2 + Cos[n])], {n, 1, 150}]

区分関数数列  (2)

有限最小極限を持つ区分数列：

Wolfram Language code: DiscreteMinLimit[Piecewise[{{n, n ≤ 4}}, Sin[n]], n -> ∞]
Wolfram Language code: DiscretePlot[{Piecewise[{{n, n ≤ 4}}, Sin[n] ], -1}, {n, 0, 75}]

無限最小極限を持つ区分数列：

Wolfram Language code: DiscreteMinLimit[Piecewise[{{Sin[n], n ≤ 10}}, n(-1) ^ n], n -> ∞]
Wolfram Language code: DiscretePlot[Piecewise[{{Sin[n], n ≤ 20}}, n(-1) ^ n], {n, 0, 75}]

周期条件を持つ区分数列：

Wolfram Language code: DiscreteMinLimit[Piecewise[{{1 + 1 / n, Mod[n, 2] == 0}, {-1 - 1 / n, Mod[n, 2] == 1}}], n -> ∞]
Wolfram Language code: DiscretePlot[Piecewise[{{1 + 1 / n, Mod[n, 2] == 0}, {-1 - 1 / n, Mod[n, 2] == 1}}], {n, 1, 75}]

整数論の数列  (2)

LCMとGCDを含む極限：

Wolfram Language code: DiscreteMinLimit[LCM[Mod[n, 3], 20], n -> ∞]
Wolfram Language code: DiscreteMinLimit[GCD[Mod[n, 56], 33], n -> ∞]

Primeを含む数列：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n Prime[n] / (n Log[n]), n -> ∞]
Wolfram Language code: DiscretePlot[(-1) ^ n Prime[n] / (n Log[n]), {n, 10, 100}]

多変量数列  (2)

ネストした最小極限を計算する：

Wolfram Language code: DiscreteMinLimit[(-1) ^ (m + n) (1000) ^ (1 / n) (m ^ 2 / (m ^ 2 + 1)), {m -> ∞, n -> ∞}]

数列とその極限をプロットする：

Wolfram Language code: DiscretePlot3D[{(-1) ^ (m + n)(1000) ^ (1 / n)(m ^ 2 / (m ^ 2 + 1)), -1}, {n, 50, 60}, {m, 50, 60}, Filling -> None]

多変量最小極限：

Wolfram Language code: DiscreteMinLimit[(m + n/m n), {m, n} -> {∞, ∞}]
Wolfram Language code: DiscreteMinLimit[Sin[(π n/3)]Cos[(π m/4)], {m, n} -> {∞, ∞}]

オプション  (6)

Assumptions  (1)

パラメータについての仮定を指定する：

Wolfram Language code: DiscreteMinLimit[E ^ (a n) Sin[n], n -> ∞]

仮定が変わると生成される結果が変わることがある：

Wolfram Language code: DiscreteMinLimit[E ^ (a n) Sin[n], n -> ∞, Assumptions -> a > 0]
Wolfram Language code: DiscreteMaxLimit[E ^ (a n) Sin[n], n -> ∞, Assumptions -> a < 0]

GenerateConditions  (3)

条件を述べずに結果を返す：

Wolfram Language code: DiscreteMinLimit[(1/2 +  ^ n), n -> ∞, GenerateConditions -> False]

この結果は x>1のときにのみ有効である：

Wolfram Language code: DiscreteMinLimit[(1/2 +  ^ n), n -> ∞]

結果がパラメータの値に依存する場合には未評価で返す：

Wolfram Language code: DiscreteMinLimit[Exp[a n]Sin[n], n -> ∞, GenerateConditions -> None]

デフォルトで，一意的な結果が返されるような条件が生成される：

Wolfram Language code: DiscreteMinLimit[Exp[a n] Sin[n], n -> ∞]

デフォルトで，特殊な値だけが結果を無効にする場合は条件が生成されない：

Wolfram Language code: DiscreteMinLimit[(x y/x^2 + (-1 + a x)^2 y^2), {x, y} -> {∞, ∞}]

GenerateConditions->Trueとすると，一般的ではない条件もレポートされる：

Wolfram Language code: DiscreteMinLimit[(x y/x^2 + (-1 + a x)^2 y^2), {x, y} -> {∞, ∞}, GenerateConditions -> True]

Method  (1)

周期数列の最小極限をデフォルトメソッドを使って計算する：

Wolfram Language code: DiscreteMinLimit[Mod[n, 2], n -> ∞]

周期数列用のメソッドを使って同じ答を得る：

Wolfram Language code: DiscreteMinLimit[Mod[n, 2], n -> ∞, Method -> "Periodic"]

0と1の間で振動しているので，数列の極限は定義されない：

Wolfram Language code: DiscreteMinLimit[Mod[n, 2], n -> ∞, Method -> "DiscreteLimit"]

PerformanceGoal  (1)

DiscreteMinLimitは，任意に大きい周期の数列を含む極限を計算する：

Wolfram Language code: expr = 1 / (Mod[n, 31] + 1 / (7 + Mod[n, 10 ^ 5]));
Wolfram Language code: DiscreteMinLimit[expr, n -> ∞]

PerformanceGoalを使って，そのような場合に高くつくかもしれない計算を避ける：

Wolfram Language code: DiscreteMinLimit[expr, n -> ∞, PerformanceGoal -> "Speed"]

MethodオプションはPerformanceGoalをオーバーライドする：

Wolfram Language code: DiscreteMinLimit[expr, n -> ∞, Method -> "Periodic", PerformanceGoal -> "Speed"]

アプリケーション  (3)

数列の漸近的最小値を計算する：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n E ^ (-10 / n), n -> ∞]

数列と漸近的最小値をプロットする：

Wolfram Language code: DiscretePlot[{(-1) ^ n E ^ (-10 / n), -1}, {n, 1, 100}]

次の数列には極限がないことを検証する：

Wolfram Language code: a[n_] := n Cos[5n] / (2n + 1)
Wolfram Language code: DiscretePlot[a[n], {n, 1, 140}]

DiscreteMaxLimitとDiscreteMinLimitは等しくないことを示す：

Wolfram Language code: DiscreteMaxLimit[a[n], n -> ∞]
Wolfram Language code: DiscreteMinLimit[a[n], n -> ∞]

DiscreteLimitを使って極限が存在しないことを確認する：

Wolfram Language code: DiscreteLimit[a[n], n -> ∞]

_(n->_(TemplateBox[{}, Integers])infty) (f(n))/(g(n))>0のとき，アルゴリズムのランタイム関数 は「big-omega of 」()であると言われる：

Wolfram Language code: Ω[n_][f_, g_] := Underscript[, nUnderscript[ -> , ℤ]∞](f/g) > 0

同様に，_(n->_(TemplateBox[{}, Integers])infty) (f(n))/(g(n))<inftyおよび_(n->_(TemplateBox[{}, Integers])infty)(f(n))/(g(n))>0のとき， は「big-theta of 」()であると言われる：

Wolfram Language code: Θ[n_][f_, g_] := Underscript[, nUnderscript[ -> , ℤ]∞](f/g) < ∞ && Underscript[, nUnderscript[ -> , ℤ]∞](f/g) > 0

という陳述は常に真である：

Wolfram Language code: Ω[n][f[n], f[n]]

で であるなら，である：

Wolfram Language code: f = n ^ 4 + 3n ^ 2 + 2; g = 5 n ^ 3; h = 10n ^ 2 + 2n + 1; {Ω[n][f, g], Ω[n][g, h], Ω[n][f, h]}

2つの関数がどちらの関係も共有しないこともある：

Wolfram Language code: f = 1; g = (1/n)Mod[-1 + n, 2] + n Mod[n, 2]; {Ω[n][f , g], Ω[n][g, f]}

したがって，はと同様のアルゴリズムランタイムの空間における反射的半順序を定義する：

Wolfram Language code: runtimes = {Exp[n], n Log[n], n, 1, n ^ 2};
Wolfram Language code: Sort[runtimes, Ω[n]]

で なら である．このことはが同値関係であることを暗示している：

Wolfram Language code: f = 10n ^ 2 + 2n + 1; g = 5 n ^ 2 + 100; {Ω[n][f, g], Ω[n][g, f], Θ[n][f, g], Θ[n][g, f]}

特性と関係  (11)

実数値関数は，常に（無限の可能性がある）最小極値を持つ：

Wolfram Language code: f[n_] := (-1) ^ n
Wolfram Language code: DiscreteMinLimit[f[n], n -> ∞]

対応する極限は存在しないかもしれない：

Wolfram Language code: DiscreteLimit[f[n], n -> ∞]

と が有限最小極値を持つならTemplateBox[{{(, {f, +, g}, )}, x, a}, DiscreteMinLimit]>=TemplateBox[{f, x, a}, DiscreteMinLimit]+TemplateBox[{g, x, a}, DiscreteMinLimit] である：

Wolfram Language code: f[n_] := Sin[n]
Wolfram Language code: g[n_] := Cos[n]
Wolfram Language code: DiscreteMinLimit[f[n] + g[n], n -> ∞] ≥ DiscreteMinLimit[f[n], n -> ∞] + DiscreteMinLimit[g[n], n -> ∞]

この場合は厳密な不等式が存在する：

Wolfram Language code: DiscreteMinLimit[f[n] + g[n], n -> ∞] > DiscreteMinLimit[f[n], n -> ∞] + DiscreteMinLimit[g[n], n -> ∞]

正の乗法定数は極限の外に出すことができる：

Wolfram Language code: f[n_] := (-1) ^ n
Wolfram Language code: c = 6;
Wolfram Language code: DiscreteMinLimit[c f[n], n -> ∞] == c DiscreteMinLimit[f[n], n -> ∞]

実数値数列について，DiscreteLimit が存在するならDiscreteMinLimitは同じ値を持つ：

Wolfram Language code: f[n_] := (-1) ^ n n / (n ^ 2 + 1)
Wolfram Language code: DiscreteLimit[f[n], n -> ∞]
Wolfram Language code: DiscreteMinLimit[f[n], n -> ∞]

が有限極限を持つなら，TemplateBox[{{(, {f, +, g}, )}, x, a}, DiscreteMinLimit]=TemplateBox[{f, x, a}, DiscreteMinLimit]+TemplateBox[{g, x, a}, DiscreteMinLimit] である：

Wolfram Language code: f[n_] := n / (n + 1)
Wolfram Language code: g[n_] := Cos[n]
Wolfram Language code: DiscreteLimit[f[n], n -> ∞]
Wolfram Language code: DiscreteMinLimit[f[n] + g[n], n -> ∞] == DiscreteMinLimit[f[n], n -> ∞] + DiscreteMinLimit[g[n], n -> ∞]

DiscreteMinLimitはDiscreteMaxLimit以下である：

Wolfram Language code: a[n_] := Sin[n]
Wolfram Language code: DiscreteMinLimit[a[n], n -> ∞] < DiscreteMaxLimit[a[n], n -> ∞]

DiscreteMinLimitとDiscreteMaxLimitが等しいなら，極限が存在し，その極限は両者の共通値に等しい：

Wolfram Language code: f[n_] := (n Cos[n]/n^2 + 1)
Wolfram Language code: {Underscript[, nUnderscript[ -> , ℤ]∞]f[n], Underscript[, nUnderscript[ -> , ℤ]∞]f[n], Underscript[, nUnderscript[ -> , ℤ]∞]f[n]}

最小極限が なら，最大極限と極限もまた である：

Wolfram Language code: f[n_] := n^2
Wolfram Language code: {Underscript[, nUnderscript[ -> , ℤ]-∞]f[n], Underscript[, nUnderscript[ -> , ℤ]-∞]f[n], Underscript[, nUnderscript[ -> , ℤ]-∞]f[n]}

DiscreteMinLimitは-DiscreteMaxLimit[-f,…]として計算することができる：

Wolfram Language code: f[n_] := Piecewise[{{n, Mod[n, 2] == 0}, {-1, True}}]
Wolfram Language code: DiscreteMinLimit[f[x], x -> ∞] == -DiscreteMaxLimit[-f[x], x -> ∞]

ならTemplateBox[{{g, (, n, )}, x, a}, MinLimit2Arg]>=TemplateBox[{{f, (, n, )}, x, a}, MaxLimit2Arg]>=TemplateBox[{{f, , {(, n, )}}, x, a}, MinLimit2Arg]である：

Wolfram Language code: f[n_] := Sin[n / 20] / n
Wolfram Language code: g[n_] := (1/n)
Wolfram Language code: Reduce[f[n] ≤ g[n]n, Integers]//Simplify
Wolfram Language code: Underscript[, nUnderscript[ -> , ℤ]-∞]g[n] ≥ Underscript[, nUnderscript[ -> , ℤ]-∞]f[n] ≥ Underscript[, nUnderscript[ -> , ℤ]-∞]f[n]

この例のように2つの最大極限が等しいなら， には極限がある：

Wolfram Language code: Underscript[, nUnderscript[ -> , ℤ]-∞]f[n] == Underscript[, nUnderscript[ -> , ℤ]-∞]g[n] == Underscript[, nUnderscript[ -> , ℤ]-∞]f[n]

これは，はさみうちの定理 （またはサンドイッチ定理）の一般化である：

Wolfram Language code: DiscretePlot[{f[n], g[n]}, {n, 500}, Filling -> {2 -> {1}}]

MinLimitは常にDiscreteMinLimit以下である：

Wolfram Language code: g[n_] := Sin[n π + Pi / 4]
Wolfram Language code: DiscreteMinLimit[g[n], n -> ∞]
Wolfram Language code: MinLimit[g[n], n -> ∞]
Wolfram Language code: Show[Plot[{g[n], -1, -1 / Sqrt[2]}, {n, 0, 10}, PlotTheme -> "DashedLines"], DiscretePlot[g[n], {n, 0, 10}, PlotMarkers -> {"Point", Large}]]

考えられる問題  (1)

DiscreteMinLimitは実数値数列に対してのみ定義される：

Wolfram Language code: DiscreteMinLimit[I, n -> ∞]

おもしろい例題  (1)

数列の最小極限集合を可視化する：

Wolfram Language code: f[n_] := {{Sin[n], -1}, {(-1) ^ n 3n ^ 2 / (n ^ 2 + 5), -3}, {(-1) ^ n, -1}, {(-1) ^ n E ^ (-10 / n), -1}, {n Sin[5n] / (3n + 1), -1 / 3}, {(-1.2) ^ n, -10000}}
Wolfram Language code: range = {{-1.1, 1.1}, {-3.1, 3.1}, {-1.1, 1.1}, {-1, 1}, {-0.36, 0.36}, {-1600, 1600}};
Wolfram Language code: Grid[Partition[Table[With[{r1 = f[n][[m, 1]], r2 = f[n][[m, 2]], r3 = range[[m]]}, DiscretePlot[{r1, r2}, {n, 1, 40}, PlotRange -> r3, ImageSize -> 210, PlotLabel -> Style[HoldForm[DiscreteMinLimit[r1, n -> Infinity]] == DiscreteMinLimit[f[n][[m, 1]], n -> Infinity], 13]]], {m, 1, 6}], 2], Frame -> All]
Wolfram Research (2017), DiscreteMinLimit, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiscreteMinLimit.html.

テキスト

Wolfram Research (2017), DiscreteMinLimit, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiscreteMinLimit.html.

CMS

Wolfram Language. 2017. "DiscreteMinLimit." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DiscreteMinLimit.html.

APA

Wolfram Language. (2017). DiscreteMinLimit. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DiscreteMinLimit.html

BibTeX

@misc{reference.wolfram_2026_discreteminlimit, author="Wolfram Research", title="{DiscreteMinLimit}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/DiscreteMinLimit.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_discreteminlimit, organization={Wolfram Research}, title={DiscreteMinLimit}, year={2017}, url={https://reference.wolfram.com/language/ref/DiscreteMinLimit.html}, note=[Accessed: 09-September-2026]}