WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

PaddedForm[expr,n]

expr の中のすべての数に余白を使って合計 n 桁のスペースを確保するようにして出力する．

PaddedForm[expr,{n,f}]

小数点以下厳密にf 桁の近似実数で出力する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
DigitBlock  
ExponentFunction  
ExponentStep  
Show More Show More
NumberFormat  
NumberMultiplier  
NumberPadding  
NumberPoint  
NumberSeparator  
NumberSigns  
SignPadding  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

PaddedForm

PaddedForm[expr,n]

expr の中のすべての数に余白を使って合計 n 桁のスペースを確保するようにして出力する．

PaddedForm[expr,{n,f}]

小数点以下厳密にf 桁の近似実数で出力する．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

の数値近似の最初の10桁を表示する：

Wolfram Language code: N[Pi, 20]
Wolfram Language code: PaddedForm[N[Pi], 20]

3桁精度の数の小数点の右側4桁を表示する：

Wolfram Language code: PaddedForm[1.23456, {3, 4}]

スコープ  (5)

機械数のデフォルト表示：

Wolfram Language code: nE = N[E]

デフォルトより多くの桁を表示する：

Wolfram Language code: PaddedForm[nE, 10]

より少なく桁を表示する：

Wolfram Language code: PaddedForm[nE, 3]

複素数をフォーマットする：

Wolfram Language code: PaddedForm[RandomComplex[], 2]

高精度数をフォーマットする：

Wolfram Language code: N[Pi, 50]
Wolfram Language code: PaddedForm[%, 20]

ベクトルにおける数字の表示を変更する：

Wolfram Language code: RandomReal[10, 5]
Wolfram Language code: PaddedForm[%, 4]

行列：

Wolfram Language code: RandomReal[10, {3, 3}]
Wolfram Language code: PaddedForm[%, 2]

混合式の厳密ではない数の表示を変更する：

Wolfram Language code: 1 / 3.Sin[x / 7.]
Wolfram Language code: PaddedForm[%, 3]

オプション  (11)

DigitBlock  (2)

デフォルトの整数：

Wolfram Language code: PaddedForm[10 ^ 9, 10]

長さ3のブロックで区切られた桁：

Wolfram Language code: PaddedForm[10 ^ 9, DigitBlock -> 3]

5桁のブロック，区切りにはスペースを使う：

Wolfram Language code: PaddedForm[30!, DigitBlock -> 5, NumberSeparator -> " "]

ExponentFunction  (1)

の近似ベキを計算する：

Wolfram Language code: p = N[E ^ Range[10, 50, 10]]

指数に3の倍数を使うように制限する：

Wolfram Language code: PaddedForm[p, ExponentFunction -> (3Quotient[#, 3]&)]

10より大きいベキにのみ指数を含める：

Wolfram Language code: PaddedForm[p, ExponentFunction -> (If[-10 < # < 10, Null, #]&)]

ExponentStep  (1)

10 桁のデフォルトのフォーマット：

Wolfram Language code: PaddedForm[1234567890., 10]

指数を6の倍数に制限する：

Wolfram Language code: PaddedForm[1234567890., 10, ExponentStep -> 6]

NumberFormat  (1)

数字をFortran風の形式で表示する：

Wolfram Language code: v = {8. ^ 5, 11. ^ 7, 13. ^ 9}
Wolfram Language code: PaddedForm[v, NumberFormat -> (Row[{#1, "e", #3}]&)]

仮数のみを表示する：

Wolfram Language code: PaddedForm[v, NumberFormat -> (#1&)]

科学表記に変換した後で指数を表示する：

Wolfram Language code: PaddedForm[v, NumberFormat -> (#3&), ExponentFunction -> (#&)]

NumberMultiplier  (1)

デフォルトの乗数を使う：

Wolfram Language code: PaddedForm[1.25 * 10 ^ 8, 10]

代りにアスタリスク(*)を使う：

Wolfram Language code: PaddedForm[1.25 * 10 ^ 8, 10, NumberMultiplier -> "*"]

NumberPadding  (1)

デフォルトでは左に充填される：

Wolfram Language code: PaddedForm[{-6.7, 6.888, 6.99999}, 4]

スペースで右に充填する：

Wolfram Language code: PaddedForm[{-6.7, 6.888, 6.99999}, {4, 3}, NumberPadding -> {"", " "}]

0で右に充填する：

Wolfram Language code: PaddedForm[{-6.7, 6.888, 6.99999}, {4, 3}, NumberPadding -> {"", "0"}]

NumberPoint  (1)

デフォルトはピリオドである：

Wolfram Language code: PaddedForm[1.2345, 3]

代りにコンマ(,)で表示する：

Wolfram Language code: PaddedForm[1.2345, 3, NumberPoint -> ","]

NumberSeparator  (1)

デフォルトの区切りは(,)である：

Wolfram Language code: PaddedForm[30!, DigitBlock -> 3]

代りにスペースを使う：

Wolfram Language code: PaddedForm[30!, DigitBlock -> 3, NumberSeparator -> " "]

NumberSigns  (1)

デフォルトでは負の符号は含まれるが正の符号は含まれない：

Wolfram Language code: PaddedForm[{-1 / 3., 2 / 3.}, 5]

正の符号も含まれるようにする：

Wolfram Language code: PaddedForm[{-1 / 3., 2 / 3.}, 5, NumberSigns -> {"-", "+"}]

符号の代りに言葉を使う：

Wolfram Language code: PaddedForm[{-1 / 3., 2 / 3.}, 5, NumberSigns -> {"minus ", "plus "}]

SignPadding  (1)

デフォルトでは符号の前に充填される：

Wolfram Language code: PaddedForm[{-1.2345, 2.4680}, {5, 2}, NumberPadding -> {" ", " "}]

代りに符号と数字の間を充填するようにする：

Wolfram Language code: PaddedForm[{-1.2345, 2.4680}, {5, 2}, SignPadding -> True, NumberPadding -> {" ", " "}]

アプリケーション  (1)

の近似値を，徐々に精度を高くし小数点以下の桁数を増やして表示する：

Wolfram Language code: Table[PaddedForm[N[Pi], {n, f}], {n, 5}, {f, 5}]

数字を小数点で揃える：

Wolfram Language code: Table[PaddedForm[N[Pi], {n, f}, NumberPadding -> {"", "0"}], {n, 5}, {f, 5}]

表形式で表示する：

Wolfram Language code: TableForm[%]

特性と関係  (5)

PaddedFormとNumberFormはデフォルトで同じ仮数と指数を使う：

Wolfram Language code: PaddedForm[N[E ^ Range[10, 20, 2]], 10]
Wolfram Language code: NumberForm[N[E ^ Range[10, 20, 2]], 10]

ScientificFormは小数点の左に1桁しかない：

Wolfram Language code: ScientificForm[N[E ^ Range[10, 20, 2]], 10]

EngineeringFormは3の倍数の指数を使う：

Wolfram Language code: EngineeringForm[N[E ^ Range[10, 20, 2]], 10]

AccountingFormは指数を使わない：

Wolfram Language code: AccountingForm[N[E ^ Range[10, 20, 2]], 10]

数を底2に変換する：

Wolfram Language code: b2 = BaseForm[123.45, 2]

数を底2で厳密に十進法の3桁まで表す：

Wolfram Language code: PaddedForm[b2, 3]

底が10の数を厳密に3桁まで再構築する：

Wolfram Language code: (2^^1.1110111)2 ^ 6

MatrixFormあるいはTableFormの数の表示を変更する：

Wolfram Language code: m = RandomReal[10 ^ 10, {3, 2}];
Wolfram Language code: {MatrixForm[m], PaddedForm[MatrixForm[m], 3]}

PaddedForm[expr,n]のタイプセット形式は，入力で使われる際は expr と同じであると解釈される：

Wolfram Language code: {PaddedForm[1.23, 2]}

出力をコピーして入力セルにペーストする． 1.2は1.23と解釈される：

Wolfram Language code: {1.23}

PaddedFormは，入力を評価してPaddedForm[expr,n]になるときは出力には現れない：

Wolfram Language code: PaddedForm[1.23, 2]

OutにはPaddedForm[1.23,2]ではなく値1.23が割り当てられる：

Wolfram Language code: %

考えられる問題  (3)

要求された精度が低い場合はプレースホルダのゼロが必要なことがある：

Wolfram Language code: PaddedForm[12345.6, 3]

デフォルトで，スペースは2つの符号の大きい方に合わせて設定される：

Wolfram Language code: PaddedForm[Column[{3.24, -5.19}], 3]
Wolfram Language code: PaddedForm[Column[{3.24, -5.19}], 3, NumberPadding -> ""]

PaddedFormは，出力のトップレベルから省略された場合でも部分式からは削除されない：

Wolfram Language code: e = PaddedForm[1.23, 2]

出力にはPaddedFormは含まれない：

Wolfram Language code: %

しかし，変数 e にはPaddedFormが含まれるので，続く評価に影響するかもしれない：

Wolfram Language code: FullForm[e]

PaddedFormが介在するため乗算は評価されない：

Wolfram Language code: 10 * e

まず変数に割当てを行い．次に結果にPaddedFormを適用することで計算可能性を維持する：

Wolfram Language code: PaddedForm[f = 1.23, 2]
Wolfram Language code: 10 * f
Wolfram Research (1991), PaddedForm, Wolfram言語関数， https://reference.wolfram.com/language/ref/PaddedForm.html.

テキスト

Wolfram Research (1991), PaddedForm, Wolfram言語関数， https://reference.wolfram.com/language/ref/PaddedForm.html.

CMS

Wolfram Language. 1991. "PaddedForm." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PaddedForm.html.

APA

Wolfram Language. (1991). PaddedForm. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PaddedForm.html

BibTeX

@misc{reference.wolfram_2026_paddedform, author="Wolfram Research", title="{PaddedForm}", year="1991", howpublished="\url{https://reference.wolfram.com/language/ref/PaddedForm.html}", note=[Accessed: 31-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_paddedform, organization={Wolfram Research}, title={PaddedForm}, year={1991}, url={https://reference.wolfram.com/language/ref/PaddedForm.html}, note=[Accessed: 31-October-2026]}