WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GeoGridPosition[{x,y},proj]

投影法 proj を使った平面図の地図作製格子中の点{x,y}を表す．

GeoGridPosition[{x,y,h},proj]

準拠楕円体に対する高さが h の，地図作製格子中の点{x,y,h}を表す．

GeoGridPosition[{{x1,y1},{x2,y2},…},proj]

地図作製格子の位置の配列を表す．

GeoGridPosition[{x,y,h},proj,datum]

指定された測地系のデータからの投影で得られた，地図作製格子中の点を表す．

GeoGridPosition[entity,proj]

指定された地理実体の地理作成格子の位置を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
位置指定  
GeoGridPositionへの変換  
地理格子位置配列  
座標の抽出  
測地系の変換  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

GeoGridPosition

GeoGridPosition[{x,y},proj]

投影法 proj を使った平面図の地図作製格子中の点{x,y}を表す．

GeoGridPosition[{x,y,h},proj]

準拠楕円体に対する高さが h の，地図作製格子中の点{x,y,h}を表す．

GeoGridPosition[{{x1,y1},{x2,y2},…},proj]

地図作製格子の位置の配列を表す．

GeoGridPosition[{x,y,h},proj,datum]

指定された測地系のデータからの投影で得られた，地図作製格子中の点を表す．

GeoGridPosition[entity,proj]

指定された地理実体の地理作成格子の位置を返す．

詳細

  • GeoGridPosition[{x,y},proj]における座標 x, y は数値で与えられなければならない．その意味は，投影法 proj によって決定される．
  • GeoGridPosition[{x,y,h},proj]の高さ h はメートル単位の数値オブジェクトあるいはQuantity長として与えることができる．
  • GeoGridPosition[{x,y,h},proj]の高さ h は，基準楕円体に対して測られた測地高さである．
  • GeoGridPosition[{x,y,h,t},proj]には，グリニッジ標準時の時刻帯で1900年1月1日から秒単位で計測された時間 t が含まれる．
  • 明示的な高さがないGeoGridPositionオブジェクトは，基準楕円体に対しての高さが0であると仮定する．明示的な時間がないGeoGridPositionオブジェクトは，現行の時刻を仮定する．
  • GeoGridPosition[pos,proj]は，基本的に地図作製投影を計算して，任意の地理位置を格子点に変換する．GeoPosition，GeoPositionXYZ，GeoPositionENU，GeoGridPositionの中から座標タイプを与えることができる．
  • GeoGridPosition[GeoPosition[{lat,lon}],proj]は測地格子から投影地図に直接投影する．
  • 反対に，GeoPosition[GeoGridPosition[{x,y},proj]]は地図から測地座標への逆投影を行う．
  • 次は，投影法の指定方法である．
  • "proj"デフォルトのパラメータ値を持つ名前付き投影法
    {"proj","param1"->val1,"param2"->val2,…}詳細なパラメータが指定された投影法
  • 使用可能な投影法の名前はGeoProjectionData[]で与えられる．
  • 特定の名前付き投影法のパラメータのデフォルト値はGeoProjectionData[proj]で与えられる．
  • 高さ h と時間 t の値は投影計算をしても保たれる．
  • GeoPosition[…][prop]は，地理格子位置の指定された特性を与える．
  • 次は，使用可能な特性である．
  		• "AbsoluteTime"1900年1月1日（00:00グリニッジ標準時）からの秒数としての時間
    		"Count"GeoGridPositionオブジェクト内の場所の数
    		"Data"GeoGridPositionオブジェクトの第1引数
    		"DateList"グリニッジ標準時による日付リスト{y,m,d,h,m,s}
    		"DateObject"完全な日付オブジェクト
    		"Datum"GeoGridPositionオブジェクトの測地系
    		"Depth"点の深さ：単一の位置については0，位置のリストについては1等
    		"Dimension"各位置の座標数
    		"Elevation"楕円体に対しての，メートル単位での数値高度
    "GeoProjection"GeoGridPositionオブジェクトの地理投影
    		"GridX"数値 x 座標
    		"GridY"数値 y 座標
    		"GridXY"数値{x,y}ペア
    		"PackingType"データがパックされている場合はIntegerまたはReal．それ以外の場合はNone

例題

すべて開く すべて閉じる

例  (3)

球面ボンヌ図法を使って測地位置を格子点に変換する：

Wolfram Language code: GeoGridPosition[GeoPosition[{37., -19., 0}], "Bonne"]

測地位置に変換し直す：

Wolfram Language code: GeoPosition[%]

中央経線にカスタム設定を使って球面心射図法を計算する：

Wolfram Language code: GeoGridPosition[GeoPosition[{37., -19., 0}], {"Bonne", "Centering" -> {-35, -100}}]

明示的に指定された投影パラメータを使って投影法を計算する：

Wolfram Language code: GeoGridPosition[GeoPosition[{37., -19., 0}], {"Albers", "Centering" -> GeoPosition[{40, -100}], "StandardParallels" -> {20, 50}}]

スコープ  (11)

位置指定  (3)

投影された x, y 座標を指定している地理格子位置オブジェクト：

Wolfram Language code: GeoGridPosition[{0.7, 0.2}, "Albers"]

高さをメートルで指定する：

Wolfram Language code: GeoGridPosition[{0.7, 0.2, 244.32}, "Albers"]

1900年からの時間も秒単位で指定する：

Wolfram Language code: GeoGridPosition[{0.7, 0.2, 244.32, 3.6*^9}, "Albers"]

さまざまな地理投影法を使った，測地位置から地図製作格子への投影：

Wolfram Language code: p = GeoPosition[{40.12, -88.24}]
Wolfram Language code: GeoGridPosition[p, "Robinson"]
Wolfram Language code: GeoGridPosition[p, "Sinusoidal"]
Wolfram Language code: GeoGridPosition[p, "LambertAzimuthal"]

地理Entityオブジェクトを直接指定する：

Wolfram Language code: GeoGridPosition[Entity["City", {"BuenosAires", "BuenosAires", "Argentina"}], "Orthographic"]

GeoGridPositionへの変換  (2)

三次元XYZ指定からの投影：

Wolfram Language code: p = GeoPositionXYZ[Entity["City", {"BuenosAires", "BuenosAires", "Argentina"}]]
Wolfram Language code: GeoGridPosition[p, "Mercator"]
Wolfram Language code: GeoGridPosition[p, "Albers"]
Wolfram Language code: GeoGridPosition[p, "Bonne"]

デフォルトではない測地系の測地位置から始める：

Wolfram Language code: GeoPosition[{34., -23.}, "ITRF90"]

この投影は測地系の情報を追跡する：

Wolfram Language code: GeoGridPosition[%, "CylindricalEqualArea"]

もとの指定を回復する：

Wolfram Language code: GeoPosition[%]

地理格子位置配列  (3)

3つの位置を持つ地理格子位置配列の投影を変更する：

Wolfram Language code: GeoGridPosition[{{-20.9, 4.6}, {94.7, -59.5}, {50.8, 27.3}}, "Mercator"]
Wolfram Language code: GeoGridPosition[%, "LambertAzimuthal"]

次は，式からの入力である：

Wolfram Language code: %//InputForm

点の配列を第1引数として使う：

Wolfram Language code: pairs = RandomReal[{-90, 90}, {10000, 2}];

すべての点が一度に変換される：

Wolfram Language code: AbsoluteTiming[r1 = GeoGridPosition[GeoPosition[pairs], "Bonne"];]

以下では，各点が個別に変換される：

Wolfram Language code: Timing[r2 = GeoGridPosition[GeoPosition[#], "Bonne"]& /@ pairs;]

結果は数値誤差まで一致する：

Wolfram Language code: First[r1] - (First /@ r2)//Abs//Max

地理格子位置配列を使うと投影の変更がより速くなる：

Wolfram Language code: ggps = GeoGridPosition[RandomGeoPosition[10000], "Albers"]
Wolfram Language code: AbsoluteTiming[r1 = GeoGridPosition[ggps, "WinkelTripel"];]
Wolfram Language code: AbsoluteTiming[r2 = GeoGridPosition[#, "WinkelTripel"]& /@ Thread[ggps, List, 1];]

結果は数値誤差を除いて一致する：

Wolfram Language code: First[r1] - (First /@ r2)//Abs//Max

座標の抽出  (1)

特性を使ってGeoPositionオブジェクトから情報を抽出する：

Wolfram Language code: p = GeoGridPosition[Here, "Albers"]
Wolfram Language code: p["Properties"]
Wolfram Language code: AssociationMap[p, %]//Normal//Column

測地系の変換  (2)

デフォルトの"ITRF00"から1936年の英国の測地系"OGB7" への測地系変換を行う：

Wolfram Language code: p = GeoGridPosition[{-1.74, 1.81, 0.}, "Albers"]
Wolfram Language code: q = GeoGridPosition[p, "Albers", "OGB7"]

暗黙の空間変化を推定するために，測地系情報を無視して地理距離を計算する：

Wolfram Language code: GeoDistance[LatitudeLongitude[p], LatitudeLongitude[q]]
Wolfram Language code: UnitConvert[%]

英国の地域では変化は小さい：

Wolfram Language code: p = GeoGridPosition[RandomGeoPosition[Entity["Country", "UnitedKingdom"]], "Albers"]
Wolfram Language code: q = GeoGridPosition[p, "Albers", "OGB7"]
Wolfram Language code: GeoDistance[LatitudeLongitude[p], LatitudeLongitude[q]]
Wolfram Language code: UnitConvert[%]

地理格子位置配列をアメリカの"NAD27"測地系からヨーロッパの"EURM"測地系に変換する：

Wolfram Language code: GeoGridPosition[{{-1.29, 0.81}, {-1.28, 0.71}, {-1.26, 0.78}}, "WinkelTripel", "NAD27"]
Wolfram Language code: GeoGridPosition[%, "WinkelTripel", "EURM"]

新たな座標値を抽出する：

Wolfram Language code: %["GridXY"]

アプリケーション  (1)

ある国の主要な国境線の緯度・経度のリストを求める：

Wolfram Language code: pos = GeoPosition[CountryData["UnitedStates", "Coordinates"]];

球面メルカトル図法を使い，測地座標を格子位置に変換する：

Wolfram Language code: Graphics[Polygon[GeoGridPosition[pos, "Mercator"][[1]]]]

特定の中心を持つカッシーニ投影法を使う：

Wolfram Language code: Graphics[Polygon[GeoGridPosition[pos, {"Cassini", "Centering" -> {-20, -50}}][[1]]]]

以下の方法も使える：

Wolfram Language code: GeoGraphics[Polygon[Entity["Country", "UnitedStates"]], GeoProjection -> {"Cassini", "Centering" -> {-20, -50}}]

特性と関係  (3)

Gudermannianは緯度座標のために逆メルカトル図法を実装する：

Wolfram Language code: Latitude[GeoGridPosition[{0, 65.}, "Mercator"]]
Wolfram Language code: Gudermannian[65.Degree] / Degree

位置を選ぶ：

Wolfram Language code: lat = 40.; lon = -10.; p = GeoPosition[{lat, lon}];

デフォルトの準拠楕円体のパラメータ：

Wolfram Language code: a = GeodesyData["ITRF00", "SemimajorAxis"]
Wolfram Language code: e = GeodesyData["ITRF00", "Eccentricity"]

円柱側面メルカトル図法を使って上記位置を楕円体に投影する：

Wolfram Language code: pr = GeoGridPosition[p, {"Mercator", "ReferenceModel" -> "ITRF00"}]

結果は以下でも得ることができる：

Wolfram Language code: χ = (InverseGudermannian[lat Degree] - e ArcTanh[e Sin[lat Degree]] + I lon Degree)
Wolfram Language code: pr[[1]] == QuantityMagnitude[a]{Im[χ], Re[χ]}

同じ位置を横断側面メルカトル図法を使って投影する：

Wolfram Language code: prt = GeoGridPosition[p, {"TransverseMercator", "ReferenceModel" -> "ITRF00"}]

結果は以下の方程式を解くことでも得ることができる：

Wolfram Language code: χ == ArcTanh[JacobiSN[w, e ^ 2]] - e ArcTanh[e JacobiSN[w, e ^ 2]]
Wolfram Language code: sol = FindRoot[%, {w, 0}, MaxIterations -> 1000]

評価する：

Wolfram Language code: z = (EllipticE[e ^ 2] - EllipticE[JacobiAmplitude[EllipticK[e ^ 2] - w, e ^ 2], e ^ 2]) /. sol
Wolfram Language code: prt[[1]] == QuantityMagnitude[a]{Im[z], Re[z]}

ある点の投影座標とその対蹠点のそれとの間の関係は，単純ではない：

Wolfram Language code: GeoGridPosition[{0.1, 0.3}, "Albers"]
Wolfram Language code: GeoAntipode[%]

考えられる問題  (1)

実際の応用では，投影法の"ReferenceModel"パラメータは，大抵の場合，GeoGridPositionの第3引数中の測地系と一致する．しかし，これは必要なことではない．例えば，標準的な「webMercator」図法は，たとえ位置が標準準拠楕円体に基づいた測地系に関連している場合でも，半径 r の球面メルカトル図法を使う．このことは，以下で表される：

Wolfram Language code: p = GeoPosition[{-50., 10.}, "WGS84"]
Wolfram Language code: r = GeodesyData["WGS84", "SemimajorAxis"]
Wolfram Language code: GeoGridPosition[p, {"Mercator", "ReferenceModel" -> r}]

楕円体メルカトル図法は若干異なる結果を与える：

Wolfram Language code: GeoGridPosition[p, {"Mercator", "ReferenceModel" -> "WGS84"}]
Wolfram Research (2008), GeoGridPosition, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoGridPosition.html （2019年に更新）.

テキスト

Wolfram Research (2008), GeoGridPosition, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoGridPosition.html （2019年に更新）.

CMS

Wolfram Language. 2008. "GeoGridPosition." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/GeoGridPosition.html.

APA

Wolfram Language. (2008). GeoGridPosition. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoGridPosition.html

BibTeX

@misc{reference.wolfram_2026_geogridposition, author="Wolfram Research", title="{GeoGridPosition}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/GeoGridPosition.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_geogridposition, organization={Wolfram Research}, title={GeoGridPosition}, year={2019}, url={https://reference.wolfram.com/language/ref/GeoGridPosition.html}, note=[Accessed: 03-November-2026]}