WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FactorInteger[n]

整数 n の素因数をこれらの指数とともにリストとして返す．

FactorInteger[n,k]

部分的な因数分解を行い，最高で k 個の識別可能な因数を取り出す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
GaussianIntegers  
アプリケーション  
基本的なアプリケーション  
整数論  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

FactorInteger

FactorInteger[n]

整数 n の素因数をこれらの指数とともにリストとして返す．

FactorInteger[n,k]

部分的な因数分解を行い，最高で k 個の識別可能な因数を取り出す．

詳細とオプション

  • FactorIntegerは素因数分解としても知られている．
  • 正の数 n=p1k1⋯ pmkm（piは素数）について，FactorInteger[n]はリスト{{p1,k1},…,{pm,km}}を与える．
  • 負の数については，単位{-1,1}が因数のリストに含まれる．
  • FactorIntegerは，有理数にも使用できる．この際，分母の素因数は負の指数とともに与えられる．
  • FactorInteger[n,GaussianIntegers->True]は，ガウスの整数上で因数分解する．
  • FactorInteger[m+I n]はガウスの整数に自動的に作用する．
  • 必要に応じて，形式{-1,1}，{I,1}や{-I,1}の単位が因数のリストに含まれる．
  • リストFactorInteger[n,k]の最終要素は，部分因数分解後に残った部分を返す．
  • FactorInteger[n,Automatic]は見付かりやすい因数だけを取り出す．
  • FactorIntegerはPrimeQを使って因数が素数かどうかを確かめる．

例題

すべて開く すべて閉じる

例  (2)

の素因数とその指数を求める：

Wolfram Language code: FactorInteger[120]

最初の100個の数の異なる素因数の数をプロットする：

Wolfram Language code: DiscretePlot[Length[FactorInteger[n]], {n, 100}]

スコープ  (6)

FactorIntegerは整数に使うことができる：

Wolfram Language code: FactorInteger[36]

有理数：

Wolfram Language code: FactorInteger[3 / 8]

ガウス整数：

Wolfram Language code: FactorInteger[9 + 12I]
Wolfram Language code: FactorInteger[36, GaussianIntegers -> True]

部分的な因数分解を求める：

Wolfram Language code: FactorInteger[20!, 4]
Wolfram Language code: FactorInteger[10 ^ 100 + 3, Automatic]

大きい整数について計算する：

Wolfram Language code: FactorInteger[10 ^ 50 + 3]

FactorIntegerはリストに縫い込まれる：

Wolfram Language code: FactorInteger[{11, 101, 1001}]

オプション  (1)

GaussianIntegers  (1)

整数上で数を因数分解する：

Wolfram Language code: FactorInteger[5]

ガウス整数：

Wolfram Language code: FactorInteger[5, GaussianIntegers -> True]

アプリケーション  (12)

基本的なアプリケーション  (5)

正の整数はどれも素因数の積として表すことができる：

Wolfram Language code: FactorInteger[60]

単位因子：

Wolfram Language code: FactorInteger[-60]

までの数の異なる素因数の数をプロットする：

Wolfram Language code: ListPlot[Table[Length[FactorInteger[n]], {n, 100}]]

ガウス整数上の異なる素因数の数と比較する：

Wolfram Language code: ListPlot[Table[Length[FactorInteger[n, GaussianIntegers -> True]], {n, 100}]]

因数の明示的な積として表示する：

Wolfram Language code: FactorInteger[20!]
Wolfram Language code: CenterDot@@(Superscript@@@%)

FactorIntegerを使って素数ベキについて調べる：

Wolfram Language code: MatchQ[FactorInteger[2401], {{_Integer, _Integer}}]
Wolfram Language code: PrimePowerQ[2401]

FactorIntegerを使って数のすべての素因子を求める：

Wolfram Language code: Part[FactorInteger[2434500], All, 1]
Wolfram Language code: Select[Divisors[2434500], PrimeQ]

整数論  (7)

FactorIntegerを使って数の約数の数を計算する：

Wolfram Language code: Times@@(FactorInteger[6!][[All, -1]] + 1)
Wolfram Language code: Length[Divisors[6!]]

FactorIntegerを使って強力な数，つまり素因数がすべて繰り返されている数を認識する：

Wolfram Language code: powQ[n_] := AllTrue[Part[FactorInteger[n], All, 2], # > 1&];
Wolfram Language code: powQ[324]
Wolfram Language code: powQ[75]

の形の数の因数分解を求める：

Wolfram Language code: Table[FactorInteger[2 ^ 2 ^ n + 1], {n, 7}]//Column

100までの自然数で素数または素数ベキであるものをすべて求める：

Wolfram Language code: Select[Range[100], Length[FactorInteger[#]] == 1&]

100までの数の中で最大の素数ベキ：

Wolfram Language code: Table[Max[Last /@ FactorInteger[n]], {n, 2, 100}]

の素因数分解に1乗として飲み現れる素数を求める：

Wolfram Language code: FactorInteger[20!]
Wolfram Language code: Cases[%, {p_, 1} -> p]

FactorIntegerを使って数の無平方の部分を計算する：

Wolfram Language code: squareFreePart[n_] := Times@@Cases[FactorInteger[n], {x_, _} -> x];
Wolfram Language code: squareFreePart[18]

分布を可視化する：

Wolfram Language code: ListPlot[Table[squareFreePart[a], {a, 1, 1000}]]

特性と関係  (9)

素数のそれ自身による素因数分解：

Wolfram Language code: PrimeQ[11]
Wolfram Language code: FactorInteger[11]

素数ベキ：

Wolfram Language code: PrimePowerQ[125]
Wolfram Language code: FactorInteger[125]

合成数は重複を含めて少なくとも2つの素因数を持つ：

Wolfram Language code: CompositeQ[60]
Wolfram Language code: FactorInteger[60]

因数分解からもとの数を計算する：

Wolfram Language code: FactorInteger[30]
Wolfram Language code: Times@@Cases[FactorInteger[30], {a_, b_} -> a ^ b ]

無平方数の素因数分解の指数はすべてである：

Wolfram Language code: SquareFreeQ[210]
Wolfram Language code: FactorInteger[210]

Divisorsは素因数を含む約数のリストを与える：

Wolfram Language code: Select[Divisors[20], PrimeQ]
Wolfram Language code: FactorInteger[20]

PrimeNuは異なる素因数の数を与える：

Wolfram Language code: Length[FactorInteger[10!]]
Wolfram Language code: PrimeNu[10!]

PrimeOmegaは素因数の数を重複を含めて与える：

Wolfram Language code: Total[FactorInteger[48][[All, -1]]]
Wolfram Language code: PrimeOmega[48]

互いに素な数は共通の素因数を持たない：

Wolfram Language code: CoprimeQ[20, 39]
Wolfram Language code: FactorInteger[20]
Wolfram Language code: FactorInteger[39]

n の素因数分解が で与えられるなら，n の約数の数はである：

Wolfram Language code: Times@@(FactorInteger[5!][[All, -1]] + 1)
Wolfram Language code: Length[Divisors[5!]]

考えられる問題  (2)

入力の大きさによって時間は急速かつ予測不可能なほどに増加することがある：

Wolfram Language code: Table[Timing[FactorInteger[2 ^ n - 1];n], {n, 50, 300, 50}]

0におけるFactorInteger：

Wolfram Language code: FactorInteger[0]
Wolfram Research (1988), FactorInteger, Wolfram言語関数， https://reference.wolfram.com/language/ref/FactorInteger.html （2007年に更新）.

テキスト

Wolfram Research (1988), FactorInteger, Wolfram言語関数， https://reference.wolfram.com/language/ref/FactorInteger.html （2007年に更新）.

CMS

Wolfram Language. 1988. "FactorInteger." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/FactorInteger.html.

APA

Wolfram Language. (1988). FactorInteger. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FactorInteger.html

BibTeX

@misc{reference.wolfram_2026_factorinteger, author="Wolfram Research", title="{FactorInteger}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/FactorInteger.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_factorinteger, organization={Wolfram Research}, title={FactorInteger}, year={2007}, url={https://reference.wolfram.com/language/ref/FactorInteger.html}, note=[Accessed: 04-September-2026]}