WOLFRAM

Wolfram 语言与系统参考资料中心

ElementData["name","property"]

给出化学元素 "name" 的指定属性的值.

ElementData[n,"property"]

给出第 n 个化学元素的指定属性.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
名称和类型  
属性和注解  
属性值  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

ElementData

如果想要访问 Wolfram 知识库，请使用 Element 类型的实体而不是 ElementData.

ElementData["name","property"]

给出化学元素 "name" 的指定属性的值.

ElementData[n,"property"]

给出第 n 个化学元素的指定属性.

更多信息

  • 化学元素可以利用其全称、标准简称或原子序数指定.
  • ElementData[] 给出由所有标准化学元素组成的列表.
  • ElementData[n] 给出第 n 个化学元素的全称.
  • ElementData["Properties"] 给出化学元素现有的全部属性的列表.
  • 在一个特定情况中不适用或未知的属性由 Missing[…] 指明.
  • 只具有特定精度的数值通常使用精度作为标签，并且以任意精度格式给出.
  • 基本元素的属性包括：
  • "AtomicNumber"原子序数
    "AtomicWeight"以原子量单位表示的平均原子质量
  • 如果未指定其它温度或压强，所有宏观性质均采用常温常压下的性质. 如果适用，均采用元素在常温常压下最稳定形式的性质.
  • 材料性质包括：
  • "BrinellHardness"布氏刻痕硬度
    "BulkModulus"体积弹性模量（非压缩性）
    "Density"常温常压下的密度
    "LiquidDensity"熔点液体密度
    "MohsHardness"莫氏耐擦伤性
    "MolarVolume"摩尔体积
    "PoissonRatio"固体的泊松比
    "ShearModulus"固体的切变模数
    "SoundSpeed"声速
    "ThermalConductivity"热导率
    "ThermalExpansion"线性热膨胀系数
    "VickersHardness"维氏刻痕硬度
    "YoungModulus"固体的杨氏模量
  • 热力性质包括：
  • "AbsoluteBoilingPoint"沸点温度（单位为开尔文）
    "AbsoluteMeltingPoint"熔点温度（单位为开尔文）
    "AdiabaticIndex"气体绝热指数
    "BoilingPoint"摄氏沸点温度
    "CriticalPressure"液-气临界点压强
    "CriticalTemperature"液-气临界点温度
    "CuriePoint"铁磁－顺磁相变点的居里温度
    "FusionHeat"固－液相变潜热
    "MeltingPoint"摄氏熔点温度
    "NeelPoint"反铁磁－顺磁体相变点的奈耳温度
    "Phase"原生态 (例如 "Solid")
    "SpecificHeat"比热容
    "SuperconductingPoint"超导相变温度（单位为开尔文）
    "VaporizationHeat"液－气相变潜热
  • 电磁和光学性质包括：
  • "Color"颜色
    "ElectricalConductivity"电导率
    "ElectricalType"导电类型 (例如 "Insulator")
    "MagneticType"磁性类型 (例如 "Paramagnetic")
    "MassMagneticSusceptibility"质量磁化率
    "MolarMagneticSusceptibility"摩尔磁化率
    "RefractiveIndex"可见光折射率
    "Resistivity"固体电阻率
    "VolumeMagneticSusceptibility"体磁化率
  • 丰度性质包括 (按质量分数)：
  • "CrustAbundance"地壳丰度
    "HumanAbundance"典型人体丰度
    "MeteoriteAbundance"碳质陨石丰度观测值
    "OceanAbundance"海洋丰度
    "SolarAbundance"太阳中丰度
    "UniverseAbundance"宇宙丰度观测值
  • 周期表属性包括：
  • "Block"填充的最外电子子壳层的标记
    "Group"周期表中的列
    "Period"周期表中的行 (电子壳层数)
    "Series"命名的元素系列 (例如 "AlkaliMetals")
  • 基本化学性质包括：
  • "AllotropicMultiplicities"同素异型分子中的原子数量
    "CommonCompoundNames"常见化合物的名称
    "ElectronAffinity"电子亲和力
    "Electronegativity"泡令电负性
    "GasAtomicMultiplicities"气相分子中的原子数
    "Valence"通常形成的化学键数量
  • 最稳定固相结晶属性包括：
  • "CrystalStructure"基本晶格结构
    "LatticeAngles"晶轴之间的角度
    "LatticeConstants"晶格常数
    "SpaceGroupNumber"国际空间群数表
    "SpaceGroup"空间群符号
  • 原子属性包括：
  • "AtomicRadius"最外层电子到核的计算距离
    "CovalentRadius"一对键接的原子，核之间距离的一半
    "ElectronConfiguration"各电子子壳层的填充数
    "ElectronConfigurationString"以标准记法表示的电子排布
    "ElectronShellConfiguration"各完整能壳的填充数
    "IonizationEnergies"各电子的电离能的列表
    "QuantumNumbers"基态角动量量子数
    "VanDerWaalsRadius"球形原子间相互作用范围
  • 核属性包括：
  • "DecayMode"最长寿命同位素的主导衰变类型
    "IsotopeAbundances"稳定同位素的质量数和丰度列表
    "IsotopeHalfLives"所有已知同位素的半衰期
    "IsotopeLifetimes"所有已知同位素的指数形式寿命
    "KnownIsotopes"所有已知同位素的原子质量数
    "MolarRadioactivity"每摩尔放射性
    "NeutronCrossSection"以靶恩为单位的热中子截面
    "NeutronMassAbsorption"热中子质量吸收系数
    "SpecificRadioactivity"特定的放射性
    "StableIsotopes"稳定同位素的原子质量数
  • 与名称相关的属性包括：
  • "Abbreviation"标准元素缩写 (例如 "Na")
    "Allotropes"同素异形体名称 (例如 "Graphite")
    "AlternateNames"其它名称 (例如 "Aluminium")
    "CASNumber"美国化学文摘社注册号
    "IconColor"Wolfram 语言分子图形图谱色
    "Name"英语名称 (例如 "hydrogen")
    "StandardName"标准 Wolfram 语言名称 (例如 "Hydrogen")
  • 历史和商业属性包括：
  • "DiscoveryCountries"发现元素的国家
    "DiscoveryYear"元素被发现的年份
  • ElementData["class"] 给出一个指定类别的元素列表. ElementData[name,"class"] 根据与 name 相应的元素是否在指定类别中给出 True 或 False.
  • 元素类别包括：
  • "Actinide"锕系元素
    "AlkaliMetal"碱金属
    "Gas"常温常压下的气体
    "Lanthanide"镧系元素
    "Liquid"常温常压下的液体
    "Ferromagnetic"常温常压下的铁磁体
    "Metal"金属
    "Metalloid"类金属
    "Natural"原生态
    "Nonmetal"非金属
    "NobleGas"惰性气体
    "Radioactive"所有形式的放射性元素
    "Solid"常温常压下的固体
    "Stable"放射性衰变稳定元素
    "Synthetic"人工合成元素
  • ElementData["name","property","ann"] 给出与属性相关的各种注释. 典型注释包括：

范例

打开所有单元 关闭所有单元

基本范例  (3)

找出碳的原子量：

Wolfram Language code: ElementData["Carbon", "AtomicWeight"]

查找钨的热导率 (国际单位制)：

Wolfram Language code: ElementData["Tungsten", "ThermalConductivity"]

查找单位：

Wolfram Language code: ElementData["Tungsten", "ThermalConductivity", "Units"]

绘出作为原子量函数的元素熔点（单位为摄氏度）：

Wolfram Language code: ListLinePlot[Table[ElementData[z, "MeltingPoint"], {z, 118}]]

范围  (17)

名称和类型  (7)

获得以原子序数排列的所有元素列表：

Wolfram Language code: ElementData[]
Wolfram Language code: Length[%]

找出一个元素的英语名称：

Wolfram Language code: ElementData["Tungsten", "Name"]

也可以找出其他名称的列表：

Wolfram Language code: ElementData["Tungsten", "AlternateNames"]

一个元素可以用其标准 Wolfram 语言名称、原子序数或缩写名称指定：

Wolfram Language code: ElementData["Gold", "AtomicNumber"]
Wolfram Language code: ElementData[79, "Abbreviation"]
Wolfram Language code: ElementData["Au", "StandardName"]

能够找到可以作为输入的其它名称：

Wolfram Language code: ElementData["Tungsten", "AlternateStandardNames"]
Wolfram Language code: ElementData["Wolfram", "StandardName"]

找出元素类别的列表：

Wolfram Language code: ElementData["Classes"]

找出属于某个类别的元素列表：

Wolfram Language code: ElementData["Gas"]
Wolfram Language code: ElementData["Radioactive"]

检验一个元素是否属于某个类别：

Wolfram Language code: ElementData["Na", "Halogen"]

属性和注解  (5)

得到一个特定元素的属性列表：

Wolfram Language code: Short[CanonicalName@ElementData["Helium", "Properties"], 4]

得到一个属性的简短文字描述：

Wolfram Language code: ElementData["Ag", "ElectronConfiguration", "Description"]

得到一个较长的文字描述：

Wolfram Language code: ElementData["Ag", "ElectronConfiguration", "LongDescription"]

找出一个属性值使用的单位：

Wolfram Language code: ElementData["Carbon", "Density"]
Wolfram Language code: ElementData["C", "Density", "Units"]

得到普通文字形式的单位：

Wolfram Language code: ElementData["C", "Density", "UnitsName"]

得到符号形式的单位：

Wolfram Language code: ElementData["C", "Density", "UnitsNotation"]

不确定性用 Interval 表示：

Wolfram Language code: ElementData["Oxygen", "AtomicWeight"]
Wolfram Language code: ElementData["Oxygen", "AtomicWeight", "Interval"]

找出有关属性的附加说明：

Wolfram Language code: ElementData["C", "ElectricalType"]
Wolfram Language code: ElementData["C", "ElectricalType", "Note"]

属性值  (5)

属性值可以是任意有效的 Wolfram 语言表达式：

Wolfram Language code: ElementData["Chlorine", "BoilingPoint"]
Wolfram Language code: ElementData["Pb", "Phase"]
Wolfram Language code: ElementData["Oxygen", "KnownIsotopes"]

用 Precision 找出某个属性的有效数字位数：

Wolfram Language code: ElementData["C", "AtomicWeight"]
Wolfram Language code: Precision[%]

对某个元素不适用的属性的值为 Missing["NotApplicable"]：

Wolfram Language code: ElementData["Helium", "MeltingPoint"]

对某个元素不存在的属性的值为 Missing["NotAvailable"]：

Wolfram Language code: ElementData["F", "SoundSpeed"]

一个元素未知的属性的值为 Missing["Unknown"]：

Wolfram Language code: ElementData["Neptunium", "LiquidDensity"]

推广和延伸  (1)

求出与一个字符串表达式匹配的元素名称列表：

Wolfram Language code: ElementData["H*"]

应用  (6)

显示蒸发热与沸点之间的线性关系：

Wolfram Language code: ListPlot[Table[{ElementData[z, "AbsoluteBoilingPoint"], ElementData[z, "VaporizationHeat"]}, {z, 118}]]

绘制元素的原子半径，该图显示出电子壳层结构的影响：

Wolfram Language code: ListPlot[Table[ElementData[z, "AtomicRadius"], {z, 118}]]

绘制各元素稳定同位素的数目：

Wolfram Language code: ListLinePlot[Table[Length[ElementData[z, "StableIsotopes"]], {z, 108}]]

绘制所有稳定同位素的原子质量：

Wolfram Language code: With[{isotopes = Flatten[ElementData[All, "StableIsotopes"]]}, ListPlot[EntityValue[isotopes, {"AtomicNumber", "AtomicMass"}], AxesLabel -> {"Z", "M"}] ]

生成一个有附加说明的临界温度和临界压强的列表：

Wolfram Language code: adata = Table[Callout[{ElementData[z, "CriticalTemperature"], ElementData[z, "CriticalPressure"]}, Row[{ElementData[z], " (", ElementData[z, "Abbreviation"], ")"}]], {z, 118}];

用附加说明产生绘图标签：

Wolfram Language code: ListPlot[adata, Frame -> True, FrameLabel -> {ElementData[1, "CriticalTemperature", "Description"], ElementData[1, "CriticalPressure", "Description"]}]

绘制基本周期表，用色码标记固体、液体和气体：

Wolfram Language code: Graphics[Table[If[Head[ElementData[z, "Group"]] =!= Missing, Inset[Style[Pane[ElementData[z, "Abbreviation"], {20, 20}], Background -> (ElementData[z, "Phase"] /. {Entity["MatterPhase", "Solid"] -> StandardBrown, Entity["MatterPhase", "Liquid"] -> StandardBlue, Entity["MatterPhase", "Gas"] -> StandardYellow, _ -> StandardGray})], {ElementData[z, "Group"], -ElementData[z, "Period"]}], {}], {z, 108}]]

属性和关系  (9)

用 Table 获得所有元素属性值的列表：

Wolfram Language code: pv1 = Table[ElementData[z, "BoilingPoint"], {z, 118}];

用 Map 做同样的事：

Wolfram Language code: pv2 = ElementData[#, "BoilingPoint"]& /@ ElementData[];
Wolfram Language code: pv1 == pv2

形成某一类别的元素的一个属性值列表：

Wolfram Language code: i = ElementData["Insulator"]
Wolfram Language code: g = {#, ElementData[#, "Resistivity"]}& /@ i

用 Grid 以格式化表格形式显示数据：

Wolfram Language code: Grid[g, Frame -> True, Alignment -> {Left}]

用 DeleteCases 过滤出没有缺失的元素：

Wolfram Language code: DeleteCases[Table[{ElementData[z], ElementData[z, "CuriePoint"]}, {z, 118}], {_, _Missing}]

用 ListPlot 绘出一个属性值列表的图：

Wolfram Language code: ListPlot[Table[ElementData[z, "Density"], {z, 118}], PlotRange -> All]

在数据跨越几个数量级时使用 ListLogPlot：

Wolfram Language code: ListLogPlot[Table[ElementData[z, "UniverseAbundance"], {z, 118}], Joined -> True]

用 LatticeData 获得固体结构详细信息：

Wolfram Language code: ElementData["Titanium", "CrystalStructure"]
Wolfram Language code: %["Image"]
Wolfram Language code: LatticeData[{"Bravais", {"Tetragonal", "BodyCentered"}}, "Properties"]

利用 IsotopeData 获得同位素详细信息：

Wolfram Language code: ElementData["Rubidium", "KnownIsotopes"]
Wolfram Language code: IsotopeData["Rubidium84", "Properties"]

用 ChemicalData 获得元素化合物的属性：

Wolfram Language code: ChemicalData["PalladiumCompound"]

分子式：

Wolfram Language code: ChemicalData["Caffeine", "Formula"]

元素统计：

Wolfram Language code: ChemicalData["Caffeine", "ElementTally"]

三维结构绘图：

Wolfram Language code: ChemicalData["Caffeine", "MoleculePlot"]

显示用于标记元素的颜色：

Wolfram Language code: ColorData["Atoms", "Panel"]
Wolfram Language code: ElementData["Osmium", "IconColor"]

可能存在的问题  (2)

不能使用非标准元素和属性名称：

Wolfram Language code: ElementData["hydrogen", "Density"]
Wolfram Language code: ElementData["Carbon", "melting point"]

用字符串函数查找标准化名称：

Wolfram Language code: Select[ElementData[], StringMatchQ[CanonicalName[#], ___ ~~ "hydrogen" ~~ ___, IgnoreCase -> True]&]
Wolfram Language code: ElementData["Hydrogen", "Density"]
Wolfram Language code: Select[ElementData["Carbon", "Properties"], StringMatchQ[CanonicalName[#], ___ ~~ "melting" ~~ ___, IgnoreCase -> True]&]
Wolfram Language code: ElementData["Carbon", "MeltingPoint"]

不能在 Missing 项上执行算术运算：

Wolfram Language code: 72 Table[ElementData[i, "Resistivity"], {i, 10}]

在执行运算前去消除 Missing 项：

Wolfram Language code: DeleteCases[Table[ElementData[i, "Resistivity"], {i, 10}], _Missing]
Wolfram Language code: 72 %

巧妙范例  (3)

依次绘制各元素的发现年份：

Wolfram Language code: ListLinePlot[Table[ElementData[z, "DiscoveryDate"] /. d_DateObject :> d["Year"], {z, 1, 108}]]

找出每个国家发现元素的数量：

Wolfram Language code: SortBy[Tally[Flatten[Table[ElementData[z, "DiscoveryCountries"], {z, 1, 108}]]], Last]

制作元素 3 种属性的表格：

Wolfram Language code: tab = Table[({1, 1, 100}(QuantityMagnitude[ElementData[z, #]]& /@ {"Density", "BoilingPoint", "ThermalConductivity"})) -> ElementData[z], {z, 1, 80}];

根据属性值把元素集中分成 10 个组：

Wolfram Language code: FindClusters[tab, 10]
Wolfram Research (2007)，ElementData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ElementData.html （更新于 2014 年）.

文本

Wolfram Research (2007)，ElementData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ElementData.html （更新于 2014 年）.

CMS

Wolfram 语言. 2007. "ElementData." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/ElementData.html.

APA

Wolfram 语言. (2007). ElementData. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ElementData.html 年

BibTeX

@misc{reference.wolfram_2026_elementdata, author="Wolfram Research", title="{ElementData}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ElementData.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_elementdata, organization={Wolfram Research}, title={ElementData}, year={2014}, url={https://reference.wolfram.com/language/ref/ElementData.html}, note=[Accessed: 08-September-2026]}