WOLFRAM

Wolfram 语言与系统参考资料中心

EllipticF[ϕ,m]

给出第一类椭圆积分 TemplateBox[{phi, m}, EllipticF].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数的属性  
微分  
积分  
级数展开式  
函数表示  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

EllipticF

EllipticF[ϕ,m]

给出第一类椭圆积分 TemplateBox[{phi, m}, EllipticF].

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (4)

数值运算：

Wolfram Language code: EllipticF[0.3, 0.8]

在实数的子集上绘图：

Wolfram Language code: Plot[EllipticF[ϕ, 0.5], {ϕ, 0, Pi / 2}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[EllipticF[z, 0.5], {z, -2 - 2 I, 2 + 2 I}, PlotLegends -> Automatic, Exclusions -> All]

原点处的级数展开式：

Wolfram Language code: Series[EllipticF[ϕ, m], {ϕ, 0, 8}]

范围  (36)

数值计算  (5)

对复变量求值：

Wolfram Language code: EllipticF[3 + 2.5 I, 2.3 - 1.5 I]

高精度计算：

Wolfram Language code: N[EllipticF[12 / 5, 3], 50]

输出的精度与输入的精度一致：

Wolfram Language code: EllipticF[2, 0.9999999999999999990000000000000000000]
Wolfram Language code: EllipticF[2, 0.9999999999999999990000000000000000000000000000000000]

在高精度条件下高效计算 EllipticF：

Wolfram Language code: EllipticF[2, 0.4`500]//Timing
Wolfram Language code: EllipticF[2, 0.4`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: EllipticF[0.2, Interval[{0.3, 0.4}]]
Wolfram Language code: EllipticF[1, CenteredInterval[-4, 1 / 10]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: EllipticF[ Around[2, 0.01], 1 / 2]

计算数组中每个元素的值：

Wolfram Language code: EllipticF[{{1, 0}, {0, 1}}, 0]

或用 MatrixFunction 计算矩阵形式的 EllipticF 函数：

Wolfram Language code: MatrixFunction[EllipticF[#, 0]&, {{1, 0}, {0, 1}}]

特殊值  (5)

自动生成简单精确值：

Wolfram Language code: EllipticF[ϕ, 0]
Wolfram Language code: {EllipticF[0, m], EllipticF[Pi / 2, m]}

无穷处的值：

Wolfram Language code: EllipticF[ϕ, Infinity]

分支切割处的极限：

Wolfram Language code: Limit[EllipticF[2 + ε I, 2], ε -> 0, Direction -> -1]
Wolfram Language code: Limit[EllipticF[2 + ε I, 2], ε -> 0, Direction -> +1]

求方程 TemplateBox[{pi, m}, EllipticF]=3 的根：

Wolfram Language code: f[m_] := EllipticF[π, m] - 3; xzero = Solve[f[m] == 0 && -1.0 < m < 0, m][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[f[m], {m, -1, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

对于第一个参数来说，EllipticF 是一个奇函数：

Wolfram Language code: EllipticF[-ϕ, m]

可视化  (3)

绘制参数 取不同值时的椭圆积分：

Wolfram Language code: Plot[{EllipticF[ϕ, 0], EllipticF[ϕ, 1], EllipticF[ϕ, 2]}, {ϕ, -2, 2}]

绘制作为参数 的函数的椭圆积分：

Wolfram Language code: Plot[{EllipticF[π, m], EllipticF[π / 2, m], EllipticF[-π / 2, m], EllipticF[-π, m]}, {m, -10, 2}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{z, 1}, EllipticF] 的实部：

Wolfram Language code: ComplexContourPlot[Re[EllipticF[z, 1]], {z, -π / 2 - I π / 2 , π / 2 + I π / 2}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{z, 1}, EllipticF] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[EllipticF[z, 1]], {z, -π / 2 - I π / 2 , π / 2 + I π / 2}, IconizedObject[«PlotOptions»]]

函数的属性  (10)

TemplateBox[{phi, 0.5`}, EllipticF] 是针对所有实数定义的：

Wolfram Language code: FunctionDomain[EllipticF[ϕ, 0.5], ϕ]

TemplateBox[{phi, 0.5`}, EllipticF] 的值域是所有实数：

Wolfram Language code: FunctionRange[EllipticF[ϕ, 0.5], ϕ, y]//Quiet

EllipticF 是第一个参数的奇函数：

Wolfram Language code: EllipticF[-ϕ, m]

TemplateBox[{phi, 0.5`}, EllipticF] 是 的解析函数：

Wolfram Language code: FunctionAnalytic[EllipticF[ϕ, .5], ϕ]

函数没有奇点或断点：

Wolfram Language code: FunctionSingularities[EllipticF[ϕ, .5], ϕ]//Quiet
Wolfram Language code: FunctionDiscontinuities[EllipticF[ϕ, .5], ϕ]//Quiet

TemplateBox[{n, m}, EllipticF] 不是 和 的亚纯函数：

Wolfram Language code: FunctionMeromorphic[EllipticF[n, m], {n, m}]

TemplateBox[{phi, 2}, EllipticF] 在实定义域上非递增：

Wolfram Language code: FunctionDomain[EllipticF[ϕ, 2], ϕ]
Wolfram Language code: FunctionMonotonicity[{EllipticF[ϕ, 2], -(π/4) ≤ ϕ ≤ (π/4)}, ϕ]//Quiet

TemplateBox[{phi, 2}, EllipticF] 是单射函数：

Wolfram Language code: FunctionInjective[EllipticF[ϕ, 2], ϕ]
Wolfram Language code: Plot[{EllipticF[ϕ, 2], .5}, {ϕ, -π / 2, π / 2}]

TemplateBox[{phi, 2}, EllipticF] 不是满射函数：

Wolfram Language code: FunctionSurjective[EllipticF[ϕ, 2], ϕ]
Wolfram Language code: Plot[{EllipticF[ϕ, 2], 2}, {ϕ, -π, π}]

TemplateBox[{phi, 2}, EllipticF] 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[{EllipticF[ϕ, 2], -(π / 4) <= ϕ <= π / 4}, ϕ]

TemplateBox[{phi, 2}, EllipticF] 既不是非递增，也不是非递减：

Wolfram Language code: FunctionConvexity[{EllipticF[ϕ, 2], -(π / 4) <= ϕ <= π / 4}, ϕ]

微分  (3)

一阶导数：

Wolfram Language code: D[EllipticF[ϕ, m], ϕ]

高阶导数：

Wolfram Language code: derivs = Table[D[EllipticF[ϕ, m], {ϕ, n}], {n, 1, 3}]//FullSimplify

绘制 时的高阶导数：

Wolfram Language code: Plot[Evaluate[derivs /. m -> 1], {ϕ, -π / 2, π / 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

相对于参数 求导：

Wolfram Language code: D[EllipticF[ϕ, m], m]

积分  (3)

EllipticF 的不定积分：

Wolfram Language code: Integrate[EllipticF[ϕ, m], m]

奇函数在以原点为中心的区间上的定积分为 0：

Wolfram Language code: Integrate[EllipticF[ϕ, m], {ϕ, -1, 1}]

更多积分：

Wolfram Language code: Integrate[Sin[z]EllipticF[z, m] , z]
Wolfram Language code: Integrate[( Sin[2 z]EllipticF[z, m]/(1 - m Sin[z]^2)^3 / 2), z]

级数展开式  (3)

EllipticF 的泰勒展开式：

Wolfram Language code: Series[EllipticF[ϕ, m], {ϕ, 0, 5}]

处 TemplateBox[{phi, 1}, EllipticF] 的前三个近似式的曲线：

Wolfram Language code: terms = Normal@Table[Series[EllipticF[ϕ, 1], {ϕ, 0, n}], {n, 1, 5, 2}]; Plot[{EllipticF[ϕ, 1], terms}, {ϕ, -2, 2}]

关于系数的展开：

Wolfram Language code: Series[EllipticF[ϕ, m], {m, 0, 3}]

处 TemplateBox[{pi, m}, EllipticF] 的前三个近似式的曲线：

Wolfram Language code: terms = Normal@Table[Series[EllipticF[π, m], {m, 0, n}], {n, 1, 3}]; Plot[{EllipticF[π, m], terms}, {m, -1, 1}, PlotLegends -> "Expressions"]

EllipticF 可被应用于幂级数：

Wolfram Language code: EllipticF[ϕ + (ϕ^2/2) + (ϕ^3/3) + O[ϕ]^4, m]
Wolfram Language code: EllipticF[ϕ, m + (m^2/2) + (m^3/3) + O[m]^4]

函数表示  (4)

第二类椭圆积分的定义：

Wolfram Language code: Integrate[(1/Sqrt[1 - m Sin[θ] ^ 2]), {θ, 0, ϕ}, Assumptions -> 0 ≤ ϕ ≤ π / 2]

与 EllipticPi 的关系：

Wolfram Language code: EllipticPi[0, ϕ, m]

EllipticF 可被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[EllipticF[ϕ, m], m]

TraditionalForm 格式：

Wolfram Language code: EllipticF[ϕ, m] // TraditionalForm

应用  (5)

执行一个椭圆积分：

Wolfram Language code: Integrate[(1/Sqrt[a x^4 + b]), x]

在复平面内绘制一个不完全的椭圆积分：

Wolfram Language code: Plot3D[Im[EllipticF[x + I y, 1 / 2]], {x, -2Pi, 2Pi}, {y, -3, 3}]

计算三维椭球体的表面积：

Wolfram Language code: area[a_, b_, c_] := With[{m = (a^2(b^2 - c^2)/b^2(a^2 - c^2)), ϑ = ArcSin[Sqrt[1 - (c^2/a^2)]]}, 2 π((b c^2 /Sqrt[a^2 - c^2])EllipticF[ϑ, m] + c^2 + b Sqrt[a^2 - c^2] EllipticE[ϑ, m])] /; a > b > c;

半轴为 3，2，1 的椭球体面积：

Wolfram Language code: area[3, 2, 1]//N

计算不同表面元素积分的体积：

Wolfram Language code: With[{a = 3, b = 2, c = 1}, NIntegrate[Sin[ϑ]Sqrt[b^2c^2Cos[φ]^2Sin[ϑ]^2 + a^2c^2Sin[φ]^2Sin[ϑ]^2 + a^2b^2Cos[ϑ]^2], {φ, 0, 2Pi}, {ϑ, 0, Pi}]]

曲线弧长参数化，最小化其曲率积分：

Wolfram Language code: DSolve[s'[φ] == -(c/Sqrt[Cos[φ]]), s[φ], φ]

聚纤气球参数化 (两个塑料平板在圆周处连接在一起然后再充气)：

Wolfram Language code: x[u_, v_] := (Cos[v]/Sqrt[Cosh[2u]]) y[u_, v_] := (Sin[v]/Sqrt[Cosh[2u]]) z[u_, v_] := With[{f = ArcSin[(Sqrt[2]Sinh[u]/Sqrt[Cosh[2u]])]}, Sqrt[2](EllipticE[f, (1/2)] - (1/2)EllipticF[f, (1/2)])]

绘制气球结果：

Wolfram Language code: ParametricPlot3D[{x[u, v], y[u, v], z[u, v]}, {v, 0, 2Pi}, {u, -8, 8}, PlotRange -> All]

计算主曲率的比率：

Wolfram Language code: Block[{h, g}, h[u_] = x[u, v] / Cos[v];g[u_] = z[u, v];(((g''[u]h'[u] - g'[u]h''[u]/(g'[u]^2 + h'[u]^2)^3 / 2))/((g'[u]/h[u]Sqrt[g'[u]^2 + h'[u]^2])))//Simplify]

表示初始平面的半径通过气球的半径：

Wolfram Language code: Module[{h, g}, h[u_] = x[u, v] / Cos[v];g[u_] = z[u, v];Integrate[Sqrt[h'[u]^2 + g'[u]^2]//Simplify, {u, 0, ∞}]]
Wolfram Language code: N[%, $MachinePrecision]

属性和关系  (7)

对于符合以下条件的实参数，EllipticF[ϕ,m] 的值是实数：

Wolfram Language code: FunctionDomain[EllipticF[ϕ, m], {ϕ, m}, Reals]

展开特殊条件：

Wolfram Language code: EllipticF[ArcCsc[Sqrt[m]], m]//FunctionExpand

在自变量限制下展开特殊条件：

Wolfram Language code: EllipticF[z, 1]//FunctionExpand
Wolfram Language code: FunctionExpand[%, 0 < z < Pi / 2]

与反函数合成需要 PowerExpand：

Wolfram Language code: EllipticF[JacobiAmplitude[z, m], m]
Wolfram Language code: PowerExpand[%]
Wolfram Language code: JacobiAmplitude[EllipticF[z, m], m]
Wolfram Language code: PowerExpand[%]

求解包含 EllipticF 的方程组：

Wolfram Language code: Solve[EllipticF[z, m]^3 + EllipticF[z, m] == x, z]

计算出超越方程的根：

Wolfram Language code: FindRoot[EllipticF[z, 2]^3 + EllipticF[z, 2] + z == 2, {z, 1}]

分支切割的极限：

Wolfram Language code: Limit[EllipticF[2 + ε I, 2], ε -> 0, Direction -> -1]//Quiet
Wolfram Language code: Limit[EllipticF[2 + ε I, 2], ε -> 0, Direction -> +1]//Quiet

对于 和 phi=TemplateBox[{u, m}, JacobiAmplitude]，TemplateBox[{phi, m}, EllipticF]=u：

Wolfram Language code: With[{m = 1 / 3}, {ParametricPlot[{ϕ, EllipticF[ϕ, m]}, {ϕ, -2Pi, 2Pi}, PlotStyle -> Thick], ParametricPlot[{JacobiAmplitude[u, m], u}, {u, -4 EllipticK[m], 4EllipticK[m]}, PlotStyle -> Directive[Dashed, Orange]]}]
Wolfram Language code: Show[%, ImageSize -> Tiny]

对于 ，只有 时才成立：

Wolfram Language code: With[{m = 4}, {ParametricPlot[{ϕ, EllipticF[ϕ, m]}, {ϕ, -ArcSin[m^-1 / 2], ArcSin[m^-1 / 2]}, PlotStyle -> Thick], ParametricPlot[{JacobiAmplitude[u, m], u}, {u, -(1/Sqrt[m])EllipticK[1 / m], (1/Sqrt[m])EllipticK[1 / m]}, PlotStyle -> Directive[Dashed, Orange]]}]
Wolfram Language code: Show[%, ImageSize -> Tiny]

可能存在的问题  (2)

定义的积分只能在附加条件下收敛：

Wolfram Language code: Integrate[(1/Sqrt[1 - m Sin[t]^2]), {t, 0, z}]

对于第二自变量存在不同规定：

Wolfram Language code: Integrate[1 / Sqrt[1 - k ^ 2 Sin[t] ^ 2], {t, 0, z}, Assumptions -> 0 < k < 1 && 0 < z < 1]
Wolfram Language code: Integrate[1 / Sqrt[(1 - t ^ 2) (1 - m t ^ 2)], {t, 0, z}, Assumptions -> 0 < m < 1 && 0 < z < 1]

巧妙范例  (2)

嵌套导数：

Wolfram Language code: NestList[D[#, x]&, EllipticF[x, m], 4]//Simplify//TraditionalForm

在整数点绘出 EllipticF：

Wolfram Language code: ArrayPlot[Table[Mod[Round[Abs[EllipticF[x y, 0.3]]], 2], {x, -50, 50}, {y, -50, 50}]]
Wolfram Research (1988)，EllipticF，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EllipticF.html （更新于 2022 年）.

文本

Wolfram Research (1988)，EllipticF，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EllipticF.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "EllipticF." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/EllipticF.html.

APA

Wolfram 语言. (1988). EllipticF. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EllipticF.html 年

BibTeX

@misc{reference.wolfram_2026_ellipticf, author="Wolfram Research", title="{EllipticF}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticF.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipticf, organization={Wolfram Research}, title={EllipticF}, year={2022}, url={https://reference.wolfram.com/language/ref/EllipticF.html}, note=[Accessed: 16-September-2026]}