WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FindFormula[data]

data を近似する純関数を求める．

FindFormula[data,x]

data を近似する変数 x の記号関数を求める．

FindFormula[data,x,n]

data を近似する関数を n 個まで求める．

FindFormula[data,x,n,prop]

特性 prop に関連付けられた最適関数を n 個まで返す．

FindFormula[data,x,n,{prop1,prop2,…}]

特性 prop1，prop2等と関連付けられた最適関数を n 個まで返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
PerformanceGoal  
RandomSeeding  
SpecificityGoal  
TargetFunctions  
アプリケーション  
人口増加  
Model Prime Numbers  
微分方程式  
軌道力学  
関連項目
関連するガイド
履歴
引用書式

FindFormula

FindFormula[data]

data を近似する純関数を求める．

FindFormula[data,x]

data を近似する変数 x の記号関数を求める．

FindFormula[data,x,n]

data を近似する関数を n 個まで求める．

FindFormula[data,x,n,prop]

特性 prop に関連付けられた最適関数を n 個まで返す．

FindFormula[data,x,n,{prop1,prop2,…}]

特性 prop1，prop2等と関連付けられた最適関数を n 個まで返す．

詳細とオプション

  • データは{{x1,y1},{x2,y2},…}または{{1,y1},{2,y2},…}の形式の配列，あるいはTimeSeriesオブジェクトでなければならない．
  • {y1,y2,…}形式のデータは{{1,y1},{2,y2},…}形式のデータに等しい．
  • FindFormula[data,x,n,All]は可能なすべての特性を持つDatasetオブジェクトを作る．
  • サポートされる特性
  • "Score"内部スコア
    "Complexity"関数の複雑さ
    "Error"平均二乗誤差
    All上記の特性すべて
  • 使用可能なオプション
  • PerformanceGoal Automaticパフォーマンスのどの面について最適化するか
    RandomSeeding Automatic内部的にどの擬似乱数生成器のシードを使うか
    SpecificityGoal 1どのような複雑さの形式を求めるか
    TargetFunctions All考慮する関数
    TimeConstraintAutomatic結果を求めるまでの最大時間
  • PerformanceGoalの可能な設定
  • "Speed"結果を求めるまでの時間を最短にする
    "Quality"よりよい結果を求めようとする
  • SpecificityGoalの可能な設定
  • "Low"より簡単なフィット
    "High"より複雑な関数
    s0（最低）からInfinity（最高）までの特定性
  • FindFormula[data,x,SpecificityGoal->Infinity]は誤差を最小にする解を求める．
  • 1に等しいSpecificityGoalは，最高の予測パフォーマンスを与える．
  • TargetFunctionsの可能な設定
  • All以下にリストされたすべての関数
    {f_(1),f_(2),…}関数
  • TargetFunctionsの可能な関数には，Plus，Times，Power，Sin，Cos，Tan，Cot，Log，Sqrt，Csc，Sec，Abs，Expがある．
  • TimeConstraintの可能な設定
  • Automatic自動
    t最大 t 秒
  • RandomSeedingの可能な設定
  • Automatic関数が呼ばれるたびに自動的にシードし直す
    Inherited内部的にシードされた乱数を使う
    seed明示的な整数または数列をシードとして使う

例題

すべて開く すべて閉じる

例  (2)

関数 x Sin[x]の値の表を作る：

Wolfram Language code: Table[{x, N[x Sin[x]]}, {x, 0, 4, .3}]

FindFormulaはデータを生成する式を求める：

Wolfram Language code: FindFormula[%, x]

既知のメルセンヌ(Mersenne)素数の指数をプロットする：

Wolfram Language code: plot = ListLogPlot[mersenneexponents = MersennePrimeExponent[Range[48]]]

データを説明する最も単純な関数を求める：

Wolfram Language code: formula = FindFormula[Log[mersenneexponents], TargetFunctions -> {Power, Times}, SpecificityGoal -> "Low"]

フィットした関数をデータとともに可視化する：

Wolfram Language code: Show[plot, LogPlot[Exp[formula[n]], {n, 1, 48}]]

スコープ  (3)

正規分布に従うノイズのあるデータを生成する：

Wolfram Language code: data = Table[{x, Sin[2x] + Cos[x] + RandomVariate[NormalDistribution[0, 0.2]]}, {x, RandomReal[{-10, 10}, 1000]}];

データを可視化する：

Wolfram Language code: ListPlot[data]

データを近似する最初の5つの最良関数を求める：

Wolfram Language code: fits = FindFormula[data, x, 5]

フィットされた関数をデータとともに可視化する：

Wolfram Language code: Show[ListPlot[data], Plot[fits, {x, -20, 60}, PlotRange -> All]]

正規分布に従うノイズのあるデータを生成する：

Wolfram Language code: data = Table[{x, -x + 2Sin[x] + RandomVariate[NormalDistribution[0, 0.2]]}, {x, RandomReal[{-10, 10}, 100]}];

データを可視化する：

Wolfram Language code: ListPlot[data]

データを近似する最初の5つの関数について，データ集合を可視化する：

Wolfram Language code: fit = FindFormula[data, x, 5, All]

正規分布に従うノイズのあるデータを生成する：

Wolfram Language code: data = Table[{x, Sin[2x] + x Exp[Cos[x]] + RandomVariate[NormalDistribution[0, 0.2]]}, {x, RandomReal[{-10, 10}, 500]}];

データを可視化する：

Wolfram Language code: ListPlot[data]

最初の300のフィットを見，そのスコアをSpecificityGoalのさまざまな設定についての誤差と複雑さの関数としてプロットする：

Wolfram Language code: fit = FindFormula[data, x, 300, {"Complexity", "Error", "Score"}, TimeConstraint -> 20, PerformanceGoal -> "Quality", SpecificityGoal -> 1];
Wolfram Language code: errorcomplexity = fit[[All, 2]]; errorcomplexity = Select[errorcomplexity, #[[2]] < 20&]; ListPlot3D[errorcomplexity, Filling -> Bottom]
Wolfram Language code: fit2 = FindFormula[data, x, 300, {"Complexity", "Error", "Score"}, TimeConstraint -> 20, PerformanceGoal -> "Quality", SpecificityGoal -> Infinity];
Wolfram Language code: errorcomplexity = fit2[[All, 2]]; errorcomplexity = Select[errorcomplexity, #[[2]] < 200&]; ListPlot3D[errorcomplexity, Filling -> Bottom]

データにフィットした最初の関数を可視化する：

Wolfram Language code: Show[ListPlot[data], Plot[fit[[1, 1]], {x, 0, 20}]]

オプション  (4)

PerformanceGoal  (1)

正規分布に従うノイズのあるデータを生成する：

Wolfram Language code: data = Table[{x, x Cos[2 x] + Sin[2 x] + x + RandomVariate[NormalDistribution[0, 0.2]]}, {x, RandomReal[{-3, 20}, 1000]}];

データを可視化する：

Wolfram Language code: ListPlot[data]

データをその内部スコアとともに近似する最良関数を求める：

Wolfram Language code: fit = FindFormula[data, x, 1, "Score" ]

PerformanceGoalを使ってその内部スコアとともにデータを近似する最良関数を求める：

Wolfram Language code: fit2 = FindFormula[data, x, 1, "Score", PerformanceGoal -> "Quality" ]

フィットされた関数をデータとともに可視化する：

Wolfram Language code: Show[ListPlot[data], Plot[{First@fit, First@fit2}, {x, -20, 60}, PlotRange -> All]]

RandomSeeding  (1)

一様分布に従うノイズでデータを生成する：

Wolfram Language code: data = Table[{x, Sin[2 + x] + RandomVariate[NormalDistribution[0, 0.2]]}, {x, RandomReal[{-10, 10}, 500]}];

FindFormulaのいろいろな評価を比較し，その違いを見る：

Wolfram Language code: Table[FindFormula[data, x], 3]

オプションRandomSeedingを使って異なる結果にならないようにする：

Wolfram Language code: Table[FindFormula[data, x, RandomSeeding -> 1], 3]

SpecificityGoal  (1)

正規分布に従うノイズのあるデータを生成する：

Wolfram Language code: data = Table[{x, x + RandomVariate[NormalDistribution[0, 2]]}, {x, RandomReal[{-3, 20}, 15]}];

データを可視化する：

Wolfram Language code: ListPlot[data]

SpecificityGoalのさまざまな値を使ってエラーのあるデータを近似する最良関数を求める：

Wolfram Language code: fits = Table[FindFormula[data, x, 1, "Error", SpecificityGoal -> i], {i, {"Low", "High"}}]

フィットした関数をデータとともに可視化する：

Wolfram Language code: Table[Show[ListPlot[data], Plot[fits[[i, 1]], {x, -20, 60}, PlotRange -> All]], {i, 1, 2}]

TargetFunctions  (1)

正規分布に従うノイズを持つデータを生成する：

Wolfram Language code: data = Table[{x, x + Log[2 x] + RandomVariate[NormalDistribution[0, 0.2]]}, {x, RandomReal[{0.1, 20}, 1000]}];

データを可視化する：

Wolfram Language code: ListPlot[data]

データを近似する最良関数を求める：

Wolfram Language code: fit = FindFormula[data, x]

TargetFunctionsを使ってデータを近似する最良関数を求める：

Wolfram Language code: fit2 = FindFormula[data, x, TargetFunctions -> {Times, Log, Plus}]

フィットされた関数をデータとともに可視化する：

Wolfram Language code: Show[ListPlot[data], Plot[{fit, fit2}, {x, -3, 20}]]

アプリケーション  (4)

人口増加  (1)

ポーランドの人口増加：

Wolfram Language code: data = Entity["Country", "Poland"][EntityProperty["Country", "Population", {"Date" -> Interval[{DateObject[{1950}], DateObject[{2015}]}]}]]

データを説明する最良の関数を求める：

Wolfram Language code: fit = FindFormula[data, x]

フィットした関数をデータとともに可視化する：

Wolfram Language code: Show[DateListPlot[data["Path"], ...], Plot[fit, {x, AbsoluteTime@data["FirstTime"], AbsoluteTime@data["LastTime"]}]]

Model Prime Numbers  (1)

最初の100個の素数のフィットを求める：

Wolfram Language code: primes = Table[Prime[n], {n, 100}];
Wolfram Language code: fit = FindFormula[primes, x]

フィットをデータおよび次の200個の素数と比較する：

Wolfram Language code: primesNext = Table[Prime[n], {n, 100, 300}];
Wolfram Language code: Show[ListPlot[primes], ListPlot[Transpose[{Range[100, 300], primesNext}], PlotStyle -> Red], Plot[fit, {x, 0, 300}, PlotStyle -> Gray], PlotRange -> All]

微分方程式  (1)

微分方程式の数値解についてのフィットを求める：

Wolfram Language code: sol = First[y /. NDSolve[{y'[x] == y[x]Cos[x], y[0] == 1}, y, {x, -5, 300}]]; times = N[Range[-5, 600] / 9]; data = Transpose[{times, sol[times] + RandomReal[.005, Length[times]]}]; lp = ListPlot[data, PlotRange -> All]
Wolfram Language code: fit = FindFormula[data, x, 1, TargetFunctions -> {Exp, Sin, Cos}, RandomSeeding -> 1234]

フィットとデータを比較する：

Wolfram Language code: Show[ListPlot[data], Plot[fit, {x, -20, 90}, PlotRange -> All]]

軌道力学  (1)

惑星の軌道周期と半長軸をプロットする：

Wolfram Language code: data = EntityValue["Planet", {"SemimajorAxis", "OrbitPeriod"}];
Wolfram Language code: ListPlot[Thread[Callout[data, EntityList["Planet"]]]]

軌道周期から軌道半径を説明する最も簡単な関数を求める：

Wolfram Language code: formula = FindFormula[data, a, RandomSeeding -> 1234]

比例定数を求める：

Wolfram Language code: formula /. a -> Quantity[1, "AstronomicalUnit"]

ケプラー(Kepler)の第3法則によって与えられる厳密な式と比較する：

Wolfram Language code: kepler = FormulaData[{"KeplersThirdLaw", "Sun"}]

比例の厳密な定数には値がある：

Wolfram Language code: Sqrt@UnitConvert[kepler[[2]] / QuantityVariable["a", "Length"] ^ 3, ("Days"^2/"AstronomicalUnit"^3)]

軌道データから得たさまざまな値と直接比較する：

Wolfram Language code: Sqrt@UnitConvert[(#2^2/#^3)&@@@data, ("Days"^2/"AstronomicalUnit"^3)]
Wolfram Research (2015), FindFormula, Wolfram言語関数， https://reference.wolfram.com/language/ref/FindFormula.html （2017年に更新）.

テキスト

Wolfram Research (2015), FindFormula, Wolfram言語関数， https://reference.wolfram.com/language/ref/FindFormula.html （2017年に更新）.

CMS

Wolfram Language. 2015. "FindFormula." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/FindFormula.html.

APA

Wolfram Language. (2015). FindFormula. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FindFormula.html

BibTeX

@misc{reference.wolfram_2026_findformula, author="Wolfram Research", title="{FindFormula}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/FindFormula.html}", note=[Accessed: 05-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_findformula, organization={Wolfram Research}, title={FindFormula}, year={2017}, url={https://reference.wolfram.com/language/ref/FindFormula.html}, note=[Accessed: 05-July-2026]}