Wolfram 语言与系统参考资料中心

GeoStyling

GeoStyling[mapstyle]

使用 mapstyle 显示多边形和其他实心地理对象的面.

GeoStyling[mapstyle,directive]

使用 mapstyle，并且应用给定的图形 directive.

范例

打开所有单元关闭所有单元

基本范例 (10)

使用默认样式：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "Austria"]]}]

显式指定 Automatic 地理样式：

Wolfram Language code: GeoGraphics[{GeoStyling[Automatic], Polygon[Entity["Country", "Austria"]]}]

使用默认的 Graphics 样式（没有地理样式）：

Wolfram Language code: GeoGraphics[{GeoStyling[None], Polygon[Entity["Country", "Austria"]]}]

显示框架地图：

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap"], Polygon[Entity["Country", "Austria"]]}]

指定已命名的颜色，并且忽略地理背景：

Wolfram Language code: GeoGraphics[{GeoStyling[Green], Polygon[Entity["Country", "Austria"]]}, GeoBackground -> None]

使用地形图：

Wolfram Language code: GeoGraphics[{EdgeForm[Black], GeoStyling["ReliefMap"], Polygon[Entity["Country", "Austria"]]}]

将地形图作为 GeoBackground 使用：

Wolfram Language code: GeoGraphics[{EdgeForm[Black], Polygon[Entity["Country", "Austria"]]}, GeoBackground -> GeoStyling["ReliefMap"]]

使用卫星图：

Wolfram Language code: GeoGraphics[{GeoStyling["Satellite"], Polygon[Entity["Country", "Austria"]]}, GeoBackground -> None]

对不同区域指定不同地理样式：

Wolfram Language code:

styles = {
	Polygon[Entity["Country", "Germany"]] -> GeoStyling["ReliefMap"], Polygon[Entity["Country", "France"]] -> GeoStyling["OutlineMap"], Polygon[Entity["Country", "Italy"]] -> GeoStyling["StreetMapNoLabels"], Polygon[Entity["Country", "Austria"]] -> GeoStyling[Red], 
	Polygon[Entity["Country", "Switzerland"]] -> GeoStyling[Blue]
	};

Wolfram Language code:

GeoGraphics[{Polygon[CountryData["EuropeSovereign"]], 
	Reverse /@ (List@@@styles)}, GeoGridLines -> Automatic]

对于有部分重叠的不同区域，指定不同的地理样式：

Wolfram Language code:

GeoGraphics[{
	GeoStyling["StreetMap"], Polygon[Entity["Country", "UnitedStates"]], 
	GeoStyling[Automatic], Purple, Polygon[EntityClass["AdministrativeDivision", "USStatesEastCoast"]], GeoStyling["ReliefMap", Opacity[.7]], Polygon[Entity["AdministrativeDivision", {"Florida", "UnitedStates"}]]}]

将地球的日光照射部分用部分透明的黄色进行样式化处理：

Wolfram Language code: GeoGraphics[{Yellow, DayHemisphere[]}, GeoBackground -> GeoStyling["ReliefMap"], GeoRange -> "World"]

月球的地势图：

Wolfram Language code: GeoGraphics[GeoModel -> "Moon", GeoRange -> All, GeoCenter -> 180, GeoBackground -> "ReliefMap"]

范围 (27)

"Coastlines" (2)

具有海岸线的世界地图：

Wolfram Language code: GeoGraphics["World", GeoBackground -> GeoStyling["Coastlines"]]

世界 Mollweide 地图，显示海岸线：

Wolfram Language code: GeoGraphics["World", GeoBackground -> GeoStyling["Coastlines"], GeoProjection -> "Mollweide"]

选择不同的图形指令：

Wolfram Language code:

GeoGraphics["World", GeoBackground -> GeoStyling[{"Coastlines", "Land" -> Gray, "Ocean" -> Black, "Border" -> White}], GeoProjection -> "Mollweide"]

"ContourMap" (2)

在一个国家上指定海拔等高线地图：

Wolfram Language code: GeoGraphics[{GeoStyling["ContourMap"], Polygon[Entity["Country", "Switzerland"]]}]

通过传递 ListContourPlot 选项，调整等高线和添加等高线样式：

Wolfram Language code:

GeoGraphics[{GeoStyling["ContourMap", Contours -> 30, ColorFunction -> (Directive[Opacity[0.4], ColorData["Pastel"][#]]&)], Polygon[Entity["Country", "Switzerland"]]}]

使用国旗颜色，显示西班牙的海拔等高线：

Wolfram Language code: EntityValue[Entity["Country", "Spain"], EntityProperty["Country", "Flag"]]

Wolfram Language code:

FlagColorCountours[countryEntity_] := Module[{allColors = Reverse[SortBy[Tally[Round[Flatten[ImageData[ColorConvert[EntityValue[countryEntity, "Flag"], "RGB"]], 1], 0.001]], Last]]}, (RGBColor@@First[#])& /@ If[# === {}, allColors, Take[allColors, Max[1, # - 1]]]&[Position[allColors, {_, _ ? (# < allColors[[1, 2]] / 20&)}, {1}, 1]]]

Wolfram Language code:

With[{country = Entity["Country", "Spain"]}, GeoGraphics[{EdgeForm[Gray], GeoStyling["ContourMap", ContourShading -> FlagColorCountours[country], Contours -> 21, ContourStyle -> None, PlotRange -> All, ColorFunctionScaling -> True], Polygon[country]}]]

"CountryBorders" (3)

具有国界线的世界地图：

Wolfram Language code: GeoGraphics["World", GeoBackground -> GeoStyling["CountryBorders"]]

具有国界线的 1900 年欧洲地图：

Wolfram Language code:

GeoGraphics[Entity["GeographicRegion", "Europe"], GeoBackground -> GeoStyling[Dated["CountryBorders", 1900]], GeoGridLines -> Automatic]

显示 1800 年对应于现代意大利的国界线：

Wolfram Language code:

GeoGraphics[Polygon[Entity["Country", "Italy"]], GeoBackground -> GeoStyling[Dated["CountryBorders", DateObject[{1800}]]]]

"GeoImage" (1)

把星条图案投影到美国地图上：

Wolfram Language code:

With[{usa = Entity["Country", "UnitedStates"]}, GeoGraphics[{GeoStyling[{"GeoImage", EntityValue[usa, "Flag"]}], Polygon[usa]}]]

"Image" (4)

把星条图案放在美国地图上：

Wolfram Language code:

With[{usa = Entity["Country", "UnitedStates"]}, GeoGraphics[{GeoStyling[{"Image", EntityValue[usa, "Flag"]}], Polygon[usa]}]]

在某些数学家的母国的当前边界范围内放置他们的图像：

Wolfram Language code:

people = {Entity["Person", "CarlFriedrichGauss::4vctc"], Entity["Person", "EvaristeGalois::573r9"], Entity["Person", "IsaacNewton::bhz5x"]};

Wolfram Language code:

SquareImage[i_Image] := With[{dims = ImageDimensions[i]}, 
	With[{size = Max@@dims}, 
	ImagePad[i, Through[{Floor, Ceiling}[(size - #) / 2]]& /@ dims, White]
	]
	]

构建图像/国家对：

Wolfram Language code:

pairs = With[{image = EntityValue[#, "Image"]}, {GeoStyling[{"Image", SquareImage[image]}], Polygon[Entity["Country", EntityValue[#, "NationalityCountries"][[1, 2]]]]}]& /@ people;

绘制地图：

Wolfram Language code: GeoGraphics[pairs, GeoBackground -> GeoStyling["ReliefMap"]]

加载来自 ExampleData 的花朵图案：

Wolfram Language code: image = ImageResize[ExampleData[{"TestImage", "Flower"}], 200]

对于荷兰作为纹理地图使用：

Wolfram Language code: GeoGraphics[{GeoStyling[{"Image", image}], Polygon[Entity["Country", "Netherlands"]]}]

使用光栅化的图形：

Wolfram Language code: data = Table[{-1 - x^2 + y, 1 + x - y^2}, {x, -3, 3, .2}, {y, -3, 3, .2}];

Wolfram Language code: graphics = ListStreamPlot[data, Frame -> False, PlotRangePadding -> None, ImagePadding -> None]

Wolfram Language code: GeoGraphics[{GeoStyling[{"Image", Rasterize[graphics]}], Polygon[["Netherlands"]]}, Frame -> True]

"OutlineMap" (5)

使用非洲轮廓图：

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap"], Polygon[EntityClass["Country", "Africa"]]}]

在地理背景样式下，使用非洲轮廓图：

Wolfram Language code:

GeoGraphics[{GeoStyling["OutlineMap"], Polygon[EntityClass["Country", "Africa"]]}, GeoBackground -> GeoStyling["ReliefMap"]]

指定实心填充的颜色，以及边颜色和样式：

Wolfram Language code:

GeoGraphics[{GeoStyling["OutlineMap", Directive[Red, EdgeForm[Directive[{Thick, Yellow}]]]], Polygon[Entity["Country", "France"]]}]

指定部分透明的颜色以及边颜色和样式：

Wolfram Language code:

GeoGraphics[{GeoStyling["OutlineMap", Directive[Blue, Opacity[.5], EdgeForm[Directive[{Thin, Green}]]]], Polygon[Entity["Country", "Spain"]]}]

地理样式指令对地理基元的裸指令有更高优先级：

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap", Blue], Red, Polygon[Entity["Country", "Australia"]]}]

在地形图背景上，对地球日照部分使用部分透明黄色的样式：

Wolfram Language code:

GeoGraphics[{GeoStyling["OutlineMap", Directive[Opacity[.2], Yellow]], DayHemisphere[]}, GeoBackground -> GeoStyling["ReliefMap"], GeoRange -> "World"]

这等价于把黄色简单地作为颜色指令给出：

Wolfram Language code: GeoGraphics[{Yellow, DayHemisphere[]}, GeoBackground -> GeoStyling["ReliefMap"], GeoRange -> "World"]

"ReliefMap" (3)

使用美国地形图：

Wolfram Language code: GeoGraphics[{GeoStyling["ReliefMap"], Polygon[Entity["Country", "UnitedStates"]]}]

在等高线地图地理背景样式下，使用美国地形图：

Wolfram Language code:

GeoGraphics[{GeoStyling["ReliefMap", EdgeForm[Thin]], Polygon[Entity["Country", "UnitedStates"]]}, GeoBackground -> GeoStyling["ContourMap"]]

使用地形图，显示在华盛顿纪念堂顶部可见的区域：

Wolfram Language code:

With[{building = Entity["Building", "WashingtonMonument"]}, GeoGraphics[{GeoStyling["ReliefMap"], GeoVisibleRegion[Append[BuildingData[building, "Position"][[1]], BuildingData[building, "Height"]]]}, GeoBackground -> GeoStyling["StreetMap", GeoStylingImageFunction -> (Darker[#1, .25]&)]]]

围绕月球上哥白尼火山口地区的地形图：

Wolfram Language code:

GeoGraphics[Entity["SolarSystemFeature", "CopernicusMoon"], GeoBackground -> GeoStyling["ReliefMap"], GeoRange -> Quantity[100, "Miles"]]

"Satellite" (2)

使用卫星图：

Wolfram Language code: GeoGraphics[{GeoStyling["Satellite"], Polygon[Entity["Country", "UnitedStates"]]}]

使用夜间卫星地图：

Wolfram Language code: GeoGraphics[{GeoStyling["SatelliteNight"], Polygon[Entity["Country", "UnitedStates"]]}]

火星上地理圆盘的卫星图：

Wolfram Language code:

GeoGraphics[{GeoStyling["Satellite"], GeoDisk[{0, 0}, Quantity[1000, "Kilometers"]]}, GeoModel -> "Mars", GeoBackground -> None]

"StreetMap" (3)

对于弗吉尼亚使用街道地图样式：

Wolfram Language code:

GeoGraphics[{GeoStyling["StreetMap"], Polygon[Entity["AdministrativeDivision", {"Virginia", "UnitedStates"}]]}, GeoBackground -> GeoStyling["ReliefMap"]]

街道地图可能具有样式处理后的边：

Wolfram Language code:

GeoGraphics[{GeoStyling["StreetMap", EdgeForm[Blue]], Polygon[Entity["AdministrativeDivision", {"Virginia", "UnitedStates"}]]}, GeoBackground -> GeoStyling["ReliefMap"]]

透明度：

Wolfram Language code:

GeoGraphics[{GeoStyling["StreetMap", Directive[EdgeForm[Black], Opacity[.5]]], Polygon[Entity["AdministrativeDivision", {"Virginia", "UnitedStates"}]]}, GeoBackground -> GeoStyling["ReliefMap"]]

但不是颜色：

Wolfram Language code:

GeoGraphics[{GeoStyling["StreetMap", FaceForm[Blue]], Polygon[Entity["AdministrativeDivision", {"Virginia", "UnitedStates"}]]}, GeoBackground -> GeoStyling["ReliefMap"]]

使用街道地图显示从华盛顿纪念堂顶部可见的区域：

Wolfram Language code:

With[{building = Entity["Building", "WashingtonMonument"]}, GeoGraphics[{GeoStyling["StreetMap"], GeoVisibleRegion[Append[BuildingData[building, "Position"][[1]], BuildingData[building, "Height"]]]}, GeoBackground -> GeoStyling["StreetMap", GeoStylingImageFunction -> (Darker[#1, .25]&)]]]

使用 GeoStylingImageFunction 可以应用图像处理效果：

Wolfram Language code:

GeoGraphics[{GeoStyling["StreetMap", EdgeForm[Black], GeoStylingImageFunction -> (Sharpen[#1, 10]&)], Polygon[Entity["Country", "France"]]}]

"StreetMapLabelsOnly" (1)

使用街道地图标签：

Wolfram Language code:

GeoGraphics[{GeoStyling["StreetMapLabelsOnly", EdgeForm[Black]], Polygon[Entity["AdministrativeDivision", {"Virginia", "UnitedStates"}]]}, GeoBackground -> GeoStyling["ReliefMap"]]

在彩色地图区域上使用街道地图标签：

Wolfram Language code:

With[{ent = Entity["AdministrativeDivision", {"Illinois", "UnitedStates"}]}, GeoGraphics[{GeoStyling["OutlineMap", Green], Polygon[ent], GeoStyling["StreetMapLabelsOnly"], Polygon[ent]}, GeoBackground -> Yellow]]

"StreetMapNoLabels" (1)

不用标签，显示弗吉尼亚的边界和街道地图：

Wolfram Language code:

GeoGraphics[{GeoStyling["StreetMapNoLabels", EdgeForm[Black]], Polygon[Entity["AdministrativeDivision", {"Virginia", "UnitedStates"}]]}]

使用没有标签的街道地图，显示从华盛顿纪念堂顶部可见的区域：

Wolfram Language code:

With[{building = Entity["Building", "WashingtonMonument"]}, GeoGraphics[{GeoStyling["StreetMapNoLabels"], GeoVisibleRegion[Append[BuildingData[building, "Position"][[1]], BuildingData[building, "Height"]]]}, GeoBackground -> GeoStyling["StreetMapNoLabels", GeoStylingImageFunction -> (Darker[#1, .25]&)]]]

Wolfram Language code:

GeoGraphics[{GeoStyling["StreetMapNoLabels", EdgeForm[Black]], Polygon[Entity["AdministrativeDivision", {"Virginia", "UnitedStates"}]]}]

选项 (14)

ColorFunction (2)

使用具有已命名颜色方案的 "ReliefMap" 样式：

Wolfram Language code:

GeoGraphics[{GeoStyling["ReliefMap", ColorFunction -> ColorData["AvocadoColors"]], Polygon[Entity["Country", "UnitedStates"]]}]

改变月球地势图的默认颜色函数：

Wolfram Language code:

GeoGraphics[GeoModel -> "Moon", GeoRange -> All, GeoCenter -> 180, GeoBackground -> GeoStyling["ReliefMap", ColorFunction -> GrayLevel], GeoProjection -> "Orthographic", GeoZoomLevel -> 2, Background -> Black, PlotRangePadding -> 0.1]

ColorFunctionScaling (1)

左边的 "ReliefMap" 样式没有参数尺度缩放；自动在右边进行尺度缩放：

Wolfram Language code:

GeoGraphics[{GeoStyling["ReliefMap", ColorFunctionScaling -> #], Polygon[Entity["Country", "UnitedStates"]]}]& /@ {False, True}

ContourLabels (1)

Wolfram Language code: GeoGraphics[{GeoStyling["ContourMap", Contours -> 5, ContourLabels -> All], Polygon[Entity["Country", "UnitedStates"]]}]

Contours (1)

指定 "ContourMap" 样式的等高线数目：

Wolfram Language code:

Table[GeoGraphics[{GeoStyling["ContourMap", Contours -> n], Polygon[Entity["Country", "UnitedStates"]]}], {n, {5, 10, 15, 30}}]

ContourShading (1)

对于 "ContourMap" 样式，使得等高线之间的区域空白：

Wolfram Language code:

GeoGraphics[{GeoStyling["ContourMap", Contours -> 30, ContourShading -> None], Polygon[Entity["Country", "UnitedStates"]]}]

使用默认的等高线阴影：

Wolfram Language code: GeoGraphics[{GeoStyling["ContourMap", Contours -> 30], Polygon[Entity["Country", "UnitedStates"]]}]

ContourStyle (1)

对于 "ContourMap" 样式指定 ContourStyle：

Wolfram Language code: GeoGraphics[{GeoStyling["ContourMap", Contours -> 30, ContourStyle -> Red], Polygon[Entity["Country", "UnitedStates"]]}]

使用默认的等高线样式：

Wolfram Language code: GeoGraphics[{GeoStyling["ContourMap", Contours -> 30], Polygon[Entity["Country", "UnitedStates"]]}]

GeoStylingImageFunction (5)

对澳大利亚地图添加椒盐噪声：

Wolfram Language code:

GeoGraphics[{GeoStyling["OutlineMap", GeoStylingImageFunction -> (ImageEffect[#, {"SaltPepperNoise", 0.5}]&)], Polygon[Entity["Country", "Austria"]]}]

锐化泰姬陵附近的一个圆形区域，模糊外面的区域：

Wolfram Language code:

GeoGraphics[{GeoStyling["StreetMap", GeoStylingImageFunction -> Sharpen], EdgeForm[Red], GeoDisk[Entity["Building", "TajMahal"], Quantity[0.5, "Miles"]]}, GeoBackground -> GeoStyling["StreetMap", GeoStylingImageFunction -> (Blur[#1, 15]&)]]

在巴黎周围添加锥形减缩的地图效果：

Wolfram Language code:

swooshRing[p_] := Module[{ρ = Norm[p], φ = ArcTan@@p}, If[ρ < 1 / 4 || ρ > 3 / 4, p, ρ {Cos[#], Sin[#]}&[φ + Pi (1 - Cos[Pi 2 (ρ - 1 / 4)])]]]

显示处理后的地图：

Wolfram Language code:

GeoGraphics[{}, GeoCenter -> Entity["City", {"Paris", "IleDeFrance", "France"}], GeoRange -> Quantity[20, "Miles"], GeoBackground -> GeoStyling["StreetMap", GeoStylingImageFunction -> (ImageTransformation[#1, swooshRing, DataRange -> {{-1, 1}, {-1, 1}}]&)]]

将国旗作为图像效果使用：

Wolfram Language code: CountryData["DemocraticRepublicCongo", "Flag"]

把国旗的许多备份放在国家上，并且模糊周围的国家：

Wolfram Language code:

With[{c = Entity["Country", "DemocraticRepublicCongo"]}, GeoGraphics[{{GeoStyling["StreetMap", GeoStylingImageFunction -> (Blur[#, 4]&)], Polygon[#]}& /@ CountryData[c, "BorderingCountries"], GeoStyling["StreetMap", GeoZoomLevel -> 5, GeoStylingImageFunction -> (Sharpen@ImageCompose[#, ImageAssemble[Table[SetAlphaChannel[Image[CountryData[c, "Flag"]], 0.2], {5}, {4}]]]&)], Polygon[c]}]]

对相邻国家应用各种图像效果：

Wolfram Language code:

GeoGraphics[{
	GeoStyling["ReliefMap", GeoStylingImageFunction -> ColorNegate], Polygon[Entity["Country", "Austria"]], Polygon[Entity["Country", "Switzerland"]], 
	GeoStyling["StreetMap", GeoStylingImageFunction -> (ImageEffect[#1, "Charcoal"]&)], Polygon[Entity["Country", "France"]], 
	GeoStyling["ReliefMap", GeoStylingImageFunction -> ({0, 0} /.  StationaryWaveletTransform[ColorCombine[Take[ColorSeparate[#1], 3][[{2, 3, 1}]], "RGB"], Automatic, 2][{0, 0}, "Image"]&)], Polygon[Entity["Country", "Germany"]]
	}]

GeoZoomLevel (2)

设置 GeoZoomLevel:

Wolfram Language code:

Table[GeoGraphics[{GeoStyling["ReliefMap", GeoZoomLevel -> n], Polygon[Entity["Country", "UnitedStates"]]}, GeoGridLines -> Automatic], {n, 4}]

以多个缩放级别显示巴黎著名建筑周边的街道地图：

Wolfram Language code:

With[{loc = Entity["Building", "NotreDameCathedral::95fcw"]}, GeoGraphics[{Red, PointSize[Large], Point[loc]}, GeoCenter -> loc, GeoRange -> Quantity[100, "Meters"], GeoZoomLevel -> #]]& /@ Range[11, 16]

属性和关系 (6)

GeoStyling[] 等价于 GeoStyling[None]，会将地理区域渲染为完全不透明：

Wolfram Language code: GeoGraphics[{GeoStyling[], Polygon[Entity["AdministrativeDivision", {"Hawaii", "UnitedStates"}]]}]

颜色基元之间应用于非实心基元，但是与最近的地理样式一起对实心地理基元发挥作用，得到一个具有红色箭头的粉红色密歇根：

Wolfram Language code:

GeoGraphics[{Red, Thick, Polygon[Entity["AdministrativeDivision", {"Michigan", "UnitedStates"}]], Arrowheads[{-.1, .1}], Arrow[{Entity["City", {"Detroit", "Michigan", "UnitedStates"}], Entity["City", {"Kalamazoo", "Michigan", "UnitedStates"}]}]}]

指定透明度不起作用，因为它被通过 GeoStyling[Automatic] 隐性设置的透明度覆盖：

Wolfram Language code:

GeoGraphics[{Red, Opacity[.8], Thick, Polygon[Entity["AdministrativeDivision", {"Michigan", "UnitedStates"}]], Arrowheads[{-.1, .1}], Arrow[{Entity["City", {"Detroit", "Michigan", "UnitedStates"}], Entity["City", {"Kalamazoo", "Michigan", "UnitedStates"}]}]}]

把透明度放在地理样式内使其发挥效果，覆盖默认的 GeoStyling[Automatic] 设置：

Wolfram Language code:

GeoGraphics[{Red, GeoStyling[Opacity[.5]], Thick, Polygon[Entity["AdministrativeDivision", {"Michigan", "UnitedStates"}]], Arrowheads[{-.1, .1}], Arrow[{Entity["City", {"Detroit", "Michigan", "UnitedStates"}], Entity["City", {"Kalamazoo", "Michigan", "UnitedStates"}]}]}]

对于地理对象，自动应用默认的地理样式（部分透明）以及紧接着的裸色指令：

Wolfram Language code:

GeoGraphics[{
	Blue, Polygon[Entity["Country", "France"]], 
	Red, Polygon[Entity["Country", "Switzerland"]]
	}]

通过删除默认地理样式，使瑞士变成纯色：

Wolfram Language code:

GeoGraphics[{
	Blue, Polygon[Entity["Country", "France"]], 
	GeoStyling[None], Red, Polygon[Entity["Country", "Switzerland"]]
	}]

使用 "OutlineMap" 地理样式以及指令 Red，使瑞士均匀地涂上颜色：

Wolfram Language code:

GeoGraphics[{
	Blue, Polygon[Entity["Country", "France"]], 
	GeoStyling["OutlineMap", Red], Polygon[Entity["Country", "Switzerland"]]
	}]

使用简短的地理样式指定等价于上述操作：

Wolfram Language code:

GeoGraphics[{
	Blue, Polygon[Entity["Country", "France"]], 
	GeoStyling[Red], Polygon[Entity["Country", "Switzerland"]]
	}]

在地理样式指定都变成红色后，删除法国和瑞士（因为法国前面的裸色指令被地理样式颜色指令覆盖）：

Wolfram Language code:

GeoGraphics[{
	GeoStyling["OutlineMap", Red], 
	Polygon[Entity["Country", "Switzerland"]], 
	Blue, Polygon[Entity["Country", "France"]]
	}]

法国蓝色，瑞士红色：

Wolfram Language code:

GeoGraphics[{
	GeoStyling[Blue], Polygon[Entity["Country", "France"]], 
	GeoStyling[Red], Polygon[Entity["Country", "Switzerland"]]
	}]

通过关闭默认样式，进行相同操作，因此裸色指令可以发挥效果：

Wolfram Language code:

GeoGraphics[{
	GeoStyling[None], 
	Blue, Polygon[Entity["Country", "France"]], 
	Red, Polygon[Entity["Country", "Switzerland"]]
	}]

地理样式应用于多边形、三角形、实心曲线和地理圆盘，但是不应用于普通二维和三维图形基元：

Wolfram Language code:

GeoGraphics[{
	GeoStyling[Green], GeoDisk[GeoPosition[{20, -100}], Quantity[2000, "Kilometers"]], GeoStyling[Blue], Polygon[GeoPosition[{{0, -40}, {40, -30}, {10, 40}}]], GeoStyling[Red], Triangle[GeoPosition[{{10, 60}, {50, 70}, {20, 140}}]], 
	GeoStyling[Yellow], Disk[GeoPosition[{-30, -100}], 20]
	}, GeoRange -> "World", Frame -> True]

地图的坐标值对应于 "Equirectangular" 投影的纬度和经度：

Wolfram Language code:

GeoGraphics[{
	Polygon[Entity["Country", "France"]], 
	Red, Polygon[Entity["Country", "Switzerland"]], Line[{{0, 45}, {5, 50}}]
	}, 
	GeoProjection -> "Equirectangular", Frame -> True
	]

地图坐标不对应于其他投影的纬度和经度：

Wolfram Language code:

GeoGraphics[{
	Polygon[Entity["Country", "France"]], 
	Red, Polygon[Entity["Country", "Switzerland"]], Line[{{0, 45}, {5, 50}}]
	}, 
	GeoProjection -> "Mercator", Frame -> True
	]

利用 GeoPosition 在任何地图投影上绘制地理线：

Wolfram Language code:

GeoGraphics[{
	Polygon[Entity["Country", "France"]], 
	Red, Polygon[Entity["Country", "Switzerland"]], Line[GeoPosition /@ {{45, 0}, {50, 5}}]
	}, 
	GeoProjection -> "Mercator", Frame -> True
	]

将 "ReliefMap" 作为地图样式使用给出要求区域的投影版本：

Wolfram Language code:

GeoGraphics[{GeoStyling["ReliefMap"], Polygon[Entity["Country", "UnitedStates"]]}, GeoProjection -> "Equirectangular", GeoRangePadding -> None]

使用 GeoElevationData 的 ReliefPlot 直接给出未投影的具有不同样式的版本，并且没有剪切：

Wolfram Language code: ReliefPlot[QuantityMagnitude[GeoElevationData[Entity["Country", "UnitedStates"]]], DataReversed -> True]

Top

	Automatic	使用默认样式
	None	不使用显式样式
	"ContourMap"	海拔数据作为等高线
	"Coastlines"	显示海岸线的地理背景样式
	"CountryBorders"	显示国界线的地理背景样式
	Dated["CountryBorders",year]	显示历史国界线的地理背景样式
	"OutlineMap"	框架图
	"ReliefMap"	海拔数据，作为有阴影的颜色
	"Satellite"	卫星图
	"SatelliteNight"	夜间卫星图像
	"SatelliteWithLabels"	带有标签的卫星图像
	"StreetMap"	街道地图数据
	"StreetMapLabelsOnly"	仅街道地图标签
	"StreetMapNoLabels"	街道地图数据，忽略标签
	{"GeoImage",image}	对未投影的多边形，对其应用作为纹理的 image，并且进行投影
	{"Image",image}	对投影多边形，将 image 作为纹理应用

GeoStyling

更多信息和选项

范例

基本范例 (10)

范围 (27)

"Coastlines" (2)

"ContourMap" (2)

"CountryBorders" (3)

"GeoImage" (1)

"Image" (4)

"OutlineMap" (5)

"ReliefMap" (3)

"Satellite" (2)

"StreetMap" (3)

"StreetMapLabelsOnly" (1)

"StreetMapNoLabels" (1)

选项 (14)

ColorFunction (2)

ColorFunctionScaling (1)

ContourLabels (1)

Contours (1)

ContourShading (1)

ContourStyle (1)

GeoStylingImageFunction (5)

GeoZoomLevel (2)

属性和关系 (6)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX