WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Total[list]

list 中の要素の合計を与える．

Total[list,n]

レベル n までのすべての要素を合計する．

Total[list,{n}]

レベル n の要素を合計する．

Total[list,{n1,n2}]

レベル n1からレベル n2までの要素を合計する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Method  
AllowedHeads  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Total

Total[list]

list 中の要素の合計を与える．

Total[list,n]

レベル n までのすべての要素を合計する．

Total[list,{n}]

レベル n の要素を合計する．

Total[list,{n1,n2}]

レベル n1からレベル n2までの要素を合計する．

詳細とオプション

  • Total[list]はApply[Plus,list]と等価である． »
  • Total[list,Infinity]は list 中の任意のレベルのすべての要素を合計する． »
  • 二次元配列あるいは行列については以下の通りである． »
  • Total[list]またはTotal[list,{1}] 各列の合計
    Total[list,{2}] 各行の合計
    Total[list,2] 全要素の全体的な合計
  • デフォルトで，Totalは，List，Association，およびSparseArray，SymmetrizedArray，QuantityArray等の特別な配列表現内の要素だけを合計する．Total[…,AllowedHeads->heads]は他の式内の要素も合計する．次は，heads の可能な設定である．
  • AutomaticList，Association，および特別な配列表現内の要素を合計する
    InheritedHead[expr]内の要素を合計する
    All任意の通常の式内の要素を合計する
    AssociationAssociation内の値を合計する
    Listリスト内の要素を合計する
    hh 内の要素を合計する
    {h1,…}任意の h1,…内の要素を合計する
  • Total[list,Method->"CompensatedSummation"]は補正総和を使って結果の数値誤差を小さくする． »
  • TotalはSparseArrayオブジェクトで使うことができる． »

例題

すべて開く すべて閉じる

例  (1)

リスト中の値の合計を出す：

Wolfram Language code: Total[{a, b, c, d}]

スコープ  (6)

厳密計算で値の合計を出す：

Wolfram Language code: list = {Pi, 1, 4, E, 7, 8};
Wolfram Language code: Total[list]

機械演算を使う：

Wolfram Language code: Total[N[list]]

47桁精度演算を使う：

Wolfram Language code: Total[N[list, 47]]

行列の列の合計を出す：

Wolfram Language code: m = (⁠| | | | | :- | :- | :- | | 1 | 2 | 3 | | 4 | 5 | 6 | | 7 | 8 | 9 |⁠);
Wolfram Language code: Total[m]

行の合計を出す：

Wolfram Language code: Total[m, {2}]

全要素の合計を出す：

Wolfram Language code: Total[m, 2]

最初の次元で部分を足すことで合計する：

Wolfram Language code: t = Array[Subscript[a, ##]&, {2, 3, 4}]
Wolfram Language code: Total[t]

最後の次元のみで合計する：

Wolfram Language code: Total[t, {-1}]

最後の二次元で合計する：

Wolfram Language code: Total[t, {-2, -1}]

最後の次元を除いてすべてを合計する：

Wolfram Language code: Total[t, -2]

全要素を合計する：

Wolfram Language code: Total[t, Infinity]

不調和配列の最後の次元を合計する：

Wolfram Language code: a = {{1, 2, 3}, {4, 5}, {6}};
Wolfram Language code: Total[a, {-1}]

全要素を合計する：

Wolfram Language code: Total[a, Infinity]

リストの長さがまちまちなので，最初の次元の合計は出せない：

Wolfram Language code: Total[a]

疎行列の列の合計を出す：

Wolfram Language code: s = SparseArray[{{i_, i_} -> -2, {i_, j_} /; Abs[i - j] == 1 -> 1}, {10, 10}]
Wolfram Language code: Total[s]
Wolfram Language code: Total[Normal[s]]

行の合計を出す：

Wolfram Language code: Total[s, {2}]

いくつかの疎なベクトルを合計する：

Wolfram Language code: list = Table[SparseArray[{2 ^ i} -> 1, {100}], {i, 6}]
Wolfram Language code: Total[list]

すべてのベクトルのすべての要素を合計する：

Wolfram Language code: Total[list, Infinity]

オプション  (2)

Method  (1)

Method->"CompensatedSummation"を使って総和による累積誤差を減らす：

Wolfram Language code: x = ConstantArray[.1, 10 ^ 6];
Wolfram Language code: Total[x, Method -> "CompensatedSummation"] - 10 ^ 5

補正加算を使わなければ，各項で小さい誤差が累積される可能性がある：

Wolfram Language code: Total[x] - 10 ^ 5

AllowedHeads  (1)

Total[expr,AllowedHeads->Inherited]は任意の頭部に使うことができる：

Wolfram Language code: Total[f[1, 2, 1], AllowedHeads -> Inherited]

導関数次数の合計を求める：

Wolfram Language code: Total[Derivative[1, 2, 1], AllowedHeads -> Inherited]

アプリケーション  (3)

単項式から多項式を形成する：

Wolfram Language code: Total[{x ^ 2, 3x ^ 3, 1}]

行列のトレースはその固有値の合計に等しいことを示す：

Wolfram Language code: m = RandomReal[1, {10, 10}];
Wolfram Language code: Tr[m]
Wolfram Language code: Total[Eigenvalues[m]]

その約数の和に等しい完全数("perfect" numbers)を求める：

Wolfram Language code: perfectQ[x_Integer] := (Total[Divisors[x]] == 2x)
Wolfram Language code: Last[Reap[Do[If[perfectQ[x], Sow[x]], {x, 1, 10000}]]]

特性と関係  (2)

Total[list]はApply[Plus,list]に等しい：

Wolfram Language code: list = RandomInteger[9, {10}]
Wolfram Language code: Total[list]
Wolfram Language code: Apply[Plus, list]

Total[list,k]はTotal[Flatten[list,k-1]]に等しい：

Wolfram Language code: t = Array[Subscript[a, ##]&, {2, 3, 4, 2}]
Wolfram Language code: Table[Total[t, k] === Total[Flatten[t, k - 1]], {k, 1, ArrayDepth[t]}]
Wolfram Research (2003), Total, Wolfram言語関数， https://reference.wolfram.com/language/ref/Total.html （2019年に更新）.

テキスト

Wolfram Research (2003), Total, Wolfram言語関数， https://reference.wolfram.com/language/ref/Total.html （2019年に更新）.

CMS

Wolfram Language. 2003. "Total." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Total.html.

APA

Wolfram Language. (2003). Total. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Total.html

BibTeX

@misc{reference.wolfram_2026_total, author="Wolfram Research", title="{Total}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Total.html}", note=[Accessed: 11-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_total, organization={Wolfram Research}, title={Total}, year={2019}, url={https://reference.wolfram.com/language/ref/Total.html}, note=[Accessed: 11-July-2026]}