WOLFRAM

Wolfram 语言与系统参考资料中心

FindShortestCurve[reg,s,t]

在区域 reg 上寻找两点 s 和 t 之间的最短曲线.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
特殊区域  
公式区域  
网格区域  
导出区域  
地理区域  
应用  
属性和关系  
可能存在的问题  
参见
历史
按以下格式引用：

FindShortestCurve

FindShortestCurve[reg,s,t]

在区域 reg 上寻找两点 s 和 t 之间的最短曲线.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

在圆上找出两点之间的最短曲线：

Wolfram Language code: FindShortestCurve[Circle[], {1, 0}, {0, 1}]
Wolfram Language code: HighlightRegion[Circle[], %]

在一个网格区域中查找两点之间的最短路径：

Wolfram Language code: path = FindShortestCurve[Sphere[], {0, 0, 1}, {0, 1, 0}];
Wolfram Language code: HighlightRegion[Sphere[], path]

计算最短路径的长度：

Wolfram Language code: ArcLength[path]

在网格上找到两点之间的最短曲线：

Wolfram Language code: FindShortestCurve[[image], {0.11, 0.11}, {0.89, 0.555}]

在网格上高亮显示曲线：

Wolfram Language code: HighlightRegion[[image], %]

范围  (14)

特殊区域  (5)

线：

Wolfram Language code: FindShortestCurve[[image], {1, 0}, {3, 0}]
Wolfram Language code: HighlightRegion[[image], %]

圆：

Wolfram Language code: FindShortestCurve[Circle[], {1, 0}, {0, 1}]
Wolfram Language code: HighlightRegion[Circle[], %]

球体：

Wolfram Language code: FindShortestCurve[Sphere[], {0, 0, 1}, {0, 1, 0}];
Wolfram Language code: HighlightRegion[Sphere[], %]

环面：

Wolfram Language code: {s, t} = RandomPoint[Torus[], 2];
Wolfram Language code: FindShortestCurve[Torus[], s, t];
Wolfram Language code: HighlightRegion[Torus[], %]

环域：

Wolfram Language code: FindShortestCurve[Annulus[], {1, 0}, {-0.8, 0.4}];
Wolfram Language code: HighlightRegion[Annulus[], %]

公式区域  (2)

ImplicitRegion：

Wolfram Language code: g = ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}];
Wolfram Language code: FindShortestCurve[g, {1, 0}, {1 / 10, 4 / 5}];
Wolfram Language code: HighlightRegion[g, %]

ParametricRegion：

Wolfram Language code: g = ParametricRegion[{{s, (1 + t) s ^ 2 - t}, -1 <= s <= 1 && 0 <= t <= 1}, {s, t}];
Wolfram Language code: FindShortestCurve[g, {-2 / 5, 1 / 10}, {2 / 5, 1 / 20}];
Wolfram Language code: HighlightRegion[g, %]

网格区域  (2)

在一维 BoundaryMeshRegion 中找到一条最短路径：

Wolfram Language code: ℛ = BoundaryMeshRegion[{{0}, {1}}, Point[{{1}, {2}}]]
Wolfram Language code: FindShortestCurve[ℛ, {0}, {1}]

二维的情况：

Wolfram Language code: ℛ = BoundaryMeshRegion[{{0, 0}, {3, 0}, {3, 3}, {0, 3}, {1, 1}, {2, 1}, {2, 2}, {1, 2}}, Line[{1, 2, 3, 4, 1}], Line[{5, 6, 7, 8, 5}]];
Wolfram Language code: FindShortestCurve[ℛ, {3, 3}, {1.5, 1}]
Wolfram Language code: HighlightRegion[ℛ, %]

三维的情况：

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {20, 3}]];
Wolfram Language code: {s, t} = RandomPoint[ℛ, 2];
Wolfram Language code: FindShortestCurve[ℛ, s, t]

在一维 MeshRegion 中寻找一条最短路径：

Wolfram Language code: ℛ = MeshRegion[{{0}, {1}, {2}, {3}}, {Line[{1, 2}], Line[{3, 4}]}]
Wolfram Language code: FindShortestCurve[ℛ, {0}, {1}]

二维的情况：

Wolfram Language code: FindShortestCurve[MengerMesh[2], {0.11, 0.11}, {0.89, 0.55}];
Wolfram Language code: HighlightRegion[MengerMesh[2], %]

三维的情况：

Wolfram Language code: ℛ = [image];
Wolfram Language code: FindShortestCurve[ℛ, {-0.79, -0.9, 0.}, {0.33, 0.94, 0.5}];
Wolfram Language code: HighlightRegion[ℛ, %]

导出区域  (3)

在一个 RegionIntersection 内找到一条最短曲线：

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];
Wolfram Language code: FindShortestCurve[ℛ, {0.2, 0.4}, {-0.3, 0.5}];
Wolfram Language code: HighlightRegion[ℛ, %]

在一个 TransformedRegion 中的最短曲线：

Wolfram Language code: ℛ = TransformedRegion[Disk[{1, 1}, 4], {Indexed[#, 1] Indexed[#, 2], Indexed[#, 1] + Indexed[#, 2]}&];
Wolfram Language code: FindShortestCurve[ℛ, {2.8, 4.9}, {-3.3, -0.2}];
Wolfram Language code: HighlightRegion[ℛ, %]

在一个 RegionBoundary 中寻找一条最短曲线：

Wolfram Language code: ℛ = RegionBoundary[MengerMesh[1, 3]];
Wolfram Language code: FindShortestCurve[ℛ, {0, 0, 0}, {1, 1, 1}];
Wolfram Language code: HighlightRegion[ℛ, %]

地理区域  (2)

具有 GeoPosition 的多边形：

Wolfram Language code: ℛ = Polygon[GeoPosition[{{{40.083441, -88.235716}, {40.083607, -88.257488}, {40.082603, -88.257149}, {40.076136999999996, -88.25740499999999}, {40.076178, -88.270888}, {40.076516, -88.271558}, {40.083686, -88.271512}, {40.083659999999995, -88.267046}, ... 33323}, {40.098112, -88.228687}, {40.095216, -88.228627}, {40.095179, -88.238547}, {40.094480999999995, -88.238546}, {40.094508999999995, -88.23267}, {40.094106, -88.232556}, {40.090666999999996, -88.232477}, {40.090741, -88.235745}}}]];
Wolfram Language code: {s, t} = RandomPoint[DiscretizeRegion@ℛ, 2];
Wolfram Language code: FindShortestCurve[ℛ, s, t]

具有 GeoGridPosition 的多边形：

Wolfram Language code: ℛ = Polygon[GeoGridPosition[{{{-0.9950503945490105, 1.2366760550756015}, {-0.9952074890903578, 1.2369207053693891}, {-0.9952196732768064, 1.2369073327446167}, {-0.9953160063787643, 1.236848436956935}, {-0.9954141759436825, 1.2369993898475449}, {-0. ... 197645333103}, {-0.9949098578570917, 1.2368130881428654}, {-0.9948663952535768, 1.2367477711687371}, {-0.9948714472169538, 1.2367426500757825}, {-0.9949211061652593, 1.2367089232486177}, {-0.9949439717990124, 1.236746107097628}}}, "Bonne"]];
Wolfram Language code: {s, t} = First[ RandomPoint[ℛ, 2]];
Wolfram Language code: FindShortestCurve[ℛ, s, t];
Wolfram Language code: HighlightRegion[ℛ, %]

应用  (6)

球面上两点之间的最短曲线：

Wolfram Language code: HighlightRegion[Sphere[], FindShortestCurve[Sphere[], {0, 0, 1}, {0, 1, 0}]]

该路径位于大圆上：

Wolfram Language code: RegionIntersection[Sphere[], InfinitePlane[{{0, 0, 1}, {0, 1, 0}, {0, 0, 0}}]]
Wolfram Language code: Show[{%%, %}]

寻找一条从因斯布鲁克到维也纳的奥地利最短路线：

Wolfram Language code: g = DiscretizeGraphics[CountryData["Austria", {"FullPolygon", "Mercator"}]];
Wolfram Language code: cities = {Entity["City", {"Innsbruck", "Tirol", "Austria"}], Entity["City", {"Vienna", "Vienna", "Austria"}]};

城市的 GeoGridPosition：

Wolfram Language code: {Innsbruck, Vienna} = First[GeoGridPosition[GeoPosition[#], "Mercator"]]& /@ cities
Wolfram Language code: path = FindShortestCurve[g, Innsbruck, Vienna];

显示路径：

Wolfram Language code: HighlightRegion[g, path]

与 GeoPath 进行比较：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "Austria"]], Red, GeoPath[cities, "Geodesic"]}]

求飞机在地球上飞行路径的两座城市之间的最短距离：

Wolfram Language code: a = 6378; b = 6357; earth = RegionBoundary@Ellipsoid[{0, 0, 0}, {a, a, b}];

在笛卡尔地心坐标系中表示西雅图和巴黎的位置：

Wolfram Language code: cities = {Entity["City", {"Seattle", "Washington", "UnitedStates"}], Entity["City", {"Paris", "IleDeFrance", "France"}]};
Wolfram Language code: pos = First@GeoPositionXYZ[cities]

将西雅图和巴黎的位置映射到椭球体上：

Wolfram Language code: {seattle, paris} = RegionNearest[earth, #]& /@ pos

显示路径：

Wolfram Language code: path = FindShortestCurve[earth, seattle, paris];
Wolfram Language code: Graphics3D[{Texture[GeoGraphics[GeoBackground -> "Satellite", ImageSize -> Large, GeoProjection -> "Equirectangular"], "Spherical"], Black, Ellipsoid[{0, 0, 0}, {a, a, b}], Red, Dashed, Thickness[0.005], path}, Boxed -> False, ViewPoint -> Front]

在橡皮筋上寻找两点之间的路径：

Wolfram Language code: g = DiscretizeGraphics[ParametricPlot3D[{Sin[t - (π/2)], 1.5Cos[(t/2) + (π/4)], Sin[t - π]}, {t, 0, 4 π}, PlotStyle -> Orange, Axes -> -None, Boxed -> False] /. Line[pts_, rest___] :> Tube[pts, 0.1, rest]];
Wolfram Language code: {s, t} = RandomPoint[g, 2];
Wolfram Language code: FindShortestCurve[g, s, t];

显示路径：

Wolfram Language code: HighlightRegion[g, %]

在人体上寻找两点之间的路径：

Wolfram Language code: body = \!\(\*Graphics3DBox[«8»]\);
Wolfram Language code: {s, t} = RandomPoint[body, 2];
Wolfram Language code: FindShortestCurve[body, s, t];

显示路径：

Wolfram Language code: HighlightRegion[body, %]

为移动机器人确定高效路径，使其能够在避开障碍物的同时，从一个点移动到另一个点：

Wolfram Language code: {robot, furniture} = { [image], \!\(\*Graphics3DBox[«6»]\)};

在此情景中，机器人的工作空间包含障碍物. 具体来说，是家具：

Wolfram Language code: Show[robot, furniture, Boxed -> True]

将工作区简化为一个二维环境：

Wolfram Language code: workspace = [image];
Wolfram Language code: {a, b} = {Most[RegionCentroid[robot]], {20, 18}};
Wolfram Language code: path = FindShortestCurve[workspace, a, b];

显示路径：

Wolfram Language code: HighlightRegion[workspace, path]

属性和关系  (1)

ShortestCurveDistance 是 FindShortestCurve 的弧长：

Wolfram Language code: c = Circle[];
Wolfram Language code: {s, t} = {{-1, 0}, {0, 1}};
Wolfram Language code: ArcLength[FindShortestCurve[c, s, t]] == ShortestCurveDistance[c, s, t]

可能存在的问题  (1)

近似方法在小尺度下可能会出现明显的数值误差：

Wolfram Language code: reg = Region[FindShortestCurve[Sphere[], {0., 0., 1.}, {0., 1., 0.}], ...]

在该区域上显示曲线：

Wolfram Language code: HighlightRegion[Sphere[], reg]
Wolfram Research (2025)，FindShortestCurve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FindShortestCurve.html.

文本

Wolfram Research (2025)，FindShortestCurve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FindShortestCurve.html.

CMS

Wolfram 语言. 2025. "FindShortestCurve." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/FindShortestCurve.html.

APA

Wolfram 语言. (2025). FindShortestCurve. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FindShortestCurve.html 年

BibTeX

@misc{reference.wolfram_2026_findshortestcurve, author="Wolfram Research", title="{FindShortestCurve}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/FindShortestCurve.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_findshortestcurve, organization={Wolfram Research}, title={FindShortestCurve}, year={2025}, url={https://reference.wolfram.com/language/ref/FindShortestCurve.html}, note=[Accessed: 09-September-2026]}