WOLFRAM

Wolfram 语言与系统参考资料中心

RecurrenceFilter[{α,β},x]

滤波器 x 使用带有系数 α 和 β 的线性递归方程.

RecurrenceFilter[tf,x]

使用由 TransferFunctionModel tf 定义的离散时间滤波器.

RecurrenceFilter[…,x,{y0,y-1,…}]

使用指定列表 {y0,y-1,…} 作为初始条件.

RecurrenceFilter[…,image]

滤波 image.

RecurrenceFilter[…,sound]

滤波采样 sound 对象.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Padding  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

RecurrenceFilter

RecurrenceFilter[{α,β},x]

滤波器 x 使用带有系数 α 和 β 的线性递归方程.

RecurrenceFilter[tf,x]

使用由 TransferFunctionModel tf 定义的离散时间滤波器.

RecurrenceFilter[…,x,{y0,y-1,…}]

使用指定列表 {y0,y-1,…} 作为初始条件.

RecurrenceFilter[…,image]

滤波 image.

RecurrenceFilter[…,sound]

滤波采样 sound 对象.

更多信息和选项

  • RecurrenceFilter[{α,β},x] 通过求解递归方程 给出对因果输入 x 的响应y，其中，n 从 1 到 Length[x]，i 为 Length[α]，j 为 Length[β].
  • RecurrenceFilter[{α,β},x] 使用初始条件 .
  • RecurrenceFilter[{α,β},x] 填充输入 x 以满足 . 值可以通过 Padding 选项改变. 当 Padding->None，响应 y 有效地从 yj 开始，输出维数一般比输入更小. »
  • 指定系数 α 和 β 分别是所需传递函数模型的分母和分子多项式系数.
  • 在 RecurrenceFilter[tf,…] 中，tf 应该是单输入单输出（SISO）系统.
  • RecurrenceFilter 作用于任意阶数的数值数组，二维和三维图像和采样声音对象，分别作用于每个通道.
  • 可能的 sound 对象包括：
  • SampledSoundList[{a1,a2,…},r]列表中给出的幅度级
    SampledSoundFunction[f,n,r]由函数产生的幅度级
    Sound[prims,…]排除 prims 中的 SoundNote 对象
  • 当应用于图像和多维数组时，指定的滤波器从第1层开始连续应用于每个维度.
  • 对于多通道图像和声音对象，分别对每个通道应用 RecurrenceFilter.

范例

打开所有单元 关闭所有单元

基本范例  (2)

滤波单位脉冲序列：

Wolfram Language code: RecurrenceFilter[{{1, -(1/2)}, {1}}, {1, 0, 0, 0, 0, 0}]

对图像进行滤波处理：

Wolfram Language code: RecurrenceFilter[{{1, -(4/5)}, {(1/5)}}, [image]]

范围  (5)

对滤波器系数使用符号式数值：

Wolfram Language code: RecurrenceFilter[{{1, Subscript[α, 1]}, {β}}, {1, 0, 0, 0, 0, 0}]

对符号式序列进行滤波：

Wolfram Language code: RecurrenceFilter[{{1, -(1/2)}, {1}}, {a, b, c, d}]

使用传递函数模型应用指定的滤波器：

Wolfram Language code: RecurrenceFilter[TransferFunctionModel[{{{z}}, -1/2 + z}, z, SamplingPeriod -> 1], {1, 0, 0, 0, 0, 0}]

指定一个初始条件：

Wolfram Language code: RecurrenceFilter[{{1, -(1/2)}, {1}}, {1, 0, 0, 0, 0, 0}, {1}]

对 TimeSeries 进行滤波：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{0., -0.27267267057145633, -0.6672983789995302, -0.5338541947930846, -0.6117404489279314, -0.6755527076595494, -0.02125421294486496, -0.10792797291843935, -0.6138271235477938, -0.3248568606554575, -0.08843449054 ... 2053424, -0.49980440691873723, -0.5388679788215971, -0.4101602764645551}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];
Wolfram Language code: filtered = RecurrenceFilter[{{.3}, {.1}}, ts]
Wolfram Language code: ListLinePlot[{ts, filtered}, PlotLegends -> {"original data", "filtered"}]

选项  (1)

Padding  (1)

默认情况下，RecurrenceFilter 使零填充量：

Wolfram Language code: RecurrenceFilter[{{1}, {1 / 3, 1 / 3, 1 / 3}}, Range[6]]

使用非零常量填充量：

Wolfram Language code: RecurrenceFilter[{{1}, {1 / 3, 1 / 3, 1 / 3}}, Range[6], Padding -> -1]

使用周期填充量：

Wolfram Language code: RecurrenceFilter[{{1}, {1 / 3, 1 / 3, 1 / 3}}, Range[6], Padding -> "Periodic"]

设置 Padding->None，返回较短的序列：

Wolfram Language code: RecurrenceFilter[{{1}, {1 / 3, 1 / 3, 1 / 3}}, Range[6], Padding -> None]

应用  (3)

用递归平滑滤波器滤波正弦信号的噪声：

Wolfram Language code: data = Table[Sin[i ^ 2 + i] + RandomReal[{-.2, .3}], {i, 0, Pi, 0.01}]; {ListLinePlot[data], ListLinePlot[RecurrenceFilter[{{1, -(4/5)}, {(1/5)}}, data]]}

对音频信号滤波：

Wolfram Language code: s = Sound[SampledSoundList[Table[Cos[( i/4.) + ((i/50.))^2], {i, 8000}], 8000]]
Wolfram Language code: RecurrenceFilter[{{1, -(4/5)}, {(1/5)}}, s]

使用低通巴特沃斯（Butterworth）滤波器滤波一图像：

Wolfram Language code: RecurrenceFilter[ToDiscreteTimeModel[ButterworthFilterModel[{3, .5}, s], 1], [image]]

属性和关系  (5)

一阶递归滤波器的脉冲响应：

Wolfram Language code: RecurrenceFilter[{{1, -(1/2)}, {1}}, {1, 0, 0, 0, 0, 0}]

非递归滤波器的阶跃响应：

Wolfram Language code: RecurrenceFilter[{{1}, {1 / 3, 1 / 3, 1 / 3}}, {1, 1, 1, 1, 1, 1}]

在二维空间中，连续对行和列应用滤波器：

Wolfram Language code: data = (⁠| | | | | | | - | - | - | - | - | | 1 | 1 | 0 | 0 | 0 | | 1 | 1 | 0 | 0 | 0 | | 0 | 0 | 0 | 0 | 0 | | 0 | 0 | 0 | 0 | 0 | | 0 | 0 | 0 | 0 | 0 |⁠); RecurrenceFilter[{{1, -1 / 2}, {1}}, data]//MatrixForm

使用 Map 只对行应用滤波器：

Wolfram Language code: Map[RecurrenceFilter[{{1, -1 / 2}, {1}}, #]&, data]//MatrixForm

对于一维数组，OutputResponse 等价于 RecurrenceFilter：

Wolfram Language code: sys = TransferFunctionModel[(z/z - (1/2)), z, SamplingPeriod -> 1]; OutputResponse[sys, {1, 0, 0, 0, 0, 0, 0, 0}][[1]] == RecurrenceFilter[sys, {1, 0, 0, 0, 0, 0, 0, 0}]

当使用差分方程描述滤波器，使用 RecurrenceTable：

Wolfram Language code: RecurrenceTable[{y[n] - (1/2)y[n - 1] == DiscreteDelta[n], y[-1] == 0}, y[n], {n, 0, 7}] == RecurrenceFilter[{{1, -(1/2)}, {1}}, {1, 0, 0, 0, 0, 0, 0, 0}]

对非递归数字滤波器，ListConvolve 和 RecurrenceFilter 返回相等的结果：

Wolfram Language code: ker = {1 / 3, 1 / 3, 1 / 3};data = {0, 0, 1, 1, 1, 1, 0, 0}; ListConvolve[ker, data] == RecurrenceFilter[{{1}, ker}, data][[3 ;; ]]
Wolfram Research (2012)，RecurrenceFilter，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RecurrenceFilter.html （更新于 2014 年）.

文本

Wolfram Research (2012)，RecurrenceFilter，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RecurrenceFilter.html （更新于 2014 年）.

CMS

Wolfram 语言. 2012. "RecurrenceFilter." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/RecurrenceFilter.html.

APA

Wolfram 语言. (2012). RecurrenceFilter. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/RecurrenceFilter.html 年

BibTeX

@misc{reference.wolfram_2026_recurrencefilter, author="Wolfram Research", title="{RecurrenceFilter}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/RecurrenceFilter.html}", note=[Accessed: 16-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_recurrencefilter, organization={Wolfram Research}, title={RecurrenceFilter}, year={2014}, url={https://reference.wolfram.com/language/ref/RecurrenceFilter.html}, note=[Accessed: 16-July-2026]}