WOLFRAM

Wolfram 语言与系统参考资料中心

FunctionMonotonicity[f,x]

变量 x 为实数，求函数 f 的单调性.

FunctionMonotonicity[f,x,dom]

x 被限制在域 dom 内，求 f 的单调性.

FunctionMonotonicity[{f,cons},x,dom]

当 x 别于是条件 cons 限制时给出 f 的单调性.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Assumptions  
GenerateConditions  
PerformanceGoal  
StrictInequalities  
应用  
基本应用  
组合函数的情况  
微积分  
概率  
解方程和优化  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

FunctionMonotonicity

FunctionMonotonicity[f,x]

变量 x 为实数，求函数 f 的单调性.

FunctionMonotonicity[f,x,dom]

x 被限制在域 dom 内，求 f 的单调性.

FunctionMonotonicity[{f,cons},x,dom]

当 x 别于是条件 cons 限制时给出 f 的单调性.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

求函数的单调性：

Wolfram Language code: FunctionMonotonicity[E ^ x, x]

变量受约束条件限制的情况下求函数的单调性：

Wolfram Language code: FunctionMonotonicity[{x ^ 2, x < 0}, x]

求函数在整数上的单调性：

Wolfram Language code: FunctionMonotonicity[Cos[2 Pi n] n, n, Integers]

范围  (5)

不受限制的实数上的单调性：

Wolfram Language code: FunctionMonotonicity[Sin[x], x]
Wolfram Language code: FunctionMonotonicity[2 ^ x, x]
Wolfram Language code: FunctionMonotonicity[Sqrt[x ^ 2] - x, x]
Wolfram Language code: Plot[{Sin[x], 2 ^ x, Sqrt[x ^ 2] - x}, {x, -3, 3}]

非实值函数的单调性为 Indeterminate：

Wolfram Language code: FunctionMonotonicity[Log[x], x]

下面的函数为实值函数，对于正的 单调性为递增：

Wolfram Language code: FunctionMonotonicity[{Log[x], x > 0}, x]

变量受约束条件限制的情况下的单调性：

Wolfram Language code: FunctionMonotonicity[{Sin[x], -Pi / 2 ≤ x ≤ Pi / 2}, x]
Wolfram Language code: FunctionMonotonicity[{Sqrt[x ^ 2] - x, x ≥ 0}, x]

函数的严格单调性：

Wolfram Language code: FunctionMonotonicity[Floor[x], x, StrictInequalities -> True]
Wolfram Language code: FunctionMonotonicity[Floor[x] + x, x, StrictInequalities -> True]

TemplateBox[{x}, Floor] 非递减，但不是严格递增. TemplateBox[{x}, Floor]+x 严格递增：

Wolfram Language code: Plot[{Floor[x], Floor[x] + x}, {x, -10, 10}]

含有符号参数的函数：

Wolfram Language code: FunctionMonotonicity[x ^ 3 + a x + b, x]

选项  (5)

Assumptions  (1)

FunctionMonotonicity 给出有条件的答案：

Wolfram Language code: FunctionMonotonicity[a x + 1, x]

查看 取其他值时函数的单调性：

Wolfram Language code: FunctionMonotonicity[a x + 1, x, Assumptions -> a < 0]

GenerateConditions  (2)

默认情况下，FunctionMonotonicity 可能会对符号参数生成条件：

Wolfram Language code: FunctionMonotonicity[E ^ (a x), x]

如果设置 GenerateConditionsNone，FunctionMonotonicity 会失败，而不是给出有条件的结果：

Wolfram Language code: FunctionMonotonicity[E ^ (a x), x, GenerateConditions -> None]

下面返回有条件的有效结果，但没有给出条件：

Wolfram Language code: FunctionMonotonicity[E ^ (a x), x, GenerateConditions -> False]

默认情况下，报告所有的条件：

Wolfram Language code: FunctionMonotonicity[x / a ^ 2, x]

如果设置 GenerateConditionsAutomatic，不报告通常为真的条件：

Wolfram Language code: FunctionMonotonicity[x / a ^ 2, x, GenerateConditions -> Automatic]

PerformanceGoal  (1)

用 PerformanceGoal 避免潜在费时的计算：

Wolfram Language code: FunctionMonotonicity[a x ^ 5 + b x ^ 3 + c x ^ 2 + d x, x, PerformanceGoal -> "Speed"]

默认设置则尝试利用所有可用的技术来给出结果：

Wolfram Language code: FunctionMonotonicity[a x ^ 5 + b x ^ 3 + c x ^ 2 + d x, x]

StrictInequalities  (1)

默认情况下，FunctionMonotonicity 计算的是非严格单调性：

Wolfram Language code: FunctionMonotonicity[#, x]& /@ {Ramp[x] + 1, Ramp[x] + x}

如果设置 StrictInequalitiesTrue，FunctionMonotonicity 计算严格单调性：

Wolfram Language code: FunctionMonotonicity[#, x, StrictInequalities -> True]& /@ {Ramp[x] + 1, Ramp[x] + x}

Ramp[x]+1 非递减，但不是严格递增. Ramp[x]+x 严格递增：

Wolfram Language code: Plot[{Ramp[x] + 1, Ramp[x] + x}, {x, -2, 2}]

应用  (19)

基本应用  (5)

对于正实数 TemplateBox[{}, PositiveReals]，正的幂 都是非递减的：

Wolfram Language code: Table[FunctionMonotonicity[f, x, PositiveReals], {f, {x^1 / 3, Sqrt[x], x, x^2, x^3}}]
Wolfram Language code: Plot[{x^1 / 3, Sqrt[x], x, x^2, x^3}, {x, 0, 2}, Rule[...]]

下式说明所有这样的函数都是非递减的：

Wolfram Language code: FunctionMonotonicity[x^α, x, PositiveReals, Assumptions -> α > 0]

实际上它们都是递增的：

Wolfram Language code: FunctionMonotonicity[x^α, x, PositiveReals, Assumptions -> α > 0, StrictInequalities -> True]

对于正实数 TemplateBox[{}, PositiveReals]，负的幂 都是非递增的：

Wolfram Language code: Table[FunctionMonotonicity[f, x, PositiveReals], {f, {(1/x^1 / 3), (1/Sqrt[x]), (1/x), (1/x^2), (1/x^3)}}]
Wolfram Language code: Plot[{(1/x^1 / 3), (1/Sqrt[x]), (1/x), (1/x^2), (1/x^3)}, {x, 0, 2}, PlotLegends -> "Expressions"]

下式说明所有这样的函数都是递减的：

Wolfram Language code: FunctionMonotonicity[x^α, x, PositiveReals, Assumptions -> α < 0, StrictInequalities -> True]

时，指数函数 是递增的， 时是递减的：

Wolfram Language code: {FunctionMonotonicity[a^x, x, Assumptions -> a > 1], FunctionMonotonicity[a^x, x, Assumptions -> 0 < a < 1]}
Wolfram Language code: Plot[{0.5^x, 1.5^x}, {x, -3, 3}]

三角函数在实数上是非单调的：

Wolfram Language code: FunctionMonotonicity[Sin[x], x]
Wolfram Language code: Plot[Sin[x], {x, -3Pi, 3Pi}]

但在小范围内是单调的：

Wolfram Language code: FunctionMonotonicity[{Sin[x], -Pi / 2 ≤ x ≤ Pi / 2}, x]
Wolfram Language code: Plot[Sin[x], {x, -Pi / 2, Pi / 2}]

TemplateBox[{x}, Ceiling] 非递减，但不是递增：

Wolfram Language code: FunctionMonotonicity[Ceiling[x], x]
Wolfram Language code: FunctionMonotonicity[Ceiling[x], x, StrictInequalities -> True]
Wolfram Language code: Plot[Ceiling[x], {x, -5, 5}]

组合函数的情况  (5)

具有单调性 的函数之和仍然具有单调性 ：

Wolfram Language code: {f, g} = {Cos[x] - x, 5Erfc[x / 5]};
Wolfram Language code: {FunctionMonotonicity[f, x], FunctionMonotonicity[g, x]}

和具有相同的单调性：

Wolfram Language code: FunctionMonotonicity[f + g, x]
Wolfram Language code: Plot[{f, g, f + g}, {x, -10, 10}, Rule[...]]

非负非递减函数的积是非递减函数：

Wolfram Language code: {f, g} = {Floor[E ^ x], Erf[x] + 1};
Wolfram Language code: {FunctionMonotonicity[f, x], FunctionMonotonicity[g, x]}

它们的积也是非递减的：

Wolfram Language code: FunctionMonotonicity[f g, x]
Wolfram Language code: Plot[{f, g, f g}, {x, -2, 2}, ...]

非递减函数的复合函数是非递减函数：

Wolfram Language code: {f, g} = {Function[x, Sinh[x / 3]], Function[x, x + Sin[x]]};
Wolfram Language code: {FunctionMonotonicity[f[x], x], FunctionMonotonicity[g[x], x]}

它们的复合函数也是非递减的：

Wolfram Language code: {FunctionMonotonicity[f[g[x]], x], FunctionMonotonicity[g[f[x]], x]}
Wolfram Language code: Plot[{f[g[x]], g[f[x]]}, {x, -10, 10}, PlotLegends -> "Expressions"]

递增函数的逆函数是递增函数：

Wolfram Language code: f = Function[x, ConditionalExpression[x ^ 3 - x ^ 2 + x, Element[x, Reals]]]
Wolfram Language code: FunctionMonotonicity[f[x], x]

反函数也是递增的：

Wolfram Language code: g = InverseFunction[f]
Wolfram Language code: FunctionMonotonicity[g[x], x]
Wolfram Language code: Plot[{f[x], g[x]}, {x, -2, 2}, Rule[...]]

非递减函数 在区间 上的值域是 ：

Wolfram Language code: f[x_] := Gamma[x] + Log[x ^ 2]
Wolfram Language code: FunctionMonotonicity[{f[x], 1 ≤ x ≤ 5}, x]
Wolfram Language code: {f[1], f[5]}

为了比较，用 FunctionRange 计算值域：

Wolfram Language code: FunctionRange[{f[x], 1 ≤ x ≤ 5}, x, y]
Wolfram Language code: Plot[{f[x], f[1], f[5]}, {x, 1, 5}]

微积分  (4)

证明 在 时有极限：

Wolfram Language code: f = ArcTan[x] + Sin[x] / (2x ^ 2);
Wolfram Language code: Plot[f, {x, 1 / 2, 30}, PlotRange -> All]

时， 非递减，并上有界：

Wolfram Language code: FunctionMonotonicity[{f, x ≥ 2}, x]
Wolfram Language code: FunctionSign[{2 - f, x ≥ 2}, x]

在 处的极限等于 的上确界：

Wolfram Language code: Limit[f, x -> Infinity]
Wolfram Language code: MaxValue[{f, x ≥ 2}, x]

证明 是收敛的：

Wolfram Language code: f = 2 ^ -n - 3 ^ -n;
Wolfram Language code: Plot[f, {n, 1, 10}]

级数的项非负，因此部分和是递增的：

Wolfram Language code: FunctionSign[{f, n ≥ 1}, n]
Wolfram Language code: s = Sum[f, {n, 1, k}]
Wolfram Language code: FunctionMonotonicity[{s, k ≥ 1}, k]

部分和上有界，因此级数收敛：

Wolfram Language code: FunctionSign[{1 - s, k ≥ 1}, k]

用 Sum 计算级数的和：

Wolfram Language code: Sum[f, {n, 1, Infinity}]

如果 非负，则 是关于 的非递减函数：

Wolfram Language code: f = t ^ 2 Sin[5t] ^ 4;
Wolfram Language code: FunctionSign[f, t]
Wolfram Language code: Plot[f, {t, -5, 5}]
Wolfram Language code: g = Integrate[f, {t, 0, x}]
Wolfram Language code: FunctionMonotonicity[g, x]
Wolfram Language code: Plot[g, {x, -5, 5}]

将一个可微函数写成一个递增函数和一个递减函数的和：

Wolfram Language code: f = x ^ 4 - 2x ^ 3 + x;
Wolfram Language code: finc = Integrate[Max[D[f, x], 0] + 1, x]//Together
Wolfram Language code: fdec = Integrate[Min[D[f, x], 0] - 1, x]//Together

检查是否需要用常数调整函数：

Wolfram Language code: f - (finc + fdec)//Simplify

测试 和 的单调性：

Wolfram Language code: FunctionMonotonicity[finc, x]
Wolfram Language code: FunctionMonotonicity[fdec, x]
Wolfram Language code: Plot[{f, finc, fdec}, {x, -1, 2}]

概率  (3)

CDF 总是非递减函数：

Wolfram Language code: cdf = CDF[NormalDistribution[], x]
Wolfram Language code: FunctionMonotonicity[cdf, x]
Wolfram Language code: Plot[cdf, {x, -5, 5}]

SurvivalFunction 总是非递增的：

Wolfram Language code: sf = SurvivalFunction[NormalDistribution[], x]
Wolfram Language code: FunctionMonotonicity[sf, x]
Wolfram Language code: Plot[sf, {x, -5, 5}]

Quantile 在 上总是非递减：

Wolfram Language code: qf = Quantile[NormalDistribution[], x]
Wolfram Language code: FunctionMonotonicity[{qf, 0 < x < 1}, x]
Wolfram Language code: Plot[qf, {x, 0, 1}]

解方程和优化  (2)

如果 在 上递增且连续，并有 ，则 在 上只有一个根：

Wolfram Language code: f[x_] := RiemannR[x ^ 2 + 1] - 2
Wolfram Language code: FunctionMonotonicity[{f[x], 0 ≤ x ≤ 3}, x, StrictInequalities -> True, "Continuity" -> True]

用 Solve 求根：

Wolfram Language code: Solve[RiemannR[x ^ 2 + 1] - 2 == 0 && 0 ≤ x ≤ 3, x]
Wolfram Language code: Plot[f[x], {x, 0, 3}, Epilog -> {Red, Point[{x /. %[[1]], 0}]}]

是非递减函数，计算 的最大值：

Wolfram Language code: f[t_] := Erf[t] g[x_, y_] := x ^ 3 - 5x y + y ^ 3 constraints = x ^ 2 + y ^ 2 ≤ 1;
Wolfram Language code: FunctionMonotonicity[f[t], t]

计算 的最大值：

Wolfram Language code: {mval, mpoint} = Maximize[{g[x, y], constraints}, {x, y}]//RootReduce

的最大值是 ，在 处取得最大值：

Wolfram Language code: {f[mval], mpoint}

为了比较，直接计算最大值：

Wolfram Language code: Maximize[{f[g[x, y]], constraints}, {x, y}]//RootReduce
Wolfram Language code: Show[{Plot3D[{f[g[x, y]], f[mval]}, {x, -1, 1}, {y, -1, 1}, ...], Graphics3D[{Red, PointSize[Large], Point[{x, y, f[mval]} /. mpoint]}]}]

属性和关系  (2)

非递减函数的和及组成的复合函数仍然是非递减函数：

Wolfram Language code: f[x_] := ArcTan[x] g[x_] := 2 ^ x
Wolfram Language code: FunctionMonotonicity[#, x]& /@ {f[x], g[x], f[x] + g[x], f[g[x]], g[f[x]]}
Wolfram Language code: Plot[{f[x], g[x], f[x] + g[x], f[g[x]], g[f[x]]}, {x, -2, 2}]

非递减函数的导数非负：

Wolfram Language code: f = x ^ 3 - x ^ 2Cos[x] + x Sin[x]
Wolfram Language code: FunctionMonotonicity[f, x]

用 D 计算导数：

Wolfram Language code: g = D[f, x]

用 FunctionSign 验证导数非负：

Wolfram Language code: FunctionSign[g, x]

绘制函数和导数：

Wolfram Language code: Plot[{f, g}, {x, -7, 7}]

可能存在的问题  (1)

函数必须处处有定义才可以是单调的：

Wolfram Language code: FunctionMonotonicity[x + Exp[-1 / x ^ 2], x]
Wolfram Language code: FunctionMonotonicity[{x + Exp[-1 / x ^ 2], x ≠ 0}, x]
Wolfram Research (2020)，FunctionMonotonicity，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FunctionMonotonicity.html.

文本

Wolfram Research (2020)，FunctionMonotonicity，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FunctionMonotonicity.html.

CMS

Wolfram 语言. 2020. "FunctionMonotonicity." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/FunctionMonotonicity.html.

APA

Wolfram 语言. (2020). FunctionMonotonicity. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FunctionMonotonicity.html 年

BibTeX

@misc{reference.wolfram_2026_functionmonotonicity, author="Wolfram Research", title="{FunctionMonotonicity}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/FunctionMonotonicity.html}", note=[Accessed: 05-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_functionmonotonicity, organization={Wolfram Research}, title={FunctionMonotonicity}, year={2020}, url={https://reference.wolfram.com/language/ref/FunctionMonotonicity.html}, note=[Accessed: 05-November-2026]}