WOLFRAM

Wolfram 语言与系统参考资料中心

DiscreteMinLimit[f,k∞]

给出序列 f[k] 当 k 在整数上趋近于 ∞ 时的最小极限 k∞f(k).

DiscreteMinLimit[f,{k1,…,kn}]

给出整数上的嵌套最小极限 ⋯ f(k1,…,kn).

DiscreteMinLimit[f,{k1,…,kn}{,…,}]

给出整数上的多变量最小极限 f(k1,…,kn).

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
初等函数序列  
整数函数序列  
Show More Show More
周期序列  
分段函数序列  
数论函数序列  
多变量序列  
选项  
Assumptions  
GenerateConditions  
Method  
PerformanceGoal  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

DiscreteMinLimit

DiscreteMinLimit[f,k∞]

给出序列 f[k] 当 k 在整数上趋近于 ∞ 时的最小极限 k∞f(k).

DiscreteMinLimit[f,{k1,…,kn}]

给出整数上的嵌套最小极限 ⋯ f(k1,…,kn).

DiscreteMinLimit[f,{k1,…,kn}{,…,}]

给出整数上的多变量最小极限 f(k1,…,kn).

更多信息和选项

  • DiscreteMinLimit 亦称为 limit inferior、infimum limit、liminf、lower limit 和 inner limit.
  • DiscreteMinLimit 计算极限的最大下限，且总是为实值序列定义. 它通常用于给出不依赖于实际极限的收敛条件和其他渐进属性.
  • 可用 f 来输入 DiscreteMinLimit[f,k∞]. 可用 dmlim来输入模板 ，用 把光标从底部移动到主体.
  • 可用 …f 来输入 DiscreteMinLimit[f,{k1,…,kn}{,…,}].
  • 的极限值为 ±∞.
  • 最小极限被定义为最小包络序列 min[ω] 的极限：
  • DiscreteMinLimit[f,k∞]DiscreteLimit[min[ω],ω∞]
    DiscreteMinLimit[f,{k1,…,kn}{∞,…,∞}]DiscreteLimit[min[ω],ω∞]
  • DiscreteMinLimit[f[k],k-∞] 等价于 DiscreteMinLimit[f[-l],l∞] 等.
  • 对单变量 f[k]，定义使用最小包络 min[ω]MinValue[{f[k],k≥ω∧k∈},k]，对多变量 f[k1,…,kn]，则使用 min[ω]MinValue[{f[k1,…,kn],k1≥ω∧⋯∧kn≥ω∧ki∈},{k1,…,kn}]. ω∞ 时，序列 min[ω] 单调增大，所以它总是有一个极限，可能是 ±∞.
  • 下图中用蓝色显示 min[k] 和 min[Min[k1,k2]].
  • 如果无法找到最小极限，DiscreteMinLimit 不进行计算，直接返回.
  • 可以给出下列选项：
  • Assumptions $Assumptions对参数的假设
    GenerateConditions Automatic是否为参数生成条件
    Method Automatic所用的方法
    PerformanceGoal "Quality"优化的目标
  • GenerateConditions 的可能设置包括：
  • Automatic只汇报非通用条件
    True汇报所有条件
    False不汇报条件
    None如果需要条件，则不进行计算，直接返回
  • PerformanceGoal 的可能设置包括 $PerformanceGoal、"Quality" 和 "Speed". 如果设置为 "Quality"， DiscreteMinLimit 通常能求解更多问题或产生更简单的结果，但会需要更多时间和内存.

范例

打开所有单元 关闭所有单元

基本范例  (4)

序列的最小极限：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n, n -> ∞]

乘积的最小极限：

Wolfram Language code: DiscretePlot[{(3 + (24 / 25) ^ n) Sin[Pi(n / 20)]}, {n, 1, 200, 3}, PlotRange -> {-4, 4}]
Wolfram Language code: DiscreteMinLimit[(3 + (24 / 25) ^ n) * Sin[Pi(n / 20)], n -> ∞]

用 dmlim 输入模板 ，用 把光标从底部移动到主体：

Wolfram Language code: Underscript[, nUnderscript[ -> , ℤ]∞]Sin[n]

TraditionalForm 输出：

Wolfram Language code: DiscreteMinLimit[f[n], n -> Infinity]//TraditionalForm

范围  (22)

基本用法  (4)

计算当 n 趋近于 Infinity 时序列的最小极限：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n 3n ^ 2 / (n ^ 2 + 5), n -> ∞]

计算当 n 趋近于 -Infinity 时序列的最小极限：

Wolfram Language code: DiscreteMinLimit[Sin[n π / 2](5 + 3 ^ n), n -> -∞]

计算多变量序列的嵌套最小极限：

Wolfram Language code: DiscreteMinLimit[Cos[m + 1 / (n + 1)], {m -> ∞, n -> ∞}]

计算一系列序列的最小极限：

Wolfram Language code: DiscreteMinLimit[{(2) ^ (-n), Cos[n π]}, n -> ∞]

初等函数序列  (6)

求有理指数序列的最小极限：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n(3n) / (1 + 6n), n -> ∞]
Wolfram Language code: DiscretePlot[{(-1) ^ n(3n) / (1 + 6n), -1 / 2}, {n, 0, 50}]

收敛几何函数序列：

Wolfram Language code: DiscreteMinLimit[(-9 / 10) ^ n, n -> ∞]
Wolfram Language code: DiscretePlot[{(-9 / 10) ^ n}, {n, 10, 40}]

振荡几何函数序列：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n, n -> ∞]
Wolfram Language code: DiscretePlot[{(-1) ^ n}, {n, 10, 30}]

发散振荡几何函数序列：

Wolfram Language code: DiscreteMinLimit[(-10 / 9) ^ n, n -> ∞]
Wolfram Language code: DiscretePlot[{(-10 / 9) ^ n}, {n, 10, 50}]

指数函数序列：

Wolfram Language code: DiscreteMinLimit[E ^ ((-1) ^ n(n) / (n + 2)), n -> ∞]
Wolfram Language code: DiscretePlot[{E ^ ((-1) ^ n(n) / (n + 2)), 1 / E}, {n, 1, 50}]

幂函数序列：

Wolfram Language code: DiscreteMinLimit[2 ^ Sin[n], n -> ∞]

三角函数序列：

Wolfram Language code: DiscreteMinLimit[Sin[n], n -> ∞]
Wolfram Language code: DiscretePlot[{Sin[n], -1}, {n, 1, 150}]
Wolfram Language code: DiscreteMinLimit[(3n / (n + 1) + (14 / 17) ^ n)Cos[Pi(n / 20)], n -> ∞]
Wolfram Language code: DiscretePlot[{(3 n / (n + 1) + (14 / 17) ^ n) * Cos[Pi(n / 20)], -3}, {n, 1, 200, 3}, PlotRange -> {-4, 4}]

反三角函数序列：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n ArcTan[n], n -> ∞]
Wolfram Language code: DiscretePlot[{(-1) ^ n ArcTan[n], -Pi / 2}, {n, 1, 30}]

对数函数序列：

Wolfram Language code: DiscreteMinLimit[Log[1 + n / (n + 1)] Sin[n Pi / 5], n -> ∞]
Wolfram Language code: DiscretePlot[{Log[1 + n / (n + 1)] Sin[n Pi / 5], %}, {n, 1, 50}]

整数函数序列  (3)

涉及 Factorial 的序列：

Wolfram Language code: DiscreteMinLimit[(k!/(-1)^kk^9), k -> ∞]
Wolfram Language code: DiscretePlot[(k!/(-1)^kk^9), {k, 15}, PlotRange -> {-5, 5}, PlotStyle -> PointSize[Large]]

涉及 FactorialPower 的序列：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n * (FactorialPower[n, 2] / (7n ^ 2 + 1)), n -> ∞]

计算涉及 Fibonacci 的序列的极限：

Wolfram Language code: DiscreteMinLimit[Fibonacci[n]Sin[n Pi / 2] / GoldenRatio ^ n, n -> ∞]

周期序列  (3)

周期序列的极限：

Wolfram Language code: DiscreteMinLimit[Mod[n, 5], n -> ∞]
Wolfram Language code: DiscretePlot[Mod[n, 5], {n, 1, 50}]
Wolfram Language code: DiscreteMinLimit[Sin[n Pi / 4], n -> ∞]
Wolfram Language code: DiscretePlot[Sin[n Pi / 4], {n, 1, 40}]
Wolfram Language code: DiscreteMinLimit[Cos[Pi n / 10], n -> Infinity]
Wolfram Language code: DiscretePlot[Cos[Pi n / 10], {n, 1, 20}]

最终周期序列：

Wolfram Language code: Table[Mod[Factorial[n] + (-1) ^ n, 5], {n, 12}]
Wolfram Language code: DiscreteMinLimit[Mod[Factorial[n] + (-1) ^ n, 5], n -> Infinity]
Wolfram Language code: DiscretePlot[Mod[Factorial[n] + (-1) ^ n, 5], {n, 1, 20}]

密集非周期序列：

Wolfram Language code: DiscreteMinLimit[Sin[n], n -> Infinity]
Wolfram Language code: DiscretePlot[{Sin[n], -1}, {n, 1, 150}]
Wolfram Language code: DiscreteMinLimit[Exp[Sin[2n] ^ 2 / (2 + Cos[n])], n -> Infinity]
Wolfram Language code: DiscretePlot[Exp[Sin[2n] ^ 2 / (2 + Cos[n])], {n, 1, 150}]

分段函数序列  (2)

最小极限为有限值的分段序列：

Wolfram Language code: DiscreteMinLimit[Piecewise[{{n, n ≤ 4}}, Sin[n]], n -> ∞]
Wolfram Language code: DiscretePlot[{Piecewise[{{n, n ≤ 4}}, Sin[n] ], -1}, {n, 0, 75}]

最小极限为无穷大值的分段序列：

Wolfram Language code: DiscreteMinLimit[Piecewise[{{Sin[n], n ≤ 10}}, n(-1) ^ n], n -> ∞]
Wolfram Language code: DiscretePlot[Piecewise[{{Sin[n], n ≤ 20}}, n(-1) ^ n], {n, 0, 75}]

周期性条件下的分段序列：

Wolfram Language code: DiscreteMinLimit[Piecewise[{{1 + 1 / n, Mod[n, 2] == 0}, {-1 - 1 / n, Mod[n, 2] == 1}}], n -> ∞]
Wolfram Language code: DiscretePlot[Piecewise[{{1 + 1 / n, Mod[n, 2] == 0}, {-1 - 1 / n, Mod[n, 2] == 1}}], {n, 1, 75}]

数论函数序列  (2)

涉及 LCM 和 GCD 的极限：

Wolfram Language code: DiscreteMinLimit[LCM[Mod[n, 3], 20], n -> ∞]
Wolfram Language code: DiscreteMinLimit[GCD[Mod[n, 56], 33], n -> ∞]

涉及 Prime 的序列：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n Prime[n] / (n Log[n]), n -> ∞]
Wolfram Language code: DiscretePlot[(-1) ^ n Prime[n] / (n Log[n]), {n, 10, 100}]

多变量序列  (2)

计算嵌套最小极限：

Wolfram Language code: DiscreteMinLimit[(-1) ^ (m + n) (1000) ^ (1 / n) (m ^ 2 / (m ^ 2 + 1)), {m -> ∞, n -> ∞}]

绘制序列和它的极限：

Wolfram Language code: DiscretePlot3D[{(-1) ^ (m + n)(1000) ^ (1 / n)(m ^ 2 / (m ^ 2 + 1)), -1}, {n, 50, 60}, {m, 50, 60}, Filling -> None]

多变量最小极限：

Wolfram Language code: DiscreteMinLimit[(m + n/m n), {m, n} -> {∞, ∞}]
Wolfram Language code: DiscreteMinLimit[Sin[(π n/3)]Cos[(π m/4)], {m, n} -> {∞, ∞}]

选项  (6)

Assumptions  (1)

指定参数的假设：

Wolfram Language code: DiscreteMinLimit[E ^ (a n) Sin[n], n -> ∞]

不同的假设会给出不同的结果：

Wolfram Language code: DiscreteMinLimit[E ^ (a n) Sin[n], n -> ∞, Assumptions -> a > 0]
Wolfram Language code: DiscreteMaxLimit[E ^ (a n) Sin[n], n -> ∞, Assumptions -> a < 0]

GenerateConditions  (3)

不陈述条件，返回结果：

Wolfram Language code: DiscreteMinLimit[(1/2 +  ^ n), n -> ∞, GenerateConditions -> False]

只有 x>1 时结果才有效：

Wolfram Language code: DiscreteMinLimit[(1/2 +  ^ n), n -> ∞]

如果结果取决于参数的值，则不进行计算，直接返回：

Wolfram Language code: DiscreteMinLimit[Exp[a n]Sin[n], n -> ∞, GenerateConditions -> None]

默认情况下，会生成返回唯一结果的条件：

Wolfram Language code: DiscreteMinLimit[Exp[a n] Sin[n], n -> ∞]

默认情况下，如果只有特殊值使结果无效，则不会生成条件：

Wolfram Language code: DiscreteMinLimit[(x y/x^2 + (-1 + a x)^2 y^2), {x, y} -> {∞, ∞}]

当设置为 GenerateConditions->True 时，即便是非通用条件，也会汇报：

Wolfram Language code: DiscreteMinLimit[(x y/x^2 + (-1 + a x)^2 y^2), {x, y} -> {∞, ∞}, GenerateConditions -> True]

Method  (1)

用缺省方法计算周期序列的最小极限：

Wolfram Language code: DiscreteMinLimit[Mod[n, 2], n -> ∞]

用针对周期序列的方法获取同样的答案：

Wolfram Language code: DiscreteMinLimit[Mod[n, 2], n -> ∞, Method -> "Periodic"]

序列的极限没有定义，因为它在 0 和 1 之间振荡：

Wolfram Language code: DiscreteMinLimit[Mod[n, 2], n -> ∞, Method -> "DiscreteLimit"]

PerformanceGoal  (1)

DiscreteMinLimit 计算周期为任意长度的序列的极限：

Wolfram Language code: expr = 1 / (Mod[n, 31] + 1 / (7 + Mod[n, 10 ^ 5]));
Wolfram Language code: DiscreteMinLimit[expr, n -> ∞]

用 PerformanceGoal 来避免此种花费时间较长的计算：

Wolfram Language code: DiscreteMinLimit[expr, n -> ∞, PerformanceGoal -> "Speed"]

Method 选项会覆盖 PerformanceGoal：

Wolfram Language code: DiscreteMinLimit[expr, n -> ∞, Method -> "Periodic", PerformanceGoal -> "Speed"]

应用  (3)

计算序列的渐进下界：

Wolfram Language code: DiscreteMinLimit[(-1) ^ n E ^ (-10 / n), n -> ∞]

绘制序列及其渐进下界：

Wolfram Language code: DiscretePlot[{(-1) ^ n E ^ (-10 / n), -1}, {n, 1, 100}]

验证下列序列没有极限：

Wolfram Language code: a[n_] := n Cos[5n] / (2n + 1)
Wolfram Language code: DiscretePlot[a[n], {n, 1, 140}]

证明 DiscreteMaxLimit 和 DiscreteMinLimit 不相等：

Wolfram Language code: DiscreteMaxLimit[a[n], n -> ∞]
Wolfram Language code: DiscreteMinLimit[a[n], n -> ∞]

用 DiscreteLimit 确认极限不存在：

Wolfram Language code: DiscreteLimit[a[n], n -> ∞]

一个算法运行时间函数 被认为是 "big-omega of "，写作 ，如果 _(n->_(TemplateBox[{}, Integers])infty) (f(n))/(g(n))>0：

Wolfram Language code: Ω[n_][f_, g_] := Underscript[, nUnderscript[ -> , ℤ]∞](f/g) > 0

同样， 还被认为是 "big-theta of "，写作 ，如果 _(n->_(TemplateBox[{}, Integers])infty) (f(n))/(g(n))<infty 和 _(n->_(TemplateBox[{}, Integers])infty)(f(n))/(g(n))>0：

Wolfram Language code: Θ[n_][f_, g_] := Underscript[, nUnderscript[ -> , ℤ]∞](f/g) < ∞ && Underscript[, nUnderscript[ -> , ℤ]∞](f/g) > 0

总是为真：

Wolfram Language code: Ω[n][f[n], f[n]]

如果 和 ，则 ：

Wolfram Language code: f = n ^ 4 + 3n ^ 2 + 2; g = 5 n ^ 3; h = 10n ^ 2 + 2n + 1; {Ω[n][f, g], Ω[n][g, h], Ω[n][f, h]}

两个函数不可能共享两种关系：

Wolfram Language code: f = 1; g = (1/n)Mod[-1 + n, 2] + n Mod[n, 2]; {Ω[n][f , g], Ω[n][g, f]}

因此， 在算法运行时间空间 (runtime space) 上定义了自反部分关系，类似于 ：

Wolfram Language code: runtimes = {Exp[n], n Log[n], n, 1, n ^ 2};
Wolfram Language code: Sort[runtimes, Ω[n]]

如果 和 ，则 ，表明 是一个等价关系：

Wolfram Language code: f = 10n ^ 2 + 2n + 1; g = 5 n ^ 2 + 100; {Ω[n][f, g], Ω[n][g, f], Θ[n][f, g], Θ[n][g, f]}

属性和关系  (11)

实值序列总是有最小极限（可能是无穷大）：

Wolfram Language code: f[n_] := (-1) ^ n
Wolfram Language code: DiscreteMinLimit[f[n], n -> ∞]

相应的极限则有可能不存在：

Wolfram Language code: DiscreteLimit[f[n], n -> ∞]

如果 和 的最小极限为有限值，则 TemplateBox[{{(, {f, +, g}, )}, x, a}, DiscreteMinLimit]>=TemplateBox[{f, x, a}, DiscreteMinLimit]+TemplateBox[{g, x, a}, DiscreteMinLimit]：

Wolfram Language code: f[n_] := Sin[n]
Wolfram Language code: g[n_] := Cos[n]
Wolfram Language code: DiscreteMinLimit[f[n] + g[n], n -> ∞] ≥ DiscreteMinLimit[f[n], n -> ∞] + DiscreteMinLimit[g[n], n -> ∞]

在这种情况下，存在严格的不相等性：

Wolfram Language code: DiscreteMinLimit[f[n] + g[n], n -> ∞] > DiscreteMinLimit[f[n], n -> ∞] + DiscreteMinLimit[g[n], n -> ∞]

正的乘数常数可以被移到极限外面：

Wolfram Language code: f[n_] := (-1) ^ n
Wolfram Language code: c = 6;
Wolfram Language code: DiscreteMinLimit[c f[n], n -> ∞] == c DiscreteMinLimit[f[n], n -> ∞]

对于实值序列，如果 DiscreteLimit 存在，则 DiscreteMinLimit 的值与之相等：

Wolfram Language code: f[n_] := (-1) ^ n n / (n ^ 2 + 1)
Wolfram Language code: DiscreteLimit[f[n], n -> ∞]
Wolfram Language code: DiscreteMinLimit[f[n], n -> ∞]

如果 的极限为有限值，则 TemplateBox[{{(, {f, +, g}, )}, x, a}, DiscreteMinLimit]=TemplateBox[{f, x, a}, DiscreteMinLimit]+TemplateBox[{g, x, a}, DiscreteMinLimit]：

Wolfram Language code: f[n_] := n / (n + 1)
Wolfram Language code: g[n_] := Cos[n]
Wolfram Language code: DiscreteLimit[f[n], n -> ∞]
Wolfram Language code: DiscreteMinLimit[f[n] + g[n], n -> ∞] == DiscreteMinLimit[f[n], n -> ∞] + DiscreteMinLimit[g[n], n -> ∞]

DiscreteMinLimit 总是小于或等于 DiscreteMaxLimit：

Wolfram Language code: a[n_] := Sin[n]
Wolfram Language code: DiscreteMinLimit[a[n], n -> ∞] < DiscreteMaxLimit[a[n], n -> ∞]

如果 DiscreteMinLimit 等于 DiscreteMaxLimit，极限存在并等于它们共有的值：

Wolfram Language code: f[n_] := (n Cos[n]/n^2 + 1)
Wolfram Language code: {Underscript[, nUnderscript[ -> , ℤ]∞]f[n], Underscript[, nUnderscript[ -> , ℤ]∞]f[n], Underscript[, nUnderscript[ -> , ℤ]∞]f[n]}

如果最小极限为 ，那么最大极限和极限也等于 ：

Wolfram Language code: f[n_] := n^2
Wolfram Language code: {Underscript[, nUnderscript[ -> , ℤ]-∞]f[n], Underscript[, nUnderscript[ -> , ℤ]-∞]f[n], Underscript[, nUnderscript[ -> , ℤ]-∞]f[n]}

可用 -DiscreteMaxLimit[-f,…] 来计算 DiscreteMinLimit：

Wolfram Language code: f[n_] := Piecewise[{{n, Mod[n, 2] == 0}, {-1, True}}]
Wolfram Language code: DiscreteMinLimit[f[x], x -> ∞] == -DiscreteMaxLimit[-f[x], x -> ∞]

如果 ，则 TemplateBox[{{g, (, n, )}, x, a}, MinLimit2Arg]>=TemplateBox[{{f, (, n, )}, x, a}, MaxLimit2Arg]>=TemplateBox[{{f, , {(, n, )}}, x, a}, MinLimit2Arg]：

Wolfram Language code: f[n_] := Sin[n / 20] / n
Wolfram Language code: g[n_] := (1/n)
Wolfram Language code: Reduce[f[n] ≤ g[n]n, Integers]//Simplify
Wolfram Language code: Underscript[, nUnderscript[ -> , ℤ]-∞]g[n] ≥ Underscript[, nUnderscript[ -> , ℤ]-∞]f[n] ≥ Underscript[, nUnderscript[ -> , ℤ]-∞]f[n]

如果两个最小极限相等，如此例，那么 的极限存在：

Wolfram Language code: Underscript[, nUnderscript[ -> , ℤ]-∞]f[n] == Underscript[, nUnderscript[ -> , ℤ]-∞]g[n] == Underscript[, nUnderscript[ -> , ℤ]-∞]f[n]

这是 "squeezing" 或 "sandwich" 定理的推广：

Wolfram Language code: DiscretePlot[{f[n], g[n]}, {n, 500}, Filling -> {2 -> {1}}]

MinLimit 总是小于或等于 DiscreteMinLimit：

Wolfram Language code: g[n_] := Sin[n π + Pi / 4]
Wolfram Language code: DiscreteMinLimit[g[n], n -> ∞]
Wolfram Language code: MinLimit[g[n], n -> ∞]
Wolfram Language code: Show[Plot[{g[n], -1, -1 / Sqrt[2]}, {n, 0, 10}, PlotTheme -> "DashedLines"], DiscretePlot[g[n], {n, 0, 10}, PlotMarkers -> {"Point", Large}]]

可能存在的问题  (1)

DiscreteMinLimit 只对实值序列有定义：

Wolfram Language code: DiscreteMinLimit[I, n -> ∞]

巧妙范例  (1)

可视化一组序列的最小极限：

Wolfram Language code: f[n_] := {{Sin[n], -1}, {(-1) ^ n 3n ^ 2 / (n ^ 2 + 5), -3}, {(-1) ^ n, -1}, {(-1) ^ n E ^ (-10 / n), -1}, {n Sin[5n] / (3n + 1), -1 / 3}, {(-1.2) ^ n, -10000}}
Wolfram Language code: range = {{-1.1, 1.1}, {-3.1, 3.1}, {-1.1, 1.1}, {-1, 1}, {-0.36, 0.36}, {-1600, 1600}};
Wolfram Language code: Grid[Partition[Table[With[{r1 = f[n][[m, 1]], r2 = f[n][[m, 2]], r3 = range[[m]]}, DiscretePlot[{r1, r2}, {n, 1, 40}, PlotRange -> r3, ImageSize -> 210, PlotLabel -> Style[HoldForm[DiscreteMinLimit[r1, n -> Infinity]] == DiscreteMinLimit[f[n][[m, 1]], n -> Infinity], 13]]], {m, 1, 6}], 2], Frame -> All]
Wolfram Research (2017)，DiscreteMinLimit，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscreteMinLimit.html.

文本

Wolfram Research (2017)，DiscreteMinLimit，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscreteMinLimit.html.

CMS

Wolfram 语言. 2017. "DiscreteMinLimit." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DiscreteMinLimit.html.

APA

Wolfram 语言. (2017). DiscreteMinLimit. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DiscreteMinLimit.html 年

BibTeX

@misc{reference.wolfram_2026_discreteminlimit, author="Wolfram Research", title="{DiscreteMinLimit}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/DiscreteMinLimit.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_discreteminlimit, organization={Wolfram Research}, title={DiscreteMinLimit}, year={2017}, url={https://reference.wolfram.com/language/ref/DiscreteMinLimit.html}, note=[Accessed: 16-September-2026]}