WOLFRAM

Wolfram 语言与系统参考资料中心

EarthquakeData[loc]

给出了 loc 对应位置的全部地震信息.

EarthquakeData[loc,mag]

把返回的地震信息限制在震级范围 mag 之内.

EarthquakeData[loc,mag,{start,end}]

给出时间段 start 和 end 之间在震级范围 mag 之内的地震数据.

EarthquakeData[loc,mag,{start,end},property]

给出从 start 到 end 之间的时间段在震级范围 mag 之内的地震的指定 property 的时间序列.

EarthquakeData[entity,property]

返回指定地震的数据.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
位置  
标识符  
震级  
日期  
属性  
关联规范  
选项  
TimeZone  
应用  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

EarthquakeData

要获得对 Wolfram 知识库的一般访问权限，请使用 Earthquake 类型的实体而不是 EarthquakeData.

EarthquakeData[loc]

给出了 loc 对应位置的全部地震信息.

EarthquakeData[loc,mag]

把返回的地震信息限制在震级范围 mag 之内.

EarthquakeData[loc,mag,{start,end}]

给出时间段 start 和 end 之间在震级范围 mag 之内的地震数据.

EarthquakeData[loc,mag,{start,end},property]

给出从 start 到 end 之间的时间段在震级范围 mag 之内的地震的指定 property 的时间序列.

EarthquakeData[entity,property]

返回指定地震的数据.

更多信息和选项

  • 位置 loc 可以 GeoPosition、{lat,lon} 或 {{lat,lon},radius} 的形式给出. radius 可以是 Quantity 或一个数，后一种情况下假定是以米为单位的. 若没有给出 radius，就使用默认值 100 公里.
  • 位置也可以区域的形式给出，使用 Entity、GeoDisk、Polygon 和 Rectangle 设定.
  • 地震的标识符 entity 和它 "Identifier" 属性的值相同. 它由两位数的网络代码和该地震的识别号码组成. 不是所有的地震都有唯一的标识符.
  • 震级 mag 可被设定为单个的，表示最小震级的值或是 {mag1,mag2} 的形式来表示范围值. 这些值被假定标度的都是矩震级（简写为 MMS）.
  • 日期可以用 DateObject 或 DateList 格式指定.
  • 位置、震级、和日期可以一起以 Association["Location"->locationspec,"Magnitude"mag,"Date"datespec] 的形式指定.
  • 选项 TimeZone->z 允许假设不同的时区.
  • 可以使用下列设置：
  • 0UTC
    $TimeZone电脑系统使用的当前时区
    z比 UTC 偏移 z 个时区
  • EarthquakeData 返回的是关联 Association，以地震实体为键. 单独的属性也可以是内层关联的键.
  • EarthquakeData 的全部属性可以用 EarthquakeData["Properties"] 求得.
  • 可以指定的属性包括：
  • "AzimuthalGap"方位相邻观测站之间最大的方位角
    "Depth"地震深度的公里数
    "Identifier"地震的网络代码和事件标识符
    "Position"地震的经纬度
    "Magnitude"地震震级
  • 当属性被指定时，EarthquakeData 返回一个 EventSeries.
  • 其它可用一般查询访问到的属性包括：
  • "PositionMethod"用于确定位置的方法
    "Magnitude"地震的震级
    "MagnitudeType"用于测量震级的方法
    "NumberOfPhases"用于计算震源位置的 P 波和 S 波到达时间的观测数量
    "NumberOfStations"报告地震 P 波和 S 波到达时间的地震台站数量

范例

打开所有单元 关闭所有单元

基本范例  (3)

找出给定位置附近历史上的地震：

Wolfram Language code: data = EarthquakeData[GeoPosition[{45, -100}]];
Wolfram Language code: Keys[data]
Wolfram Language code: #["Period"]& /@ Values[data]

发现世界各地的强烈地震：

Wolfram Language code: data = EarthquakeData[All, 9];
Wolfram Language code: #["Magnitude"]& /@ Values[data]

探索某一区域地震的历史：

Wolfram Language code: data = EarthquakeData[Rectangle[{39, -85}, {42, -95}]];
Wolfram Language code: DateListPlot[Values[{#["Period"], #["Magnitude"]}& /@ data], Filling -> 0, Joined -> False]

范围  (14)

位置  (6)

搜索给定经纬度附近的地震：

Wolfram Language code: EarthquakeData[{45, -90}]

用（千米）数或 Quantity 指定搜索半径：

Wolfram Language code: EarthquakeData[{{40.11, -108.24}, Quantity[20, "Miles"]}]

Entity 可被用于找出给定位置附近的地震：

Wolfram Language code: data = EarthquakeData[Entity["Building", "EmpireStateBuilding"]];
Wolfram Language code: Length[data]

指定地震必须位于的经纬度范围：

Wolfram Language code: data = EarthquakeData[Rectangle[{40, -110}, {41, -111}]];
Wolfram Language code: #["Position"]& /@ Values[data]

利用 Polygon 给出三角形区域内所有已知的地震：

Wolfram Language code: pol = Polygon[GeoPosition[{{38.11, -100.24}, {42.11, -100.24}, {38.11, -109.24}}]];
Wolfram Language code: data = EarthquakeData[pol];
Wolfram Language code: GeoGraphics[{Gray, Opacity[0.5], pol, Red, Point[#["Position"]& /@ Values[data]]}]

GeoDisk 可被用于指定搜索区域：

Wolfram Language code: data = EarthquakeData[GeoDisk[{40.11, -108.24}, Quantity[100, "Miles"]]];
Wolfram Language code: Length[data]

标识符  (1)

找出各种地震的标识符：

Wolfram Language code: EarthquakeData[Rectangle[{33, 134}, {38, 138}], 4, {{2012, 1, 1}, {2012, 12, 31}}, "Identifier"]["Values"]

使用标识符，你可以直接查询特定的地震：

Wolfram Language code: EarthquakeData[Entity["Earthquake", "USc0007jku"], "Depth"]

震级  (2)

指定返回地震震级的下限：

Wolfram Language code: data = EarthquakeData[Polygon[GeoPosition[{{39, -85}, {39, -95}, {42, -95}, {42, -85}}]], 5];
Wolfram Language code: #["Magnitude"]& /@ data

把地震结果限制在指定的震级上下限之间：

Wolfram Language code: data = Values[EarthquakeData[{{38, -88}, Quantity[50, "Miles"]}, {4, 5}]];
Wolfram Language code: #["Magnitude"]& /@ data

日期  (1)

搜索指定日期范围内的地震：

Wolfram Language code: data = EarthquakeData[All, {6, 10}, {{2012, 12, 1}, {2013, 1, 1}}];
Wolfram Language code: DateListPlot[{#["Period"], #["Magnitude"]}& /@ data, Filling -> 0, Joined -> False]

属性  (2)

找出 EarthquakeData 的全部属性：

Wolfram Language code: EarthquakeData["Properties"]

检查地震的其它属性，如地震的记录深度：

Wolfram Language code: EarthquakeData[All, {8, 10}, {{2011, 1, 1}, {2013, 1, 1}}, "Depth"]

关联规范  (2)

日期、震级和位置可以一起用 Association 指定：

Wolfram Language code: EarthquakeData[Association["Location" -> Polygon[Entity["Country", "Japan"]], "Magnitude" -> 6, "Date" -> {{2002, 1, 1}, {2004, 1, 1}}]]

Association 设定也适用于属性参数：

Wolfram Language code: EarthquakeData[Association["Location" -> Polygon[Entity["Country", "Japan"]], "Magnitude" -> 6, "Date" -> {{2000, 1, 1}, {2005, 1, 1}}], "Depth"]

选项  (1)

TimeZone  (1)

找出发生在 2012 年 12 月 21 日的地震：

Wolfram Language code: data = EarthquakeData[All, {6, 10}, {{2012, 12, 21, 0, 0, 0}, {2012, 12, 22, 0, 0, 0}}]

默认情况下，按你所在时区给出日期，与 $TimeZone 给出的一样：

Wolfram Language code: data[[1, "Period"]]

用 TimeZone 选项指定输出日期对象的时区：

Wolfram Language code: EarthquakeData[All, {6, 10}, {{2012, 12, 21, 0, 0, 0}, {2012, 12, 22, 0, 0, 0}}, TimeZone -> 0][[1, "Period"]]

用 DateObject 指定控制输入中日期的时区：

Wolfram Language code: EarthquakeData[All, {6, 10}, {DateObject[{2012, 12, 22, 0, 0, 0}, TimeZone -> 5], DateObject[{2012, 12, 23, 0, 0, 0}, TimeZone -> 5]}, TimeZone -> 5][[1, "Period"]]

应用  (3)

检查日本地震的记录深度和震级：

Wolfram Language code: data = Values[EarthquakeData[Polygon[Entity["Country", "Japan"]], 5, {{2000, 1, 1}, {2013, 9, 20}}]]; depths = #["Depth"]& /@ data; magnitudes = #["Magnitude"]& /@ data;
Wolfram Language code: ListPlot[Transpose[{depths, magnitudes}], Axes -> False, Frame -> True, FrameLabel -> {"Depth", "Magnitude"}]

把记录的地震频率看作它们震级的函数：

Wolfram Language code: magnitudes = #["Magnitude"]& /@ Values[EarthquakeData[All, 5, {{1990, 1, 1}, {2013, 9, 20}}]];
Wolfram Language code: ListLogPlot[Transpose[{Range[5, 10, 0.25], BinCounts[magnitudes, {4.75, 10, 0.25}]}], Joined -> True]

比较欧洲首都城市 1980 年以来 100 公里范围内有记录的地震次数：

Wolfram Language code: cities = CountryData["Europe", "CapitalCity"];
Wolfram Language code: Grid[Reverse@SortBy[{#, Length[EarthquakeData[CityData[#, "Coordinates"], -1, {{1980, 1, 1}, {2013, 9, 20}}]]}& /@ cities, Last], Frame -> All]

巧妙范例  (4)

从 2011 年日本东北大地震的矩震级来计算地震矩 ：

Wolfram Language code: Mw = EarthquakeData[{38.3, 142.4}, {9, 10}, {{2011, 3, 10}, {2011, 3, 11}}, "Magnitude"]["Values"][[1]]

从 FormulaData 中提取 的公式：

Wolfram Language code: formulas = FormulaData[{"SeismicMoment", "RuptureArea"}]
Wolfram Language code: Solve[{formulas[[2]] /. {Subscript[M, w] -> Mw, Subscript[M, 0] -> M0}}, M0]

可视化在加利福尼亚州发生的地震的记录深度和位置：

Wolfram Language code: data = {#["Position"], #["Depth"]}& /@ Values[EarthquakeData[Polygon[Entity["AdministrativeDivision", {"California", "UnitedStates"}]], 4, {{1980, 1, 1}, {2013, 11, 20}}]];
Wolfram Language code: Graphics3D[{Opacity[0.6], Map[Append[Reverse[#], 0]&, EntityValue[Entity["AdministrativeDivision", {"California", "UnitedStates"}], "Polygon"] /.  GeoPosition -> Identity, {-2}], Blue, Opacity[1], Line[Apply[{Append[Reverse[First[#]], 0], Append[Reverse[First[#]], -(QuantityMagnitude[#2]/10)]}&, data, {1}]]}, Axes -> True]

在地图上标出全球范围内过去二十年有记录的主要地震：

Wolfram Language code: data = Values[EarthquakeData[All, 5, {{1990, 1, 1}, {1995, 9, 20}}]]; Length[data]
Wolfram Language code: pts = Normal[GroupBy[{Round@#["Magnitude"], #["Position"]}& /@ data, First, GeoPosition[#[[All, 2, 1]]]&]];
Wolfram Language code: GeoGraphics[ {Hue[0.7 (1 - #1 / 9)], PointSize[0.0007 #1], Point[#2]} & @@@ pts, GeoRange -> "World", ImageSize -> 500]

检查世界各地经计算得到的地震深度：

Wolfram Language code: depthpts = Normal[GroupBy[{Round@#["Depth"], #["Position"]}& /@ data, First, GeoPosition[#[[All, 2, 1]]]&]];
Wolfram Language code: Max[depthpts[[All, 1]]]
Wolfram Language code: GeoGraphics[{Hue[0.7 (1 - QuantityMagnitude[#1] / 700)], PointSize[0.006 QuantityMagnitude[#1] / 700], Point[#2]}&@@@pts, GeoRange -> "World", ImageSize -> 500]

检查加利福尼亚州及附近记录的地震：

Wolfram Language code: data = EarthquakeData[Entity["AdministrativeDivision", {"California", "UnitedStates"}], 4, {{1980, 1, 1}, {2013, 9, 20}}, "Position"]["Values"];
Wolfram Language code: GeoGraphics[{GeoStyling["ReliefMap"], Red, Point[data]}]
Wolfram Research (2014)，EarthquakeData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EarthquakeData.html.

文本

Wolfram Research (2014)，EarthquakeData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EarthquakeData.html.

CMS

Wolfram 语言. 2014. "EarthquakeData." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/EarthquakeData.html.

APA

Wolfram 语言. (2014). EarthquakeData. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EarthquakeData.html 年

BibTeX

@misc{reference.wolfram_2026_earthquakedata, author="Wolfram Research", title="{EarthquakeData}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/EarthquakeData.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_earthquakedata, organization={Wolfram Research}, title={EarthquakeData}, year={2014}, url={https://reference.wolfram.com/language/ref/EarthquakeData.html}, note=[Accessed: 04-September-2026]}