WOLFRAM

Wolfram 语言与系统参考资料中心

PageRankCentrality[g,α]

权重为 α，给出图 g 中的顶点的网页排名 (page-rank) 中心度列表.

PageRankCentrality[g,α,β]

权重为 α，初始中心度为 β，给出网页排名中心度列表.

PageRankCentrality[{vw,…},…]

用规则 vw 指定图 g.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
WorkingPrecision  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

PageRankCentrality

PageRankCentrality[g,α]

权重为 α，给出图 g 中的顶点的网页排名 (page-rank) 中心度列表.

PageRankCentrality[g,α,β]

权重为 α，初始中心度为 β，给出网页排名中心度列表.

PageRankCentrality[{vw,…},…]

用规则 vw 指定图 g.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

计算网页排名中心度：

Wolfram Language code: g = RandomGraph[{10, 20}];
Wolfram Language code: PageRankCentrality[g, 0.1]

突出显示：

Wolfram Language code: HighlightGraph[g, VertexList[g], VertexSize -> Thread[VertexList[g] -> Rescale[%]]]

求一个人随机点击超链接会到达特定页面的概率：

Wolfram Language code: g = [image];
Wolfram Language code: Part[PageRankCentrality[g, 0.85], VertexIndex[g, "wolframalpha.com"]]

对网页排序，最常见的页面排在最前面：

Wolfram Language code: Part[VertexList[g], Ordering[PageRankCentrality[g, 0.85], All, Greater]]//Short

范围  (7)

PageRankCentrality 可用于无向图：

Wolfram Language code: PageRankCentrality[[image], 0.5]

有向图：

Wolfram Language code: PageRankCentrality[[image], 0.5]

多图：

Wolfram Language code: PageRankCentrality[[image], 0.5]

混合图：

Wolfram Language code: PageRankCentrality[[image], 0.5]

用规则指定图：

Wolfram Language code: PageRankCentrality[{1 -> 3, 2 -> 1, 3 -> 6, 4 -> 6, 1 -> 5, 5 -> 4, 6 -> 1}, 0.5]

非默认初始中心度：

Wolfram Language code: PageRankCentrality[[image], 0.5, {0.1, 0.2, 0.3, 0.1, 0.2, 0.1}]

PageRankCentrality 可用于大规模图：

Wolfram Language code: g = GridGraph[{10, 10, 10, 10}];
Wolfram Language code: PageRankCentrality[g, 0.5]//Short//Timing

选项  (3)

WorkingPrecision  (3)

默认情况下，PageRankCentrality 使用机器精度计算求出中心度：

Wolfram Language code: PageRankCentrality[[image], 1 / 10]

指定更高的工作精度：

Wolfram Language code: PageRankCentrality[[image], 1 / 10, WorkingPrecision -> 50]

无限工作精度对应于精确计算：

Wolfram Language code: PageRankCentrality[[image], 1 / 10, WorkingPrecision -> ∞]

应用  (6)

基于一个人随机点击超链接将到达特定页面的似然值，对网页排序：

Wolfram Language code: g = [image];
Wolfram Language code: SortBy[{VertexList[g], PageRankCentrality[g, 0.85]}, Last]//Reverse

为 CycleGraph 突出显示网页排名中心度：

Wolfram Language code: HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]];
Wolfram Language code: g = CycleGraph[8, DirectedEdges -> True, VertexSize -> Large];
Wolfram Language code: cc = PageRankCentrality[g, 0.5];
Wolfram Language code: HighlightCentrality[g, cc]

GridGraph:

Wolfram Language code: g = GridGraph[{10, 10}, DirectedEdges -> True, VertexSize -> 0.5];
Wolfram Language code: cc = PageRankCentrality[g, 0.5];
Wolfram Language code: HighlightCentrality[g, cc]

CompleteKaryTree:

Wolfram Language code: g = CompleteKaryTree[3, 3, DirectedEdges -> True, VertexSize -> Large];
Wolfram Language code: cc = PageRankCentrality[g, 0.5];
Wolfram Language code: HighlightCentrality[g, cc]

PathGraph:

Wolfram Language code: g = PathGraph[Range[20], DirectedEdges -> True, VertexSize -> Large];
Wolfram Language code: cc = PageRankCentrality[g, 0.5];
Wolfram Language code: HighlightCentrality[g, cc]

公司网络的网页通过超链接相连. 求在多次点击后，最可能到达的页面，阻尼因子为 0.85：

Wolfram Language code: g = DynamicModule[«3»];
Wolfram Language code: With[{c = PageRankCentrality[g, 0.85]}, Pick[VertexList[g], c, Max[c]]]

下面的道路网络中，每个节点表示一条道路，两个道路如果交叉就相连. 预测总是有交通流的道路：

Wolfram Language code: g = [image];
Wolfram Language code: c = PageRankCentrality[ReverseGraph[g], 0.2];
Wolfram Language code: Pick[VertexList[g], c, Max[c]]

查找哪种物种的灭绝会导致在食品链的生态系统崩溃：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "SimpleFoodWeb"}]
Wolfram Language code: c = PageRankCentrality[ReverseGraph[g], 0.85];
Wolfram Language code: Pick[VertexList[g], c, Max[c]]

淋病奈瑟菌的代谢蜂窝网络. 求在系统中发挥边缘作用的蛋白质：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "MetabolicNetworkNeisseriaGonorrhoeae"}];
Wolfram Language code: c = PageRankCentrality[g, 0.85];
Wolfram Language code: Part[VertexList[g], Ordering[c, 10]]

这些蛋白质有最低的入度：

Wolfram Language code: SortBy[VertexList[g], VertexInDegree[g, #]&]//Shallow

属性和关系  (3)

中心度向量是线性系统 c=alpha TemplateBox[{a}, Transpose].d.c+beta 的标准化解：

Wolfram Language code: g = [image];
Wolfram Language code: n = VertexCount[g]; α = 1 / 3; β = ConstantArray[1 / n, n];
Wolfram Language code: PageRankCentrality[g, α, β]

求解线性系统：

Wolfram Language code: d = DiagonalMatrix[Table[1 / Max[1, k], {k, VertexOutDegree[g]}]]; a = AdjacencyMatrix[g];
Wolfram Language code: LinearSolve[IdentityMatrix[n] - α a.d, β]//Normalize[N[#], Total]&

网页排名中心度被标准化处理：

Wolfram Language code: PageRankCentrality[[image], 0.1]
Wolfram Language code: Total[%]

使用 VertexIndex 获取特定顶点的中心度：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: PageRankCentrality[g, 0.1][[VertexIndex[g, "Anna"]]]
Wolfram Research (2010)，PageRankCentrality，Wolfram 语言函数，https://reference.wolfram.com/language/ref/PageRankCentrality.html （更新于 2024 年）.

文本

Wolfram Research (2010)，PageRankCentrality，Wolfram 语言函数，https://reference.wolfram.com/language/ref/PageRankCentrality.html （更新于 2024 年）.

CMS

Wolfram 语言. 2010. "PageRankCentrality." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/PageRankCentrality.html.

APA

Wolfram 语言. (2010). PageRankCentrality. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/PageRankCentrality.html 年

BibTeX

@misc{reference.wolfram_2026_pagerankcentrality, author="Wolfram Research", title="{PageRankCentrality}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/PageRankCentrality.html}", note=[Accessed: 05-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_pagerankcentrality, organization={Wolfram Research}, title={PageRankCentrality}, year={2024}, url={https://reference.wolfram.com/language/ref/PageRankCentrality.html}, note=[Accessed: 05-November-2026]}