WOLFRAM

Wolfram 语言与系统参考资料中心

FARIMAProcess[{a1,…,ap},d,{b1,…,bq},v]

表示自回归分数整合滑动平均过程 以满足它的第 d 阶差分是一个 ARMAProcess[{a1,…,ap},{b1,…,bq,v].

FARIMAProcess[{a1,…,ap},d,{b1,…,bq},Σ]

表示向量自回归分数整合滑动平均过程 (y1(t),… ,yn(t)) 以满足它的第 (d,…,d) 阶差分是一个向量 ARMAProcess.

FARIMAProcess[{a1,…,ap},{d1,…,dn},{b1,…,bq},Σ]

表示向量自回归分数整合滑动平均过程 (y1(t),… ,yn(t)) 以满足它的第 (d1,…,dn) 阶差分是一个向量 ARMAProcess.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
协方差和谱函数  
平稳性和可逆性  
估计方法  
过程切片性质  
表示法  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

FARIMAProcess

FARIMAProcess[{a1,…,ap},d,{b1,…,bq},v]

表示自回归分数整合滑动平均过程 以满足它的第 d 阶差分是一个 ARMAProcess[{a1,…,ap},{b1,…,bq,v].

FARIMAProcess[{a1,…,ap},d,{b1,…,bq},Σ]

表示向量自回归分数整合滑动平均过程 (y1(t),… ,yn(t)) 以满足它的第 (d,…,d) 阶差分是一个向量 ARMAProcess.

FARIMAProcess[{a1,…,ap},{d1,…,dn},{b1,…,bq},Σ]

表示向量自回归分数整合滑动平均过程 (y1(t),… ,yn(t)) 以满足它的第 (d1,…,dn) 阶差分是一个向量 ARMAProcess.

更多信息

  • FARIMAProcess 也称为 ARFIMA 或者长记忆时间序列.
  • FARIMAProcess 是离散时间和连续状态随机过程.
  • FARIMA 过程由差分方程 描述，其中 是状态输出， 是白噪声输入，而 是平移算子.
  • 标量 FARIMA 过程具有传递函数 ，其中 .
  • 向量 FARIMA 过程具有传递矩阵 ，其中 ，并且 是 × 单位矩阵.
  • 标量 FARIMA 过程应该有实系数 ai 和 bj，实积分参数 d，以满足 ，和正方差 v.
  • 维向量 FARIMA 过程应该有维度为× 的实系数矩阵 ai 和 bj 以及实积分参数 di 以满足 或者实积分参数 d 以满足 ，而协方差矩阵 Σ 应该是大小为 × 的对称正定矩阵.
  • FARIMAProcess[p,d,q] 和 FARIMAProcess[p,q] 表示阶数为 p 和 q 的 FARIMA 过程，其中已知或者未知的积分阶数 d 用于 EstimatedProcess 和相关函数中.
  • FARIMAProcess 可以与诸如 CovarianceFunction、RandomFunction 和 TimeSeriesForecast 等函数一起使用.

范例

打开所有单元 关闭所有单元

基本范例  (3)

模拟 FARIMA 过程：

Wolfram Language code: sample = RandomFunction[FARIMAProcess[{.1}, .3, {-.3}, 1], {0, 10 ^ 2}]
Wolfram Language code: ListPlot[sample, Filling -> Axis]

协方差函数：

Wolfram Language code: CovarianceFunction[FARIMAProcess[{}, d, {}, σ^2], s, t]
Wolfram Language code: DiscretePlot3D[CovarianceFunction[FARIMAProcess[{.1}, .4, {.4}, 1], s, t], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

相关函数：

Wolfram Language code: DiscretePlot[CorrelationFunction[FARIMAProcess[{.1}, .2, {.3}, 1], h], {h, 0, 20}, ExtentSize -> 1 / 2]

偏相关函数：

Wolfram Language code: DiscretePlot[PartialCorrelationFunction[FARIMAProcess[{}, .2, {}, 1], h], {h, 1, 30}, ExtentSize -> 1 / 2]

范围  (25)

基本用法  (8)

模拟一组路径：

Wolfram Language code: data = RandomFunction[FARIMAProcess[{.5}, .3, {.3}, 1], {30}, 4]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

在给定精度下模拟：

Wolfram Language code: RandomFunction[FARIMAProcess[{2 / 10, 1 / 10}, 1 / 3, {2 / 7}, 1 / 10], {1, 4}, WorkingPrecision -> 20]["Path"]

模拟一阶标量过程：

Wolfram Language code: sample[d_] := (SeedRandom[3];RandomFunction[FARIMAProcess[{.1}, d, {.2}, .1], {1, 2 10 ^ 2}]);

积分参数正值和负值的样本路径：

Wolfram Language code: ListPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["d = ", ToString[#]]]& /@ {-.4, .4}

模拟二维过程：

Wolfram Language code: α = {{.2, .1}, {-.3, .2}}; β = {{.2, .5}, {-.2, .9}}; δ = {.2, -.4}; Σ = {{1, 0}, {0, .3}}; sample = RandomFunction[FARIMAProcess[{α}, δ, {β}, Σ], {1, 10 ^ 2}];

从数据创建二维样本路径函数：

Wolfram Language code: s = TimeSeries[sample, ResamplingMethod -> Automatic]; f = s["PathFunction"]; g[t_ ? NumericQ] := f[t]

路径颜色是时间的函数：

Wolfram Language code: ParametricPlot[g[t], {t, 1, 100}, ColorFunction -> Function[{x, y, t}, (ColorData["BlueGreenYellow"][t])], PlotStyle -> Thick, AspectRatio -> 1, AxesLabel -> {x, y}]

创建具有时间的三维样本路径：

Wolfram Language code: gg[t_ ? NumericQ] := Join[{t}, f[t]]

路径的颜色是时间的函数：

Wolfram Language code: ParametricPlot3D[gg[t], {t, 1, 100}, ColorFunction -> Function[{t, x, y}, (ColorData["BlueGreenYellow"][t])], PlotStyle -> Thick, BoxRatios -> 1, AxesLabel -> {t, x, y}]

模拟三维过程：

Wolfram Language code: α = {{.2, .1, .1}, {-.3, .2, .1}, {-.3, .2, -.1}}; β = {{.2, .5, .1}, {-.2, .9, .5}, {.3, .1, -.4}}; δ = {.2, .4, .3}; Σ = {{1, 0, 0}, {0, .3, 0}, {0, 0, .1}}; SeedRandom[4];sample = RandomFunction[FARIMAProcess[{α}, δ, {β}, Σ], {1, 10 ^ 2}];

从数据创建样本路径函数：

Wolfram Language code: s = TimeSeries[sample, ResamplingMethod -> Automatic]; f = s["PathFunction"]; g[t_ ? NumericQ] := f[t]

路径的颜色是时间的函数：

Wolfram Language code: ParametricPlot3D[g[t], {t, 1, 100}, ColorFunction -> Function[{x, y, z, t}, (ColorData["BlueGreenYellow"][t])], PlotStyle -> Thick, BoxRatios -> 1, AxesLabel -> {x, y, z}]

估计过程参数：

Wolfram Language code: sample = RandomFunction[FARIMAProcess[{.3}, .2, {.5}, .1], {1, 10 ^ 3}]; eproc = EstimatedProcess[sample, FARIMAProcess[1, 1]]

比较样本协方差函数和估计过程的协方差函数：

Wolfram Language code: Show[ListPlot[CovarianceFunction[sample, {8}], Filling -> 0, PlotStyle -> {PointSize[Large], Orange}], DiscretePlot[CovarianceFunction[eproc, h], {h, 0, 8}, ExtentSize -> 1 / 2]]

估计分数噪声的积分阶数：

Wolfram Language code: sample = RandomFunction[FARIMAProcess[{}, .2, {}, .1], {1, 10 ^ 3}]; eproc = EstimatedProcess[sample, FARIMAProcess[0, d, 0], ProcessEstimator -> "MethodOfMoments"]

比较样本相关函数与估计过程的相关函数：

Wolfram Language code: Show[ListPlot[CorrelationFunction[sample, {12}], Filling -> 0, PlotStyle -> {PointSize[Large], Orange}, PlotRange -> {0, 1}], DiscretePlot[CorrelationFunction[eproc, h], {h, 0, 12}, ExtentSize -> 1 / 2, PlotRange -> {0, 1}]]

预测将来值：

Wolfram Language code: proc = FARIMAProcess[{.7}, .4, {-.3}, .1];sample = RandomFunction[proc, {1, 10 ^ 2}];

预测下 20 步：

Wolfram Language code: forecast = TimeSeriesForecast[proc, sample, {20}]

显示预测路径：

Wolfram Language code: forecast["Path"]

绘制数据和预测数值的图线：

Wolfram Language code: ListLinePlot[{sample, forecast}, InterpolationOrder -> 0, Filling -> Axis]

协方差和谱函数  (5)

纯 FARIMA 的解析形式的相关函数：

Wolfram Language code: CorrelationFunction[FARIMAProcess[{}, d, {}, σ^2], h]

对于具有数值可用的自回归和平均移动分量的 FARIMA：

Wolfram Language code: Table[CorrelationFunction[FARIMAProcess[{1 / 3}, .2, {1, 2}, 1], h], {h, 0, 5}]

对于特例，偏相关没有解析式：

Wolfram Language code: PartialCorrelationFunction[FARIMAProcess[{}, d, {}, σ^2], h]

相关矩阵：

Wolfram Language code: Correlation[FARIMAProcess[{.1}, .3, {.4}, 1][{1, 2, 3}]]//MatrixForm

纯 FARIMA 的特例：

Wolfram Language code: Correlation[FARIMAProcess[{}, d, {}, σ^2][{s, t}]]//MatrixForm

协方差矩阵：

Wolfram Language code: Covariance[FARIMAProcess[{.1}, .3, {.4}, 1][{1, 2, 3}]]//MatrixForm

纯 FARIMA 的特例：

Wolfram Language code: Covariance[FARIMAProcess[{}, d, {}, σ^2][{s, t}]]//MatrixForm

功率谱密度：

Wolfram Language code: Plot[PowerSpectralDensity[FARIMAProcess[{-.6, -.7}, .3, {.4, .3}, 1], w], {w, -π, π}, Filling -> Axis]
Wolfram Language code: PowerSpectralDensity[FARIMAProcess[{a}, d, {b}, σ^2], w]

向量 FARIMAProcess：

Wolfram Language code: a = {{1 / 9, 0}, {1 / 3, 1 / 2}}; b = {{1, 1 / 4}, {1 / 2, 0}}; Σ = {{1, 0}, {0, 1}}; proc = FARIMAProcess[{a}, {1 / 3, -1 / 4}, {b}, Σ];
Wolfram Language code: psd = PowerSpectralDensity[proc, ω]; psd//FullSimplify//MatrixForm

平稳性和可逆性  (4)

检查一个时间序列是否是弱平稳的：

Wolfram Language code: WeakStationarity[FARIMAProcess[{1, 2}, .2, {3}, 1]]
Wolfram Language code: WeakStationarity[FARIMAProcess[{}, .2, {3}, 1]]

求过程成为弱平稳的条件：

Wolfram Language code: WeakStationarity[FARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, d, {Subscript[b, 1], Subscript[b, 2]}, σ^2]]

求可逆性条件：

Wolfram Language code: TimeSeriesInvertibility[FARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, d, {Subscript[b, 1], Subscript[b, 2]}, σ^2]]

检查时间序列是否可逆的：

Wolfram Language code: proc = FARIMAProcess[{1 / 3}, 1 / 4, {1, 2}, 1];
Wolfram Language code: TimeSeriesInvertibility[proc]

求可逆表示法：

Wolfram Language code: ToInvertibleTimeSeries[proc]

估计方法  (2)

估计 FARIMAProcess 的可用方法：

Wolfram Language code: methods = {Automatic, "SpectralEstimator"};
Wolfram Language code: SeedRandom[111]; data = RandomFunction[FARIMAProcess[{.4}, -.4, {.3}, 1], {100}];
Wolfram Language code: Grid[res = Table[{m, EstimatedProcess[data, FARIMAProcess[1, 1], ProcessEstimator -> m]}, {m, methods}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

比较对数似然：

Wolfram Language code: LogLikelihood[#[[2]], data]& /@ res

估计分数噪声的可用方法：

Wolfram Language code: methods = {Automatic, "SpectralEstimator", "MethodOfMoments"};
Wolfram Language code: SeedRandom[11]; data = RandomFunction[FARIMAProcess[{}, -.4, {}, 1], {100}];
Wolfram Language code: Grid[res = Table[{m, EstimatedProcess[data, FARIMAProcess[0, 0], ProcessEstimator -> m]}, {m, methods}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

谱估计允许您指定用于 PowerSpectralDensity 计算的窗：

Wolfram Language code: SeedRandom[11]; data = RandomFunction[FARIMAProcess[{.4, .2}, .3, {.3}, 1], {100}];
Wolfram Language code: Grid[Table[{m, EstimatedProcess[data, FARIMAProcess[2, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> m}]}, {m, {10, BartlettWindow, {3, HannWindow}}}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

光谱估值器使用下列求解器：

Wolfram Language code: solvers = {Automatic, "FindMinimum", "NMinimize"};
Wolfram Language code: Grid[Table[{m, EstimatedProcess[data, FARIMAProcess[2, 1], ProcessEstimator -> {"SpectralEstimator", Method -> m}]}, {m, solvers}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

这种方法允许固定参数：

Wolfram Language code: EstimatedProcess[data, FARIMAProcess[{.1, b}, d, {m}, v], ProcessEstimator -> "SpectralEstimator"]

也允许参数之间的一些关系：

Wolfram Language code: EstimatedProcess[data, FARIMAProcess[{b, b}, d, {m}, v], ProcessEstimator -> "SpectralEstimator"]

过程切片性质  (5)

单一时间 SliceDistribution:

Wolfram Language code: SliceDistribution[FARIMAProcess[{.1}, .2, {.4}, 1], t]

多时间切片分布：

Wolfram Language code: SliceDistribution[FARIMAProcess[{.1}, .2, {.4}, 1], {s, s + 3}]
Wolfram Language code: SliceDistribution[FARIMAProcess[{.1}, .2, {.4}, 1], {1, 2, 3}]

一阶概率密度函数：

Wolfram Language code: pdf = PDF[FARIMAProcess[{.1}, .2, {.4}, 1][t], x]
Wolfram Language code: Plot[pdf, {x, -4, 4}, Filling -> Axis]

静态均值和方差：

Wolfram Language code: μ = Mean[FARIMAProcess[{.1}, .2, {.4}, 1][∞]]
Wolfram Language code: v = Variance[FARIMAProcess[{.1}, .2, {.4}, 1][∞]]

与正态分布的密度函数比较：

Wolfram Language code: PDF[NormalDistribution[μ, Sqrt[v]], x]
Wolfram Language code: FullSimplify[% - PDF[FARIMAProcess[{.1}, .2, {.4}, 1][∞], x]]

计算表达式的期望：

Wolfram Language code: Expectation[x[t]^2, xFARIMAProcess[{.1}, .2, {.4}, 1.]]

计算概率：

Wolfram Language code: Probability[x[t] < 6, xFARIMAProcess[{.1}, .2, {.4}, 1]]

偏度和峰度：

Wolfram Language code: Skewness[FARIMAProcess[{.1}, .2, {.4}, 1][t]]
Wolfram Language code: Kurtosis[FARIMAProcess[{.1}, .2, {.4}, 1][t]]

阶数 r 的 Moment：

Wolfram Language code: Moment[FARIMAProcess[{.1}, .2, {.4}, 1][t], r]

母函数：

Wolfram Language code: CharacteristicFunction[FARIMAProcess[{.1}, .2, {.4}, 1][t], w]
Wolfram Language code: MomentGeneratingFunction[FARIMAProcess[{.1}, .2, {.4}, 1][t], w]

CentralMoment 及其母函数：

Wolfram Language code: CentralMoment[FARIMAProcess[{.1}, .2, {.4}, 1][t], r]
Wolfram Language code: CentralMomentGeneratingFunction[FARIMAProcess[{.1}, .2, {.4}, 1][t], w]

对于符号式阶数，FactorialMoment 无解析形式：

Wolfram Language code: FactorialMoment[FARIMAProcess[{.1}, .2, {.4}, 1][t], 3]
Wolfram Language code: FactorialMomentGeneratingFunction[FARIMAProcess[{.1}, .2, {.4}, 1][t], w]

Cumulant 及其母函数：

Wolfram Language code: Cumulant[FARIMAProcess[{.1}, .2, {.4}, 1][t], r]
Wolfram Language code: CumulantGeneratingFunction[FARIMAProcess[{.1}, .2, {.4}, 1][t], w]

表示法  (1)

使用 ARMAProcess 近似：

Wolfram Language code: ARMAProcess[FARIMAProcess[{.2, .3}, .4, {.1}, 1], {5, 3}]

使用 MAProcess 近似：

Wolfram Language code: MAProcess[FARIMAProcess[{.2, .3}, .4, {.1}, 1], 5]

使用 ARProcess 近似：

Wolfram Language code: proc = FARIMAProcess[{.2, .3}, .4, {.1}, 1]; aproc = ARProcess[proc, 5]

比较过程和近似的随机样本：

Wolfram Language code: SeedRandom[13];sample = RandomFunction[proc, {100}]; SeedRandom[13];asample = RandomFunction[aproc, {100}]; ListLinePlot[{sample, asample}, PlotLegends -> {"FARIMA", "AR"}]

应用  (1)

考虑 622-1281 年间尼罗河每年最低水位的时间序列：

Wolfram Language code: NileFlow = TemporalData[TimeSeries, {{{1157, 1088, 1169, 1169, 984, 1322, 1178, 1103, 1211, 1292, 1124, 1171, 1133, 1227, 1142, 1216, 1259, 1299, 1232, 1117, 1155, 1232, 1083, 1020, 1394, 1196, 1148, 1083, 1189, 1133, 1034, 1157, 1034, 1097, 1299, 1 ... 1187, 1254, 1198, 1263, 1283, 1252, 1160, 1234, 1234, 1232, 1306, 1205, 1054, 1151, 1108, 1097}}, {{622, 1284, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];
Wolfram Language code: ListLinePlot[NileFlow, Filling -> Axis, PlotRange -> {{622, 1284}, All}]

中心化数据：

Wolfram Language code: cNileFlow = Standardize[NileFlow, Mean, 1&]

找到一个 FARIMA 模型：

Wolfram Language code: eproc = EstimatedProcess[cNileFlow, FARIMAProcess[{a}, d, {}, v]]

预测未来值：

Wolfram Language code: f = TimeSeriesForecast[eproc, cNileFlow, {1, 100}]

调整至平均水平和适当的时间标记：

Wolfram Language code: forecast = Mean[NileFlow] + f

绘制尼罗河最小流量及百年预测：

Wolfram Language code: ListLinePlot[{NileFlow, forecast}, Filling -> Axis, PlotRange -> {{622, 1384}, All}]

属性和关系  (5)

对于 -1/2<d<0，相关性是可累加的：

Wolfram Language code: Sum[CorrelationFunction[FARIMAProcess[{}, d, {}, 1], h], {h, 0, ∞}, Assumptions -> -1 / 2 < d < 0]

对于 0<d<1/2，相关性的总和发散：

Wolfram Language code: sums = Accumulate[CorrelationFunction[FARIMAProcess[{}, .3, {}, 1], {0, 1000}]]; ListPlot[sums]

对于正积分阶数，FARIMAProcess 有长记忆：

Wolfram Language code: proc[d_] := FARIMAProcess[{}, d, {}, 1];
Wolfram Language code: DiscretePlot[CovarianceFunction[proc[#], k], {k, 1, 50, 5}, ExtentSize -> 1 / 2, PlotRange -> {-.3, .6}, PlotLabel -> StringJoin["d = ", ToString[#]]]& /@ {-.3, -.2, .2, .3}

FARIMAProcess 是 ARMAProcess 的一个推广：

Wolfram Language code: TransferFunctionModel[FARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, 0, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]
Wolfram Language code: TransferFunctionModel[ARMAProcess[{Subscript[a, 1], Subscript[a, 2]}, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]
Wolfram Language code: % - %%

FARIMAProcess 是 ARProcess 的一个推广：

Wolfram Language code: TransferFunctionModel[FARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, 0, {}, σ^2], z]
Wolfram Language code: TransferFunctionModel[ARProcess[{Subscript[a, 1], Subscript[a, 2]}, σ^2], z]
Wolfram Language code: % - %%

FARIMAProcess 是 MAProcess 的一个推广：

Wolfram Language code: TransferFunctionModel[FARIMAProcess[{}, 0, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]
Wolfram Language code: TransferFunctionModel[MAProcess[{Subscript[b, 1], Subscript[b, 2]}, σ^2], z]
Wolfram Language code: % - %%

可能存在的问题  (2)

ToInvertibleTimeSeries 不是总存在：

Wolfram Language code: ToInvertibleTimeSeries[FARIMAProcess[{.2}, .3, {.3, 1}, .2]]

矩量法仅对分数噪声的估计有效：

Wolfram Language code: sample = RandomFunction[FARIMAProcess[{}, .2, {}, .1], {1, 10 ^ 3}];
Wolfram Language code: EstimatedProcess[sample, FARIMAProcess[{a}, d, {b}, v], ProcessEstimator -> "MethodOfMoments"]

使用其他求解器：

Wolfram Language code: EstimatedProcess[sample, FARIMAProcess[{a}, d, {b}, v], ProcessEstimator -> Automatic]

巧妙范例  (2)

模拟三维 FARIMAProcess：

Wolfram Language code: A = {{.2, .1, .1}, {0, -.2, .3}, {.2, -.1, .3}}; B = {{.1, .2, -.1}, {-.1, .3, .1}, {.1, .1, 0}}; S = {{.8, .1, -.2}, {.1, .5, .1}, {-.2, .1, .3}}; proc = FARIMAProcess[{A}, {.3, .2, .4}, {B}, S]; data = RandomFunction[proc, {100}, k = 3]["ValueList"];
Wolfram Language code: Graphics3D@Table[{ColorData["SolarColors"][RandomReal[]], Tube@Line@data[[i]]}, {i, k}]

模拟 FARIMA 过程的路径：

Wolfram Language code: data = RandomFunction[FARIMAProcess[{.3}, .2, {.6}, 1], {50}, 200];

在 50 处取切片，并对它的分布进行可视化：

Wolfram Language code: sd = data["SliceData", 50];
Wolfram Language code: cf = ColorData["Rainbow"]; sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 55]&[HistogramList[sd, {Range[Min[sd], Max[sd], (Max[sd] - Min[sd]) / 20]}]];

在 50 处绘制切片分布的路径和直方图分布：

Wolfram Language code: ListLinePlot[data, ImageSize -> 400, PlotRange -> All, AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {51, 0}, {0, 10}], PlotStyle -> (cf /@ Rescale[sd]), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, 15}, {.5, .5}}]
Wolfram Research (2012)，FARIMAProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FARIMAProcess.html.

文本

Wolfram Research (2012)，FARIMAProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FARIMAProcess.html.

CMS

Wolfram 语言. 2012. "FARIMAProcess." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/FARIMAProcess.html.

APA

Wolfram 语言. (2012). FARIMAProcess. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FARIMAProcess.html 年

BibTeX

@misc{reference.wolfram_2026_farimaprocess, author="Wolfram Research", title="{FARIMAProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/FARIMAProcess.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_farimaprocess, organization={Wolfram Research}, title={FARIMAProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/FARIMAProcess.html}, note=[Accessed: 09-September-2026]}