WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FindRoot[f,{x,x0}]

x=x0 から始めて f の数値根を求める．

FindRoot[lhs==rhs,{x,x0}]

方程式 lhs==rhs の数値解を求める．

FindRoot[{f1,f2,…},{{x,x0},{y,y0},…}]

すべての fi の連立数値根を求める．

FindRoot[{eqn1,eqn2,…},{{x,x0},{y,y0},…}]

連立方程式 eqniの数値解を求める．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
オプション  
AccuracyGoal  
DampingFactor  
EvaluationMonitor  
Show More Show More
Jacobian  
MaxIterations  
Method  
PrecisionGoal  
StepMonitor  
WorkingPrecision  
アプリケーション  
逆関数の計算  
境界値問題を解く  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

FindRoot

FindRoot[f,{x,x0}]

x=x0 から始めて f の数値根を求める．

FindRoot[lhs==rhs,{x,x0}]

方程式 lhs==rhs の数値解を求める．

FindRoot[{f1,f2,…},{{x,x0},{y,y0},…}]

すべての fi の連立数値根を求める．

FindRoot[{eqn1,eqn2,…},{{x,x0},{y,y0},…}]

連立方程式 eqniの数値解を求める．

詳細とオプション

  • 変数の初期値がリストで与えられているとき，変数の値は同じ次元のリストであると解釈される．
  • FindRootはSolveから得るのと同じ形式の x, y, … のための代入リストを返す．
  • FindRootは，まずすべての変数の値を局所化し，次に記号的となった変数で f を評価し，繰り返して結果を数値的に評価する．
  • FindRootは属性HoldAllを持ち，Blockを用いて実質的に変数を局所化する．
  • FindRoot[lhs==rhs,{x,x0,x1}]は x0と x1を x の最初の2つの値とし，導関数を用いずに解を求める．
  • FindRoot[lhs==rhs,{x,xstart,xmin,xmax}]は，x が xminから xmaxの範囲外に出た場合にこの検索を中止するという条件で，解を求める．
  • x の初期値を1つしか指定しなければ，FindRootはニュートン法を用いて解を求める．初期値を2つ指定すると，FindRootは割線法の変形を用いる．
  • すべての方程式と初期値が実数の場合，FindRootは実根のみを求める．複素数が含まれる場合は複素根も求める．
  • 初期値に0.Iを加えることで，常にFindRootに複素根を求めさせることができる．
  • 指定可能なオプション
  • AccuracyGoal Automatic目標とする確度
    EvaluationMonitor None式が評価されたときに常に評価される式
    Jacobian Automaticこの系のヤコビ行列式
    MaxIterations 100使用する最大反復回数
    TemplateBox[{Method, paclet:ref/Method}, RefLink, BaseStyle -> {3ColumnTableMod}] Automatic使用するメソッド
    PrecisionGoal Automatic目標とする精度
    StepMonitor Noneステップを取るたびに常に評価される式
    WorkingPrecision MachinePrecision内部計算に使用する精度
  • デフォルト設定ではAccuracyGoalとPrecisionGoalの設定はWorkingPrecision/2である．
  • AccuracyGoalの設定で，根の位置の値と根における関数の値の両方の目標確度の桁数を指定する．
  • PrecisionGoalの設定で根の位置の値の目標精度桁数を指定する．
  • FindRootはAccuracyGoalまたはPrecisionGoalで指定された目標精度（または確度）に達するまで計算を続ける．
  • FindRootがMaxIterationsの反復ステップ内で指定された正確さの解が見出せない場合，最近見出した近似解を返す．この場合，この点を初期値としてFindRootを再適用する．

例題

すべて開く すべて閉じる

例  (3)

付近で の根を求める：

Wolfram Language code: FindRoot[Sin[x] + Exp[x], {x, 0}]

付近で の解を求める：

Wolfram Language code: FindRoot[Cos[x] == x, {x, 0}]

非線形方程式系を解く：

Wolfram Language code: FindRoot[{Exp[x - 2] == y, y ^ 2 == x}, {{x, 1}, {y, 1}}]

スコープ  (4)

2つの非線形方程式の系の解を求める：

Wolfram Language code: FindRoot[{y == Exp[x], x + y == 2}, {{x, 1}, {y, 1}}]

三変数の三変成分関数の根を求める：

Wolfram Language code: FindRoot[{Sin[x + y], Cos[x - y], x ^ 2 + y ^ 2 - z}, {{x, 1}, {y, 0}, {z, 0}}]

複素数の初期値を与えることで複素数値を使った探索が行える：

Wolfram Language code: FindRoot[Zeta[z], {z, 1 / 2 + 14 I}]

実数入力に対して方程式が複素数である場合，実数の初期値が複素数の結果を与えていることがある：

Wolfram Language code: FindRoot[(Cos[z + I] - 2)(z + 2), {z, 1}]
Wolfram Language code: FindRoot[(Cos[z + I] - 2)(z + 2), {z, -1}]

一般化と拡張  (1)

変数は，初期値で指定されている場合にはベクトル値として考えることができる：

Wolfram Language code: A = {{1, 2, 3}, {4, 5, 6}, {6, 7, 8}};
Wolfram Language code: FindRoot[{A.x == λ x, x.x == 1}, {{x, RandomReal[1, 3]}, {λ, 1}}]

オプション  (10)

AccuracyGoal  (1)

誤差推定の許容率を変える：

Wolfram Language code: 10 - x /. FindRoot[Sin[x - 10] - x + 10, {x, 0}]

停止のための誤差許容率を緩める：

Wolfram Language code: 10 - x /. FindRoot[Sin[x - 10] - x + 10, {x, 0}, AccuracyGoal -> 4, PrecisionGoal -> 4]

根までの推定相対距離を停止の主要基準とする：

Wolfram Language code: 10 - x /. FindRoot[Sin[x - 10] - x + 10, {x, 0}, AccuracyGoal -> Infinity, PrecisionGoal -> 8]

DampingFactor  (1)

DampingFactorを使って高次根への収束をスピードアップすることができる：

Wolfram Language code: Block[{s = 0}, {FindRoot[Sin[x] - 1, {x, 1.5}, StepMonitor :> s++], s}]
Wolfram Language code: Block[{s = 0}, {FindRoot[Sin[x] - 1, {x, 1.5}, DampingFactor -> 2, StepMonitor :> s++], s}]

EvaluationMonitor  (1)

EvaluationMonitorを使って使用された関数評価を追跡記録することができる：

Wolfram Language code: {res, {evx}} = Reap[FindRoot[x ^ 2 == Exp[x], {x, 0}, EvaluationMonitor :> Sow[x]]]
Wolfram Language code: Show[Plot[{x ^ 2, Exp[x]}, {x, -1, 0}], ListPlot[{Transpose[{evx, evx ^ 2}], Transpose[{evx, Exp[evx]}]}]]

Jacobian  (1)

「ブラックボックス」関数に関数行列式を指定する：

Wolfram Language code: n = 1000; A = SparseArray[{{i_, i_} -> -2., {i_, j_} /; Abs[i - j] == 1 -> 1.}, {n, n}, 0.]; blackbox[x_ ? VectorQ] := n ^ 2 A.x + x - x ^ 3 - 1;
Wolfram Language code: J[x_ ? VectorQ] := Module[{d = 1 - 3 x ^ 2}, n ^ 2 A + SparseArray[{i_, i_} :> d[[i]], {n, n}]]
Wolfram Language code: sc = ConstantArray[0., n]; Block[{e = 0}, Timing[FindRoot[blackbox[x], {x, sc}, Jacobian -> J[x], EvaluationMonitor :> e++];e]]

指定された関数行列式がなければ，有限差分の計算に余分な評価が行われる：

Wolfram Language code: Block[{e = 0}, Timing[FindRoot[blackbox[x], {x, sc}, EvaluationMonitor :> e++];e]]

疎な形式を知っているならば，疎なパターンテンプレートを指定することで評価回数を少なくできる：

Wolfram Language code: sp = SparseArray[{{i_, j_} /; Abs[i - j] ≤ 1 -> _}, {n, n}]
Wolfram Language code: Block[{e = 0}, Timing[FindRoot[blackbox[x], {x, sc}, Jacobian -> {"FiniteDifference", Sparse -> sp}, EvaluationMonitor :> e++];e]]

さまざまなメソッドが必要とするヤコビ行列式の評価数を調べる：

Wolfram Language code: Block[{j = 0}, FindRoot[blackbox[x], {x, sc}, Jacobian -> {J[x], EvaluationMonitor :> j++}];"Jacobian Evaluations" -> j]
Wolfram Language code: Block[{j = 0}, FindRoot[blackbox[x], {x, sc}, Method -> "AffineCovariantNewton", Jacobian -> {J[x], EvaluationMonitor :> j++}];"Jacobian Evaluations" -> j]

MaxIterations  (1)

使うステップ数を制限したり増したりする：

Wolfram Language code: FindRoot[Exp[1 / (x ^ 2 - 1)] - 10 ^ -8, {x, .1}, MaxIterations -> 10]

デフォルトの反復回数は100である：

Wolfram Language code: FindRoot[Exp[1 / (x ^ 2 - 1)], {x, .1}]

この軟化子関数は においてすべての導関数が0なので，アルゴリズムは最終的に停止する：

Wolfram Language code: FindRoot[Exp[1 / (x ^ 2 - 1)], {x, .1}, MaxIterations -> 1000]

Method  (2)

メソッドオプションについては制約条件のない最適化も参照されたい．

異なる方法で の根を求める：

Wolfram Language code: f[x_] = ArcTan[1000 Cos[x]]; Plot[f[x], {x, 0, 12}, Exclusions -> None]

FindRootで使われるステップと評価をモニターする関数を定義する：

Wolfram Language code: monitoredFindRoot[args__] := Module[{s = 0, e = 0, j = 0}, {FindRoot[args, StepMonitor :> s++, EvaluationMonitor :> e++, Jacobian -> {Automatic, EvaluationMonitor :> j++}], "Steps" -> s, "Evaluations" -> e, "Jacobian Evaluations" -> j}]

デフォルトの方法（ニュートン法）：

Wolfram Language code: monitoredFindRoot[ArcTan[1000Cos[x]], {x, 1}]

ブレント(Brent)法の根の囲い込みには根を囲む2つの初期条件が必要である：

Wolfram Language code: monitoredFindRoot[ArcTan[1000Cos[x]], {x, 1, 2}, Method -> "Brent"]

割線法は2つの初期条件で始まる：

Wolfram Language code: monitoredFindRoot[ArcTan[1000Cos[x]], {x, 1, 2}, Method -> "Secant"]

アフィン共変ニュートン法を選択する：

Wolfram Language code: monitoredFindRoot[ArcTan[1000Cos[x]], {x, 1}, Method -> "AffineCovariantNewton"]

PrecisionGoal  (1)

誤差推定の許容率を変える：

Wolfram Language code: 10 - x /. FindRoot[Sin[x - 10] - x + 10, {x, 0}]

停止のための誤差許容率を緩める：

Wolfram Language code: 10 - x /. FindRoot[Sin[x - 10] - x + 10, {x, 0}, AccuracyGoal -> 4, PrecisionGoal -> 4]

根までの推定相対距離を停止の主要基準とする：

Wolfram Language code: 10 - x /. FindRoot[Sin[x - 10] - x + 10, {x, 0}, AccuracyGoal -> Infinity, PrecisionGoal -> 8]

StepMonitor  (1)

いつ反復ステップが取られるかモニターする：

Wolfram Language code: f[x_, y_] = {x - 1, 10(y - Cos[2x] + 1)};
Wolfram Language code: {res, {stxy}} = Reap[FindRoot[f[x, y], {{x, -1}, {y, -1}}, StepMonitor :> Sow[{x, y}]]]

の等高線プロット上でステップを表す：

Wolfram Language code: ContourPlot[f[x, y].f[x, y], {x, -1, 1}, {y, -2, 1}, Epilog -> {Red, Map[Point, stxy]}]

ステップ（赤）とその評価（緑）を表す．ステップには数回の評価が必要なことがある：

Wolfram Language code: {res, {exy}} = Reap[FindRoot[f[x, y], {{x, -1}, {y, -1}}, EvaluationMonitor :> Sow[{x, y}]]];
Wolfram Language code: ContourPlot[f[x, y].f[x, y], {x, -1, 1}, {y, -2, 1}, Epilog -> {{PointSize[0.04], Red, Map[Point, stxy]}, {Green, Map[Point, exy]}}]

WorkingPrecision  (1)

100桁精度演算で根を求める：

Wolfram Language code: FindRoot[Cos[x ^ 2] - x, {x, 1}, WorkingPrecision -> 100]

機械精度で始め，適応的に精度を100まで上げて根を求める：

Wolfram Language code: Block[{prec = MachinePrecision}, FindRoot[Cos[x ^ 2] - x, {x, 1.0}, WorkingPrecision -> 100, StepMonitor :> If[Precision[x] ≠ prec, prec = Precision[x];Print["Increased precision to ", prec, " at x = ", x];]]]

アプリケーション  (3)

逆関数の計算  (1)

同型写像 について，その逆関数 は の根である：

Wolfram Language code: inv[f_, s_] := Function[{t}, s /. FindRoot[f - t, {s, 1}]]

指数関数の近似逆関数：

Wolfram Language code: einv = inv[Exp[x], x]

これは組込みのLog関数に非常に近い：

Wolfram Language code: Plot[einv[x] - Log[x], {x, 0, 1}, PlotRange -> All]

振動周期を与える「ブラックボックス」関数：

Wolfram Language code: f[a_ ? NumberQ] := Module[{p = 0}, NDSolve[{x''[t] + x[t] + x[t] ^ 3 == 0, x[0] == a, x'[0] == 0}, x, {t, ∞}, Method -> {"EventLocator", "Event" -> x[t], "EventAction" :> Throw[p = t, "StopIntegration"]}]; 4p];
Wolfram Language code: Plot[f[a], {a, 0, 4}]

その逆関数をプロットする：

Wolfram Language code: finv = inv[f[a], a]
Wolfram Language code: Plot[finv[s], {s, 3, 6}]

境界値問題を解く  (2)

シューティング法を使って境界値問題 , を解く：

Wolfram Language code: x1[s_ ? NumberQ] := First[x[1] /. NDSolve[{x''[t] + x'[t] + x[t] ^ 3 == Sin[4 t], x[0] == 0, x'[0] == s}, x, {t, 0, 1}]]
Wolfram Language code: Plot[x1[s], {s, -10, 10}]

根の両側の点を使ってカッコにいれる初期値を与える：

Wolfram Language code: FindRoot[x1[s], {s, -1, 0}]

解をプロットする：

Wolfram Language code: sol = NDSolve[{x''[t] + x'[t] + x[t] ^ 3 == Sin[4t], x[0] == 0, x'[0] == s} /. %, x, {t, 0, 1}]
Wolfram Language code: Plot[x[t] /. sol, {t, 0, 1}]

n 個の選点で境界値問題 , を解く：

Wolfram Language code: n = 100;

一階の系として考える：

Wolfram Language code: f[{u_, v_}] := {v, (1 - u - u ^ 3) / ϵ};

台形法則を使った連結に関する方程式：

Wolfram Language code: eqns = Flatten[Join[{Subscript[u, 0] == 0, Subscript[u, n] == 0}, Table[Thread[{Subscript[u, i], Subscript[v, i]} == {Subscript[u, i - 1], Subscript[v, i - 1]} + (1/2 n)(f[{Subscript[u, i - 1], Subscript[v, i - 1]}] + f[{Subscript[u, i], Subscript[v, i]}])], {i, 1, n}]]];

初期値として0を使う：

Wolfram Language code: sv = Flatten[Table[{{Subscript[u, i], 0}, {Subscript[v, i], 0}}, {i, 0, n}], 1];

ϵ の特定の値について解を求める：

Wolfram Language code: froot = FindRoot[eqns /. ϵ -> 0.01, sv]; sol = Table[Subscript[u, i], {i, 0, n}] /. froot; ListLinePlot[sol]

特性と関係  (2)

方程式の多項式系の場合，NSolveはすべての解をFindRootは1つの解を求める：

Wolfram Language code: polysys = Table[Total[RandomInteger[{-9, 9}, 5]RandomChoice[{x, y, z}, 5] ^ RandomInteger[{0, 3}, 5]] == 0, {3}]

FindRootは反復法を使って1つの解を求める：

Wolfram Language code: FindRoot[polysys, Transpose[{{x, y, z}, RandomComplex[1 + I, 3]}]]

NSolveは直接法を使ってすべての解を求める：

Wolfram Language code: NSolve[polysys, {x, y, z}]

パラメータまたは厳密解を含む方程式の場合はSolve，Reduce，FindInstanceのいずれかを使う：

Wolfram Language code: eq = x Exp[2x + a] + 3 == 0;

Solveはいくつかの解を返す：

Wolfram Language code: Solve[eq, x]

Reduceはすべての解を列挙する：

Wolfram Language code: Reduce[eq, x]

FindInstanceは特定の例を求める：

Wolfram Language code: FindInstance[eq, {x, a}, 2]

考えられる問題  (3)

関数が複素関数の場合は，変数は複素値を持つことができる：

Wolfram Language code: FindRoot[Zeta[1 / 2 + I t], {t, 1}]

関数が実数のままなら，変数も実数であると考えられる：

Wolfram Language code: FindRoot[Abs[Zeta[1 / 2 + I t]], {t, 1}]

関数を記号的に評価するのには時間がかかることがある：

Wolfram Language code: f[x_] := Nest[Sin[# + Sin[2#]]&, x, 20]
Wolfram Language code: FindRoot[f[x], {x, 0}]//Timing

関数の定義を制限して記号評価を避ける：

Wolfram Language code: g[x_ ? NumericQ] := Nest[Sin[# + Sin[2#]]&, x, 20]
Wolfram Language code: FindRoot[g[x], {x, 0}]//Timing

検索領域を制限しすぎると問題が発生する可能性がある．2つの非線形方程式の解を1/2から始まる[0,1]の領域で求める：

Wolfram Language code: FindRoot[{y == Exp[x], x + y == 2}, {{x, 1 / 2, 0, 1}, {y, 1 / 2, 0, 1}}]
Wolfram Research (1988), FindRoot, Wolfram言語関数， https://reference.wolfram.com/language/ref/FindRoot.html （2003年に更新）.

テキスト

Wolfram Research (1988), FindRoot, Wolfram言語関数， https://reference.wolfram.com/language/ref/FindRoot.html （2003年に更新）.

CMS

Wolfram Language. 1988. "FindRoot." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2003. https://reference.wolfram.com/language/ref/FindRoot.html.

APA

Wolfram Language. (1988). FindRoot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FindRoot.html

BibTeX

@misc{reference.wolfram_2026_findroot, author="Wolfram Research", title="{FindRoot}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/FindRoot.html}", note=[Accessed: 11-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_findroot, organization={Wolfram Research}, title={FindRoot}, year={2003}, url={https://reference.wolfram.com/language/ref/FindRoot.html}, note=[Accessed: 11-August-2026]}