WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FARIMAProcess[{a1,…,ap},d,{b1,…,bq},v]

d 次差分がARMAProcess[{a1,…,ap},{b1,…,bq},v]であるような，FARIMA（自己回帰実数和分移動平均）過程 を表す．

FARIMAProcess[{a1,…,ap},d,{b1,…,bq},Σ]

(d,…,d)次差分がベクトルARMAProcessであるような，ベクトルFARIMA過程(y1(t),… ,yn(t))を表す．

FARIMAProcess[{a1,…,ap},{d1,…,dn},{b1,…,bq},Σ]

(d1,…,dn)次差分がベクトルARMAProcessであるような，ベクトルFARIMA過程(y1(t),… ,yn(t))を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
共分散とスペクトル  
定常性と可逆性  
推定法  
過程スライス特性  
表現  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

FARIMAProcess

FARIMAProcess[{a1,…,ap},d,{b1,…,bq},v]

d 次差分がARMAProcess[{a1,…,ap},{b1,…,bq},v]であるような，FARIMA（自己回帰実数和分移動平均）過程 を表す．

FARIMAProcess[{a1,…,ap},d,{b1,…,bq},Σ]

(d,…,d)次差分がベクトルARMAProcessであるような，ベクトルFARIMA過程(y1(t),… ,yn(t))を表す．

FARIMAProcess[{a1,…,ap},{d1,…,dn},{b1,…,bq},Σ]

(d1,…,dn)次差分がベクトルARMAProcessであるような，ベクトルFARIMA過程(y1(t),… ,yn(t))を表す．

詳細

  • FARIMAProcessは，ARFIMAあるいは長期記憶時系列としても知られている．
  • FARIMAProcessは，離散時間・連続状態のランダム過程である．
  • FARIMA過程は差分方程式で説明される．ただし，は状態出力，はホワイトノイズ入力，はシフト演算子である．
  • スカラーFARIMA過程には伝達関数 がある．ただし，である．
  • ベクトルFARIMA 過程には伝達行列 がある．ただし，であり， は × 恒等行列である．
  • スカラーFARIMA過程には，実数係数 ai，bj，となるような実数の和分母数 d，正の分散 v がなければならない．
  • 次元のベクトルFARIMA過程には，次元が × の実数係数行列 aiと bj， となるような実数の和分母数 di，あるいは となるような実数和分の母数 d がなければならず，共分散行列 Σ は次元 × の正定値対称行列でなければならない．
  • FARIMAProcess[p,d,q]およびFARIMAProcess[p,q]は，EstimatedProcessおよび関連関数で使用するための，既知あるいは未知の積分次数 d を持つ次数 p および q のFARIMA過程を表す．
  • FARIMAProcessは，CovarianceFunction，RandomFunction，TimeSeriesForecast等の関数で使うことができる．

例題

すべて開く すべて閉じる

例  (3)

FARIMA過程のシミュレーションを行う：

Wolfram Language code: sample = RandomFunction[FARIMAProcess[{.1}, .3, {-.3}, 1], {0, 10 ^ 2}]
Wolfram Language code: ListPlot[sample, Filling -> Axis]

共分散関数：

Wolfram Language code: CovarianceFunction[FARIMAProcess[{}, d, {}, σ^2], s, t]
Wolfram Language code: DiscretePlot3D[CovarianceFunction[FARIMAProcess[{.1}, .4, {.4}, 1], s, t], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

相関関数：

Wolfram Language code: DiscretePlot[CorrelationFunction[FARIMAProcess[{.1}, .2, {.3}, 1], h], {h, 0, 20}, ExtentSize -> 1 / 2]

偏相関関数：

Wolfram Language code: DiscretePlot[PartialCorrelationFunction[FARIMAProcess[{}, .2, {}, 1], h], {h, 1, 30}, ExtentSize -> 1 / 2]

スコープ  (25)

基本的な用法  (8)

経路の集合のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[FARIMAProcess[{.5}, .3, {.3}, 1], {30}, 4]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

指定精度でシミュレーションを行う：

Wolfram Language code: RandomFunction[FARIMAProcess[{2 / 10, 1 / 10}, 1 / 3, {2 / 7}, 1 / 10], {1, 4}, WorkingPrecision -> 20]["Path"]

一次スカラー過程のシミュレーションを行う：

Wolfram Language code: sample[d_] := (SeedRandom[3];RandomFunction[FARIMAProcess[{.1}, d, {.2}, .1], {1, 2 10 ^ 2}]);

和分の母数の正と負の値についてのサンプル経路：

Wolfram Language code: ListPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["d = ", ToString[#]]]& /@ {-.4, .4}

二次元過程のシミュレーションを行う：

Wolfram Language code: α = {{.2, .1}, {-.3, .2}}; β = {{.2, .5}, {-.2, .9}}; δ = {.2, -.4}; Σ = {{1, 0}, {0, .3}}; sample = RandomFunction[FARIMAProcess[{α}, δ, {β}, Σ], {1, 10 ^ 2}];

データから2Dサンプル経路関数を作る：

Wolfram Language code: s = TimeSeries[sample, ResamplingMethod -> Automatic]; f = s["PathFunction"]; g[t_ ? NumericQ] := f[t]

経路の色は時間の関数である：

Wolfram Language code: ParametricPlot[g[t], {t, 1, 100}, ColorFunction -> Function[{x, y, t}, (ColorData["BlueGreenYellow"][t])], PlotStyle -> Thick, AspectRatio -> 1, AxesLabel -> {x, y}]

時間を含む3Dサンプル経路関数を作る：

Wolfram Language code: gg[t_ ? NumericQ] := Join[{t}, f[t]]

経路の色は，時間の関数である：

Wolfram Language code: ParametricPlot3D[gg[t], {t, 1, 100}, ColorFunction -> Function[{t, x, y}, (ColorData["BlueGreenYellow"][t])], PlotStyle -> Thick, BoxRatios -> 1, AxesLabel -> {t, x, y}]

三次元過程のシミュレーションを行う：

Wolfram Language code: α = {{.2, .1, .1}, {-.3, .2, .1}, {-.3, .2, -.1}}; β = {{.2, .5, .1}, {-.2, .9, .5}, {.3, .1, -.4}}; δ = {.2, .4, .3}; Σ = {{1, 0, 0}, {0, .3, 0}, {0, 0, .1}}; SeedRandom[4];sample = RandomFunction[FARIMAProcess[{α}, δ, {β}, Σ], {1, 10 ^ 2}];

データからサンプル経路関数を作る：

Wolfram Language code: s = TimeSeries[sample, ResamplingMethod -> Automatic]; f = s["PathFunction"]; g[t_ ? NumericQ] := f[t]

経路の色は時間の関数である：

Wolfram Language code: ParametricPlot3D[g[t], {t, 1, 100}, ColorFunction -> Function[{x, y, z, t}, (ColorData["BlueGreenYellow"][t])], PlotStyle -> Thick, BoxRatios -> 1, AxesLabel -> {x, y, z}]

過程の母数を推定する：

Wolfram Language code: sample = RandomFunction[FARIMAProcess[{.3}, .2, {.5}, .1], {1, 10 ^ 3}]; eproc = EstimatedProcess[sample, FARIMAProcess[1, 1]]

サンプルの共分散関数と推定過程の共分散関数を比べる：

Wolfram Language code: Show[ListPlot[CovarianceFunction[sample, {8}], Filling -> 0, PlotStyle -> {PointSize[Large], Orange}], DiscretePlot[CovarianceFunction[eproc, h], {h, 0, 8}, ExtentSize -> 1 / 2]]

非整数ノイズの和分次数を推定する：

Wolfram Language code: sample = RandomFunction[FARIMAProcess[{}, .2, {}, .1], {1, 10 ^ 3}]; eproc = EstimatedProcess[sample, FARIMAProcess[0, d, 0], ProcessEstimator -> "MethodOfMoments"]

サンプルの相関関数と推定過程の共分散関数を比べる：

Wolfram Language code: Show[ListPlot[CorrelationFunction[sample, {12}], Filling -> 0, PlotStyle -> {PointSize[Large], Orange}, PlotRange -> {0, 1}], DiscretePlot[CorrelationFunction[eproc, h], {h, 0, 12}, ExtentSize -> 1 / 2, PlotRange -> {0, 1}]]

将来価値を予測する：

Wolfram Language code: proc = FARIMAProcess[{.7}, .4, {-.3}, .1];sample = RandomFunction[proc, {1, 10 ^ 2}];

次の20ステップについての予測を求める：

Wolfram Language code: forecast = TimeSeriesForecast[proc, sample, {20}]

予測経路を示す：

Wolfram Language code: forecast["Path"]

データと予測された値をプロットする：

Wolfram Language code: ListLinePlot[{sample, forecast}, InterpolationOrder -> 0, Filling -> Axis]

共分散とスペクトル  (5)

純粋なFARIMAの閉形式の相関関数：

Wolfram Language code: CorrelationFunction[FARIMAProcess[{}, d, {}, σ^2], h]

数値的に使用できる自己回帰要素と移動平均要素を含むFARIMAについて：

Wolfram Language code: Table[CorrelationFunction[FARIMAProcess[{1 / 3}, .2, {1, 2}, 1], h], {h, 0, 5}]

偏相関は，特殊ケースについて閉形式を持つ：

Wolfram Language code: PartialCorrelationFunction[FARIMAProcess[{}, d, {}, σ^2], h]

相関行列：

Wolfram Language code: Correlation[FARIMAProcess[{.1}, .3, {.4}, 1][{1, 2, 3}]]//MatrixForm

純粋なFARIMAの特殊ケース：

Wolfram Language code: Correlation[FARIMAProcess[{}, d, {}, σ^2][{s, t}]]//MatrixForm

共分散行列：

Wolfram Language code: Covariance[FARIMAProcess[{.1}, .3, {.4}, 1][{1, 2, 3}]]//MatrixForm

純粋なFARIMAの特殊ケース：

Wolfram Language code: Covariance[FARIMAProcess[{}, d, {}, σ^2][{s, t}]]//MatrixForm

パワースペクトル密度：

Wolfram Language code: Plot[PowerSpectralDensity[FARIMAProcess[{-.6, -.7}, .3, {.4, .3}, 1], w], {w, -π, π}, Filling -> Axis]
Wolfram Language code: PowerSpectralDensity[FARIMAProcess[{a}, d, {b}, σ^2], w]

ベクトルFARIMAProcess：

Wolfram Language code: a = {{1 / 9, 0}, {1 / 3, 1 / 2}}; b = {{1, 1 / 4}, {1 / 2, 0}}; Σ = {{1, 0}, {0, 1}}; proc = FARIMAProcess[{a}, {1 / 3, -1 / 4}, {b}, Σ];
Wolfram Language code: psd = PowerSpectralDensity[proc, ω]; psd//FullSimplify//MatrixForm

定常性と可逆性  (4)

時系列が弱定常かどうかを調べる：

Wolfram Language code: WeakStationarity[FARIMAProcess[{1, 2}, .2, {3}, 1]]
Wolfram Language code: WeakStationarity[FARIMAProcess[{}, .2, {3}, 1]]

過程が弱定常になる条件を求める：

Wolfram Language code: WeakStationarity[FARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, d, {Subscript[b, 1], Subscript[b, 2]}, σ^2]]

可逆条件を求める：

Wolfram Language code: TimeSeriesInvertibility[FARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, d, {Subscript[b, 1], Subscript[b, 2]}, σ^2]]

時系列が可逆かどうかを調べる：

Wolfram Language code: proc = FARIMAProcess[{1 / 3}, 1 / 4, {1, 2}, 1];
Wolfram Language code: TimeSeriesInvertibility[proc]

その可逆表現を求める：

Wolfram Language code: ToInvertibleTimeSeries[proc]

推定法  (2)

FARIMAProcessの推定に使用可能なメソッド：

Wolfram Language code: methods = {Automatic, "SpectralEstimator"};
Wolfram Language code: SeedRandom[111]; data = RandomFunction[FARIMAProcess[{.4}, -.4, {.3}, 1], {100}];
Wolfram Language code: Grid[res = Table[{m, EstimatedProcess[data, FARIMAProcess[1, 1], ProcessEstimator -> m]}, {m, methods}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

対数尤度法を比較する：

Wolfram Language code: LogLikelihood[#[[2]], data]& /@ res

非整数ノイズの推定に使用可能なメソッド：

Wolfram Language code: methods = {Automatic, "SpectralEstimator", "MethodOfMoments"};
Wolfram Language code: SeedRandom[11]; data = RandomFunction[FARIMAProcess[{}, -.4, {}, 1], {100}];
Wolfram Language code: Grid[res = Table[{m, EstimatedProcess[data, FARIMAProcess[0, 0], ProcessEstimator -> m]}, {m, methods}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

スペクトル推定器では，PowerSpectralDensityの計算に使う窓を指定することができる：

Wolfram Language code: SeedRandom[11]; data = RandomFunction[FARIMAProcess[{.4, .2}, .3, {.3}, 1], {100}];
Wolfram Language code: Grid[Table[{m, EstimatedProcess[data, FARIMAProcess[2, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> m}]}, {m, {10, BartlettWindow, {3, HannWindow}}}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

スペクトル推定器では次のソルバを使うことができる：

Wolfram Language code: solvers = {Automatic, "FindMinimum", "NMinimize"};
Wolfram Language code: Grid[Table[{m, EstimatedProcess[data, FARIMAProcess[2, 1], ProcessEstimator -> {"SpectralEstimator", Method -> m}]}, {m, solvers}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

このメソッドでは固定母数を使うことができる：

Wolfram Language code: EstimatedProcess[data, FARIMAProcess[{.1, b}, d, {m}, v], ProcessEstimator -> "SpectralEstimator"]

母数間のある種の関係も使うことができる：

Wolfram Language code: EstimatedProcess[data, FARIMAProcess[{b, b}, d, {m}, v], ProcessEstimator -> "SpectralEstimator"]

過程スライス特性  (5)

単一の時間スライス分布（SliceDistribution）：

Wolfram Language code: SliceDistribution[FARIMAProcess[{.1}, .2, {.4}, 1], t]

複数の時間スライス分布：

Wolfram Language code: SliceDistribution[FARIMAProcess[{.1}, .2, {.4}, 1], {s, s + 3}]
Wolfram Language code: SliceDistribution[FARIMAProcess[{.1}, .2, {.4}, 1], {1, 2, 3}]

一次確率密度関数：

Wolfram Language code: pdf = PDF[FARIMAProcess[{.1}, .2, {.4}, 1][t], x]
Wolfram Language code: Plot[pdf, {x, -4, 4}, Filling -> Axis]

定常の平均と分散：

Wolfram Language code: μ = Mean[FARIMAProcess[{.1}, .2, {.4}, 1][∞]]
Wolfram Language code: v = Variance[FARIMAProcess[{.1}, .2, {.4}, 1][∞]]

正規分布の密度関数と比べる：

Wolfram Language code: PDF[NormalDistribution[μ, Sqrt[v]], x]
Wolfram Language code: FullSimplify[% - PDF[FARIMAProcess[{.1}, .2, {.4}, 1][∞], x]]

式の期待値を計算する：

Wolfram Language code: Expectation[x[t]^2, xFARIMAProcess[{.1}, .2, {.4}, 1.]]

確率を計算する：

Wolfram Language code: Probability[x[t] < 6, xFARIMAProcess[{.1}, .2, {.4}, 1]]

歪度と尖度：

Wolfram Language code: Skewness[FARIMAProcess[{.1}, .2, {.4}, 1][t]]
Wolfram Language code: Kurtosis[FARIMAProcess[{.1}, .2, {.4}, 1][t]]

次数 r のMoment：

Wolfram Language code: Moment[FARIMAProcess[{.1}, .2, {.4}, 1][t], r]

母関数：

Wolfram Language code: CharacteristicFunction[FARIMAProcess[{.1}, .2, {.4}, 1][t], w]
Wolfram Language code: MomentGeneratingFunction[FARIMAProcess[{.1}, .2, {.4}, 1][t], w]

CentralMomentとその母関数：

Wolfram Language code: CentralMoment[FARIMAProcess[{.1}, .2, {.4}, 1][t], r]
Wolfram Language code: CentralMomentGeneratingFunction[FARIMAProcess[{.1}, .2, {.4}, 1][t], w]

FactorialMomentは，記号次数の閉形式を持たない：

Wolfram Language code: FactorialMoment[FARIMAProcess[{.1}, .2, {.4}, 1][t], 3]
Wolfram Language code: FactorialMomentGeneratingFunction[FARIMAProcess[{.1}, .2, {.4}, 1][t], w]

Cumulantとその母関数：

Wolfram Language code: Cumulant[FARIMAProcess[{.1}, .2, {.4}, 1][t], r]
Wolfram Language code: CumulantGeneratingFunction[FARIMAProcess[{.1}, .2, {.4}, 1][t], w]

表現  (1)

ARMAProcessで近似する：

Wolfram Language code: ARMAProcess[FARIMAProcess[{.2, .3}, .4, {.1}, 1], {5, 3}]

MAProcessで近似する：

Wolfram Language code: MAProcess[FARIMAProcess[{.2, .3}, .4, {.1}, 1], 5]

ARProcessで近似する：

Wolfram Language code: proc = FARIMAProcess[{.2, .3}, .4, {.1}, 1]; aproc = ARProcess[proc, 5]

過程のランダムサンプルとその近似を比べる：

Wolfram Language code: SeedRandom[13];sample = RandomFunction[proc, {100}]; SeedRandom[13];asample = RandomFunction[aproc, {100}]; ListLinePlot[{sample, asample}, PlotLegends -> {"FARIMA", "AR"}]

アプリケーション  (1)

西暦622年から1284年までのナイル川の年ごとの最低水位を，時系列として考察する：

Wolfram Language code: NileFlow = TemporalData[TimeSeries, {{{1157, 1088, 1169, 1169, 984, 1322, 1178, 1103, 1211, 1292, 1124, 1171, 1133, 1227, 1142, 1216, 1259, 1299, 1232, 1117, 1155, 1232, 1083, 1020, 1394, 1196, 1148, 1083, 1189, 1133, 1034, 1157, 1034, 1097, 1299, 1 ... 1187, 1254, 1198, 1263, 1283, 1252, 1160, 1234, 1234, 1232, 1306, 1205, 1054, 1151, 1108, 1097}}, {{622, 1284, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];
Wolfram Language code: ListLinePlot[NileFlow, Filling -> Axis, PlotRange -> {{622, 1284}, All}]

データを集中させる：

Wolfram Language code: cNileFlow = Standardize[NileFlow, Mean, 1&]

FARIMAモデルを求める：

Wolfram Language code: eproc = EstimatedProcess[cNileFlow, FARIMAProcess[{a}, d, {}, v]]

将来価値を予測する：

Wolfram Language code: f = TimeSeriesForecast[eproc, cNileFlow, {1, 100}]

平均レベルと適切なタイムスタンプに調整し直す：

Wolfram Language code: forecast = Mean[NileFlow] + f

ナイル川の最小流量を100年間の予測とともにプロットする：

Wolfram Language code: ListLinePlot[{NileFlow, forecast}, Filling -> Axis, PlotRange -> {{622, 1384}, All}]

特性と関係  (5)

相関は-1/2<d<0について加算可能である：

Wolfram Language code: Sum[CorrelationFunction[FARIMAProcess[{}, d, {}, 1], h], {h, 0, ∞}, Assumptions -> -1 / 2 < d < 0]

0<d<1/2では，相関の総和は発散する：

Wolfram Language code: sums = Accumulate[CorrelationFunction[FARIMAProcess[{}, .3, {}, 1], {0, 1000}]]; ListPlot[sums]

FARIMAProcessは，正の和分次数についての長期記憶を持つ：

Wolfram Language code: proc[d_] := FARIMAProcess[{}, d, {}, 1];
Wolfram Language code: DiscretePlot[CovarianceFunction[proc[#], k], {k, 1, 50, 5}, ExtentSize -> 1 / 2, PlotRange -> {-.3, .6}, PlotLabel -> StringJoin["d = ", ToString[#]]]& /@ {-.3, -.2, .2, .3}

FARIMAProcessは，ARMAProcessを一般化したものである：

Wolfram Language code: TransferFunctionModel[FARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, 0, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]
Wolfram Language code: TransferFunctionModel[ARMAProcess[{Subscript[a, 1], Subscript[a, 2]}, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]
Wolfram Language code: % - %%

FARIMAProcessは，ARProcessを一般化したものである：

Wolfram Language code: TransferFunctionModel[FARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, 0, {}, σ^2], z]
Wolfram Language code: TransferFunctionModel[ARProcess[{Subscript[a, 1], Subscript[a, 2]}, σ^2], z]
Wolfram Language code: % - %%

FARIMAProcessは，MAProcessを一般化したものである：

Wolfram Language code: TransferFunctionModel[FARIMAProcess[{}, 0, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]
Wolfram Language code: TransferFunctionModel[MAProcess[{Subscript[b, 1], Subscript[b, 2]}, σ^2], z]
Wolfram Language code: % - %%

考えられる問題  (2)

ToInvertibleTimeSeriesは常に存在するとは限らない：

Wolfram Language code: ToInvertibleTimeSeries[FARIMAProcess[{.2}, .3, {.3, 1}, .2]]

モーメント法は，非整数ノイズの推定についてのみサポートされている：

Wolfram Language code: sample = RandomFunction[FARIMAProcess[{}, .2, {}, .1], {1, 10 ^ 3}];
Wolfram Language code: EstimatedProcess[sample, FARIMAProcess[{a}, d, {b}, v], ProcessEstimator -> "MethodOfMoments"]

別のソルバを使う：

Wolfram Language code: EstimatedProcess[sample, FARIMAProcess[{a}, d, {b}, v], ProcessEstimator -> Automatic]

おもしろい例題  (2)

三次元FARIMAProcessのシミュレーションを行う：

Wolfram Language code: A = {{.2, .1, .1}, {0, -.2, .3}, {.2, -.1, .3}}; B = {{.1, .2, -.1}, {-.1, .3, .1}, {.1, .1, 0}}; S = {{.8, .1, -.2}, {.1, .5, .1}, {-.2, .1, .3}}; proc = FARIMAProcess[{A}, {.3, .2, .4}, {B}, S]; data = RandomFunction[proc, {100}, k = 3]["ValueList"];
Wolfram Language code: Graphics3D@Table[{ColorData["SolarColors"][RandomReal[]], Tube@Line@data[[i]]}, {i, k}]

FARIMA過程からの経路のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[FARIMAProcess[{.3}, .2, {.6}, 1], {50}, 200];

50におけるスライスを取り，その分布を可視化する：

Wolfram Language code: sd = data["SliceData", 50];
Wolfram Language code: cf = ColorData["Rainbow"]; sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 55]&[HistogramList[sd, {Range[Min[sd], Max[sd], (Max[sd] - Min[sd]) / 20]}]];

50におけるスライス分布の経路とヒストグラム分布をプロットする：

Wolfram Language code: ListLinePlot[data, ImageSize -> 400, PlotRange -> All, AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {51, 0}, {0, 10}], PlotStyle -> (cf /@ Rescale[sd]), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, 15}, {.5, .5}}]
Wolfram Research (2012), FARIMAProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/FARIMAProcess.html.

テキスト

Wolfram Research (2012), FARIMAProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/FARIMAProcess.html.

CMS

Wolfram Language. 2012. "FARIMAProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FARIMAProcess.html.

APA

Wolfram Language. (2012). FARIMAProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FARIMAProcess.html

BibTeX

@misc{reference.wolfram_2026_farimaprocess, author="Wolfram Research", title="{FARIMAProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/FARIMAProcess.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_farimaprocess, organization={Wolfram Research}, title={FARIMAProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/FARIMAProcess.html}, note=[Accessed: 12-September-2026]}