WOLFRAM

Wolfram 语言与系统参考资料中心

SolidMechanicsStrain[vars,pars,displ]

得出包含变量 vars、参数 pars 和位移 displ 的固体力学总应变.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
稳态分析  
稳态平面应力分析  
静态平面应变分析  
稳态超弹性平面应力分析  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

SolidMechanicsStrain

SolidMechanicsStrain[vars,pars,displ]

得出包含变量 vars、参数 pars 和位移 displ 的固体力学总应变.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (1)

计算位移造成的应变：

Wolfram Language code: SolidMechanicsStrain[{{u[x, y, z], v[x, y, z], w[x, y, z]}, {x, y, z}}, <||>, {-α y z, α x z, w[x, y]}]

可视化应变：

Wolfram Language code: MatrixForm[%]

范围  (6)

计算位移造成的应变：

Wolfram Language code: vars = {{u[x, y, z], v[x, y, z], w[x, y, z]}, {x, y, z}}; strain = SolidMechanicsStrain[vars, <||>, vars[[1]]]

查看工程应变：

Wolfram Language code: MatrixForm[strain]

计算应变张量：

Wolfram Language code: strainTensor = 1 / 2(Grad@@vars + Transpose[Grad@@vars]); MatrixForm[strainTensor]

验证工程应变与应变张量之间的关系：

Wolfram Language code: strain == {{1, 2, 2}, {2, 1, 2}, {2, 2, 1}} * strainTensor

可以关闭线性弹性状态下工程应变的默认用法：

Wolfram Language code: MatrixForm[SolidMechanicsStrain[vars, <|"EngineeringStrain" -> False|>, vars[[1]]]]

稳态分析  (1)

计算末端固定并在顶部施加力的勺子的挠度. 设置变量和参数：

Wolfram Language code: vars = {{u[x, y, z], v[x, y, z], w[x, y, z]}, {x, y, z}}; pars = <|"Material" -> ["Silver"]|>;

设置 PDE 和几何形状：

Wolfram Language code: spoon = \!\(\*Graphics3DBox[«8»]\); displacement = NDSolveValue[{SolidMechanicsPDEComponent[vars, pars] == SolidBoundaryLoadValue[x >= 1 / 10, vars, pars, <|"Force" -> {0, 0, Quantity[-100, "Newtons"]}|>], SolidFixedCondition[x <= -1 / 10, vars, pars]}, {u, v, w}, {x, y, z}∈spoon];

计算位移造成的应变：

Wolfram Language code: strains = SolidMechanicsStrain[vars, pars, displacement]

可视化 应变：

Wolfram Language code: SliceContourPlot3D[strains[[3, 3]], spoon, {x, y, z}∈spoon, ...]

稳态平面应力分析  (2)

计算底部固定并在其余边施加压力的矩形钢板的位移. 设置区域、变量和参数：

Wolfram Language code: Ω = Rectangle[{0, 0}, {1 / 25, 3 / 100}]; vars = {{u[x, y], v[x, y]}, {x, y}}; pars = <|"SolidMechanicsModelForm" -> "PlaneStress", "YoungModulus" -> 200 * 10 ^ 9, "PoissonRatio" -> 3 / 10, "Thickness" -> 10 ^ -4|>;

求解方程：

Wolfram Language code: displacement = NDSolveValue[{SolidMechanicsPDEComponent[vars, pars] == SolidBoundaryLoadValue[x == 1 / 25, vars, pars, <|"Pressure" -> {0, 2 * 10 ^ 8}|>] + SolidBoundaryLoadValue[y == 3 / 100, vars, pars, <|"Pressure" -> {2 * 10 ^ 8, 0}|>] + SolidBoundaryLoadValue[x == 0, vars, pars, <|"Pressure" -> {0, -2 * 10 ^ 8}|>], SolidFixedCondition[y == 0, vars, pars]}, {u[x, y], v[x, y]}, {x, y}∈Ω]

可视化位移：

Wolfram Language code: VectorDisplacementPlot[displacement, {x, y}∈Ω, Rule[...]]

计算应变：

Wolfram Language code: strain = SolidMechanicsStrain[vars, pars, displacement]

验证 方向上的法向应变大约为 0：

Wolfram Language code: MinMax[strain[[1, 1]][[0]]["ValuesOnGrid"]]

验证 方向上的法向应变大约为 0：

Wolfram Language code: MinMax[strain[[2, 2]][[0]]["ValuesOnGrid"]]

求剪切应变：

Wolfram Language code: MinMax[strain[[1, 2]][[0]]["ValuesOnGrid"]]

作为扩展模型计算平面应力的例子. 这样可以计算平面外应变，并验证平面外应力为 0. 矩形钢板左侧固定，右侧有强制位移. 设置区域、变量和参数. 现在变量包括所有三个方向：

Wolfram Language code: Ω = Rectangle[{0, 0}, {40 * 10 ^ -3, 30 * 10 ^ -3}]; vars = {{u[x, y], v[x, y], w[x, y]}, {x, y, z}}; pars = <|"SolidMechanicsModelForm" -> "ExtendedPlaneStress", "YoungModulus" -> 200 * 10 ^ 9, "PoissonRatio" -> 0.3, "Thickness" -> 10 ^ -4|>;

用三个半自变量求解方程：

Wolfram Language code: displacement = NDSolveValue[{SolidMechanicsPDEComponent[vars, pars] == {0, 0}, SolidDisplacementCondition[x == 0, vars, pars, <|"Displacement" -> {0, 0}|>], SolidDisplacementCondition[x == 40 * 10 ^ -3, vars, pars, <|"Displacement" -> {-40 / 10 ^ 6, 0}|>]}, {u[x, y], v[x, y], w[x, y]}, {x, y}∈Ω]

请注意，现在位移列表中有三个输出变量. 查看主要变量的位移：

Wolfram Language code: VectorDisplacementPlot[displacement[[1 ;; 2]], {x, y}∈Ω, Rule[...]]

计算应变：

Wolfram Language code: strain = SolidMechanicsStrain[vars, pars, displacement]

请注意，应变是一个 3×3 数组. 可视化平面外应变：

Wolfram Language code: ContourPlot[strain[[3, 3]], {x, y}∈Ω, PlotRange -> All, PlotLegends -> Automatic]

根据应变计算应力：

Wolfram Language code: stress = SolidMechanicsStress[vars, pars, strain]

请注意，应力是一个 3×3 的数组. 验证平面应力条件：

Wolfram Language code: stress[[3, 3]]

静态平面应变分析  (1)

作为扩展模型计算平面应变的例子. 这样就可以计算平面外应力，并验证平面外应变为 0. 设置区域、变量和参数. 现在变量包括所有三个方向：

Wolfram Language code: Ω = Rectangle[]; pars = <|"SolidMechanicsModelForm" -> "ExtendedPlaneStrain", "YoungModulus" -> 30 * 10 ^ 3, "PoissonRatio" -> 3 / 10, "Thickness" -> 1|>; vars = {{u[x, y], v[x, y], 0}, {x, y, z}};

设置固体力学 PDE 分量：

Wolfram Language code: op = SolidMechanicsPDEComponent[vars, pars]

设置 PDE：

Wolfram Language code: pde = {op == {0, 0}, SolidFixedCondition[x == 0, vars, pars], SolidDisplacementCondition[x == 1, vars, pars, <|"Displacement" -> {0.1, None}|>]};

求解 PDE：

Wolfram Language code: displacement = NDSolveValue[pde, {u[x, y], v[x, y], 0}, {x, y}∈Ω]

根据位移计算应变：

Wolfram Language code: strain = SolidMechanicsStrain[vars, pars, displacement]

请注意，应变是一个 3×3 数组. 验证平面应变条件：

Wolfram Language code: strain[[3, 3]]

根据应变计算应力：

Wolfram Language code: stress = SolidMechanicsStress[vars, pars, strain]

请注意，应力是一个 3×3 的数组. 将平面外应力可视化：

Wolfram Language code: ContourPlot[stress[[3, 3]], {x, y}∈Ω, PlotRange -> All, PlotLegends -> Automatic]

稳态超弹性平面应力分析  (1)

计算左侧固定并在右侧施加力的矩形橡胶板的位移. 设置区域、变量和参数：

Wolfram Language code: Ω = Rectangle[{0, 0}, {1, 1}]; vars = {{u[x, y], v[x, y]}, {x, y}}; pars = <|"SolidMechanicsMaterialModel" -> "NeoHookeanIsotropic", "LameParameter" -> 10 ^ 6, "ShearModulus" -> 5000, "SolidMechanicsModelForm" -> "PlaneStress", "Thickness" -> 0.01|>;

解方程：

Wolfram Language code: displacement = NDSolveValue[ {SolidMechanicsPDEComponent[vars, pars] == SolidBoundaryLoadValue[x == 1, vars, pars, <|"Force" -> {Quantity[300, "Newtons"], 0}|>], SolidFixedCondition[x == 0, vars, pars]}, {u[x, y], v[x, y]}, {x, y}∈Ω];

可视化位移：

Wolfram Language code: VectorDisplacementPlot[displacement, {x, y}∈Rectangle[{0, 0}, {1, 1}], ...]

计算位移造成的应变：

Wolfram Language code: strains = SolidMechanicsStrain[vars, pars, displacement]

可视化 应变：

Wolfram Language code: ContourPlot[strains[[1, 1]], {x, y}∈Ω, PlotRange -> All]

可能存在的问题  (1)

默认情况下，固体力学框架将工程应变用于线性弹性状态. 可以取消工程应变的使用.

用固体力学 PDE 模型设置辅助函数：

Wolfram Language code: solve[vars_, pars_] := Module[{displacement}, displacement = NDSolveValue[{SolidMechanicsPDEComponent[vars, pars] == {0, 0, 0}, SolidFixedCondition[x == 0, vars, pars], SolidDisplacementCondition[x == 1, vars, pars, <|"Displacement" -> {0.01, None, None}|>]}, vars[[1]], vars[[-1]]∈Cuboid[]];SolidMechanicsStrain[vars, pars, displacement] ]

创建变量和参数：

Wolfram Language code: vars = {{u[x, y, z], v[x, y, z], w[x, y, z]}, {x, y, z}}; pars = <|"Material" -> Entity["Element", "Titanium"]|>;

在使用工程应变的情况下求解固体力学模型：

Wolfram Language code: str1 = solve[vars, pars];

在不使用工程应变的情况下求解固体力学模型：

Wolfram Language code: str2 = solve[vars, Join[<|"EngineeringStrain" -> False|>, pars]];

在特定点上验证 engineering formulation 的剪切应变与正常 strain formulation 的相关系数为 2：

Wolfram Language code: pos = {x -> 0.01, y -> 0.025, z -> 0.19}; engineeringStrain = Normal[str1] /. pos; trueStrain = Normal[str2] /. pos; Chop[({{1, 2, 2}, {2, 1, 2}, {2, 2, 1}} * trueStrain) - engineeringStrain]
Wolfram Research (2021)，SolidMechanicsStrain，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SolidMechanicsStrain.html （更新于 2025 年）.

文本

Wolfram Research (2021)，SolidMechanicsStrain，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SolidMechanicsStrain.html （更新于 2025 年）.

CMS

Wolfram 语言. 2021. "SolidMechanicsStrain." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/SolidMechanicsStrain.html.

APA

Wolfram 语言. (2021). SolidMechanicsStrain. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/SolidMechanicsStrain.html 年

BibTeX

@misc{reference.wolfram_2026_solidmechanicsstrain, author="Wolfram Research", title="{SolidMechanicsStrain}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/SolidMechanicsStrain.html}", note=[Accessed: 09-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_solidmechanicsstrain, organization={Wolfram Research}, title={SolidMechanicsStrain}, year={2025}, url={https://reference.wolfram.com/language/ref/SolidMechanicsStrain.html}, note=[Accessed: 09-November-2026]}