EllipticF

EllipticF[ϕ,m]

第1種楕円積分を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
実数について，かつのとき， $TemplateBox[{phi, m}, EllipticF]=int_0^phi(1-m sin^2(theta))^(-1/2)dtheta$ が成り立つ．
EllipticFに関する完全楕円積分は，EllipticKである．
EllipticFは実数引数についてJacobiAmplitudeの逆関数である．のとき，についてである．
EllipticF[ϕ,m]は，およびで分枝が不連続となる．
特別な引数の場合，EllipticFは，自動的に厳密値を計算する．
EllipticFは任意の数値精度で評価できる．
EllipticFは自動的にリストに縫い込まれる．
EllipticFはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開くすべて閉じる

例 (4)

数値的に評価する：

Wolfram Language code: EllipticF[0.3, 0.8]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[EllipticF[ϕ, 0.5], {ϕ, 0, Pi / 2}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[EllipticF[z, 0.5], {z, -2 - 2 I, 2 + 2 I}, PlotLegends -> Automatic, Exclusions -> All]

原点における級数展開：

Wolfram Language code: Series[EllipticF[ϕ, m], {ϕ, 0, 8}]

スコープ (36)

数値評価 (5)

複素引数について評価する：

Wolfram Language code: EllipticF[3 + 2.5 I, 2.3 - 1.5 I]

高精度で評価する：

Wolfram Language code: N[EllipticF[12 / 5, 3], 50]

出力精度は入力精度に従う：

Wolfram Language code: EllipticF[2, 0.9999999999999999990000000000000000000]

Wolfram Language code: EllipticF[2, 0.9999999999999999990000000000000000000000000000000000]

EllipticFを高精度で効率よく評価する：

Wolfram Language code: EllipticF[2, 0.4`500]//Timing

Wolfram Language code: EllipticF[2, 0.4`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: EllipticF[0.2, Interval[{0.3, 0.4}]]

Wolfram Language code: EllipticF[1, CenteredInterval[-4, 1 / 10]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: EllipticF[ Around[2, 0.01], 1 / 2]

配列の要素ごとの値を計算する：

Wolfram Language code: EllipticF[{{1, 0}, {0, 1}}, 0]

MatrixFunctionを使って行列のEllipticF関数を計算することもできる：

Wolfram Language code: MatrixFunction[EllipticF[#, 0]&, {{1, 0}, {0, 1}}]

特定の値 (5)

簡単な厳密値は自動的に生成される：

Wolfram Language code: EllipticF[ϕ, 0]

Wolfram Language code: {EllipticF[0, m], EllipticF[Pi / 2, m]}

無限大における値：

Wolfram Language code: EllipticF[ϕ, Infinity]

分岐点における極限値：

Wolfram Language code: Limit[EllipticF[2 + ε I, 2], ε -> 0, Direction -> -1]

Wolfram Language code: Limit[EllipticF[2 + ε I, 2], ε -> 0, Direction -> +1]

方程式の根を求める：

Wolfram Language code:

f[m_] := EllipticF[π, m] - 3;
xzero = Solve[f[m] == 0 && -1.0 < m < 0, m][[1, 1, 2]]//Quiet

Wolfram Language code: Plot[f[m], {m, -1, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

EllipticFは，その第1パラメータに対して奇関数である：

Wolfram Language code: EllipticF[-ϕ, m]

可視化 (3)

パラメータのさまざまな値について楕円積分をプロットする：

Wolfram Language code: Plot[{EllipticF[ϕ, 0], EllipticF[ϕ, 1], EllipticF[ϕ, 2]}, {ϕ, -2, 2}]

楕円積分をそのパラメータの関数としてプロットする：

Wolfram Language code:

Plot[{EllipticF[π, m], EllipticF[π / 2, m], EllipticF[-π / 2, m], EllipticF[-π, m]}, {m, -10, 2}, IconizedObject[«PlotOptions»]]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[EllipticF[z, 1]], {z, -π / 2 - I π / 2 , π / 2 + I π / 2}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[EllipticF[z, 1]], {z, -π / 2 - I π / 2 , π / 2 + I π / 2}, IconizedObject[«PlotOptions»]]

関数の特性 (10)

はすべての実数について定義される：

Wolfram Language code: FunctionDomain[EllipticF[ϕ, 0.5], ϕ]

はすべての実数値を取る：

Wolfram Language code: FunctionRange[EllipticF[ϕ, 0.5], ϕ, y]//Quiet

EllipticFはその第1パラメータについての奇関数である：

Wolfram Language code: EllipticF[-ϕ, m]

はの解析関数である：

Wolfram Language code: FunctionAnalytic[EllipticF[ϕ, .5], ϕ]

特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[EllipticF[ϕ, .5], ϕ]//Quiet

Wolfram Language code: FunctionDiscontinuities[EllipticF[ϕ, .5], ϕ]//Quiet

はおよびの有理関数ではない：

Wolfram Language code: FunctionMeromorphic[EllipticF[n, m], {n, m}]

は実数領域上で非減少ではない：

Wolfram Language code: FunctionDomain[EllipticF[ϕ, 2], ϕ]

Wolfram Language code: FunctionMonotonicity[{EllipticF[ϕ, 2], -(π/4) ≤ ϕ ≤ (π/4)}, ϕ]//Quiet

は単射である：

Wolfram Language code: FunctionInjective[EllipticF[ϕ, 2], ϕ]

Wolfram Language code: Plot[{EllipticF[ϕ, 2], .5}, {ϕ, -π / 2, π / 2}]

は全射ではない：

Wolfram Language code: FunctionSurjective[EllipticF[ϕ, 2], ϕ]

Wolfram Language code: Plot[{EllipticF[ϕ, 2], 2}, {ϕ, -π, π}]

は非負でも非正でもない：

Wolfram Language code: FunctionSign[{EllipticF[ϕ, 2], -(π / 4) <= ϕ <= π / 4}, ϕ]

は凸でも凹でもない：

Wolfram Language code: FunctionConvexity[{EllipticF[ϕ, 2], -(π / 4) <= ϕ <= π / 4}, ϕ]

微分 (3)

一次導関数：

Wolfram Language code: D[EllipticF[ϕ, m], ϕ]

高次導関数：

Wolfram Language code: derivs = Table[D[EllipticF[ϕ, m], {ϕ, n}], {n, 1, 3}]//FullSimplify

についての高次導関数をプロットする：

Wolfram Language code:

Plot[Evaluate[derivs /. m -> 1], {ϕ, -π / 2, π / 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

パラメータについて導関数する：

Wolfram Language code: D[EllipticF[ϕ, m], m]

積分 (3)

EllipticFの不定積分：

Wolfram Language code: Integrate[EllipticF[ϕ, m], m]

原点を中心とした区間上の奇関数の定積分は0である：

Wolfram Language code: Integrate[EllipticF[ϕ, m], {ϕ, -1, 1}]

その他の積分例：

Wolfram Language code: Integrate[Sin[z]EllipticF[z, m] , z]

Wolfram Language code: Integrate[( Sin[2 z]EllipticF[z, m]/(1 - m Sin[z]^2)^3 / 2), z]

級数展開 (3)

EllipticFのテイラー(Taylor)展開：

Wolfram Language code: Series[EllipticF[ϕ, m], {ϕ, 0, 5}]

の周囲のの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[EllipticF[ϕ, 1], {ϕ, 0, n}], {n, 1, 5, 2}];
Plot[{EllipticF[ϕ, 1], terms}, {ϕ, -2, 2}]

モジュールについての級数における展開：

Wolfram Language code: Series[EllipticF[ϕ, m], {m, 0, 3}]

の周りのの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[EllipticF[π, m], {m, 0, n}], {n, 1, 3}];
Plot[{EllipticF[π, m], terms}, {m, -1, 1}, PlotLegends -> "Expressions"]

EllipticFはベキ級数に適用できる：

Wolfram Language code: EllipticF[ϕ + (ϕ^2/2) + (ϕ^3/3) + O[ϕ]^4, m]

Wolfram Language code: EllipticF[ϕ, m + (m^2/2) + (m^3/3) + O[m]^4]

関数表現 (4)

第2種楕円積分の定義：

Wolfram Language code: Integrate[(1/Sqrt[1 - m Sin[θ] ^ 2]), {θ, 0, ϕ}, Assumptions -> 0 ≤ ϕ ≤ π / 2]

EllipticPiとの関係：

Wolfram Language code: EllipticPi[0, ϕ, m]

EllipticFはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[EllipticF[ϕ, m], m]

TraditionalFormによる表示：

Wolfram Language code: EllipticF[ϕ, m] // TraditionalForm

アプリケーション (5)

楕円積分を行う：

Wolfram Language code: Integrate[(1/Sqrt[a x^4 + b]), x]

複素平面上で不完全楕円積分をプロットする：

Wolfram Language code: Plot3D[Im[EllipticF[x + I y, 1 / 2]], {x, -2Pi, 2Pi}, {y, -3, 3}]

3軸の楕円の表面積を計算する：

Wolfram Language code:

area[a_, b_, c_] := With[{m = (a^2(b^2 - c^2)/b^2(a^2 - c^2)), ϑ = ArcSin[Sqrt[1 - (c^2/a^2)]]}, 2 π((b c^2 /Sqrt[a^2 - c^2])EllipticF[ϑ, m] + c^2 + b Sqrt[a^2 - c^2] EllipticE[ϑ, m])] /; a > b > c;

半軸が3，2，1の楕円の面積：

Wolfram Language code: area[3, 2, 1]//N

微分表面要素を積分して体積を計算する：

Wolfram Language code:

With[{a = 3, b = 2, c = 1}, NIntegrate[Sin[ϑ]Sqrt[b^2c^2Cos[φ]^2Sin[ϑ]^2 + a^2c^2Sin[φ]^2Sin[ϑ]^2 + a^2b^2Cos[ϑ]^2], {φ, 0, 2Pi}, {ϑ, 0, Pi}]]

曲率の二乗の積分を最小にする曲線の弧の長さのパラメータ化：

Wolfram Language code: DSolve[s'[φ] == -(c/Sqrt[Cos[φ]]), s[φ], φ]

マイラー(Mylar)樹脂製の風船（2つの平たいプラスチックシートの周囲を縫い合わせ，膨らませたもの）のパラメータ化：

Wolfram Language code:

x[u_, v_] := (Cos[v]/Sqrt[Cosh[2u]])
y[u_, v_] := (Sin[v]/Sqrt[Cosh[2u]])
z[u_, v_] := With[{f = ArcSin[(Sqrt[2]Sinh[u]/Sqrt[Cosh[2u]])]}, Sqrt[2](EllipticE[f, (1/2)] - (1/2)EllipticF[f, (1/2)])]

結果の風船をプロットする：

Wolfram Language code: ParametricPlot3D[{x[u, v], y[u, v], z[u, v]}, {v, 0, 2Pi}, {u, -8, 8}, PlotRange -> All]

主曲率の割合を計算する：

Wolfram Language code:

Block[{h, g}, h[u_] = x[u, v] / Cos[v];g[u_] = z[u, v];(((g''[u]h'[u] - g'[u]h''[u]/(g'[u]^2 + h'[u]^2)^3 / 2))/((g'[u]/h[u]Sqrt[g'[u]^2 + h'[u]^2])))//Simplify]

もとのシートの半径を膨らませた風船の半径で表す：

Wolfram Language code: Module[{h, g}, h[u_] = x[u, v] / Cos[v];g[u_] = z[u, v];Integrate[Sqrt[h'[u]^2 + g'[u]^2]//Simplify, {u, 0, ∞}]]

Wolfram Language code: N[%, $MachinePrecision]

特性と関係 (7)

EllipticF[ϕ,m]は，以下の制約条件のもとで，実数引数については実数値である：

Wolfram Language code: FunctionDomain[EllipticF[ϕ, m], {ϕ, m}, Reals]

特殊形を展開する：

Wolfram Language code: EllipticF[ArcCsc[Sqrt[m]], m]//FunctionExpand

特殊形を引数に制限を付けて展開する：

Wolfram Language code: EllipticF[z, 1]//FunctionExpand

Wolfram Language code: FunctionExpand[%, 0 < z < Pi / 2]

逆関数を伴う合成にはPowerExpandが必要である：

Wolfram Language code: EllipticF[JacobiAmplitude[z, m], m]

Wolfram Language code: PowerExpand[%]

Wolfram Language code: JacobiAmplitude[EllipticF[z, m], m]

Wolfram Language code: PowerExpand[%]

EllipticFを含む方程式を解く：

Wolfram Language code: Solve[EllipticF[z, m]^3 + EllipticF[z, m] == x, z]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[EllipticF[z, 2]^3 + EllipticF[z, 2] + z == 2, {z, 1}]

分枝切断線における極限：

Wolfram Language code: Limit[EllipticF[2 + ε I, 2], ε -> 0, Direction -> -1]//Quiet

Wolfram Language code: Limit[EllipticF[2 + ε I, 2], ε -> 0, Direction -> +1]//Quiet

でならである：

Wolfram Language code:

With[{m = 1 / 3}, {ParametricPlot[{ϕ, EllipticF[ϕ, m]}, {ϕ, -2Pi, 2Pi}, PlotStyle -> Thick], ParametricPlot[{JacobiAmplitude[u, m], u}, {u, -4 EllipticK[m], 4EllipticK[m]}, PlotStyle -> Directive[Dashed, Orange]]}]

Wolfram Language code: Show[%, ImageSize -> Tiny]

のときはについてのみ真である：

Wolfram Language code:

With[{m = 4}, {ParametricPlot[{ϕ, EllipticF[ϕ, m]}, {ϕ, -ArcSin[m^-1 / 2], ArcSin[m^-1 / 2]}, PlotStyle -> Thick], ParametricPlot[{JacobiAmplitude[u, m], u}, {u, -(1/Sqrt[m])EllipticK[1 / m], (1/Sqrt[m])EllipticK[1 / m]}, PlotStyle -> Directive[Dashed, Orange]]}]

Wolfram Language code: Show[%, ImageSize -> Tiny]

考えられる問題 (2)

定義積分は，追加的な条件があるときにのみ収束する：

Wolfram Language code: Integrate[(1/Sqrt[1 - m Sin[t]^2]), {t, 0, z}]

第2引数には別の約束事が存在する：

Wolfram Language code: Integrate[1 / Sqrt[1 - k ^ 2 Sin[t] ^ 2], {t, 0, z}, Assumptions -> 0 < k < 1 && 0 < z < 1]

Wolfram Language code: Integrate[1 / Sqrt[(1 - t ^ 2) (1 - m t ^ 2)], {t, 0, z}, Assumptions -> 0 < m < 1 && 0 < z < 1]

おもしろい例題 (2)

ネストした導関数：

Wolfram Language code: NestList[D[#, x]&, EllipticF[x, m], 4]//Simplify//TraditionalForm

EllipticFを整数点でプロットする：

Wolfram Language code: ArrayPlot[Table[Mod[Round[Abs[EllipticF[x y, 0.3]]], 2], {x, -50, 50}, {y, -50, 50}]]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

EllipticF

詳細

例題

例 (4)

スコープ (36)

数値評価 (5)

特定の値 (5)

可視化 (3)

関数の特性 (10)

微分 (3)

積分 (3)

級数展開 (3)

関数表現 (4)

アプリケーション (5)

特性と関係 (7)

考えられる問題 (2)

おもしろい例題 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

EllipticF

詳細

例題

例 (4)

スコープ (36)

数値評価 (5)

特定の値 (5)

可視化 (3)

関数の特性 (10)

微分 (3)

積分 (3)

級数展開 (3)

関数表現 (4)

アプリケーション (5)

特性と関係 (7)

考えられる問題 (2)

おもしろい例題 (2)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX