WOLFRAM

Wolfram 语言与系统参考资料中心

DrazinInverse[m]

找到方阵 m 的 Drazin 广义逆 .

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
特殊矩阵  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

DrazinInverse

DrazinInverse[m]

找到方阵 m 的 Drazin 广义逆 .

更多信息和选项

  • 方阵 m 的 Drazin 逆是基于 m 的不变子空间的广义逆.
  • Drazin 逆是广义逆，就像 Moore– Penrose 逆是广义逆一样. 然而，Drazin 逆处理不变子空间，并涉及特征值问题、微分方程和差分方程的解等，而 Moore– Penrose 逆处理的是最小二乘并涉及拟合问题、SVD、逼近等.
  • DrazinInverse[m] 可以计算为 t.(TemplateBox[{c}, Inverse] 0; 0 0).TemplateBox[{t}, Inverse]，其中 {t,c,n} 是由 CoreNilpotentDecomposition[m] 返回的列表. »
  • Drazin 逆 满足关系 和 . »
  • 矩阵的幂零指数 定义为对应于零特征值的最大约当块的大小. Drazin 逆 满足关系 ，其中 是 m 的幂零指数. »
  • 对于非奇异方阵 m，Drazin 逆 等价于标准逆.
  • DrazinInverse[m] formats as in StandardForm and TraditionalForm. »

范例

打开所有单元 关闭所有单元

基本范例  (3)

计算矩阵的 Drazin 逆矩阵：

Wolfram Language code: DrazinInverse[(⁠| | | | | - | - | - | | 1 | 2 | 0 | | 5 | 1 | 3 | | 0 | 0 | 0 |⁠)]//MatrixForm

3×3 矩阵的 Drazin 逆：

Wolfram Language code: m = {{2, 0, 0}, {-1, 1 / 5, 1}, {-1 / 3, -1, -1}};
Wolfram Language code: (d = DrazinInverse[m])//MatrixForm

验证这个广义逆的一些属性：

Wolfram Language code: d.m == m.d
Wolfram Language code: d.m.d == d

4×4 矩阵的 Drazin 逆：

Wolfram Language code: m = {{-2, 5, 4, 4}, {3, -3, -3, -4}, {-4, 1, 2, 4}, {-2, 4, 5, 3}};
Wolfram Language code: (d = DrazinInverse[m])//MatrixForm

验证 DrazinInverse 的定义：

Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];
Wolfram Language code: a = PadRight[Inverse[c], Dimensions[m]];
Wolfram Language code: d === t.a.Inverse[t]

范围  (11)

基本用法  (7)

机器精度矩阵的 Drazin 逆：

Wolfram Language code: DrazinInverse[{{0.2, -0.32}, {0.1, -0.16}}]

复矩阵的 Drazin 逆：

Wolfram Language code: DrazinInverse[{{-4 + 6 I, 8 - 10 I, 2}, {-2 + 3 I, 4 - 5 I, 1}, {1, -1, 1}}]

精确矩阵的 Drazin 逆：

Wolfram Language code: DrazinInverse[{{1, 2, -2}, {4, 5, -3}, {1, 5, -3}}]

任意精度矩阵的 Drazin 逆矩阵：

Wolfram Language code: DrazinInverse[RandomReal[4, {2, 2}, WorkingPrecision -> 20]]

符号矩阵的 Drazin 逆：

Wolfram Language code: DrazinInverse[{{a, a, 1}, {0, 0, 0}, {2, 3, -1}}]//Simplify

大型机器精度矩阵的求逆是高效的：

Wolfram Language code: mat = RandomReal[{0, 10}, {800, 800}];
Wolfram Language code: AbsoluteTiming[DrazinInverse[mat];]

输出格式：

Wolfram Language code: DrazinInverse[m]

特殊矩阵  (4)

稀疏矩阵的 Drazin 逆作为正常矩阵返回：

Wolfram Language code: SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {3, 3}]
Wolfram Language code: DrazinInverse[%]

结构化矩阵的 Drazin 逆：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 3, {2, 2} -> 1, {3, 1} -> -5}, {3, 3}, Symmetric[All]]
Wolfram Language code: DrazinInverse[%]

IdentityMatrix 是它自身的 Drazin 逆：

Wolfram Language code: DrazinInverse[IdentityMatrix[3]]

希尔伯特矩阵的 Drazin 逆：

Wolfram Language code: DrazinInverse[HilbertMatrix[3]]

应用  (3)

求解具有奇异系数的矩阵微分方程 ，：

Wolfram Language code: a = (| | | | | -- | - | -- | | 1 | 0 | -2 | | -1 | 0 | 2 | | 2 | 3 | 2 |);b = (| | | | | --- | --- | --- | | 0 | 1 | 2 | | -27 | -22 | -17 | | 18 | 14 | 10 |);v = {-1, -8, 13};

由于 和 为奇异矩阵，因此方程式无法放入标准格式 :

Wolfram Language code: {Det[a], Det[b]}

解为 ，其中 对 求解且 对 求解：

Wolfram Language code: MatrixExp[-DrazinInverse[LinearSolve[a + b, a]].LinearSolve[a + b, b]t].v//Simplify

与 DSolveValue 给出的结果进行比较：

Wolfram Language code: DSolveValue[{a.y'[t] + b.y[t] == 0, y[0] == v}, y[t]∈Vectors[3], t]

求具有奇异系数矩阵 的矩阵差分方程 的通解：

Wolfram Language code: m = (⁠| | | | | -- | -- | -- | | 4 | 2 | -2 | | -8 | -3 | 1 | | -6 | -2 | 0 |⁠);

矩阵 为奇异矩阵：

Wolfram Language code: Det[m]

解为 ，其中 为任意向量：

Wolfram Language code: x[n_] = Simplify[MatrixPower[DrazinInverse[m], n + 1].m.{C[1], C[2], C[3]}, n > 0]

验证解：

Wolfram Language code: m.x[n + 1] == x[n]//Simplify

计算图的有效电阻矩阵：

Wolfram Language code: g = [image];
Wolfram Language code: MatrixForm[rm = With[{n = VertexCount[g], km = Normal[KirchhoffMatrix[g]]}, Table[ReplacePart[Diagonal[DrazinInverse[ReplacePart[km, k -> UnitVector[n, k]]]], k -> 0], {k, n}]]]

计算有效图电阻：

Wolfram Language code: Total[rm, 2] / 2

属性和关系  (8)

DrazinInverse 与可逆矩阵的 Inverse 相同：

Wolfram Language code: m = {{2, 5}, {7, 18}};
Wolfram Language code: DrazinInverse[m]
Wolfram Language code: Inverse[m]

DrazinInverse[m] 满足关系 和 ：

Wolfram Language code: m = {{0, 1, 0}, {0, 1, 1}, {0, 0, 0}};
Wolfram Language code: (d = DrazinInverse[m])//MatrixForm

验证所需的属性：

Wolfram Language code: d.m == m.d
Wolfram Language code: d.m.d == d

与 PseudoInverse 不同， 不一定是这种情况：

Wolfram Language code: m.d.m == m

另一个 Moore–Penrose 方程 [更多信息] 不需满足：

Wolfram Language code: {m.d == (m.d), d.m == (m.d)}

DrazinInverse 在矩阵共轭下是不变的，即 (a.b.TemplateBox[{a}, Inverse])^D=a.b^D.TemplateBox[{a}, Inverse]：

Wolfram Language code: a = {{8, 7, 0}, {9, 9, 2}, {9, 4, 7}}; b = {{6, 7, 6}, {5, 8, 5}, {1, 6, 4}};
Wolfram Language code: DrazinInverse[a.b.Inverse[a]] == a.DrazinInverse[b].Inverse[a]

DrazinInverse 可以通过 CoreNilpotentDecomposition 计算：

Wolfram Language code: m = {{-6, -3, -4, 2}, {0, -1, 0, 1}, {9, 6, 6, -2}, {0, 4, 0, 1}};
Wolfram Language code: {t, c, n} = CoreNilpotentDecomposition[m];
Wolfram Language code: d = DrazinInverse[m];

验证等量关系 m^D=t.(TemplateBox[{c}, Inverse] 0; 0 0).TemplateBox[{t}, Inverse]：

Wolfram Language code: d === t.PadRight[Inverse[c], Dimensions[m]].Inverse[t]

对于对角矩阵 m，DrazinInverse[m] 是非零元素反转的对角矩阵：

Wolfram Language code: DrazinInverse[DiagonalMatrix[{3, 14, 0}]]//MatrixForm

考虑 JordanDecomposition[m] 给出的约当矩阵 ：

Wolfram Language code: m = (⁠| | | | | | - | - | -- | -- | | 2 | 6 | -9 | -2 | | 6 | 6 | -3 | -6 | | 0 | 0 | 4 | 0 | | 2 | 6 | -9 | -2 |⁠); {s, j} = JordanDecomposition[m];

DrazinInverse 将具有零对角线的块映射到零，将其他块映射到它们的逆：

Wolfram Language code: {j//MatrixForm, DrazinInverse[j]//MatrixForm}

此外，m^D=s.j^D.TemplateBox[{s}, Inverse]：

Wolfram Language code: DrazinInverse[m] == s.DrazinInverse[j].Inverse[s]

定义一个计算方阵索引的函数：

Wolfram Language code: matrixIndex[m_ ? SquareMatrixQ] := Length[NestWhileList[m.#&, IdentityMatrix[Length[m]], MatrixRank[#1] != MatrixRank[#2]&, 2]] - 2

计算矩阵的索引：

Wolfram Language code: m = {{4, 2, -2}, {-5, -3, 4}, {-3, -2, 3}};
Wolfram Language code: k = matrixIndex[m]

DrazinInverse[m] 满足关系 ，其中 k 是 m 的索引：

Wolfram Language code: MatrixPower[m, k + 1].DrazinInverse[m] == MatrixPower[m, k]

PseudoInverse[m] 可以使用 DrazinInverse 计算为 TemplateBox[{{{{m, ^, {(, {(, {-, 1}, )}, )}}, =, {TemplateBox[{{(, m}}, ConjugateTranspose], ., m}}, )}, D}, Superscript].TemplateBox[{m}, ConjugateTranspose]：

Wolfram Language code: m = {{2, 2, -2}, {5, 1, -3}, {1, 5, -3}};
Wolfram Language code: PseudoInverse[m] == DrazinInverse[ConjugateTranspose[m].m].ConjugateTranspose[m]
Wolfram Research (2021)，DrazinInverse，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DrazinInverse.html （更新于 2025 年）.

文本

Wolfram Research (2021)，DrazinInverse，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DrazinInverse.html （更新于 2025 年）.

CMS

Wolfram 语言. 2021. "DrazinInverse." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/DrazinInverse.html.

APA

Wolfram 语言. (2021). DrazinInverse. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DrazinInverse.html 年

BibTeX

@misc{reference.wolfram_2026_drazininverse, author="Wolfram Research", title="{DrazinInverse}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/DrazinInverse.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_drazininverse, organization={Wolfram Research}, title={DrazinInverse}, year={2025}, url={https://reference.wolfram.com/language/ref/DrazinInverse.html}, note=[Accessed: 08-September-2026]}