WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Log2[x]

底を2とする x の対数を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
定義  
積分  
級数展開  
関数の恒等式と簡約  
アプリケーション  
特性と関係  
関連項目
関連するガイド
関連リンク
履歴
引用書式

Log2

Log2[x]

底を2とする x の対数を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • Log2は可能な場合は厳密な整数または有理数の結果を返す．
  • 特別な引数の場合，Log2は自動的に厳密値を計算する．
  • Log2は任意の数値精度で評価することができる．
  • Log2は自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (5)

Log2は底が2の対数を与える：

Wolfram Language code: Log2[2 ^ 10]
Wolfram Language code: Log2[1.4142]
Wolfram Language code: Log2[x]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Log2[x], {x, 0, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Log2[z ^ 3], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点からシフトされた級数展開：

Wolfram Language code: Series[Log2[1 + x], {x, 0, 5}]

特異点における漸近展開：

Wolfram Language code: Series[Log2[x], {x, -1, 3}, Assumptions -> Im[x] > 0]

スコープ  (43)

数値評価  (7)

数値的に評価する：

Wolfram Language code: Log2[9.]

高精度で評価する：

Wolfram Language code: N[Log2[45], 100]

出力精度は入力精度に従う：

Wolfram Language code: Log2[5.211111111111111111]

複素数入力：

Wolfram Language code: N[Log2[2 + I]]

高精度で効率的に評価する：

Wolfram Language code: Log2[1600`100]//Timing
Wolfram Language code: Log2[456`100000];//Timing

Log2は実数値区間を扱うことができる：

Wolfram Language code: Log2[Interval[{1 / 3, 2}]]

Aroundを使って平均的な場合の統計区間を計算する：

Wolfram Language code: Log2[ Around[1 / 5, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: Log2[{{2, 1}, {0, 1 / 2}}]

MatrixFunctionを使って行列のLog2関数を計算することもできる：

Wolfram Language code: MatrixFunction[Log2, {{2, 1}, {0, 1 / 2}}]//FullSimplify

特定の値  (6)

固定点におけるLog2の値：

Wolfram Language code: Table[Log2[n ], {n, {1, 2, 4, 8}}]
Wolfram Language code: Table[Log2[1 / n], {n, {1, 2, 4, 8}}]

ゼロにおける値：

Wolfram Language code: Log2[0]

無限大における値：

Wolfram Language code: Log2[ComplexInfinity]
Wolfram Language code: Log2[Infinity]

引数0を与えると記号的な結果が与えられる：

Wolfram Language code: Log2[0]

Log2の零点：

Wolfram Language code: Log2[1]

Log2[x]=0.5となる x の値を求める：

Wolfram Language code: xval = x /. FindRoot[Log2[x] == 0.5, {x, 0.1}]
Wolfram Language code: Plot[Log2[x], {x, 0, 2E}, Epilog -> Style[Point[{xval, Log2[xval]}], PointSize[Large], Red]]

可視化  (3)

Log2関数をプロットする：

Wolfram Language code: Plot[Log2[x], {x, 0, 4}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Log2[z]], {z, -2 - 2I, 2 + 2 I}, Contours -> 20]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Log2[z]], {z, -2 - 2I, 2 + 2 I}, Contours -> 20]

でプロットする：

Wolfram Language code: PolarPlot[Log2[ϕ], {ϕ, 0, 12π}, Frame -> True]

関数の特性  (10)

Log2すべての正の値について定義される：

Wolfram Language code: FunctionDomain[Log2[x], x]

Log2は非零のすべての複素数値について定義される：

Wolfram Language code: FunctionDomain[Log2[x], x, Complexes]

Log2関数の値域：

Wolfram Language code: FunctionRange[Log2[x], x, y]
Wolfram Language code: FunctionRange[Log2[x], x, y, Complexes]

Log2は解析関数ではない：

Wolfram Language code: FunctionAnalytic[Log2[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[Log2[x], x]

Log2は負の実軸に沿って分枝切断線を持つ：

Wolfram Language code: Limit[Log2[-2 + ϵ I], ϵ -> 0, Direction -> "FromAbove"]
Wolfram Language code: Limit[Log2[-2 + ϵ I], ϵ -> 0, Direction -> "FromBelow"]

Log2は正の実数上で単調である：

Wolfram Language code: FunctionMonotonicity[Log2[x], x, PositiveReals]

Log2は単射である：

Wolfram Language code: FunctionInjective[Log2[x], x]
Wolfram Language code: Plot[{Log2[x], 1 / 2}, {x, 0, 5}]

Log2は全射である：

Wolfram Language code: FunctionSurjective[Log2[x], x]
Wolfram Language code: Plot[{Log2[x], 5}, {x, 0, 200}]

Log2は非負でも非正でもない：

Wolfram Language code: FunctionSign[Log2[x], x]

Log2は x≤0について特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[Log2[x], x]
Wolfram Language code: FunctionDiscontinuities[Log2[x], x]

Log2は正の実数上で凹である：

Wolfram Language code: FunctionConvexity[{Log2[x], x > 0}, x]

TraditionalFormによる表示：

Wolfram Language code: Log2[x]//HoldForm//TraditionalForm

定義  (3)

一次導関数：

Wolfram Language code: D[Log2[x], x]

高次導関数：

Wolfram Language code: Table[D[Log2[x], {x, k}], {k, 1, 5}]

高次導関数をプロットする：

Wolfram Language code: Plot[%, {x, -10, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative", "Fifth Derivative"}]

次導関数の式：

Wolfram Language code: D[Log2[x], {x, k}]

積分  (3)

Integrateを使って不定積分を計算する：

Wolfram Language code: Integrate[Log2[x], x]

Log2の定積分：

Wolfram Language code: Integrate[Log2[x], {x, 0, 1}]

その他の積分例：

Wolfram Language code: Integrate[Log10[x]Log2[x], x]//FullSimplify
Wolfram Language code: Integrate[Log2[z] ^ a, z]
Wolfram Language code: Integrate[t ^ (α - 1)Log2[t], {t, 0, 1}, Assumptions -> Re[α] > 0]

級数展開  (5)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[Log2[x], {x, 2, 4}]

の周りの最初の3つの近似のプロット：

Wolfram Language code: terms = Normal@Table[Series[Log2[x], {x, 1, m}], {m, 1, 5, 2}]; Plot[{Log2[x], terms}, {x, 0, 5}]

SeriesCoefficientを使った級数展開の一般項：

Wolfram Language code: SeriesCoefficient[Log2[x], {x, 1, n}]

FourierSeries：

Wolfram Language code: FourierSeries[Log2[x], x, 1]// FullSimplify

分枝切断線における漸近展開：

Wolfram Language code: Series[Log2[x], {x, -2, 3}]

Log2はベキ級数に適用できる：

Wolfram Language code: Log2[x + (x^2/2) + (x^3/3) + O[x]^4]

関数の恒等式と簡約  (6)

Log2の基本的な恒等式：

Wolfram Language code: 2 ^ Log2[x]

ベキ関数簡約の対数：

Wolfram Language code: FunctionExpand[Log2[x^a], x > 0 && a∈Reals]

仮定の下で対数を簡約する：

Wolfram Language code: Log2[2 ^ n]
Wolfram Language code: Simplify[%, n > 0]

積の対数：

Wolfram Language code: FunctionExpand[Log2[x y], x > 0 && x + y ≥ 0]

底の変更：

Wolfram Language code: FullSimplify[Log2[x] == (Log[a, x]/Log[a, 2])]

実変数 x および y を仮定して展開する：

Wolfram Language code: ComplexExpand[Log2[x + I y]]//FullSimplify

アプリケーション  (5)

関数方程式からの整列合併アルゴリズムの最悪の複雑さ：

Wolfram Language code: RSolve[w[n] == 2w[n / 2] + n - 1 && w[1] == 0, w[n], n]

最高の場合における整列合併アルゴリズムの複雑さ：

Wolfram Language code: RSolve[b[2n] == 2 b[n] + n && b[1] == 0, b[n], n]

バブルソートは整列合併よりも漸近的に悪い：

Wolfram Language code: mComparisons[n_] := n Log2[n / 2] + 1
Wolfram Language code: bComparisons[n_] := n(n - 1) / 2
Wolfram Language code: Limit[mComparisons[n] / bComparisons[n], n -> Infinity]

半減期の単位でサンプルの寿命を求める：

Wolfram Language code: y[17.] /. RSolve[{y[t + 1] == y[t] / 2, y[0] == 3.5}, y, t]
Wolfram Language code: Log2[3.5 / %]

より大きい整数を保存するために必要なビット数を計算する：

Wolfram Language code: Log2[BarnesG[500]]//N
Wolfram Language code: Ceiling[%]

厳密な結果と比較する：

Wolfram Language code: BitLength[BarnesG[500]]

参加者（またはチーム）が2である単一のトーナメントで勝者を決定するのに必要なラウンド数を求める．そのためには，2を何乗すれば参加者（またはチーム）総数以上になるかを求める．

例えば，参加者が4人のトーナメントで勝者を決定するためには2ラウンド必要だが，32チームが参加するトーナメントで勝者を決定するためには5ラウンド必要になる．計算にLog2を使う：

Wolfram Language code: rounds = Log2[4]
Wolfram Language code: round2 = Log2[32]

特性と関係  (2)

Wolfram言語の機械実数を表すために使われるビット数：

Wolfram Language code: Log2[10.]$MachinePrecision

仮定を使った簡約：

Wolfram Language code: Log2[2 ^ n]
Wolfram Language code: Refine[%, n∈Reals]
Wolfram Research (2008), Log2, Wolfram言語関数， https://reference.wolfram.com/language/ref/Log2.html.

テキスト

Wolfram Research (2008), Log2, Wolfram言語関数， https://reference.wolfram.com/language/ref/Log2.html.

CMS

Wolfram Language. 2008. "Log2." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Log2.html.

APA

Wolfram Language. (2008). Log2. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Log2.html

BibTeX

@misc{reference.wolfram_2026_log2, author="Wolfram Research", title="{Log2}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Log2.html}", note=[Accessed: 04-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_log2, organization={Wolfram Research}, title={Log2}, year={2008}, url={https://reference.wolfram.com/language/ref/Log2.html}, note=[Accessed: 04-November-2026]}