WOLFRAM

Wolfram 语言与系统参考资料中心

ElectricPotentialCondition[pred,vars,pars]

表示偏微分方程的电势表面边界条件，谓词 pred 指示其适用位置，并具有模型变量 vars 和全局参数 pars.

ElectricPotentialCondition[pred,vars,pars,lkey]

表示电势表面边界条件，其局部参数在 pars[lkey] 中指定.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
一维  
二维  
三维  
参见
技术笔记
相关指南
历史
按以下格式引用：

ElectricPotentialCondition

ElectricPotentialCondition[pred,vars,pars]

表示偏微分方程的电势表面边界条件，谓词 pred 指示其适用位置，并具有模型变量 vars 和全局参数 pars.

ElectricPotentialCondition[pred,vars,pars,lkey]

表示电势表面边界条件，其局部参数在 pars[lkey] 中指定.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

设置电势表面边界条件：

Wolfram Language code: ElectricPotentialCondition[x ≥ 0, {V[x, y], {x, y}}, <|"ElectricPotential" -> Subscript[V, s][x, y]|>]

设置默认电势表面边界条件：

Wolfram Language code: ElectricPotentialCondition[x ≥ 0, {V[x, y], {x, y}}, <||>]

计算模型变量 vars 和参数 pars 下的电势分布，其中左边界的电势 为 [TemplateBox[{InterpretationBox[, 1], "V", volts, "Volts"}, QuantityTF]] ，右边界为接地电势：

指定模型变量和静电参数.

Wolfram Language code: vars = {V[x], {x}}; pars = <|"RelativePermittivity" -> 2|>;

设置并求解静电偏微分方程：

Wolfram Language code: Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 10|>], ElectricPotentialCondition[x == 1 / 5, vars, pars, <|"ElectricPotential" -> 0|>]}}, V, x∈Line[{{0}, {1 / 5}}]];

可视化解：

Wolfram Language code: Plot[Vfun[x], {x, 0, 1 / 5}, AxesLabel -> {"x", "V"}]

范围  (4)

使用模型参数 pars 和多个特定参数边界条件定义静电分析的模型变量 vars：

Wolfram Language code: vars = {V[x, y], {x, y}}; pars = <|"RelativePermittivity" -> 1, "BoundaryCondition1" -> <|<|"ElectricPotential" -> V1|>|>, "BoundaryCondition2" -> <|<|"ElectricPotential" -> V2|>|>|>;
Wolfram Language code: ElectricPotentialCondition[x == 0, vars, pars, "BoundaryCondition1"]
Wolfram Language code: ElectricPotentialCondition[x == 1, vars, pars, "BoundaryCondition2"]

一维  (1)

计算距离 [TemplateBox[{InterpretationBox[, 1], "cm", centimeters, "Centimeters"}, QuantityTF]] 且垂直于 轴放置的两个平行板之间的电势分布. 左侧平板保持恒定电势 [TemplateBox[{InterpretationBox[, 1], "V", volts, "Volts"}, QuantityTF]]，而右侧平板接地， . 平板之间的区域具有相对介电常数 和均匀的电荷密度 [TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]]. 要在模型中使用的方程如下：

del .(-epsilon_0epsilon_r del V(x))^(︷^( electrostatic model)) =rho_v

设置静电模型变量 vars：

Wolfram Language code: vars = {V[x], {x}};

设置区域 ：

Wolfram Language code: Ω = Line[{{0}, {0.08}}];

指定静电模型参数：

Wolfram Language code: pars = <|"RelativePermittivity" -> 1, "VolumeChargeDensity" -> -10*^-8|>;

指定电势条件：

Wolfram Language code: Subscript[Γ, v] = {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 1|>], ElectricPotentialCondition[x == 0.08, vars, pars]}

建立方程：

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0

求解偏微分方程：

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, v]}, V, x∈Ω]

可视化解：

Wolfram Language code: Plot[Vfun[x], x∈Ω]

二维  (1)

求解导电率为 的三压开关中的电动标量电势. 模型中使用的方程为：

del .(-sigma del V(x,y))^(︷^( stationary current model)) =0

设置静电模型变量 vars：

Wolfram Language code: vars = {V[x, y], {x, y}};

设置区域 ：

Wolfram Language code: Ω = RegionUnion[Rectangle[{0, 2.5}, {10, 7.5}], Rectangle[{9, -2.5}, {10 + 9, 2.5}], Rectangle[{0, -7.5}, {10, -2.5}]];

指定导电率 :

Wolfram Language code: pars = <|"ElectricalConductivity" -> 6*^7|>;

指定下边界的地电位：

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[y == -7.5, vars, pars, <|"ElectricPotential" -> 0|>];

指定上边界的电动势为 [TemplateBox[{InterpretationBox[, 1], "V", volts, "Volts"}, QuantityTF]]：

Wolfram Language code: Subscript[Γ, potential] = ElectricPotentialCondition[y == 7.5, vars, pars, <|"ElectricPotential" -> 5|>];

求解 PDE：

Wolfram Language code: Vfun = NDSolveValue[{ElectricCurrentPDEComponent[vars, pars] == 0, Subscript[Γ, ground], Subscript[Γ, potential]}, V, {x, y}∈Ω];

计算电流密度矢量：

Wolfram Language code: Jfield = -6*^7 * Grad[Vfun[x, y], {x, y}];

可视化电流密度矢量：

Wolfram Language code: VectorPlot[Jfield, {x, y}∈Ω, AspectRatio -> Automatic]

三维  (1)

建立一个简化的变压器套管绝缘子模型，在与高压导体接触的内壁上设置电动势条件，在一个表面板（）上设置接地电势边界. 模型中使用的方程为：

del .(-epsilon_0epsilon_r del V(x,y,z))^(︷^( electrostatic model)) =0

设置静电模型变量 vars：

Wolfram Language code: vars = {V[x, y, z], {x, y, z}};

设置几何体：

Wolfram Language code: insulator = \!\(\*Graphics3DBox[«7»]\);

指定相对介电常数 ：

Wolfram Language code: pars = <|"RelativePermittivity" -> 5|>;

指定表面的接地电位 ：

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[z == 0.2, vars, pars, <|"ElectricPotential" -> 0|>];

指定内壁的电动势为 [TemplateBox[{InterpretationBox[, 1], "V", volts, "Volts"}, QuantityTF]]：

Wolfram Language code: Subscript[Γ, potential] = ElectricPotentialCondition[x ^ 2 + y ^ 2 <= 0.2 ^ 2, vars, pars, <|"ElectricPotential" -> 10 ^ 3|>];

建立方程：

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0;

求解偏微分方程：

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, ground], Subscript[Γ, potential]}, V, {x, y, z}∈insulator]

可视化解：

Wolfram Language code: Legended[RegionPlot3D[insulator, ColorFunction -> Function[{x, y, z}, ColorData[{"Rainbow", MinMax[Vfun["ValuesOnGrid"]]}][Vfun[x, y, z]]], ...], BarLegend[...]]
Wolfram Research (2024)，ElectricPotentialCondition，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ElectricPotentialCondition.html （更新于 2024 年）.

文本

Wolfram Research (2024)，ElectricPotentialCondition，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ElectricPotentialCondition.html （更新于 2024 年）.

CMS

Wolfram 语言. 2024. "ElectricPotentialCondition." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/ElectricPotentialCondition.html.

APA

Wolfram 语言. (2024). ElectricPotentialCondition. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ElectricPotentialCondition.html 年

BibTeX

@misc{reference.wolfram_2026_electricpotentialcondition, author="Wolfram Research", title="{ElectricPotentialCondition}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/ElectricPotentialCondition.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_electricpotentialcondition, organization={Wolfram Research}, title={ElectricPotentialCondition}, year={2024}, url={https://reference.wolfram.com/language/ref/ElectricPotentialCondition.html}, note=[Accessed: 09-September-2026]}