WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FormulaData[name]

公式 name についての方程式を与える．

FormulaData[name,{var1quantity1,var2quantity2,…}]

変数 variに指定された値 quantityiを使用して，方程式を解くか簡約するかする．

FormulaData[name,"property"]

公式 name の指定された特性の値を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
使用法  
複数の方定式  
変数指定  
オプション  
UnitSystem  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
標準物理定数  
基本的な物理公式  
関連項目
関連するガイド
履歴
引用書式

FormulaData

FormulaData[name]

公式 name についての方程式を与える．

FormulaData[name,{var1quantity1,var2quantity2,…}]

変数 variに指定された値 quantityiを使用して，方程式を解くか簡約するかする．

FormulaData[name,"property"]

公式 name の指定された特性の値を与える．

詳細とオプション

  • FormulaDataは，"OhmsLaw"や"LawOfSines"等の標準的な名前を使って，公式についての代数方程式を返す．
  • FormulaDataによって返される変数は，QuantityVariableラッパー付きで表現される．
  • variについて指定された値は，ListあるいはAssociationとして入力することができる．
  • 方程式に代入する値のリストを指定するとき，入力変数の値は var->value で指定できる．var は文字列でもQuantityVariableでもよく，value は，数，記号，あるいはQuantityでよい．
  • 未指定の変数が方程式の数と一致する場合，FormulaDataは，残りの変数については実数解について解こうとする．さもなければ，指定された全変数を与えられた変数で置換する．
  • FormulaData[]は使用可能なすべての公式のリストを返す．
  • FormulaData["Properties"]は公式について使用可能なすべての特性を返す．
  • 使用可能な特性
  • "Classes"この公式を含むクラス
    "DefaultValues"変数のサンプル値
    "ExternalIdentifiers"公式の出典情報
    "Formula"公式についての方程式
    "QuantityVariableDimensions"すべての変数についての基底の次元のリスト
    "QuantityVariableNames"すべての変数の英語名
    "QuantityVariablePhysicalQuantities"すべての変数の物理量
    "QuantityVariables"公式中の全変数のリスト
    "QuantityVariableTable"公式についてのすべての変数の詳細
  • "Classes"は，"Physics"や"Chemistry"のような一般的なカテゴリと{"Physics", "Mechanics"}のような下位範疇を含む．
  • "Association"を第2あるいは第3引数として指定してAssociationの出力を変えることができる．FormulaData[name, "Association"]は，1つまたは複数の方程式を，方程式の左辺がキーであるAssociationとして返す．FormulaData[name,{var1quantity1,var2quantity2,…},"Association"]は式の解または簡約された方程式をAssociationとして返す．FormulaData[name,"property","Association"]はListの代りにAssociationを返す．
  • FormulaDataは以下のオプションを取る．
  • UnitSystem $UnitSystemそれによって結果が返される単位系
    "UseDefaultValues"False指定されていない単位にデフォルト値を与える

例題

すべて開く すべて閉じる

例  (3)

公式についての方程式を求める：

Wolfram Language code: FormulaData["OhmsLaw"]

公式の変数について解を求める値を含める：

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> Quantity[1, "Volts"], "R" -> Quantity[1, "Ohms"]}]

公式の名前はFormulaLookupで求めることができる：

Wolfram Language code: FormulaLookup["kinetic energy"]
Wolfram Language code: FormulaData["KineticEnergy"]

公式の値は自由形式入力()を使って挿入することができる：

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> ["3V"], "R" -> ["2Ω"]}]

スコープ  (16)

使用法  (9)

FormulaDataが使うすべての公式を求める：

Wolfram Language code: FormulaData[]//Short

FormulaDataがサポートするすべての特性を求める：

Wolfram Language code: FormulaData["Properties"]

方程式中のすべてのQuantityVariableを求める：

Wolfram Language code: FormulaData["OhmsLaw", "QuantityVariables"]

方程式の変数の物理量を求める：

Wolfram Language code: FormulaData["OhmsLaw", "QuantityVariablePhysicalQuantities"]

方程式についての変数名を知る：

Wolfram Language code: FormulaData["ConeMomentOfInertia", "QuantityVariableNames"]

方程式について，その物理量の次元を求める：

Wolfram Language code: FormulaData["OhmsLaw", "QuantityVariableDimensions"]

公式の変数のすべての特性を表示する：

Wolfram Language code: FormulaData["OhmsLaw", "QuantityVariableTable"]

公式の出典情報を求める：

Wolfram Language code: FormulaData["DolbearsLaw", "ExternalIdentifiers"]
Wolfram Language code: FormulaData[{"BussardRamjet", "PhotonDrive"}, "ExternalIdentifiers"]

公式が属するクラスを求める：

Wolfram Language code: FormulaData["OhmsLaw", "Classes"]

複数の方定式  (3)

公式によっては複数の方程式を持つものもある：

Wolfram Language code: FormulaData["ConeMomentOfInertia"]

複数の方程式を持つ公式は，可能な場合はすべての変数について解かれる：

Wolfram Language code: FormulaData["TriangleAreaSSS", {"a" -> Quantity[1, "Meters"], "b" -> Quantity[1, "Meters"], "c" -> Quantity[1, "Meters"]}]

公式の標準的な名前の中には，プランクの放射法則の異なる形式のようにリストとして指定されるものもある：

Wolfram Language code: FormulaLookup["planck's law"]
Wolfram Language code: Column[{FormulaData[{"PlanckRadiationLaw", "Wavelength"}], FormulaData[{"PlanckRadiationLaw", "Frequency"}]}]

変数指定  (4)

公式の変数はQuantityVariableで指定することができる：

Wolfram Language code: FormulaData["OhmsLaw", {QuantityVariable["V", "ElectricPotential"] -> Quantity[1, "Volts"]}]

QuantityVariableの記号成分も使うことができる：

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> Quantity[1, "Volts"]}]

変数は公式の変数についての有効な入力である：

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> x}]

純粋な数もまた有効である：

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> 2}]

Associationを使って形式変数を指定することができる：

Wolfram Language code: FormulaData["OhmsLaw", <|QuantityVariable["V", "ElectricPotential"] -> Quantity[1, "Volts"]|>]

オプション  (1)

UnitSystem  (1)

UnitSystemを使って結果の単位を制御する：

Wolfram Language code: FormulaData["DolbearsLaw", {"N" -> 60}, UnitSystem -> "Imperial"]
Wolfram Language code: FormulaData["DolbearsLaw", {"N" -> 60}, UnitSystem -> "Metric"]

アプリケーション  (1)

公式の方程式は，続く計算に使うことができる：

Wolfram Language code: equation = FormulaData["StefanBoltzmannLaw", {"ϵ" -> 1, "T" -> Quantity[t, "Kelvins"]}]

温度について積分する：

Wolfram Language code: Integrate[equation[[2]], {t, 0, 1000}]

方程式の動作をプロットする：

Wolfram Language code: Plot[equation[[2]], {t, 0, 1000}, AxesLabel -> {"temperature", equation[[1]]}]

特性と関係  (2)

FormulaLookupを使ってクラスまたは名前で公式を求める：

Wolfram Language code: FormulaLookup["uncertianty relation"]

クラスには文字列およびより具体的な文字列のリストが含まれる：

Wolfram Language code: FormulaLookup[{"Physics", "QuantumMechanics"}]//Short

使用可能なクラスのリストを得る：

Wolfram Language code: FormulaLookup["Classes"]//Short

特定の式のクラスを求める：

Wolfram Language code: FormulaData["OhmsLaw", "Classes"]

考えられる問題  (3)

FormulaLookupを使って方程式の名前を求める：

Wolfram Language code: FormulaData["ohm's law"]
Wolfram Language code: FormulaLookup["ohm's law"]

入力量は適切な次元のものでなければならない：

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> Quantity[1, "Amps"]}]

未指定の変数が式内の方程式の数よりも少ないなら，その系は過剰決定系である：

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> Quantity[1, "Volts"], "I" -> Quantity[1, "Amperes"], "R" -> Quantity[1, "Ohms"]}]

おもしろい例題  (2)

標準物理定数  (1)

光速およびプランクの定数の両方をパラメータとして含むすべての公式を求める：

Wolfram Language code: Grid[{#, FormulaData[#]}& /@ Select[FormulaData[], MemberQ[FormulaData[#], "SpeedOfLight", ∞] && MemberQ[FormulaData[#], "PlanckConstant", ∞]&], Dividers -> Center, Alignment -> Left]

基本的な物理公式  (1)

プランクの定数，光速，あるいは引力定数をパラメータとして含むすべての公式を選ぶ：

Wolfram Language code: chGFormulas = Select[(Column[Flatten@{#, FormulaData[#], FormulaData[#, "QuantityVariableTable"]}]& /@ FormulaData[]) /. Quantity[q_, "ReducedPlanckConstant"] :> Quantity[q /. None -> 1 / (2Pi), "PlanckConstant"], MemberQ[#, "PlanckConstant" | "SpeedOfLight" | "GravitationalConstant", ∞]&];

関連する物理量に基づいた公式のネットワークを構築する：

Wolfram Language code: chGformulaNetwork = Select[{UndirectedEdge[#1, #2], Length[Intersection @@(Union[Last /@ Cases[#, _QuantityVariable, ∞]]& /@ {#1, #2})]}&@@@ Subsets[chGFormulas, {2}], Last[#] > 0&];
Wolfram Language code: Graph[First /@ chGformulaNetwork, EdgeWeight -> 1 / (Last /@ chGformulaNetwork), GraphLayout -> {"VertexLayout" -> {"SpringElectricalEmbedding", "EdgeWeighted" -> True}}, VertexLabels -> Placed["Name", Tooltip]]
Wolfram Research (2014), FormulaData, Wolfram言語関数， https://reference.wolfram.com/language/ref/FormulaData.html （2019年に更新）.

テキスト

Wolfram Research (2014), FormulaData, Wolfram言語関数， https://reference.wolfram.com/language/ref/FormulaData.html （2019年に更新）.

CMS

Wolfram Language. 2014. "FormulaData." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/FormulaData.html.

APA

Wolfram Language. (2014). FormulaData. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FormulaData.html

BibTeX

@misc{reference.wolfram_2026_formuladata, author="Wolfram Research", title="{FormulaData}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/FormulaData.html}", note=[Accessed: 11-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_formuladata, organization={Wolfram Research}, title={FormulaData}, year={2019}, url={https://reference.wolfram.com/language/ref/FormulaData.html}, note=[Accessed: 11-November-2026]}