Wolfram 语言与系统参考资料中心

Erfc

Erfc[z]

用来给出补余误差函数 .

范例

打开所有单元关闭所有单元

基本范例 (5)

数值计算：

Wolfram Language code: Erfc[0.95]

在实数的子集上绘图：

Wolfram Language code: Plot[Erfc[x], {x, -5, 5}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[Erfc[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点处的级数展开式：

Wolfram Language code: Series[Erfc[x], {x, 0, 10}]

Infinity 处的级数展开式：

Wolfram Language code: Series[Erfc[x], {x, ∞, 5}]//Normal

范围 (40)

数值计算 (6)

数值计算：

Wolfram Language code: Erfc[1.5]

高精度计算：

Wolfram Language code: N[Erfc[3 / 2], 50]

输出精度与输入精度一致：

Wolfram Language code: Erfc[1.5000000000000000000000000000]

对复变量求值：

Wolfram Language code: Erfc[1.5 - I]

在高精度条件下高效计算 Erf：

Wolfram Language code: Erfc[1.2`500]//Timing

Wolfram Language code: Erfc[1.2`5000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: Erfc[Interval[{.2, .3}]]

Wolfram Language code: Erfc[CenteredInterval[1, 1 / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: Erfc[ Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: Erfc[{{0 , I π / 2}, {π , 0}}]//FunctionExpand

或用 MatrixFunction 计算矩阵形式的 Erfc 函数：

Wolfram Language code: MatrixFunction[Erfc, {{0, I π / 2}, {π, 0}}]//FunctionExpand

特殊值 (3)

自动生成简单精确值：

Wolfram Language code: Erfc[0]

无穷处的值：

Wolfram Language code: Erfc[{Infinity, -Infinity}]

求拐点以作为的根：

Wolfram Language code: xinfl = Solve[D[Erfc[x], {x, 2}] == 0 && -1 < x < 1, x][[1, 1, 2]]

Wolfram Language code: Plot[Erfc[x], {x, -4, 4}, Epilog -> Style[Point[{xinfl, Erfc[xinfl]}], PointSize[Large], Red]]

可视化 (2)

绘制 Erfc 函数：

Wolfram Language code: Plot[Erfc[x], {x, -3, 3}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[Erfc[z]], {z, -2 - 2 I, 2 + 2 I}, Contours -> 20]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[Erfc[z]], {z, -2 - 2 I, 2 + 2 I}, Contours -> 20]

函数属性 (9)

Erfc 是针对所有实数和复数定义的：

Wolfram Language code: FunctionDomain[Erfc[x], x]

Wolfram Language code: FunctionDomain[Erfc[z], z, Complexes]

Erfc 的值域为 0 和 2 之间的所有实数：

Wolfram Language code: FunctionRange[Erfc[x], x, y]

Erfc 具有镜像属性：

Wolfram Language code: FullSimplify[Erfc[Conjugate[z]] == Conjugate[Erfc[z]]]

Erfc 是 x 的解析函数：

Wolfram Language code: FunctionAnalytic[Erfc[x], x]

函数没有奇点和断点：

Wolfram Language code: FunctionSingularities[Erfc[x], x]

Wolfram Language code: FunctionDiscontinuities[Erfc[x], x]

Erfc 非递增：

Wolfram Language code: FunctionMonotonicity[Erfc[x], x]

Erfc 是单射函数：

Wolfram Language code: FunctionInjective[Erfc[x], x]

Wolfram Language code: Plot[{Erfc[x], .5}, {x, -5, 5}]

Erfc 不是满射函数：

Wolfram Language code: FunctionSurjective[Erfc[x], x]

Wolfram Language code: Plot[{Erfc[x], -2}, {x, -10, 10}]

Erfc 非负：

Wolfram Language code: FunctionSign[Erfc[x], x]

Erfc 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[Erfc[x], x]

微分 (3)

一阶导数：

Wolfram Language code: D[Erfc[x], x]

高阶导数：

Wolfram Language code: Table[D[Erfc[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -4, 4}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

n 阶导数的公式：

Wolfram Language code: D[Erfc[x], {x, n}]

积分 (3)

Erfc 的不定积分：

Wolfram Language code: Integrate[Erfc[x], x]

Erfc 的定积分：

Wolfram Language code: Integrate[Erfc[x], {x, -3, 3}]

更多积分：

Wolfram Language code: Integrate[z^αErfc[z^β], z]

Wolfram Language code: Integrate[z Exp[z]Erfc[z], z]

Wolfram Language code: Integrate[Erfc[z]^2, {z, 0, Infinity}]

级数展开式 (4)

Erfc 的泰勒展开式：

Wolfram Language code: Series[Erfc[x], {x, 0, 7}]

绘制 Erfc 在处的前三个近似式：

Wolfram Language code:

terms = Normal@Table[Series[Erfc[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{Erfc[x], terms}, {x, -2, 2}]

Erfc 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[Erfc[x], {x, 0, n}]

Erfc 的渐近展开式：

Wolfram Language code: Series[Erfc[x], {x, Infinity, 1}]//Normal

Erfc 可用于幂级数：

Wolfram Language code: Erfc[Sin[x] + O[x] ^ 10]

积分变换 (3)

用 FourierTransform 计算 Erfc 的傅立叶变换：

Wolfram Language code: FourierTransform[Erfc[t], t, ω]

LaplaceTransform：

Wolfram Language code: LaplaceTransform[Erfc[t], t, s]

MellinTransform：

Wolfram Language code: MellinTransform[Erfc[x], x, s]

函数恒等式和化简 (3)

用 FunctionExpand 转换成其他函数：

Wolfram Language code: FunctionExpand[Erfc[x]]

Wolfram Language code: FullSimplify[%]

Erfc 的积分定义：

Wolfram Language code: (2/Sqrt[π])Integrate[Exp[-t^2], {t, x, Infinity}]

含有基本算术运算的参数：

Wolfram Language code: Erfc[-z] == 2 - Erfc[z]//FullSimplify

Wolfram Language code: Erfc[Sqrt[z^2]]//FunctionExpand

函数表示 (4)

Erfc 与 Erf 的关系：

Wolfram Language code: Erfc[z] == Erf[z, Infinity]//FullSimplify

Wolfram Language code: Erfc[z] == 1 - Erf[z]//FullSimplify

Erfc 可以表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[Erfc[x], x]

Erfc 可以表示为 MeijerG 的形式：

Wolfram Language code: MeijerGReduce[Erfc[x], x]

Wolfram Language code: Activate[%]//FullSimplify

TraditionalForm 格式：

Wolfram Language code: TraditionalForm[Erfc[x]]

应用 (5)

NormalDistribution 的 CDF 可以表示为补余误差函数：

Wolfram Language code: CDF[NormalDistribution[0, σ], x]

随机值大于的概率：

Wolfram Language code: Probability[x > n σ, xNormalDistribution[0, σ], Assumptions -> n > 0]

Wolfram Language code: Table[%, {n, 1, 3}]//N

求解关于分段常量初始条件的热方程：

Wolfram Language code: temp[x_, t_] := With[{η = (1/2 Sqrt[t])}, (Erfc[(x - 1)η] - Erfc[(x + 1)η]) / 2]

检验解是否满足热方程：

Wolfram Language code: D[temp[x, t], t] == D[temp[x, t], x, x]// Simplify

绘制不同时间的解：

Wolfram Language code: Plot[Evaluate[{temp[x, 0.01], temp[x, 0.2], temp[x, 0.6], temp[x, 1.5]}], {x, -4, 4}]

定义通过 HermiteH 补余误差函数：

Wolfram Language code: FullSimplify[2HermiteH[-1, x] / Sqrt[Pi]]

Wolfram Language code: Plot[%, {x, 0, 10}]

阴影边缘的干涉图案：

Wolfram Language code: Plot[(1/2)Abs[Exp[-(π I x^2/2)]Erfc[((1 - I/2))Sqrt[π]x]]^2, {x, -8, 8}]

装置的寿命遵循 Birnbaum–Saunders 分布. 求装置的可靠性：

Wolfram Language code: r = SurvivalFunction[BirnbaumSaundersDistribution[α, λ], t]

风险函数的水平渐近线为：

Wolfram Language code: Limit[Refine[HazardFunction[BirnbaumSaundersDistribution[α, 1], t], t > 0], t -> ∞, Assumptions -> α > 0]

Wolfram Language code: Limit[Refine[HazardFunction[BirnbaumSaundersDistribution[1, λ], t], t > 0], t -> ∞, Assumptions -> λ > 0]

求两个串联装置的可靠性：

Wolfram Language code: rs = r r//PiecewiseExpand

求两个并联装置的可靠性：

Wolfram Language code: rp = 1 - (1 - r)(1 - r)//PiecewiseExpand

比较两个系统在且时的可靠性：

Wolfram Language code: Block[{α = 0.8, λ = 1.2}, Plot[{rs, rp}, {t, 0, 5}, PlotLegends -> {"in series", "in parallel"}]]

属性和关系 (3)

用 FunctionExpand 来转换成其它函数：

Wolfram Language code: FunctionExpand[Erfc[x]]

Wolfram Language code: FullSimplify[%]

用反函数组成：

Wolfram Language code: {Erfc[InverseErfc[z]], InverseErfc[Erfc[z]]}

Wolfram Language code: PowerExpand[%]

求解超越方程：

Wolfram Language code: Solve[Erfc[x] == 1 / 2, x]

可能存在的问题 (3)

对于较大的参数，中间值可能会下溢：

Wolfram Language code: Erfc[-2 10 ^ 8 - 10. ^ 3 I]

实部参数为较大的虚数时，误差函数非常接近2：

Wolfram Language code: Erfc[-30`16 + 10 ^ -1 I]

对于非常大的参数，可能会给出未经计算的结果：

Wolfram Language code: Erfc[10. ^ 100 I]

巧妙范例 (1)

部分分子为连续整数的连分数：

Wolfram Language code: With[{n = 20}, 1 / (1 + ContinuedFractionK[HoldForm[k], 1, {k, n}])]

其极限可以用 Erfc 来表示：

Wolfram Language code: 1 / (1 + ContinuedFractionK[k, 1, {k, ∞}])

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Erfc

更多信息

范例

基本范例 (5)