WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ExternalOperation["Eval","code"]

"code"の外部評価器を表す．

ExternalOperation["Eval","code",assoc]

パラメータが assoc で与えられる，"code"の外部評価器を表す．

ExternalOperation["Call",func,arg1,arg2,…]

指定された引数 arg1, arg2, …で関数 func を呼び出す．

ExternalOperation["GetAttribute",obj,"attr"]

obj の特性"attr"を取得する．

ExternalOperation["SetAttribute",obj,"attr",val]

obj の属性"attr"を指定された値 val に設定する．

ExternalOperation["Cast",obj,"type"]

obj の型を指定された"type"に変換する．

ExternalOperation["op", arg1,arg2,…]

引数 arg1, arg2, ….を使って"op"という名前の外部操作を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
外部操作  
"Eval"  
"Call"  
"GetAttribute"  
"SetAttribute"  
"Cast"  
特性と関係  
関連項目
関連するガイド
関連するワークフロー
履歴
引用書式

ExternalOperation   

外部評価器のリスト »

ExternalOperation["Eval","code"]

"code"の外部評価器を表す．

ExternalOperation["Eval","code",assoc]

パラメータが assoc で与えられる，"code"の外部評価器を表す．

ExternalOperation["Call",func,arg1,arg2,…]

指定された引数 arg1, arg2, …で関数 func を呼び出す．

ExternalOperation["GetAttribute",obj,"attr"]

obj の特性"attr"を取得する．

ExternalOperation["SetAttribute",obj,"attr",val]

obj の属性"attr"を指定された値 val に設定する．

ExternalOperation["Cast",obj,"type"]

obj の型を指定された"type"に変換する．

ExternalOperation["op", arg1,arg2,…]

引数 arg1, arg2, ….を使って"op"という名前の外部操作を表す．

詳細

例題

すべて開く すべて閉じる

例  (1)

コード"2+2"を評価するExternalOperationを作成する：

Wolfram Language code: op = ExternalOperation["Eval", "2+2"]

ExternalEvaluateを使って操作を実行する：

Wolfram Language code: ExternalEvaluate["Python", op]

スコープ  (7)

ExternalOperationは評価しない：

Wolfram Language code: call = ExternalOperation["Call"]

下向きの値を使って引数を累積することができる：

Wolfram Language code: op = call[ExternalOperation["Eval", "max"], 1, 2]

ExternalEvaluateを使って操作を実行する：

Wolfram Language code: ExternalEvaluate["Python", op]

"GetAttribute"操作の操作形式を定義する：

Wolfram Language code: yeargetter = ExternalOperation["GetAttribute", "year"]

Pythonセッションを開始する：

Wolfram Language code: session = StartExternalSession["Python"]

ExternalObjectを作成する：

Wolfram Language code: date = ExternalEvaluate[session, <|"Command" -> ExternalOperation["Import", "datetime", "date"], "Arguments" -> {2012, 10, 10}, "ReturnType" -> "ExternalObject"|>]

指定された属性のオブジェクトに演算子を使用する：

Wolfram Language code: date[yeargetter]

新たな操作を作って同じことを行うこともできる：

Wolfram Language code: year = yeargetter[date]

この操作はExternalEvaluateを使って評価する必要がある：

Wolfram Language code: ExternalEvaluate[session, year]

セッションを閉じる：

Wolfram Language code: DeleteObject[session]

外部操作  (5)

"Eval"  (1)

Pythonを使った任意のコード評価を表すExternalOperationを実行する：

Wolfram Language code: ExternalEvaluate["Python", ExternalOperation["Eval", "2+2"]]

第2引数を使って評価内容を渡す：

Wolfram Language code: ExternalEvaluate["Python", ExternalOperation["Eval", "a + b", <|"a" -> 2, "b" -> 3|>]]

"Call"  (1)

Pythonで関数を作成するExternalOperationを定義する：

Wolfram Language code: op = ExternalOperation["Eval", "max"]

ExternalOperation "Call"を実行して関数を呼び出す：

Wolfram Language code: call = ExternalOperation["Call", op, 1, 2]

ExternalEvaluateを使って操作を実行する：

Wolfram Language code: ExternalEvaluate["Python", call]

"Call"操作の任意の引数はExternalOperationでよい：

Wolfram Language code: ExternalEvaluate["Python", ExternalOperation["Call", op, 1, ExternalOperation["Eval", "2+2"]]]

引数は，以下を実行してExternalEvaluate内で直接渡すこともできる：

Wolfram Language code: ExternalEvaluate["Python", op -> {1, 2}]

結果は以下のPythonコードを実行することに等しい：

Wolfram Language code: ExternalEvaluate["Python", "max(1, 2)"]

"GetAttribute"  (1)

日付を扱うPythonセッションを開始する：

Wolfram Language code: session = StartExternalSession[{"Python", "SessionProlog" -> "import datetime"}];

日付時刻オブジェクトのためのExternalObjectを返す：

Wolfram Language code: now = ExternalEvaluate[session, <|"Command" -> "datetime.datetime.now()", "ReturnType" -> "ExternalObject"|>]

"GetAttribute"を使って年属性を抽出する：

Wolfram Language code: ExternalEvaluate[session, ExternalOperation["GetAttribute", now, "year"]]

結果は以下のPythonコードを実行することに等しい：

Wolfram Language code: ExternalEvaluate[session, "datetime.datetime.now().year"]

セッションを削除する：

Wolfram Language code: DeleteObject[session]

"SetAttribute"  (1)

十進数を扱うPythonセッションを開始する：

Wolfram Language code: session = StartExternalSession[{"Python", "SessionProlog" -> "from decimal import getcontext, Decimal"}];

十進法モジュールの内容を取得する：

Wolfram Language code: context = ExternalEvaluate[session, "getcontext()"]

精度を6に設定する：

Wolfram Language code: ExternalEvaluate[session, ExternalOperation["SetAttribute", context, "prec", 6]]

精度が6に設定されたことをチェックする：

Wolfram Language code: ExternalEvaluate[session, ExternalOperation["GetAttribute", context, "prec"]]
Wolfram Language code: ExternalEvaluate[session, "Decimal('0') + Decimal('0.123456789')"]

結果は以下のPythonコードを実行することに等しい：

Wolfram Language code: ExternalEvaluate[session, "getcontext().prec = 6"]

セッションを削除する：

Wolfram Language code: DeleteObject[session]

"Cast"  (1)

現在の日付を表すExternalObjectを作成する：

Wolfram Language code: session = StartExternalSession["Python"];
Wolfram Language code: now = ExternalEvaluate[session, <|"Command" -> "import datetime; datetime.datetime.now()", "ReturnType" -> "ExternalObject"|>]

"Expression"を使ってオブジェクトをWolfram言語の式として返す：

Wolfram Language code: ExternalEvaluate[session, ExternalOperation["Cast", now, "Expression"]]

Cast操作はExternalObjectサブ値の中でも実行できる：

Wolfram Language code: now[ExternalOperation["Cast", "Expression"]]

シンボルExpressionは同じことへのショートカットである：

Wolfram Language code: now[Expression]

オブジェクトを文字列として返す：

Wolfram Language code: now[ExternalOperation["Cast", "String"]]

シンボルStringは同じことへのショートカットである：

Wolfram Language code: now[String]

オブジェクトをExternalObjectとして返す：

Wolfram Language code: now[ExternalOperation["Cast", "ExternalObject"]]

シンボルExternalObjectは同じことへのショートカットである：

Wolfram Language code: now[ExternalObject]

ExternalEvaluateで"ReturnType"を使っても同じことができる：

Wolfram Language code: ExternalEvaluate[session, <|"Command" -> now, "ReturnType" -> "String"|>]

セッションを削除する：

Wolfram Language code: DeleteObject[session]

特性と関係  (5)

ExternalOperationを使ってExternalObjectから操作が抽出できる：

Wolfram Language code: ExternalOperation[ExternalObject["Python", "2+2"]]

ExternalFunctionを使っても同じことができる：

Wolfram Language code: ExternalOperation[ExternalFunction["Python", "str"]]

ExternalOperationは，ExternalFunctionの引数として使うことができる：

Wolfram Language code: ExternalFunction["Python", "len"][ExternalOperation["Eval", "[1, 2, 3]"]]

ExternalEvaluateを使っても同じことができる：

Wolfram Language code: ExternalEvaluate["Python", "len" -> ExternalOperation["Eval", "[1, 2, 3]"]]

ExternalOperationはExternalObjectの引数として使うことができる：

Wolfram Language code: ExternalObject["Python", "len"][ExternalOperation["Call", {1, 2, 3}]]

実行された操作は以下と同じである：

Wolfram Language code: op = ExternalOperation["Call", {1, 2, 3}][ExternalObject["Python", "len"]]

これは，ExternalEvaluateを使って行うこともできる：

Wolfram Language code: ExternalEvaluate["Python", op]

結果は以下のPythonコードを実行することに等しい：

Wolfram Language code: ExternalEvaluate["Python", "len((1, 2, 3))"]

システムモジュールに使えるExternalObjectを作成する：

Wolfram Language code: sys = ExternalObject["Python", ExternalOperation["Import", "sys"]]

文字列が使われると，"GetAttribute"の操作がPythonを含むほとんどの評価で実行される：

Wolfram Language code: sys["maxsize"]

結果は明示的に"GetAttribute"操作を実行することに等しい：

Wolfram Language code: sys[ExternalOperation["GetAttribute", "maxsize"]]

ExternalObjectの複数の引数を使うことで複数の操作が結合できる：

Wolfram Language code: uuid = ExternalObject["Python", ExternalOperation["Import", "uuid"]]
Wolfram Language code: uuid[ExternalOperation["GetAttribute", "uuid4"], ExternalOperation["Call"], ExternalOperation["Cast", "String"]]

これは，以下のように，より簡潔に書くことができる：

Wolfram Language code: uuid["uuid4" -> {}, String]
Wolfram Research (2024), ExternalOperation, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExternalOperation.html.

テキスト

Wolfram Research (2024), ExternalOperation, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExternalOperation.html.

CMS

Wolfram Language. 2024. "ExternalOperation." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ExternalOperation.html.

APA

Wolfram Language. (2024). ExternalOperation. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ExternalOperation.html

BibTeX

@misc{reference.wolfram_2026_externaloperation, author="Wolfram Research", title="{ExternalOperation}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/ExternalOperation.html}", note=[Accessed: 18-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_externaloperation, organization={Wolfram Research}, title={ExternalOperation}, year={2024}, url={https://reference.wolfram.com/language/ref/ExternalOperation.html}, note=[Accessed: 18-June-2026]}