Wolfram 语言与系统参考资料中心

EngineeringForm

EngineeringForm[expr]

用工程记数法输出 expr 中的所有实数.

EngineeringForm[expr,n]

用 n 个数位的精度输出数据.

范例

打开所有单元关闭所有单元

基本范例 (2)

工程记法中的不同数：

Wolfram Language code: EngineeringForm[{123450000.0, 0.00012345, 123.45}]

用 3 位精度：

Wolfram Language code: EngineeringForm[{123450000.0, 0.00012345, 123.45}, 3]

范围 (5)

机器数的默认显示：

Wolfram Language code: nE = N[E]

显示比默认情况下更多的数位：

Wolfram Language code: EngineeringForm[nE, 10]

显示更少的数位：

Wolfram Language code: EngineeringForm[nE, 2]

格式化一个复数：

Wolfram Language code: EngineeringForm[RandomComplex[]]

格式化一个高精度数：

Wolfram Language code: EngineeringForm[N[Pi ^ 10, 20]]

用更少数字位：

Wolfram Language code: EngineeringForm[N[Pi ^ 10, 20], 10]

改变向量中数的显示：

Wolfram Language code: RandomReal[2000, 5]

Wolfram Language code: EngineeringForm[%, 4]

矩阵：

Wolfram Language code: RandomReal[2000, {3, 3}]

Wolfram Language code: EngineeringForm[%, 4]

改变混合表达式中不精确数的显示：

Wolfram Language code: y = 150.Sin[x / 7.]

Wolfram Language code: EngineeringForm[y]

用 4 位精度数：

Wolfram Language code: EngineeringForm[y, 4]

选项 (11)

DigitBlock (2)

缺省整数：

Wolfram Language code: EngineeringForm[10 ^ 9]

每三位数字分隔：

Wolfram Language code: EngineeringForm[10 ^ 9, DigitBlock -> 3]

以空格作为分隔符，每五位数字分隔：

Wolfram Language code: EngineeringForm[30!, DigitBlock -> 5, NumberSeparator -> " "]

ExponentFunction (1)

计算的近似幂：

Wolfram Language code: p = N[E ^ Range[10, 50, 10]]

限制指数为 3 的倍数：

Wolfram Language code: EngineeringForm[p, ExponentFunction -> (3Quotient[#, 3]&)]

指数仅包含大于 10 的幂：

Wolfram Language code: EngineeringForm[p, ExponentFunction -> (If[-10 < # < 10, Null, #]&)]

ExponentStep (1)

缺省格式为10位：

Wolfram Language code: EngineeringForm[1234567890., 10]

限制指数为 6 的倍数：

Wolfram Language code: EngineeringForm[1234567890., 10, ExponentStep -> 6]

NumberFormat (1)

以 Fortran‐like 形式显示数字：

Wolfram Language code: v = {8. ^ 5, 11. ^ 7, 13. ^ 9}

Wolfram Language code: EngineeringForm[v, NumberFormat -> (Row[{#1, "e", #3}]&)]

只显示尾数：

Wolfram Language code: EngineeringForm[v, NumberFormat -> (#1&)]

仅显示转换为科学形式的指数：

Wolfram Language code: EngineeringForm[v, NumberFormat -> (#3&), ExponentFunction -> (#&)]

NumberMultiplier (1)

使用缺省的乘法运算符 ×：

Wolfram Language code: EngineeringForm[1.25 * 10 ^ 8]

用星号 (*) 代替：

Wolfram Language code: EngineeringForm[1.25 * 10 ^ 8, NumberMultiplier -> "*"]

NumberPadding (1)

默认情况下，不在左侧、右侧填充：

Wolfram Language code: EngineeringForm[{-67.0, 6.888, 699.999}, 4]

在左侧填充空格：

Wolfram Language code: EngineeringForm[{-67.0, 6.888, 699.999}, 4, NumberPadding -> {" ", ""}]

NumberPoint (1)

默认是一个周期：

Wolfram Language code: EngineeringForm[123.45]

用逗号 (,) 替代显示：

Wolfram Language code: EngineeringForm[123.45, NumberPoint -> ","]

NumberSeparator (1)

默认分隔符是逗号(,)：

Wolfram Language code: EngineeringForm[30!, DigitBlock -> 3]

用空格替代：

Wolfram Language code: EngineeringForm[30!, DigitBlock -> 3, NumberSeparator -> " "]

NumberSigns (1)

默认包含负号而不是正号：

Wolfram Language code: EngineeringForm[{-1 / 3., 2 / 3.}]

同样包含正号：

Wolfram Language code: EngineeringForm[{-1 / 3., 2 / 3.}, NumberSigns -> {"-", "+"}]

用语句代替符号：

Wolfram Language code: EngineeringForm[{-1 / 3., 2 / 3.}, NumberSigns -> {"minus ", "plus "}]

SignPadding (1)

在符号前有默认填充：

Wolfram Language code: EngineeringForm[{-1.2345, 2.4680}, 10, NumberPadding -> {" ", " "}]

在符号和数字间填充：

Wolfram Language code: EngineeringForm[{-1.2345, 2.4680}, 10, SignPadding -> True, NumberPadding -> {" ", " "}]

属性和关系 (5)

EngineeringForm 默认情况下使用 3 的倍数的指数：

Wolfram Language code: EngineeringForm[N[E ^ Range[10, 20, 2]], 10]

NumberForm 和 PaddedForm 默认情况下包含大于 5 的指数：

Wolfram Language code: NumberForm[N[E ^ Range[10, 20, 2]], 10]

Wolfram Language code: PaddedForm[N[E ^ Range[10, 20, 2]], 10]

ScientificForm 在小数点的左边有一位数字：

Wolfram Language code: ScientificForm[N[E ^ Range[10, 20, 2]], 10]

AccountingForm 没有指数：

Wolfram Language code: AccountingForm[N[E ^ Range[10, 20, 2]], 10]

转换为以 2 为底的数：

Wolfram Language code: b2 = BaseForm[123.45, 2]

表示以 2 为底的数：

Wolfram Language code: EngineeringForm[b2]

重新构建以 10 为底的数：

Wolfram Language code: (2^^1.111011011100110011)2 ^ 6

在 MatrixForm 或 TableForm 中影响数字显示：

Wolfram Language code: m = RandomReal[10 ^ 8, {3, 2}];

Wolfram Language code: {MatrixForm[m], EngineeringForm[MatrixForm[m], 3]}

作为输入时，EngineeringForm[expr] 的排版形式被解释为与 expr 一样：

Wolfram Language code: {EngineeringForm[1234.]}

复制输出，将其粘贴到输入单元. 1.234×10³ 被解释为 1234.：

Wolfram Language code: {1234.}

当输入的运算结果为 EngineeringForm[expr] 时，EngineeringForm 不会出现在输出中

Wolfram Language code: EngineeringForm[1234.]

Out 被赋值 1234.，不是 EngineeringForm[1234.]：

Wolfram Language code: %

可能存在的问题 (2)

如果要求的精度很低，可能需要占位符零：

Wolfram Language code: EngineeringForm[12345.6, 3, ExponentFunction -> (If[-5 < # < 5, Null, #]&)]

即便输出省略了上一层的 EngineeringForm，子表达式中依然存在：

Wolfram Language code: e = EngineeringForm[1234.]

输出中没有 EngineeringForm：

Wolfram Language code: %

但是，变量 e 含有 EngineeringForm，可能会影响后续的计算：

Wolfram Language code: FullForm[e]

由于 EngineeringForm 的存在，不能计算乘积：

Wolfram Language code: 10 * e

先对变量赋值，然后对结果应用 EngineeringForm，使计算可以进行：

Wolfram Language code: (f = 1234.)//EngineeringForm

Wolfram Language code: 10 * f

Top

DigitBlock	Infinity	间断之间数字的数量
ExponentFunction	Automatic	应用于指数的函数
ExponentStep	3	指数递增的步长
NumberFormat	Automatic	用于集合尾数、基数和指数的函数
NumberMultiplier	"×"	用以表示乘法的字符串
NumberPadding	{"",""}	用以表示左右填充的字符串
NumberPoint	"."	表示小数点的字符串
NumberSeparator	{",", " "}	表示在块之间插入字符串
NumberSigns	{"-",""}	用以表示负数和正数符号的字符串
SignPadding	False	是否在符号后插入填充

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

EngineeringForm

更多信息和选项

范例

基本范例 (2)

范围 (5)