WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GeoLength[g]

測地経路 g の長さを与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
オプション  
UnitSystem  
GeoModel  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

GeoLength

GeoLength[g]

測地経路 g の長さを与える．

詳細とオプション

例題

すべて開く すべて閉じる

例  (4)

地球上の測地経路の長さの合計を計算する：

Wolfram Language code: GeoLength[GeoPath[{Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Entity["City", {"Toronto", "Ontario", "Canada"}]}]]

測地線分で形成された経路の長さの合計を計算する：

Wolfram Language code: GeoLength[GeoPath[{{0, 0}, {0, 40}, {40, 70}}]]

同じ点を繋ぐ航程線の長さを計算する：

Wolfram Language code: GeoLength[GeoPath[{{0, 0}, {0, 40}, {40, 70}}, "RhumbLine"]]

地球の赤道の長さ：

Wolfram Language code: GeoLength[GeoPath["Equator"]]

完全な子午線の長さ：

Wolfram Language code: 2GeoLength[GeoPath["PrimeMeridian"]]

測地円の外周の長さ：

Wolfram Language code: GeoLength[GeoCircle[Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}], Quantity[500, "Miles"]]]

スコープ  (3)

異なる一次元の測地要素の長さを計算する：

Wolfram Language code: GeoLength[GeoPath[{{0, 0}, {40, 30}, {20, -10}}]]
Wolfram Language code: GeoLength[GeoCircle[{0, 0}, Quantity[500, "Miles"]]]
Wolfram Language code: GeoLength[DayNightTerminator[DateObject[{2015, 12, 21}]]]
Wolfram Language code: GeoLength[GeoHemisphereBoundary[Here]]

穴がある領域の外周の長さを，繋がれた単一のオブジェクトとして：

Wolfram Language code: outer = GeoPath[{{0, 0}, {40, 0}, {40, 100}, {0, 100}, {0, 0}}]; inner1 = GeoPath[{{10, 10}, {30, 10}, {30, 40}, {10, 40}, {10, 10}}]; inner2 = GeoPath[{{10, 60}, {30, 60}, {30, 90}, {10, 90}, {10, 60}}];
Wolfram Language code: g = JoinedCurve[{{outer}, {inner1}, {inner2}}];
Wolfram Language code: GeoGraphics[{Red, g}]
Wolfram Language code: GeoLength[g]

これは，内側と外側の曲線の長さを足して求めることもできる：

Wolfram Language code: GeoLength[outer] + GeoLength[inner1] + GeoLength[inner2]

GeoGroupを使って異なるタイプの経路を組み合せることができる：

Wolfram Language code: g1 = GeoCircle[Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Quantity[600, "Miles"]]; g2 = GeoPath[{Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Entity["City", {"Toronto", "Ontario", "Canada"}]}];
Wolfram Language code: GeoLength[GeoGroup[{g1, g2}]]
Wolfram Language code: % == Total[GeoLength[{g1, g2}]]

一般化と拡張  (1)

GeoLength[Line[{p1,p2,…}]]は，地理位置 piについては，GeoLength[GeoPath[{p1,p2,…}]]に等しい：

Wolfram Language code: GeoLength[Line[GeoPosition[{{0, 0}, {0, 40}, {40, 70}}]]]
Wolfram Language code: % == GeoLength[GeoPath[{{0, 0}, {0, 40}, {40, 70}}]]

オプション  (2)

UnitSystem  (1)

$UnitSystemの値で決められた単位を使う：

Wolfram Language code: $UnitSystem
Wolfram Language code: GeoLength[GeoPath["NorthernTropic"]]

使用する単位系を指定する：

Wolfram Language code: GeoLength[GeoPath["NorthernTropic"], UnitSystem -> "Metric"]

GeoModel  (1)

地球の測地経路の長さ：

Wolfram Language code: g = GeoPath[{{10, 40}, {20, 50}, {-40, 120}}]; GeoLength[g]

対応する火星上の経路の長さ：

Wolfram Language code: GeoLength[g, GeoModel -> "Mars"]

アプリケーション  (2)

国境の長さをその多角形から計算する：

Wolfram Language code: GeoLength[GeoBoundary[Entity["Country", "Spain"]["Polygon"]]]

多角形における近似のために，この値は実際の国境の長さよりも短い：

Wolfram Language code: Entity["Country", "Spain"]["BoundaryLength"]

平行線の線分の長さ，つまり任意の幾何学経路の平行線上への投影は経距と呼ばれる：

Wolfram Language code: GeoLength[GeoPath[{"Parallel", 38, {0, 5}}]]

これを海里で表現する：

Wolfram Language code: UnitConvert[%, "NauticalMiles"]

特性と関係  (1)

点のリストで定義された測地経路については，GeoLength[GeoPath[list]]はGeoDistance[list]に等しい：

Wolfram Language code: list = RandomReal[{-90, 90}, {10, 2}]
Wolfram Language code: GeoLength[GeoPath[list]]
Wolfram Language code: % == GeoDistance[list]
Wolfram Research (2016), GeoLength, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoLength.html.

テキスト

Wolfram Research (2016), GeoLength, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoLength.html.

CMS

Wolfram Language. 2016. "GeoLength." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GeoLength.html.

APA

Wolfram Language. (2016). GeoLength. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoLength.html

BibTeX

@misc{reference.wolfram_2026_geolength, author="Wolfram Research", title="{GeoLength}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/GeoLength.html}", note=[Accessed: 20-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_geolength, organization={Wolfram Research}, title={GeoLength}, year={2016}, url={https://reference.wolfram.com/language/ref/GeoLength.html}, note=[Accessed: 20-June-2026]}