WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Erfc[z]

相補誤差関数を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評睊  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
積分変換  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Erfc

Erfc[z]

相補誤差関数を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • Erfc[z]は，で与えられる．
  • 特別な引数の場合，Erfcは，自動的に厳密値を計算する．
  • Erfcは任意の数値精度で評価できる．
  • Erfcは自動的にリストに縫い込まれる．
  • ErfcはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (5)

数値的に評価する：

Wolfram Language code: Erfc[0.95]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Erfc[x], {x, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Erfc[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[Erfc[x], {x, 0, 10}]

Infinityにおける級数展開：

Wolfram Language code: Series[Erfc[x], {x, ∞, 5}]//Normal

スコープ  (40)

数値評睊  (6)

数値的に評価する：

Wolfram Language code: Erfc[1.5]

高精度で評価する：

Wolfram Language code: N[Erfc[3 / 2], 50]

出力精度は入力精度に従う：

Wolfram Language code: Erfc[1.5000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: Erfc[1.5 - I]

Erfを高精度で効率よく評価する：

Wolfram Language code: Erfc[1.2`500]//Timing
Wolfram Language code: Erfc[1.2`5000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Erfc[Interval[{.2, .3}]]
Wolfram Language code: Erfc[CenteredInterval[1, 1 / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Erfc[ Around[2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: Erfc[{{0 , I π / 2}, {π , 0}}]//FunctionExpand

MatrixFunctionを使って行列のErfc関数を計算することもできる：

Wolfram Language code: MatrixFunction[Erfc, {{0, I π / 2}, {π, 0}}]//FunctionExpand

特定の値  (3)

簡単な厳密値は自動的に生成される：

Wolfram Language code: Erfc[0]

無限大における値：

Wolfram Language code: Erfc[{Infinity, -Infinity}]

変曲点をの根として求める：

Wolfram Language code: xinfl = Solve[D[Erfc[x], {x, 2}] == 0 && -1 < x < 1, x][[1, 1, 2]]
Wolfram Language code: Plot[Erfc[x], {x, -4, 4}, Epilog -> Style[Point[{xinfl, Erfc[xinfl]}], PointSize[Large], Red]]

可視化  (2)

Erfc関数をプロットする：

Wolfram Language code: Plot[Erfc[x], {x, -3, 3}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Erfc[z]], {z, -2 - 2 I, 2 + 2 I}, Contours -> 20]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Erfc[z]], {z, -2 - 2 I, 2 + 2 I}, Contours -> 20]

関数の特性  (9)

Erfcはすべての実数値と虚数値について定義される：

Wolfram Language code: FunctionDomain[Erfc[x], x]
Wolfram Language code: FunctionDomain[Erfc[z], z, Complexes]

Erfcは0から2までのすべての実数値を取る：

Wolfram Language code: FunctionRange[Erfc[x], x, y]

Erfcは鏡特性erfc(TemplateBox[{z}, Conjugate])=TemplateBox[{{erfc, (, z, )}}, Conjugate]を有する：

Wolfram Language code: FullSimplify[Erfc[Conjugate[z]] == Conjugate[Erfc[z]]]

Erfcは x の解析関数である：

Wolfram Language code: FunctionAnalytic[Erfc[x], x]

特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[Erfc[x], x]
Wolfram Language code: FunctionDiscontinuities[Erfc[x], x]

Erfcは非増加である：

Wolfram Language code: FunctionMonotonicity[Erfc[x], x]

Erfcは単射である：

Wolfram Language code: FunctionInjective[Erfc[x], x]
Wolfram Language code: Plot[{Erfc[x], .5}, {x, -5, 5}]

Erfcは全射ではない：

Wolfram Language code: FunctionSurjective[Erfc[x], x]
Wolfram Language code: Plot[{Erfc[x], -2}, {x, -10, 10}]

Erfcは非負である：

Wolfram Language code: FunctionSign[Erfc[x], x]

Erfcは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Erfc[x], x]

微分  (3)

一次導関数：

Wolfram Language code: D[Erfc[x], x]

高次導関数：

Wolfram Language code: Table[D[Erfc[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -4, 4}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

n 次導関数の式：

Wolfram Language code: D[Erfc[x], {x, n}]

積分  (3)

Erfcの不定積分：

Wolfram Language code: Integrate[Erfc[x], x]

Erfcの定積分：

Wolfram Language code: Integrate[Erfc[x], {x, -3, 3}]

その他の積分例：

Wolfram Language code: Integrate[z^αErfc[z^β], z]
Wolfram Language code: Integrate[z Exp[z]Erfc[z], z]
Wolfram Language code: Integrate[Erfc[z]^2, {z, 0, Infinity}]

級数展開  (4)

Erfcのテイラー(Taylor)展開：

Wolfram Language code: Series[Erfc[x], {x, 0, 7}]

の周りのErfcの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[Erfc[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{Erfc[x], terms}, {x, -2, 2}]

Erfcの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[Erfc[x], {x, 0, n}]

Erfcの漸近展開：

Wolfram Language code: Series[Erfc[x], {x, Infinity, 1}]//Normal

Erfcはベキ級数に適用できる：

Wolfram Language code: Erfc[Sin[x] + O[x] ^ 10]

積分変換  (3)

FourierTransformを使ってErfcのフーリエ(Fourier)変換を計算する：

Wolfram Language code: FourierTransform[Erfc[t], t, ω]

LaplaceTransform：

Wolfram Language code: LaplaceTransform[Erfc[t], t, s]

MellinTransform：

Wolfram Language code: MellinTransform[Erfc[x], x, s]

関数の恒等式と簡約  (3)

FunctionExpandを使って他の関数に変換する：

Wolfram Language code: FunctionExpand[Erfc[x]]
Wolfram Language code: FullSimplify[%]

Erfcの積分定義：

Wolfram Language code: (2/Sqrt[π])Integrate[Exp[-t^2], {t, x, Infinity}]

基本的な算術演算を含む引数：

Wolfram Language code: Erfc[-z] == 2 - Erfc[z]//FullSimplify
Wolfram Language code: Erfc[Sqrt[z^2]]//FunctionExpand

関数表現  (4)

ErfcとErfの関係：

Wolfram Language code: Erfc[z] == Erf[z, Infinity]//FullSimplify
Wolfram Language code: Erfc[z] == 1 - Erf[z]//FullSimplify

ErfcはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[Erfc[x], x]

ErfcはMeijerGによって表すことができる：

Wolfram Language code: MeijerGReduce[Erfc[x], x]
Wolfram Language code: Activate[%]//FullSimplify

TraditionalFormによる表示：

Wolfram Language code: TraditionalForm[Erfc[x]]

アプリケーション  (5)

NormalDistributionのCDFは相補誤差関数によって表すことができる：

Wolfram Language code: CDF[NormalDistribution[0, σ], x]

ランダムな値が よりも大きくなる確率：

Wolfram Language code: Probability[x > n σ, xNormalDistribution[0, σ], Assumptions -> n > 0]
Wolfram Language code: Table[%, {n, 1, 3}]//N

区分定数の初期条件についての熱伝導方程式の解：

Wolfram Language code: temp[x_, t_] := With[{η = (1/2 Sqrt[t])}, (Erfc[(x - 1)η] - Erfc[(x + 1)η]) / 2]

解が熱伝導方程式を満足するかどうかをチェックする：

Wolfram Language code: D[temp[x, t], t] == D[temp[x, t], x, x]// Simplify

異なる時間について解をプロットする：

Wolfram Language code: Plot[Evaluate[{temp[x, 0.01], temp[x, 0.2], temp[x, 0.6], temp[x, 1.5]}], {x, -4, 4}]

HermiteHを使ってスケールされた相補誤差関数を定義する：

Wolfram Language code: FullSimplify[2HermiteH[-1, x] / Sqrt[Pi]]
Wolfram Language code: Plot[%, {x, 0, 10}]

影の端の干渉縞：

Wolfram Language code: Plot[(1/2)Abs[Exp[-(π I x^2/2)]Erfc[((1 - I/2))Sqrt[π]x]]^2, {x, -8, 8}]

デバイスの寿命はBirnbaum–Saunders分布に従う．デバイスの信頼性を求める：

Wolfram Language code: r = SurvivalFunction[BirnbaumSaundersDistribution[α, λ], t]

ハザード関数は水平の漸近線 を持つ：

Wolfram Language code: Limit[Refine[HazardFunction[BirnbaumSaundersDistribution[α, 1], t], t > 0], t -> ∞, Assumptions -> α > 0]
Wolfram Language code: Limit[Refine[HazardFunction[BirnbaumSaundersDistribution[1, λ], t], t > 0], t -> ∞, Assumptions -> λ > 0]

直列に繋がれたそのような2つのデバイスの信頼性を求める：

Wolfram Language code: rs = r r//PiecewiseExpand

並列に繋がれたそのような2つのデバイスの信頼性を求める：

Wolfram Language code: rp = 1 - (1 - r)(1 - r)//PiecewiseExpand

両方の系の信頼性を と について比較する：

Wolfram Language code: Block[{α = 0.8, λ = 1.2}, Plot[{rs, rp}, {t, 0, 5}, PlotLegends -> {"in series", "in parallel"}]]

特性と関係  (3)

FunctionExpandを使って他の関数に変換する：

Wolfram Language code: FunctionExpand[Erfc[x]]
Wolfram Language code: FullSimplify[%]

逆関数を使って構築する：

Wolfram Language code: {Erfc[InverseErfc[z]], InverseErfc[Erfc[z]]}
Wolfram Language code: PowerExpand[%]

超越方程式を解く：

Wolfram Language code: Solve[Erfc[x] == 1 / 2, x]

考えられる問題  (3)

大きい引数については，中間値がアンダーフローすることがある：

Wolfram Language code: Erfc[-2 10 ^ 8 - 10. ^ 3 I]

大きい負の実部の引数についての誤差関数は，2に非常に近くなることがある：

Wolfram Language code: Erfc[-30`16 + 10 ^ -1 I]

非常に大きい引数は，未評価の結果を返すことがある：

Wolfram Language code: Erfc[10. ^ 100 I]

おもしろい例題  (1)

部分分子が連続する整数である連分数：

Wolfram Language code: With[{n = 20}, 1 / (1 + ContinuedFractionK[HoldForm[k], 1, {k, n}])]

その極限はErfcを使って表現できる：

Wolfram Language code: 1 / (1 + ContinuedFractionK[k, 1, {k, ∞}])
Wolfram Research (1991), Erfc, Wolfram言語関数， https://reference.wolfram.com/language/ref/Erfc.html （2022年に更新）.

テキスト

Wolfram Research (1991), Erfc, Wolfram言語関数， https://reference.wolfram.com/language/ref/Erfc.html （2022年に更新）.

CMS

Wolfram Language. 1991. "Erfc." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/Erfc.html.

APA

Wolfram Language. (1991). Erfc. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Erfc.html

BibTeX

@misc{reference.wolfram_2026_erfc, author="Wolfram Research", title="{Erfc}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/Erfc.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_erfc, organization={Wolfram Research}, title={Erfc}, year={2022}, url={https://reference.wolfram.com/language/ref/Erfc.html}, note=[Accessed: 08-September-2026]}