WOLFRAM

Wolfram 语言与系统参考资料中心

RegionDifference[reg1,reg2]

给出区域 reg1 和 reg2 的差别.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
特殊区域  
公式区域  
网格区域  
导出区域  
CSG 区域  
细分区域  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

RegionDifference

RegionDifference[reg1,reg2]

给出区域 reg1 和 reg2 的差别.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

两个圆盘的差集：

Wolfram Language code: RegionDifference[Disk[{0, 0}, 2], Disk[{3, 0}, 2]];

可视化:

Wolfram Language code: Region[%]

两个 MeshRegion 对象的差集：

Wolfram Language code: RegionDifference[[image], [image]]

范围  (16)

特殊区域  (6)

对于某些区域，显式计算差集：

Wolfram Language code: Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}]; Subscript[ℛ, 2] = Disk[{3, 0}, 1];
Wolfram Language code: Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

区域不相交：

Wolfram Language code: Graphics[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Yellow, Subscript[ℛ, 3]}}]

此处，差集为空：

Wolfram Language code: Subscript[ℛ, 1] = Cuboid[]; Subscript[ℛ, 2] = Ball[{0, 0, 0}, 2];
Wolfram Language code: Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

该立方体含在球中：

Wolfram Language code: Graphics3D[{Opacity[0.5], {Red, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}}]

Line 区域的差集：

Wolfram Language code: ℛ = RegionDifference[Line[{{1}, {4}}], Line[{{2}, {3}}]];

可视化：

Wolfram Language code: Region[ℛ]

Polygon 区域的差集：

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{0, 0}, {3, -1}, {2, 0}, {3, 1}}]; Subscript[ℛ, 2] = Polygon[{{5, 0}, {2, 1}, {3, 0}, {2, -1}}];
Wolfram Language code: ℛ = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

可视化区域：

Wolfram Language code: Region[ℛ]

两个 Cuboid 区域的差集:

Wolfram Language code: ℛ = RegionDifference[Cuboid[], Cuboid[{0.5, 0.5, 0.5}]];

可视化：

Wolfram Language code: Region[ℛ]

有不同 RegionDimension 的区域的差集：

Wolfram Language code: ℛ = RegionDifference[Circle[{0, 0}, 1], Disk[{1, 0}, 1]];

可视化：

Wolfram Language code: Region[ℛ]

公式区域  (2)

ImplicitRegion 对象之差是一个 ImplicitRegion：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x ≤ 1, {x}]; Subscript[ℛ, 2] = ImplicitRegion[x ≥ -1, {x}];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

2D:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}]; Subscript[ℛ, 2] = ImplicitRegion[x^2 + (y - 1)^2 ≤ 1, {x, y}];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

3D:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 + z^2 ≤ 1, {x, y, z}]; Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 + z^2 ≤ 1, {x, y, z}];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

nD:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}]; Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegion 对象的差集:

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{u, v}, {{u, 0, 2}, {v, 0, 2}}]; Subscript[ℛ, 2] = ParametricRegion[{u + 1, v + 1}, {{u, 0, 2}, {v, 0, 2}}];
Wolfram Language code: ℛ = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

可视化：

Wolfram Language code: Region[ℛ]

网格区域  (2)

BoundaryMeshRegion 对象之差是一个 BoundaryMeshRegion：

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Language code: BoundedRegionQ[%]

2D:

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Language code: BoundedRegionQ[%]

3D:

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Language code: BoundedRegionQ[%]

全维 (full-dimensional) MeshRegion 对象之差是一个 MeshRegion：

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Language code: MeshRegionQ[%]

2D:

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Language code: MeshRegionQ[%]

3D:

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Language code: MeshRegionQ[%]

导出区域  (2)

BooleanRegion 对象之差：

Wolfram Language code: Subscript[ℛ, 1] = BooleanRegion[Or, {Triangle[{{0, 0}, {2, 3}, {-2, 3}}], Triangle[{{0, 2}, {2, -1}, {-2, -1}}]}]; Subscript[ℛ, 2] = BooleanRegion[And, {Triangle[{{0, 0}, {2, 3}, {-2, 3}}], Triangle[{{0, 2}, {2, -1}, {-2, 2}}]}];
Wolfram Language code: ℛ = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

可视化：

Wolfram Language code: Region[ℛ]

TransformedRegion 对象之差：

Wolfram Language code: Subscript[ℛ, 1] = TransformedRegion[Cuboid[], RotationTransform[Pi / 8, {1, 0, 0}]]; Subscript[ℛ, 2] = TransformedRegion[Cuboid[], RotationTransform[Pi / 8, {0, 1, 0}]];
Wolfram Language code: ℛ = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

可视化：

Wolfram Language code: Region[ℛ]

CSG 区域  (2)

二维 CSGRegion 对象之差：

Wolfram Language code: Subscript[ℛ, 1] = CSGRegion[{Disk[], Rectangle[]}]; Subscript[ℛ, 2] = CSGRegion[{Disk[{0, 0}, 1 / 2], Rectangle[{0, 0}, {1 / 2, 1 / 2}]}];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

三维 CSGRegion 对象之差：

Wolfram Language code: Subscript[ℛ, 1] = CSGRegion[{Cube[1.5], Cube[{0, 0, 1}, 3 / 4]}]; Subscript[ℛ, 2] = CSGRegion[{Cylinder[{{0, 0, -2}, {0, 0, 2}}, 1 / 3], Cylinder[{{-2, 0, 0}, {2, 0, 0}}, 1 / 2]}];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

细分区域  (2)

二维 SubdivisionRegion 对象之差：

Wolfram Language code: Subscript[ℛ, 1] = SubdivisionRegion[Rectangle[]]; Subscript[ℛ, 2] = SubdivisionRegion[Rectangle[{1 / 2, 1 / 2}]];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

三维 SubdivisionRegion 对象之差：

Wolfram Language code: Subscript[ℛ, 1] = SubdivisionRegion[Cube[1]]; Subscript[ℛ, 2] = SubdivisionRegion[Tetrahedron[4]];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

应用  (4)

区域之差：

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};
Wolfram Language code: Multicolumn[Table[RegionDifference[Subscript[ℛ, 1], TransformedRegion[Subscript[ℛ, 2], TranslationTransform[{0, 0, t}]]], {t, 0, 2.5, 0.5}], 3, Appearance -> "Horizontal" ]

将圆环定义为两个圆盘的差集：

Wolfram Language code: annulus = RegionDifference[Disk[{0, 0}, 2], Disk[{0, 0}, 1]];
Wolfram Language code: Region[annulus]

面积是两个圆盘面积之差：

Wolfram Language code: Area[annulus]
Wolfram Language code: Area[Disk[{0, 0}, 2]] - Area[Disk[{0, 0}, 1]]

定义一个球壳，这是圆环在三维空间的推广：

Wolfram Language code: shell = RegionDifference[Ball[{0, 0, 0}, 2], Ball[{0, 0, 0}, 1]];
Wolfram Language code: RegionPlot3D[shell, PlotPoints -> 40, PlotStyle -> Opacity[0.5]]

体积是两个球体体积之差：

Wolfram Language code: Volume[shell]
Wolfram Language code: Volume[Ball[{0, 0, 0}, 2]] - Volume[Ball[{0, 0, 0}, 1]]

生成错觉轮廓：

Wolfram Language code: disks = RegionUnion[Disk[{0, 0}, 2], Disk[{6, 0}, 2], Disk[{3, 5}, 2]];
Wolfram Language code: RegionDifference[disks, Triangle[{{0, 0}, {6, 0}, {3, 5}}]]//Region

属性和关系  (5)

如果点 p 属于 reg1，但不属于 reg2，那么它属于 RegionDifference[reg1,reg2]：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 2]; Subscript[ℛ, 2] = Disk[{0, 3}, 2]; Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

用 RegionMember 来测试其归属：

Wolfram Language code: p = {0, 0};
Wolfram Language code: RegionMember[Subscript[ℛ, 3], p] == RegionMember[Subscript[ℛ, 1], p]∧ !RegionMember[Subscript[ℛ, 2], p]

RegionDifference 是两个区域的布尔组合 ¬#2∧#1：

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]] == BooleanRegion[¬#2∧#1&, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

可用 RegionUnion 和 RegionDifference 来求 RegionSymmetricDifference：

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};
Wolfram Language code: RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]] == RegionUnion[RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]], RegionDifference[Subscript[ℛ, 2], Subscript[ℛ, 1]]]

差的 RegionDimension 最多可以是第一个输入：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = Disk[{1, 0}, 1]; Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];
Wolfram Language code: RegionDimension[Subscript[ℛ, 3]] == RegionDimension[Subscript[ℛ, 1]]

然而它可以是更小的值：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = ImplicitRegion[y > 0∨y < 0, {x, y}]; Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];

这个差集是一条线段，因此维数是 1：:

Wolfram Language code: RegionDimension[Subscript[ℛ, 3]]

如果两个区域不相交，则它们的差的 RegionMeasure 是第一个输入的度量：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = Disk[{3, 0}, 1]; Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];
Wolfram Language code: RegionMeasure[Subscript[ℛ, 3]] == RegionMeasure[Subscript[ℛ, 1]]

如果它们有重叠，则必须减去 RegionIntersection 的度量：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = Disk[{1, 0}, 1]; Subscript[ℛ, 3] = RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]];
Wolfram Language code: RegionMeasure[Subscript[ℛ, 3]] == RegionMeasure[Subscript[ℛ, 1]] - RegionMeasure[RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]]

可能存在的问题  (1)

只有当区域有同样的 RegionEmbeddingDimension 时，它们的差才有定义：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = Ball[{0, 0, 1}, 1];
Wolfram Language code: RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]]

巧妙范例  (1)

两个螺旋多边形之差：

Wolfram Language code: RegionDifference[[image], [image]]
Wolfram Research (2014)，RegionDifference，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RegionDifference.html （更新于 2017 年）.

文本

Wolfram Research (2014)，RegionDifference，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RegionDifference.html （更新于 2017 年）.

CMS

Wolfram 语言. 2014. "RegionDifference." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2017. https://reference.wolfram.com/language/ref/RegionDifference.html.

APA

Wolfram 语言. (2014). RegionDifference. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/RegionDifference.html 年

BibTeX

@misc{reference.wolfram_2026_regiondifference, author="Wolfram Research", title="{RegionDifference}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/RegionDifference.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_regiondifference, organization={Wolfram Research}, title={RegionDifference}, year={2017}, url={https://reference.wolfram.com/language/ref/RegionDifference.html}, note=[Accessed: 01-November-2026]}