WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

LLMSynthesizeSubmit[prompt]

入力 prompt に従ってテキストを非同期的に生成する．

LLMSynthesizeSubmit[{prompt1,…}]

複数の promptiを組み合せる．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Authentication  
LLMEvaluator  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

LLMSynthesizeSubmit

LLMSynthesizeSubmit[prompt]

入力 prompt に従ってテキストを非同期的に生成する．

LLMSynthesizeSubmit[{prompt1,…}]

複数の promptiを組み合せる．

詳細とオプション

  • LLMSynthesizeSubmitは，大規模言語モデル(LLM)を使い，プロンプトの指示に従ってテキストを非同期的に生成する．コンテンツ，完全な文，抽出された情報等を作成することができる．
  • LLMSynthesizeSubmitは，外部サービスの認証，請求，インターネット接続を必要とする．
  • 次は，prompt の可能な値である．
  • "text"静的テキスト
    LLMPrompt["name"]リポジトリプロンプト
    StringTemplate[…]テンプレートテキスト
    TemplateObject[…]プロンプト作成用のテンプレート
    Image[…]静的画像（すべてのLLMがサポートする訳ではない）
    {prompt1,…}プロンプトのリスト
  • prompt の静的コンテンツの曖昧さは明示的な連想シンタックスを使って解消できる．
  • <|"Type""Text","Data"data|>明示的なテキスト部分
    <|"Type""Image","Data"data|>明示的な画像部分（File[…]オブジェクトをサポートする）
  • テンプレートオブジェクトは，TemplateObject[…][]によって自動的に文字列に変換される．
  • TemplateObjectで作成されたプロンプトはテキストと画像を含むことがある．
  • LLMSynthesizeSubmitはTaskObject[…]を返す．
  • 次は，指定可能なオプションである．
  • Authentication Automatic認証スキーム
    HandlerFunctions生成されたイベントの処理方法
    HandlerFunctionsKeysAutomaticハンドラ関数に渡すパラメータ
    LLMEvaluator $LLMEvaluator使用するLLM設定
  • LLMSynthesizeSubmitの非同期実行の間にイベントが生成されることがある．
  • 次は，LLMによってトリガされるイベントである．
  • "ContentChunkReceived"受信したメッセージのコンテンツの増分
    "StoppingReasonReceived"受信した生成を停止する理由
    "MetadataReceived"受信したその他のメタデータ
    "ToolRequestReceived"受信したLLMToolRequest[…]
    "UsageInformationReceived"受信した使用情報の増分
  • 次は，ローカルの処理でトリガされるイベントである．
  • "CompletionGenerated"補完が生成された
    "ToolResponseGenerated"LLMToolResponse[…]が生成された
  • 以下は，タスクフレームワークによってトリガされるイベントである．
  • "FailureOccurred"計算中に失敗が生成された
    "TaskFinished"タスクは完全に終了した
    "TaskRemoved"タスクは削除されつつある
    "TaskStarted"タスクが開始された
    "TaskStatusChanged"タスクのステータスが変わった
  • HandlerFunctionsf は，すべてのイベントに f を使う．
  • HandlerFunctions-><|…,"eventi"->fi,…|>の指定のとき，fi[assoc]は eventiが生成されるたびに評価される．assoc の要素はHandlerFunctionsKeysの設定で指定されたキーを持つ．
  • LLMSynthesizeSubmitは，assoc 内の値を取得するために必要ではない限り，外部サービスリクエストを実行しない．LLMリクエストの構築に関連する要素，すなわち"Prompt"，"PromptText"，"LLMEvaluator"，またはタスクフレームワークに関連する要素，すなわち"EventName"，"Failure"，"Task"，"TaskStatus"は，LLM 呼出しをトリガしない．
  • 次は，HandlerFunctionsKeysによる可能なキー指定である．
  • "CompletionText"LLMからのテキストによる答
    "CompletionToolsText"ツールのインタラクションを含むテキストによる答
    "ContentChunk"メッセージの部分
    "EventName"処理されているイベント名
    "Failure"タスクが失敗したときに生成される失敗オブジェクト
    "FullText""History"の文字列表現
    "History"プロンプトと完了を含む完全な履歴
    "Model"メッセージの生成に使われるモデル
    "Prompt"LLMに送信されたコンテンツ
    "PromptText""Prompt"の文字列表現
    "StoppingReason"生成が中止された理由
    "Task"LLMSynthesizeSubmitによって生成されたタスクオブジェクト
    "TaskStatus"タスクのステータス
    "ToolRequest"最後に生成されたLLMToolRequest[…]
    "Timestamp"メッセージのタイムスタンプ
    "ToolRequests"LLMToolRequestオブジェクトのリスト
    "ToolResponse"最後に生成されたLLMToolResponse[…]
    "ToolResponses"LLMToolResponseオブジェクトのリスト
    "Usage"トークンの使用量
    "UsageIncrement"トークン使用量のアップデート
    {key1,…}キーのリスト
    Allすべてのキー
    AutomaticHandlerFunctionsからキーを割り出す
  • まだ受け取られていない値はMissing["NotAvailable"]として与えられる．
  • LLMEvaluatorはLLMConfigurationオブジェクトあるいは以下の任意のキーを含む連想に設定できる．
  • "MaxTokens"生成するトークンの最大数
    "Model"ベースモデル
    "PromptDelimiter"プロンプト間に挿入する文字列
    "Prompts"初期プロンプトあるいはLLMPromptGeneratorオブジェクト
    "StopTokens"生成を停止するトークン
    "Temperature"サンプリング温度
    "ToolMethod"ツールの呼出しに使用するメソッド
    "Tools"使用可能にするLLMToolオブジェクトのリスト
    "TopProbabilities"サンプリングクラスのカットオフ
    "TotalProbabilityCutoff"サンプリング確率のカットオフ（核サンプリング）
  • 次は，"Model"の有効な形式である．
  • name名前付きのモデル
    {service,name}service からの名前付きのモデル
    <|"Service"service,"Name"name|>完全に指定されたモデル
  • 複数のプロンプトは"PromptDelimiter"特性によって分離される．
  • 生成されるテキストは分布からサンプリングされる．サンプリングの詳細は，LLMEvaluatorの以下の特性を使って指定できる．
  • "Temperature"tAutomatic正の温度 t を使ったサンプリング
    "TopProbabilities"kAutomatic最も高い k 個の確率クラスだけからサンプリングされる
    "TotalProbabilityCutoff"pAutomatic累積確率が少なくとも p の最も可能性が高い選択肢からサンプリングされる（核サンプリング）
  • これらのパラメータのAutomatic値は，指定された"Model"のデフォルトを使う．
  • 次は，"ToolMethod"の可能な値である．
  • "Service"service のツール構造に依存する
    "Textual"プロンプトに基づいたツール呼出しを使う
  • 次は，Authenticationの可能な値である．
  • Automatic認証方法を自動的に選択する
    Environment環境変数中のキーをチェックする
    SystemCredentialシステムキーチェーンのキーをチェックする
    ServiceObject[…]サービスオブジェクトから認証情報を継承する
    "string"明示的なAPIキーを与える
  • AuthenticationAutomaticとすると，関数はEnvironmentおよびSystemCredential内の変数ToUpperCase[service]<>"_API_KEY" をチェックする．それ以外の場合はServiceConnect[service]を使う．
  • LLMSynthesizeSubmitは機械学習を使用する．その訓練集合とメソッドはWolfram言語のバージョンによって異なることがあり，与えられる結果も異なる可能性がある．

例題

すべて開く すべて閉じる

例  (2)

非同期のテキスト生成タスクを開始する：

Wolfram Language code: LLMSynthesizeSubmit["A short sentence about a boar", HandlerFunctions -> <|"TaskFinished" -> Function[res = #CompletionText]|>]

生成されたテキストを検査する：

Wolfram Language code: res

単純なプロンプトを使って生成されたテキストを動的に取り出す：

Wolfram Language code: chunks = {}; LLMSynthesizeSubmit["A list of 5 random cat breeds", HandlerFunctions -> <|"ContentChunkReceived" -> Function[AppendTo[chunks, #ContentChunk]]|>];

全生成ステップを表示する：

Wolfram Language code: chunks

スコープ  (4)

プロンプトに基づいてテキストを合成する：

Wolfram Language code: task = LLMSynthesizeSubmit["the product of 5 and 6 is ", HandlerFunctions -> <|"TaskFinished" -> Function[res = #CompletionText]|>]

生成されたテキストを調べる：

Wolfram Language code: res

テキストと画像の両方をプロンプトに使う：

Wolfram Language code: task = LLMSynthesizeSubmit[{"what is this image?", [image], "Tell me just one word about it"}, HandlerFunctions -> <|"TaskFinished" -> Function[res = #CompletionText]|>]

生成されたテキストを調べる：

Wolfram Language code: res

異なる特性を返すように指定する：

Wolfram Language code: task = LLMSynthesizeSubmit["the product of 5 and 6 is ", HandlerFunctions -> <|"TaskFinished" -> Function[res = #FullText]|>]

プロンプトと補完の両方を調べる：

Wolfram Language code: res

リクエストのプロンプトを実行せずに検査する：

Wolfram Language code: Block[ {$AllowInternet = False, res} , TaskWait@LLMSynthesizeSubmit[ {"be brief", "what is the price per mile for a bike path"}, HandlerFunctions -> <|"TaskFinished" -> Function[res = #PromptText] |> ]; res ]

オプション  (8)

Authentication  (4)

APIの認証キーを与える：

Wolfram Language code: LLMSynthesizeSubmit["the product of 5 and 6 is ", Authentication -> "<my-key>"]

オペレーティングシステムのキーチェーンを使ってAPIキーを格納する：

Wolfram Language code: SystemCredential["OPENAI_API_KEY"] = "<my-key>"

システムのキーチェーンにキーを探す：

Wolfram Language code: LLMSynthesizeSubmit["the product of 5 and 6 is ", Authentication -> SystemCredential]

APIキーを環境変数に格納する：

Wolfram Language code: SetEnvironment["OPENAI_API_KEY" -> "<my-key>"]

システム環境にキーを探す：

Wolfram Language code: LLMSynthesizeSubmit["the product of 5 and 6 is ", Authentication -> Environment]

サービスオブジェクトを介して認証する：

Wolfram Language code: so = ServiceConnect["OpenAI"]
Wolfram Language code: LLMSynthesizeSubmit["the product of 5 and 6 is ", Authentication -> so]

LLMEvaluator  (4)

デフォルトで，テキスト生成は終了トークンが生成されるまで続く：

Wolfram Language code: LLMSynthesizeSubmit["the first 20 digits of Pi", HandlerFunctions -> <|"TaskFinished" -> Function@MessageDialog[#CompletionText]|>]

生成されるサンプル（トークン）の量を制限する：

Wolfram Language code: LLMSynthesizeSubmit["the first 20 digits of Pi", LLMEvaluator -> <|"MaxTokens" -> 3|>, HandlerFunctions -> <|"TaskFinished" -> Function@MessageDialog[#CompletionText]|>]

サンプリングは零度で行うように指定する：

Wolfram Language code: LLMSynthesizeSubmit["What's the plural of mouse?", LLMEvaluator -> <|"Temperature" -> 0|>, HandlerFunctions -> <|"TaskFinished" -> Function@MessageDialog[#CompletionText]|>]

生成されるものにより変化があるように高い温度を指定する：

Wolfram Language code: LLMSynthesizeSubmit["What's the plural of mouse?", LLMEvaluator -> <|"Temperature" -> 1.5|>, HandlerFunctions -> <|"TaskFinished" -> Function@MessageDialog[#CompletionText]|>]

分布を切断する前に最大累積確率を指定する：

Wolfram Language code: LLMSynthesizeSubmit["What's the plural of mouse?", LLMEvaluator -> <|"TotalProbabilityCutoff" -> .2|>, HandlerFunctions -> <|"TaskFinished" -> Function@MessageDialog[#CompletionText]|>]

生成に使うサービスとモデルを指定する：

Wolfram Language code: LLMSynthesizeSubmit["What's the plural of mouse?", LLMEvaluator -> <|"Model" -> {"Anthropic", "claude-haiku-4-5"}|>, HandlerFunctions -> <|"TaskFinished" -> Function@MessageDialog[#CompletionText]|>]

考えられる問題  (2)

テキスト生成が指示に文字通り従うとは保証されない：

Wolfram Language code: LLMSynthesizeSubmit["Print Pi to the 57th decimal digit, nothing else", HandlerFunctions -> <|"TaskFinished" -> Function[pi = #CompletionText]|>]
Wolfram Language code: pi
Wolfram Language code: StringLength[pi]

正確な計算に厳密な算術を使う：

Wolfram Language code: N[Pi, 57 + 1]

失敗は，キャッチされなければ通知されない：

Wolfram Language code: LLMSynthesizeSubmit["Print Pi to the 57th decimal digit, nothing else", LLMEvaluator -> <|"Model" -> <|"Name" -> "thismodeldoesnotexists", "Service" -> Automatic|>|>, HandlerFunctions -> <|"TaskRemoved" -> Function[failure = #Failure; res = #CompletionText]|>]

補完を調べる：

Wolfram Language code: res

潜在的な失敗をチェックする：

Wolfram Language code: failure
Wolfram Research (2025), LLMSynthesizeSubmit, Wolfram言語関数， https://reference.wolfram.com/language/ref/LLMSynthesizeSubmit.html.

テキスト

Wolfram Research (2025), LLMSynthesizeSubmit, Wolfram言語関数， https://reference.wolfram.com/language/ref/LLMSynthesizeSubmit.html.

CMS

Wolfram Language. 2025. "LLMSynthesizeSubmit." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/LLMSynthesizeSubmit.html.

APA

Wolfram Language. (2025). LLMSynthesizeSubmit. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LLMSynthesizeSubmit.html

BibTeX

@misc{reference.wolfram_2026_llmsynthesizesubmit, author="Wolfram Research", title="{LLMSynthesizeSubmit}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/LLMSynthesizeSubmit.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_llmsynthesizesubmit, organization={Wolfram Research}, title={LLMSynthesizeSubmit}, year={2025}, url={https://reference.wolfram.com/language/ref/LLMSynthesizeSubmit.html}, note=[Accessed: 01-November-2026]}