WOLFRAM

Wolfram 语言与系统参考资料中心

lhs==rhs 或 Equal[lhs,rhs]

如果 lhs 和 rhs 相同，lhsrhs 返回 True.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
數值等式  
符號等式  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Equal

lhs==rhs 或 Equal[lhs,rhs]

如果 lhs 和 rhs 相同，lhsrhs 返回 True.

更多信息

  • lhsrhs 用来表示一个即将使用函数如 Solve 等操作的符号方程.
  • 如果 lhs 和 rhs 是同一表达式，lhsrhs 返回 True.
  • 如果通过比较数字或其它原始数据，比如字符串，lhs 和 rhs 确实不相等，lhsrhs 返回 False.
  • 对于近似数，如果它们至多在最后八个二进制位不同(粗略地计算，等价于至多在最后两个十进制位不同)，则它们被认为是相等的.
  • 机器精度的允许误差基于数字精度而降低.
  • 22. 的结果为 True.
  • 如果所有 ei 相等，e1==e2==e3 的结果为 True.
  • Equal[] 和 Equal[e] 总是给出 True. »
  • 对于精确数值，Equal 在内部通过数值近似建立不等式. 这个过程可能受到全局变量 $MaxExtraPrecision 设置的影响.
  • 当 lhs 或 rhs 包含诸如 Indeterminate 和 Overflow 的对象时，Equal 保留不求值.
  • 在 StandardForm 和 InputForm 中，lhsrhs 可以输入为 lhs\[Equal]rhs 或 lhsrhs.
  • 可由 \[LongEqual] 或 lhsrhs 输入.
  • 在 TraditionalForm 中，lhs==rhs 的输出结果为 lhsrhs.

背景

  • Equal[expr1,expr2] 返回 True，如果 expr1 和 expr2 数值相等，False，如果它们不相等并且未被计算（如果不能建立相等性）. 例如，Equal[(1+Sqrt[5])/2,GoldenRatio] 返回 True，Equal[1,2] 返回 False，Equal[1,a] 返回未被计算. Equal[expr1,expr2] 可使用双等号 expr1==expr2 输入或使用 \[Equal] 字符，如 expr1expr2. 多自变数形式 Equal[expr1,expr2,…], 也可以输入为 expr1==expr2…，返回 True 如果所有表达式 expri 是数值相等，False，如果至少两个不相等并没有被计算. 单个自变数形式 Equal[expr] 返回 True（有点矛盾的是，单个自变数的形式 Unequal[expr] 也是这个结果）.
  • 如果机器精度 (MachinePrecision) 或更多的数字只是在最后 7 个二进制数字不同的话则认为是相等的. 低于机器精度的数字相等性是建于最低精度数的精度内. 例如，1.01`2==1 返回 True，而 1.01`3==1 返回 False. 对于确切的数值量，Equal 使用数值近似建立不等性，其可以受全局变量 $MaxExtraPrecision 的值所影响.
  • Equal 与其他符号相关. Set[expr1,expr2]（可以使用“单等号”语法 expr1=expr2 进行输入） 计算 expr2 并把结果赋给 expr1 的值，其中 SameQ[expr1,expr2]（可以使用“三等号”语法 expr1===expr2 输入） 返回 True. 如果 expr1 和 expr2 是相等的，否则返回 False. 与 Equal 相反，SameQ 区别不同的数字表示；例如，SameQ[1,1.] 和 SameQ[1.,1.+0.I] 均返回 False. SameQ 的行为也不同于 Equal，因为 SameQ 总是计算为 True 或 False，其中，如果没有解决相等性，Equal 会仍然保留不被计算. Unequal（可以输入为 expr1!=expr2）与 Equal 相反. Equal 还有运算符形式 EqualTo. Equal 的布尔逻辑类似是 Equivalent.
  • 在某些情况下，当 Equal 返回未计算，如果给定的表达式有 ，可用 PossibleZeroQ 指明. 例如，Equal[Erf[Log[4]+2Log[Sin[Pi/8]]]-Erf[Log[2-Sqrt[2]]],0] 返回计算的，在第一个变量调用 PossibleZeroQ 返回 True（以及信息性消息表明零值不能被严格建立）. 有时当 Equal 不能时，符号简化像 Simplify、FullSimplify 和 RootReduce 也可用于严格建立相等性（包括刚才给出的例子）.

范例

打开所有单元 关闭所有单元

基本范例  (2)

测试方程：

Wolfram Language code: 2 + 2 == 4

描述方程：

Wolfram Language code: x ^ 2 == 1 + x
Wolfram Language code: Solve[%, x]

范围  (12)

數值等式  (6)

测试等式：

Wolfram Language code: 3 / 2 == 5 / 3

二进制数据最后七位近似值：

Wolfram Language code: 2^^1.000000000000000000000000000000000000000000000000000000000000 == 2^^1.000000000000000000000000000000000000000000000000000001111111

比较精确数值和近似数值：

Wolfram Language code: N[Pi, 20] == Pi
Wolfram Language code: N[Pi, 20] == Pi(1 + 2 ^ 8 10 ^ -20)

比较两个精确数值，数值测试可能会有相反结果：

Wolfram Language code: Pi ^ E == E ^ Pi

用符号方法证明相等：

Wolfram Language code: Sqrt[2] + Sqrt[3] == Sqrt[5 + 2Sqrt[6]]

Equal 的符号方法不足以证明等式：

Wolfram Language code: Sqrt[2] + Sqrt[3] == Root[# ^ 4 - 10# ^ 2 + 1&, 4]

用 RootReduce 判断两个数字是否相等：

Wolfram Language code: RootReduce[%]

用 Equal 在足够的精度下以数值方法证明不相等：

Wolfram Language code: Sqrt[2] + Sqrt[3] == Root[# ^ 4 - 10# ^ 2 + 1&, 4] + 10 ^ -100

RootReduce 证明两个数字不相等：

Wolfram Language code: RootReduce[%]

$MaxExtraPrecision 证明不相等：

Wolfram Language code: Block[{$MaxExtraPrecision = 100}, Sqrt[2] + Sqrt[3] == Root[# ^ 4 - 10# ^ 2 + 1&, 4] + 10 ^ -100]

符號等式  (6)

符号比较：

Wolfram Language code: x == x

Equal 不会自动证明这个等式：

Wolfram Language code: (x + 1) ^ 2 == x ^ 2 + 2x + 1

使用 Expand 来证明：

Wolfram Language code: Expand[%]

符号方程：

Wolfram Language code: a x == b

用 Solve 证明方程：

Wolfram Language code: Solve[%, x]

Reduce 给出包括需要非正常参数的解决方案：

Wolfram Language code: Reduce[%%, x]

比较两个以上的表达式：

Wolfram Language code: 3 == 3. == 3.000000
Wolfram Language code: x + y + z == x ^ 2 - y ^ 2 - z ^ 2 == x y z == 3
Wolfram Language code: Reduce[%, {x, y, z}]

比较列表：

Wolfram Language code: {1, 2} == {1, 2}
Wolfram Language code: {a, b, c} == {d, e}

比较字符串：

Wolfram Language code: "abc" == "ABC"

属性和关系  (7)

非双参数的 Equal 为 Unequal：

Wolfram Language code: Not[x == y]

非三参数的 Equal 不会自动单一化：

Wolfram Language code: Not[x == y == z]

用 LogicalExpand 表达双参数 Unequal：

Wolfram Language code: LogicalExpand[%]

非三参数 Equal 不等同于三参数 Unequal：

Wolfram Language code: LogicalExpand[x ≠ y ≠ z]

Equal 测试数学表达式对象是否相等：

Wolfram Language code: {x == x, x == y, Sqrt[2] + Sqrt[3] == Sqrt[5 + 2Sqrt[6]], Pi == N[Pi]}

SameQ 测试表达式是否相等：

Wolfram Language code: {x === x, x === y, Sqrt[2] + Sqrt[3] === Sqrt[5 + 2Sqrt[6]], Pi === N[Pi]}

Equal 将无法判断是否相等的表达式原样输出：

Wolfram Language code: a = Log[Sqrt[2] + Sqrt[3]]; b = Log[5 + 2Sqrt[6]] / 2; a == b

FullSimplify 使用精确数值变换证明相等：

Wolfram Language code: FullSimplify[a == b]

PossibleZeroQ 用数值和符号方法判断表达式是否为零：

Wolfram Language code: PossibleZeroQ[a - b]

PossibleZeroQ 用数值方法准确判断数值是否为零：

Wolfram Language code: PossibleZeroQ[a - b + 10 ^ -10000]

用 Solve 解答一般值参数的方程：

Wolfram Language code: Solve[a x ^ 2 + b x + c == 0, x]

Reduce 给出包括非普通值参数的解决方案：

Wolfram Language code: Reduce[a x ^ 2 + b x + c == 0, x]

用 Reduce 求解特殊领域的方程：

Wolfram Language code: Reduce[x ^ 2 + y ^ 2 == 5, {x, y}, Reals]
Wolfram Language code: Reduce[x ^ 2 + y ^ 2 == 5, {x, y}, Integers]

Equal[e] 给出 True：

Wolfram Language code: Equal[e]

Equal[] 的结果也为 True：

Wolfram Language code: Equal[]

可能存在的问题  (5)

判断时对机器精度附近的数值很敏感：

Wolfram Language code: 2.00006 - 2.00005 == 0.00001

额外数字破坏相等性：

Wolfram Language code: 2.00006 - 2.00005//InputForm

任意相似精度数值不存在这个问题：

Wolfram Language code: 2.00006`16 - 2.00005`16 == 0.00001`16

自动精度下，Equal 会仅仅关注前十个有效数字：

Wolfram Language code: Precision[2.00006`16 - 2.00005`16]

测试机器精度成功：

Wolfram Language code: 2.6 - 2.5 == 0.1

Equal 忽略其他额外有效数字：

Wolfram Language code: 2.6 - 2.5//InputForm

对于近似数，相等性可能不是可传递的：

Wolfram Language code: {x, y, z} = {1. - 1.*^-14, 1., 1. + 1.*^-14};
Wolfram Language code: x == y
Wolfram Language code: y == z
Wolfram Language code: x == z

Equal 不识别布尔操作符：

Wolfram Language code: (p || q) == (q || p)//FullSimplify

Equivalent 则识别：

Wolfram Language code: p || q⧦q || p//FullSimplify
Wolfram Research (1988)，Equal，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Equal.html （更新于 2007 年）.

文本

Wolfram Research (1988)，Equal，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Equal.html （更新于 2007 年）.

CMS

Wolfram 语言. 1988. "Equal." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2007. https://reference.wolfram.com/language/ref/Equal.html.

APA

Wolfram 语言. (1988). Equal. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Equal.html 年

BibTeX

@misc{reference.wolfram_2026_equal, author="Wolfram Research", title="{Equal}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Equal.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_equal, organization={Wolfram Research}, title={Equal}, year={2007}, url={https://reference.wolfram.com/language/ref/Equal.html}, note=[Accessed: 11-September-2026]}