WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EarthquakeData[loc]

loc に対応する場所について，すべての地震特性を与える．

EarthquakeData[loc,mag]

返される地震を，マグニチュードの範囲 mag のものに限る．

EarthquakeData[loc,mag,{start,end}]

start から end までの時間区間における，マグニチュードの範囲 mag 内での地震のデータを与える．

EarthquakeData[loc,mag,{start,end},property]

start から end までの時間区間における，マグニチュードの範囲 mag 内での地震について，一連の地震の property を与える．

EarthquakeData[entity,property]

特定の地震についてのデータを返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
場所  
識別子  
マグニチュード  
日付  
特性  
連想指定  
オプション  
TimeZone  
アプリケーション  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

EarthquakeData

Wolfram Knowledgebaseへの一般的なアクセスには，EarthquakeDataではなく，タイプEarthquakeの実体を使用のこと．

EarthquakeData[loc]

loc に対応する場所について，すべての地震特性を与える．

EarthquakeData[loc,mag]

返される地震を，マグニチュードの範囲 mag のものに限る．

EarthquakeData[loc,mag,{start,end}]

start から end までの時間区間における，マグニチュードの範囲 mag 内での地震のデータを与える．

EarthquakeData[loc,mag,{start,end},property]

start から end までの時間区間における，マグニチュードの範囲 mag 内での地震について，一連の地震の property を与える．

EarthquakeData[entity,property]

特定の地震についてのデータを返す．

詳細とオプション

  • 場所 loc は，GeoPosition，{lat,lon}，{{lat,lon},radius}のいずれかで与えられる．radius は，Quantityまたは数字で与えられる．数字の場合，単位はメートルであるとされる．radius が与えられていない場合には，デフォルト値100キロメートルが使われる．
  • 場所は，Entity，GeoDisk，Polygon，Rectangleの指定を使って領域として与えることもできる．
  • 地震の識別子 entity は，"Identifier"特性の値と同じである．これは，2桁のネットワークコードとその地震の識別番号からなる．すべての地震に固有の識別子があるわけではない．
  • マグニチュード mag は，最小マグニチュードを指定する単一単一の値として，あるいは値の範囲を指定する{mag1,mag2}として指定することができる．値は，モーメントマグニチュードスケール(MMS)で表されていると想定される．
  • 日付は，DateObjectとして，あるいはDateList形式で指定することができる．
  • 位置，大きさ，日付も，Association["Location"->locationspec,"Magnitude"mag,"Date"datespec]として一緒に指定することができる．
  • オプション TimeZone->z で別の時間帯を想定することができる．
  • 使用できる設定
  • 0UTC
    $TimeZone使用中のコンピュータシステムの現在の時間帯
    zUTCのオフセット z
  • EarthquakeDataは，地震実体をキーとして使ってAssociationを返す．個々の特性もまた，内部連想におけるキーである．
  • EarthquakeData["Properties"]を使ってEarthquakeDataの全特性を得ることができる．
  • 指定可能な特性
  • "AzimuthalGap"方位角によって隣接している測候所と測候所の間の方位角の最大ギャップ
    "Depth"地震の深さ（単位：キロメートル）
    "Identifier"地震のネットワークコードと事象識別子
    "Position"地震の緯度と経度
    "Magnitude"地震のマグニチュード
  • 特性が指定されると，EarthquakeDataはEventSeriesを返す．
  • 一般クエリを通してアクセス可能なその他の特性
  • "PositionMethod"場所を見極めるために使われる方法
    "Magnitude"地震のマグニチュード
    "MagnitudeType"マグニチュードを測定するために使われる方法
    "NumberOfPhases"震源の場所を計算するのに使われるP波とS波の到着時間の観察の数
    "NumberOfStations"地震のP波とS波の到着時間を報告した地震観測点の数

例題

すべて開く すべて閉じる

例  (3)

指定の場所近くで起った過去の地震を求める：

Wolfram Language code: data = EarthquakeData[GeoPosition[{45, -100}]];
Wolfram Language code: Keys[data]
Wolfram Language code: #["Period"]& /@ Values[data]

世界中の大きい地震を調べる：

Wolfram Language code: data = EarthquakeData[All, 9];
Wolfram Language code: #["Magnitude"]& /@ Values[data]

ある地域について地震の履歴を調べる：

Wolfram Language code: data = EarthquakeData[Rectangle[{39, -85}, {42, -95}]];
Wolfram Language code: DateListPlot[Values[{#["Period"], #["Magnitude"]}& /@ data], Filling -> 0, Joined -> False]

スコープ  (14)

場所  (6)

指定の緯度と経度の近くで起った地震を検索する：

Wolfram Language code: EarthquakeData[{45, -90}]

検索の半径を数字（単位：キロメートル）あるいはQuantityとして指定する：

Wolfram Language code: EarthquakeData[{{40.11, -108.24}, Quantity[20, "Miles"]}]

Entityを使って指定の場所近くで起った地震を見付けることができる：

Wolfram Language code: data = EarthquakeData[Entity["Building", "EmpireStateBuilding"]];
Wolfram Language code: Length[data]

緯度と経度の範囲を指定して，地震を検索する：

Wolfram Language code: data = EarthquakeData[Rectangle[{40, -110}, {41, -111}]];
Wolfram Language code: #["Position"]& /@ Values[data]

Polygonを使って，三角領域内で起った既知の地震すべてを求める：

Wolfram Language code: pol = Polygon[GeoPosition[{{38.11, -100.24}, {42.11, -100.24}, {38.11, -109.24}}]];
Wolfram Language code: data = EarthquakeData[pol];
Wolfram Language code: GeoGraphics[{Gray, Opacity[0.5], pol, Red, Point[#["Position"]& /@ Values[data]]}]

GeoDiskを使って，検索領域を指定することができる：

Wolfram Language code: data = EarthquakeData[GeoDisk[{40.11, -108.24}, Quantity[100, "Miles"]]];
Wolfram Language code: Length[data]

識別子  (1)

さまざまな地震について識別子を求める：

Wolfram Language code: EarthquakeData[Rectangle[{33, 134}, {38, 138}], 4, {{2012, 1, 1}, {2012, 12, 31}}, "Identifier"]["Values"]

識別子を使うと，特定の地震についてのクエリを直接行うことができる：

Wolfram Language code: EarthquakeData[Entity["Earthquake", "USc0007jku"], "Depth"]

マグニチュード  (2)

返される地震のマグニチュードの下限を指定する：

Wolfram Language code: data = EarthquakeData[Polygon[GeoPosition[{{39, -85}, {39, -95}, {42, -95}, {42, -85}}]], 5];
Wolfram Language code: #["Magnitude"]& /@ data

地震の結果を，マグニチュードの上限と下限の間のものに限る：

Wolfram Language code: data = Values[EarthquakeData[{{38, -88}, Quantity[50, "Miles"]}, {4, 5}]];
Wolfram Language code: #["Magnitude"]& /@ data

日付  (1)

特定の日付範囲内の地震を検索する：

Wolfram Language code: data = EarthquakeData[All, {6, 10}, {{2012, 12, 1}, {2013, 1, 1}}];
Wolfram Language code: DateListPlot[{#["Period"], #["Magnitude"]}& /@ data, Filling -> 0, Joined -> False]

特性  (2)

EarthquakeDataの特性すべてを求める：

Wolfram Language code: EarthquakeData["Properties"]

地震の記録された深さ等，地震の他の特性を調べる：

Wolfram Language code: EarthquakeData[All, {8, 10}, {{2011, 1, 1}, {2013, 1, 1}}, "Depth"]

連想指定  (2)

日付，大きさ，位置は，Associationを使って一緒に指定することができる：

Wolfram Language code: EarthquakeData[Association["Location" -> Polygon[Entity["Country", "Japan"]], "Magnitude" -> 6, "Date" -> {{2002, 1, 1}, {2004, 1, 1}}]]

Associationの指定は，特性引数と一緒に使うことができる：

Wolfram Language code: EarthquakeData[Association["Location" -> Polygon[Entity["Country", "Japan"]], "Magnitude" -> 6, "Date" -> {{2000, 1, 1}, {2005, 1, 1}}], "Depth"]

オプション  (1)

TimeZone  (1)

2012年12月21日に発生した地震を求める：

Wolfram Language code: data = EarthquakeData[All, {6, 10}, {{2012, 12, 21, 0, 0, 0}, {2012, 12, 22, 0, 0, 0}}]

デフォルトで，日付指定には$TimeZoneで与えられるユーザの時刻帯が使われる：

Wolfram Language code: data[[1, "Period"]]

TimeZoneオプションを使って出力の日付オブジェクトの時刻帯を指定する：

Wolfram Language code: EarthquakeData[All, {6, 10}, {{2012, 12, 21, 0, 0, 0}, {2012, 12, 22, 0, 0, 0}}, TimeZone -> 0][[1, "Period"]]

DateObject指定を使って入力の日付中の時刻帯を制御する：

Wolfram Language code: EarthquakeData[All, {6, 10}, {DateObject[{2012, 12, 22, 0, 0, 0}, TimeZone -> 5], DateObject[{2012, 12, 23, 0, 0, 0}, TimeZone -> 5]}, TimeZone -> 5][[1, "Period"]]

アプリケーション  (3)

日本の地震について，記録された深さとマグニチュードを調べる：

Wolfram Language code: data = Values[EarthquakeData[Polygon[Entity["Country", "Japan"]], 5, {{2000, 1, 1}, {2013, 9, 20}}]]; depths = #["Depth"]& /@ data; magnitudes = #["Magnitude"]& /@ data;
Wolfram Language code: ListPlot[Transpose[{depths, magnitudes}], Axes -> False, Frame -> True, FrameLabel -> {"Depth", "Magnitude"}]

記録された地震の頻度をそのマグニチュードの関数として観察する：

Wolfram Language code: magnitudes = #["Magnitude"]& /@ Values[EarthquakeData[All, 5, {{1990, 1, 1}, {2013, 9, 20}}]];
Wolfram Language code: ListLogPlot[Transpose[{Range[5, 10, 0.25], BinCounts[magnitudes, {4.75, 10, 0.25}]}], Joined -> True]

1980年来にヨーロッパの首都100キロメートル以内で記録された地震の数を比べる：

Wolfram Language code: cities = CountryData["Europe", "CapitalCity"];
Wolfram Language code: Grid[Reverse@SortBy[{#, Length[EarthquakeData[CityData[#, "Coordinates"], -1, {{1980, 1, 1}, {2013, 9, 20}}]]}& /@ cities, Last], Frame -> All]

おもしろい例題  (4)

2011年の東北地震について，モーメントマグニチュードスケールから地震モーメント を計算する：

Wolfram Language code: Mw = EarthquakeData[{38.3, 142.4}, {9, 10}, {{2011, 3, 10}, {2011, 3, 11}}, "Magnitude"]["Values"][[1]]

FormulaDataから についての公式を抽出する：

Wolfram Language code: formulas = FormulaData[{"SeismicMoment", "RuptureArea"}]
Wolfram Language code: Solve[{formulas[[2]] /. {Subscript[M, w] -> Mw, Subscript[M, 0] -> M0}}, M0]

カリフォルニアにおける，地震の記録された深さとその場所を可視化する：

Wolfram Language code: data = {#["Position"], #["Depth"]}& /@ Values[EarthquakeData[Polygon[Entity["AdministrativeDivision", {"California", "UnitedStates"}]], 4, {{1980, 1, 1}, {2013, 11, 20}}]];
Wolfram Language code: Graphics3D[{Opacity[0.6], Map[Append[Reverse[#], 0]&, EntityValue[Entity["AdministrativeDivision", {"California", "UnitedStates"}], "Polygon"] /.  GeoPosition -> Identity, {-2}], Blue, Opacity[1], Line[Apply[{Append[Reverse[First[#]], 0], Append[Reverse[First[#]], -(QuantityMagnitude[#2]/10)]}&, data, {1}]]}, Axes -> True]

過去20年間に世界中で記録された大きい地震をマップする：

Wolfram Language code: data = Values[EarthquakeData[All, 5, {{1990, 1, 1}, {1995, 9, 20}}]]; Length[data]
Wolfram Language code: pts = Normal[GroupBy[{Round@#["Magnitude"], #["Position"]}& /@ data, First, GeoPosition[#[[All, 2, 1]]]&]];
Wolfram Language code: GeoGraphics[ {Hue[0.7 (1 - #1 / 9)], PointSize[0.0007 #1], Point[#2]} & @@@ pts, GeoRange -> "World", ImageSize -> 500]

世界中の地震について計算された深さを調べる：

Wolfram Language code: depthpts = Normal[GroupBy[{Round@#["Depth"], #["Position"]}& /@ data, First, GeoPosition[#[[All, 2, 1]]]&]];
Wolfram Language code: Max[depthpts[[All, 1]]]
Wolfram Language code: GeoGraphics[{Hue[0.7 (1 - QuantityMagnitude[#1] / 700)], PointSize[0.006 QuantityMagnitude[#1] / 700], Point[#2]}&@@@pts, GeoRange -> "World", ImageSize -> 500]

カリフォルニア州とその周辺で記録された地震を調べる：

Wolfram Language code: data = EarthquakeData[Entity["AdministrativeDivision", {"California", "UnitedStates"}], 4, {{1980, 1, 1}, {2013, 9, 20}}, "Position"]["Values"];
Wolfram Language code: GeoGraphics[{GeoStyling["ReliefMap"], Red, Point[data]}]
Wolfram Research (2014), EarthquakeData, Wolfram言語関数， https://reference.wolfram.com/language/ref/EarthquakeData.html.

テキスト

Wolfram Research (2014), EarthquakeData, Wolfram言語関数， https://reference.wolfram.com/language/ref/EarthquakeData.html.

CMS

Wolfram Language. 2014. "EarthquakeData." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/EarthquakeData.html.

APA

Wolfram Language. (2014). EarthquakeData. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EarthquakeData.html

BibTeX

@misc{reference.wolfram_2026_earthquakedata, author="Wolfram Research", title="{EarthquakeData}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/EarthquakeData.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_earthquakedata, organization={Wolfram Research}, title={EarthquakeData}, year={2014}, url={https://reference.wolfram.com/language/ref/EarthquakeData.html}, note=[Accessed: 08-September-2026]}