WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EngineeringForm[expr]

すべての実数を工学用表記にして expr を出力する．

EngineeringForm[expr,n]

n 桁精度で数を出力する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
DigitBlock  
ExponentFunction  
ExponentStep  
Show More Show More
NumberFormat  
NumberMultiplier  
NumberPadding  
NumberPoint  
NumberSeparator  
NumberSigns  
SignPadding  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

EngineeringForm

EngineeringForm[expr]

すべての実数を工学用表記にして expr を出力する．

EngineeringForm[expr,n]

n 桁精度で数を出力する．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

工学表記での異なる数：

Wolfram Language code: EngineeringForm[{123450000.0, 0.00012345, 123.45}]

3桁精度を使う：

Wolfram Language code: EngineeringForm[{123450000.0, 0.00012345, 123.45}, 3]

スコープ  (5)

機械数のデフォルト表示：

Wolfram Language code: nE = N[E]

デフォルトより多い桁数を表示する：

Wolfram Language code: EngineeringForm[nE, 10]

少ない桁数を表示する：

Wolfram Language code: EngineeringForm[nE, 2]

複素数をフォーマットする：

Wolfram Language code: EngineeringForm[RandomComplex[]]

高精度数をフォーマットする：

Wolfram Language code: EngineeringForm[N[Pi ^ 10, 20]]

より少ない桁数を使う：

Wolfram Language code: EngineeringForm[N[Pi ^ 10, 20], 10]

ベクトルにおける数の表示を変更する：

Wolfram Language code: RandomReal[2000, 5]
Wolfram Language code: EngineeringForm[%, 4]

行列：

Wolfram Language code: RandomReal[2000, {3, 3}]
Wolfram Language code: EngineeringForm[%, 4]

混ざった式の厳密ではない数の表示を変更する：

Wolfram Language code: y = 150.Sin[x / 7.]
Wolfram Language code: EngineeringForm[y]

厳密な4桁を使う：

Wolfram Language code: EngineeringForm[y, 4]

オプション  (11)

DigitBlock  (2)

デフォルトの整数：

Wolfram Language code: EngineeringForm[10 ^ 9]

長さ3のブロックで区切られた桁：

Wolfram Language code: EngineeringForm[10 ^ 9, DigitBlock -> 3]

5桁のブロック，区切りにはスペースを使う：

Wolfram Language code: EngineeringForm[30!, DigitBlock -> 5, NumberSeparator -> " "]

ExponentFunction  (1)

の近似ベキを計算する：

Wolfram Language code: p = N[E ^ Range[10, 50, 10]]

指数に3の倍数を使うように制限する：

Wolfram Language code: EngineeringForm[p, ExponentFunction -> (3Quotient[#, 3]&)]

10より大きいベキにのみ指数を含める：

Wolfram Language code: EngineeringForm[p, ExponentFunction -> (If[-10 < # < 10, Null, #]&)]

ExponentStep  (1)

10桁のデフォルトのフォーマット：

Wolfram Language code: EngineeringForm[1234567890., 10]

指数を6の倍数に制限する：

Wolfram Language code: EngineeringForm[1234567890., 10, ExponentStep -> 6]

NumberFormat  (1)

数字をFortran風の形式で表示する：

Wolfram Language code: v = {8. ^ 5, 11. ^ 7, 13. ^ 9}
Wolfram Language code: EngineeringForm[v, NumberFormat -> (Row[{#1, "e", #3}]&)]

仮数のみを表示する：

Wolfram Language code: EngineeringForm[v, NumberFormat -> (#1&)]

科学表記に変換した後で指数のみを表示する：

Wolfram Language code: EngineeringForm[v, NumberFormat -> (#3&), ExponentFunction -> (#&)]

NumberMultiplier  (1)

デフォルトの乗算記号×を使う：

Wolfram Language code: EngineeringForm[1.25 * 10 ^ 8]

代りにアスタリスク(*)を使う：

Wolfram Language code: EngineeringForm[1.25 * 10 ^ 8, NumberMultiplier -> "*"]

NumberPadding  (1)

デフォルトでは左にも右にも充填されない：

Wolfram Language code: EngineeringForm[{-67.0, 6.888, 699.999}, 4]

スペースで左側に充填する：

Wolfram Language code: EngineeringForm[{-67.0, 6.888, 699.999}, 4, NumberPadding -> {" ", ""}]

NumberPoint  (1)

デフォルトはピリオドである：

Wolfram Language code: EngineeringForm[123.45]

代りにコンマ(,)で表示する：

Wolfram Language code: EngineeringForm[123.45, NumberPoint -> ","]

NumberSeparator  (1)

デフォルトの区切りはコンマ(,)である：

Wolfram Language code: EngineeringForm[30!, DigitBlock -> 3]

代りにスペースを使う：

Wolfram Language code: EngineeringForm[30!, DigitBlock -> 3, NumberSeparator -> " "]

NumberSigns  (1)

デフォルトでは負の符号は含まれるが正の符号は含まれない：

Wolfram Language code: EngineeringForm[{-1 / 3., 2 / 3.}]

正の符号も含まれるようにする：

Wolfram Language code: EngineeringForm[{-1 / 3., 2 / 3.}, NumberSigns -> {"-", "+"}]

符号の代りに言葉を使う：

Wolfram Language code: EngineeringForm[{-1 / 3., 2 / 3.}, NumberSigns -> {"minus ", "plus "}]

SignPadding  (1)

デフォルトでは符号の前に充填される：

Wolfram Language code: EngineeringForm[{-1.2345, 2.4680}, 10, NumberPadding -> {" ", " "}]

代りに符号と数字の間を充填するようにする：

Wolfram Language code: EngineeringForm[{-1.2345, 2.4680}, 10, SignPadding -> True, NumberPadding -> {" ", " "}]

特性と関係  (5)

EngineeringFormはデフォルトで3の倍数の指数を使う：

Wolfram Language code: EngineeringForm[N[E ^ Range[10, 20, 2]], 10]

NumberFormとPaddedFormはデフォルトで5より大きい指数を含む：

Wolfram Language code: NumberForm[N[E ^ Range[10, 20, 2]], 10]
Wolfram Language code: PaddedForm[N[E ^ Range[10, 20, 2]], 10]

ScientificFormはデフォルトで，小数点の左が1桁である：

Wolfram Language code: ScientificForm[N[E ^ Range[10, 20, 2]], 10]

AccountingFormは指数を使わない：

Wolfram Language code: AccountingForm[N[E ^ Range[10, 20, 2]], 10]

数を底2に変換する：

Wolfram Language code: b2 = BaseForm[123.45, 2]

数を底2で表す：

Wolfram Language code: EngineeringForm[b2]

底10の数を再構築する：

Wolfram Language code: (2^^1.111011011100110011)2 ^ 6

MatrixFormあるいはTableFormの数の表示に影響する：

Wolfram Language code: m = RandomReal[10 ^ 8, {3, 2}];
Wolfram Language code: {MatrixForm[m], EngineeringForm[MatrixForm[m], 3]}

EngineeringForm[expr]のタイプセット形式は，入力で使われるときは expr と同じであると解釈される：

Wolfram Language code: {EngineeringForm[1234.]}

出力をコピーして入力セルにペーストする．1.234×103は1234.であると解釈される：

Wolfram Language code: {1234.}

EngineeringFormは，入力を評価するとEngineeringForm[expr]になるときは出力には現れない：

Wolfram Language code: EngineeringForm[1234.]

Outには，EngineeringForm[1234.]ではなく値1234.が割り当てられる：

Wolfram Language code: %

考えられる問題  (2)

要求された精度が低い場合はプレースホルダのゼロが必要なことがある：

Wolfram Language code: EngineeringForm[12345.6, 3, ExponentFunction -> (If[-5 < # < 5, Null, #]&)]

EngineeringFormは，出力のトップレベルから省略された場合でも部分式からは削除されない：

Wolfram Language code: e = EngineeringForm[1234.]

出力はEngineeringFormではない：

Wolfram Language code: %

しかし，変数 e はEngineeringFormなので，続く評価に影響するかもしれない：

Wolfram Language code: FullForm[e]

EngineeringFormが介在するため乗算は評価されない：

Wolfram Language code: 10 * e

まず変数に割当てを行い．次に結果にEngineeringFormを適用することで計算可能性を維持する：

Wolfram Language code: (f = 1234.)//EngineeringForm
Wolfram Language code: 10 * f
Wolfram Research (1988), EngineeringForm, Wolfram言語関数， https://reference.wolfram.com/language/ref/EngineeringForm.html （2003年に更新）.

テキスト

Wolfram Research (1988), EngineeringForm, Wolfram言語関数， https://reference.wolfram.com/language/ref/EngineeringForm.html （2003年に更新）.

CMS

Wolfram Language. 1988. "EngineeringForm." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2003. https://reference.wolfram.com/language/ref/EngineeringForm.html.

APA

Wolfram Language. (1988). EngineeringForm. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EngineeringForm.html

BibTeX

@misc{reference.wolfram_2026_engineeringform, author="Wolfram Research", title="{EngineeringForm}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/EngineeringForm.html}", note=[Accessed: 14-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_engineeringform, organization={Wolfram Research}, title={EngineeringForm}, year={2003}, url={https://reference.wolfram.com/language/ref/EngineeringForm.html}, note=[Accessed: 14-October-2026]}