Wolfram 语言与系统参考资料中心

Factor

Factor[poly]

在整数上对一个多项式分解因式.

Factor[poly,Modulusp]

以素数 p 为模对多项式分解因式.

Factor[poly,Extension{a₁,a₂,…}]

对一个多项式分解因式，而这个多项式的系数允许是代数数 a_i 的有理组合.

范例

打开所有单元关闭所有单元

基本范例 (3)

对单变量多项式进行因式分解：

Wolfram Language code: Factor[1 + 2x + x ^ 2]

Wolfram Language code: Factor[x ^ 10 - 1]

对多变量多项式进行因式分解：

Wolfram Language code: Factor[x ^ 10 - y ^ 10]

整数模数 2 上的因式分解：

Wolfram Language code: Factor[x ^ 10 - 1, Modulus -> 2]

范围 (13)

基本用法 (6)

一元多项式：

Wolfram Language code: Factor[x ^ 3 - 6x ^ 2 + 11x - 6]

多元多项式：

Wolfram Language code: Factor[2x ^ 3 y - 2a ^ 2x y - 3a ^ 2x ^ 2 + 3a ^ 4]

有理函数：

Wolfram Language code: Factor[(x ^ 3 + 2x ^ 2) / (x ^ 2 - 4y ^ 2) - (x + 2) / (x ^ 2 - 4y ^ 2)]

非多项式表达式：

Wolfram Language code: Factor[2 ^ (3x) - 1]

Factor 可作用于列表的各项：

Wolfram Language code: Factor[{x ^ 2 - 1, x ^ 4 - 1, x ^ 8 - 1}]

Factor 可作用于等式和不等式：

Wolfram Language code: Factor[1 < 1 + 2 x + x ^ 2 + 1 / (1 + x) < 2]

高级用法 (7)

在高斯整数上对多项式进行因式分解：

Wolfram Language code: Factor[x ^ 2 + 1, GaussianIntegers -> True]

在代数扩展域上对多项式进行因式分解：

Wolfram Language code: Factor[x ^ 4 - 2, Extension -> Sqrt[2]]

在整数模数 3 上对多项式进行因式分解：

Wolfram Language code: Factor[x ^ 3 + 1, Modulus -> 3]

对有限域上的多项式因式分解：

Wolfram Language code: ℱ = FiniteField[17, 3];

Wolfram Language code: Factor[ℱ[3]x ^ 2 + ℱ[1771]]

Wolfram Language code: Factor[x ^ 3 + 5x + 19, Extension -> ℱ]

对有限域的扩张上的多项式进行因式分解：

Wolfram Language code:

ℱ = FiniteField[29, 3];
𝒢 = FiniteField[29, 6];
ℰ = FiniteFieldEmbedding[ℱ, 𝒢];

在把嵌入更大的域后，本在上不可约的多项式此时可以因式分解：

Wolfram Language code: Factor[ℱ[12]x ^ 2 + ℱ[34]x + ℱ[56]]

Wolfram Language code: Factor[ℱ[12]x ^ 2 + ℱ[34]x + ℱ[56], Extension -> ℰ]

某些非多项式表达式可以因式分解：

Wolfram Language code: Factor[x ^ (2s) + 2x ^ s + 1]

Wolfram Language code: Factor[x ^ (2 / 3s) + 2x ^ s + 1]

Wolfram Language code: Factor[Exp[2s] + 2Exp[s] + 1]

对一个阶为的多项式进行因式分解：

Wolfram Language code:

rpoly[n_] := RandomInteger[{-2 ^ 10, 2 ^ 10}, {n + 1}].x ^ Range[0, n]
SeedRandom[1234];
p = rpoly[1000]; q = rpoly[1000];
r = Expand[p q];

Wolfram Language code: Factor[r]//Short//AbsoluteTiming

选项 (7)

Extension (4)

在代数数域上因式分解：

Wolfram Language code: Factor[1 + x ^ 4, Extension -> Sqrt[2]]

Wolfram Language code: Factor[1 + x ^ 4, Extension -> {Sqrt[2], I}]

Extension->Automatic 自动扩展到涵盖系数的域上：

Wolfram Language code: Factor[2 + 2Sqrt[2]x + x ^ 2]

Wolfram Language code: Factor[2 + 2Sqrt[2]x + x ^ 2, Extension -> Automatic]

对有限域上的有整数系数的多项式进行分解：

Wolfram Language code: ℱ = FiniteField[73, 4];

Wolfram Language code: Factor[x ^ 4 + 21x + 3, Extension -> ℱ]

对一个系数在有限域中的多项式进行因式分解：

Wolfram Language code: ℱ = FiniteField[7, 2];

Wolfram Language code: Factor[ℱ[1]x ^ 4 + ℱ[234]x + ℱ[567]]

将嵌入更大的域，可以进一步进行因式分解：

Wolfram Language code:

𝒢 = FiniteField[7, 4];
ℰ = FiniteFieldEmbedding[ℱ, 𝒢];

Wolfram Language code: Factor[ℱ[1]x ^ 4 + ℱ[234]x + ℱ[567], Extension -> ℰ]

GaussianIntegers (1)

在高斯整数上做因式分解：

Wolfram Language code: Factor[1 + x ^ 2, GaussianIntegers -> True]

Wolfram Language code: Factor[1 + x ^ 2, Extension -> I]

Modulus (1)

在有限域上做因式分解：

Wolfram Language code: Factor[5 + x ^ 12]

Wolfram Language code: Factor[5 + x ^ 12, Modulus -> 7]

Trig (1)

因式分解三角学表达式：

Wolfram Language code: Factor[Sin[x] + Sin[y], Trig -> True]

应用 (3)

使用多项式对行为进行建模时，确定多项式何时为零非常重要. 例如，假设可用以下表达式对生产视频游戏系统的成本进行建模：

Wolfram Language code: cost[x_] := -.03x ^ 3 + 4x ^ 2 - x + 500

Wolfram Language code: Plot[cost[x], {x, 0, 100}]

同时假设可用以下公式对收入进行建模：

Wolfram Language code: revenue[x_] := .03x ^ 2 - 4x + 200

Wolfram Language code: Plot[revenue[x], {x, 0, 100}]

如果你想知道获利之前必须卖出的游戏的数量，计算出差额：

Wolfram Language code: profit[x_] := revenue[x] - cost[x]

Wolfram Language code: Plot[profit[x], {x, 0, 100}]

然后用 Factor 算出利润函数为零的数量：

Wolfram Language code: Factor[profit[x]]

下图告诉我们时利润为零：

Wolfram Language code: Plot[profit[x], {x, 130, 140}]

求一个与自身的平方相等的数字：

Wolfram Language code: x ^ 2 == x

从等式的两边同时减去：

Wolfram Language code: SubtractSides[%, x]

用 Factor 求多项式何时为零：

Wolfram Language code: Factor[%]

与自身的平方相等的数字为和：

Wolfram Language code: 0 ^ 2

Wolfram Language code: 1 ^ 2

计算两个多项式的最大公约式：

Wolfram Language code: Factor[-x ^ 2 + x]

Wolfram Language code: Factor[x ^ 4 - 1]

可以看出它们共有的因式为 . 用 PolynomialGCD 确认该结果：

Wolfram Language code: PolynomialGCD[-x ^ 2 + x, x ^ 4 - 1]

属性和关系 (3)

Expand 实际上是 Factor 的逆过程：

Wolfram Language code: Factor[x ^ 50 - 1]

Wolfram Language code: Expand[Factor[x ^ 50 - 1]]

FactorList 给出因子列表：

Wolfram Language code: FactorList[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

FactorSquareFree 仅合并多重因子：

Wolfram Language code: f = x ^ 9 + 9x ^ 8 + 21x ^ 7 - 27x ^ 6 - 153x ^ 5 - 81x ^ 4 + 239x ^ 3 + 207x ^ 2 - 108x - 108;

Wolfram Language code: Factor[f]

Wolfram Language code: FactorSquareFree[f]

巧妙范例 (2)

的第一个因式分解，其中 2 显示为系数：

Wolfram Language code: Factor[x ^ 105 - 1]

可视化的因式的数量：

Wolfram Language code: ListLinePlot[Table[Length[Factor[x ^ n - 1]], {n, 200}]]

Top

Extension	None	要使用的系数域
GaussianIntegers	False	是否在高斯整数上进行因式分解
Modulus	0	假设的整数模数
Trig	False	是否进行三角和代数变换

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Factor

更多信息和选项

范例

基本范例 (3)

范围 (13)

基本用法 (6)

高级用法 (7)

选项 (7)

Extension (4)

GaussianIntegers (1)

Modulus (1)

Trig (1)

应用 (3)

属性和关系 (3)

巧妙范例 (2)

文本

CMS

APA

BibTeX

BibLaTeX

Factor

更多信息和选项

范例

基本范例 (3)

范围 (13)

基本用法 (6)

高级用法 (7)

选项 (7)

Extension (4)

GaussianIntegers (1)

Modulus (1)

Trig (1)

应用 (3)

属性和关系 (3)

巧妙范例 (2)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX