Wolfram 语言与系统参考资料中心

FactorInteger

给出了整数 n 的素数因子列表，以及它们的指数.

FactorInteger[n,k]

部分因式分解，包含最多 k 个不同的因子.

范例

打开所有单元关闭所有单元

基本范例 (2)

求的质因数及其指数：

Wolfram Language code: FactorInteger[120]

绘制前 100 个数字的相异质数的数量：

Wolfram Language code: DiscretePlot[Length[FactorInteger[n]], {n, 100}]

范围 (6)

FactorInteger 适用于整数：

Wolfram Language code: FactorInteger[36]

有理数：

Wolfram Language code: FactorInteger[3 / 8]

高斯整数：

Wolfram Language code: FactorInteger[9 + 12I]

Wolfram Language code: FactorInteger[36, GaussianIntegers -> True]

求部分因数分解：

Wolfram Language code: FactorInteger[20!, 4]

Wolfram Language code: FactorInteger[10 ^ 100 + 3, Automatic]

对大整数进行计算：

Wolfram Language code: FactorInteger[10 ^ 50 + 3]

FactorInteger 逐项作用于列表的各个元素：

Wolfram Language code: FactorInteger[{11, 101, 1001}]

选项 (1)

GaussianIntegers (1)

将数字分解为整数：

Wolfram Language code: FactorInteger[5]

高斯整数：

Wolfram Language code: FactorInteger[5, GaussianIntegers -> True]

应用 (12)

基本应用 (5)

每个正整数都可以表示为质因数的乘积：

Wolfram Language code: FactorInteger[60]

单位因子：

Wolfram Language code: FactorInteger[-60]

绘制前个数字的相异质因数的数量：

Wolfram Language code: ListPlot[Table[Length[FactorInteger[n]], {n, 100}]]

与高斯整数上相异质因数的数量相比：

Wolfram Language code: ListPlot[Table[Length[FactorInteger[n, GaussianIntegers -> True]], {n, 100}]]

显示因数的积：

Wolfram Language code: FactorInteger[20!]

Wolfram Language code: CenterDot@@(Superscript@@@%)

用 FactorInteger 测试素数幂：

Wolfram Language code: MatchQ[FactorInteger[2401], {{_Integer, _Integer}}]

Wolfram Language code: PrimePowerQ[2401]

用 FactorInteger 求一个数字的所有质因数：

Wolfram Language code: Part[FactorInteger[2434500], All, 1]

Wolfram Language code: Select[Divisors[2434500], PrimeQ]

数论 (7)

用 FactorInteger 计算一个数字的因数的数量：

Wolfram Language code: Times@@(FactorInteger[6!][[All, -1]] + 1)

Wolfram Language code: Length[Divisors[6!]]

用 FactorInteger 识别幂数，即质因数皆为重复的数字的数：

Wolfram Language code: powQ[n_] := AllTrue[Part[FactorInteger[n], All, 2], # > 1&];

Wolfram Language code: powQ[324]

Wolfram Language code: powQ[75]

求形式数的分解：

Wolfram Language code: Table[FactorInteger[2 ^ 2 ^ n + 1], {n, 7}]//Column

求100以内为素数或素数幂的全部自然数：

Wolfram Language code: Select[Range[100], Length[FactorInteger[#]] == 1&]

素数的最高次幂，直到 100：

Wolfram Language code: Table[Max[Last /@ FactorInteger[n]], {n, 2, 100}]

求的素因子分解中仅有一次幂的素数：

Wolfram Language code: FactorInteger[20!]

Wolfram Language code: Cases[%, {p_, 1} -> p]

用 FactorInteger 计算一个数字的无平方数因数：

Wolfram Language code: squareFreePart[n_] := Times@@Cases[FactorInteger[n], {x_, _} -> x];

Wolfram Language code: squareFreePart[18]

可视化分布：

Wolfram Language code: ListPlot[Table[squareFreePart[a], {a, 1, 1000}]]

属性和关系 (9)

质数的质因数分解是自身：

Wolfram Language code: PrimeQ[11]

Wolfram Language code: FactorInteger[11]

素数幂：

Wolfram Language code: PrimePowerQ[125]

Wolfram Language code: FactorInteger[125]

合数至少有两个质因数，包括重数：

Wolfram Language code: CompositeQ[60]

Wolfram Language code: FactorInteger[60]

通过因数分解计算原来的数：

Wolfram Language code: FactorInteger[30]

Wolfram Language code: Times@@Cases[FactorInteger[30], {a_, b_} -> a ^ b ]

无平方数因数的数的质因数分解的指数都是：

Wolfram Language code: SquareFreeQ[210]

Wolfram Language code: FactorInteger[210]

Divisors 给出因数列表，包括质因数：

Wolfram Language code: Select[Divisors[20], PrimeQ]

Wolfram Language code: FactorInteger[20]

PrimeNu 给出相异质因数的数量：

Wolfram Language code: Length[FactorInteger[10!]]

Wolfram Language code: PrimeNu[10!]

PrimeOmega 给出质因数的数量，计入重数：

Wolfram Language code: Total[FactorInteger[48][[All, -1]]]

Wolfram Language code: PrimeOmega[48]

互质的数没有共同的质因数：

Wolfram Language code: CoprimeQ[20, 39]

Wolfram Language code: FactorInteger[20]

Wolfram Language code: FactorInteger[39]

如果 n 的质因数分解为，则 n 的因数的数量为：

Wolfram Language code: Times@@(FactorInteger[5!][[All, -1]] + 1)

Wolfram Language code: Length[Divisors[5!]]

可能存在的问题 (2)

随输入大小不同，计算时间可能迅速增长且无法预计：

Wolfram Language code: Table[Timing[FactorInteger[2 ^ n - 1];n], {n, 50, 300, 50}]

零的 FactorInteger：

Wolfram Language code: FactorInteger[0]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

FactorInteger

更多信息和选项

范例

基本范例 (2)

范围 (6)