TransformColumns[tab,ncolf]
通过转换表格数据 tab 对每一行应用函数 f,添加一个名为 ncol 的新列.
TransformColumns[tab,{ncol1f1,ncol2f2,…}]
通过对每一行依次应用函数 fi 添加多个新列 ncoli.
TransformColumns[transfs]
表示可用于表格数据的 TransformColumns 的运算符形式.
TransformColumns
TransformColumns[tab,ncolf]
通过转换表格数据 tab 对每一行应用函数 f,添加一个名为 ncol 的新列.
TransformColumns[tab,{ncol1f1,ncol2f2,…}]
通过对每一行依次应用函数 fi 添加多个新列 ncoli.
TransformColumns[transfs]
表示可用于表格数据的 TransformColumns 的运算符形式.
更多信息和选项
- TransformColumns 通常用于添加新列或修改现有列,保留其余列.
- 表格数据 tab 的可能形式包括:
-
Tabular[…] 类型一致的表格数据 Dataset[…] 通用的分层数据 TimeSeries[…] 采样时间-值数据对集合 EventSeries[…] 时间事件序列 {assoc1,assoc2,…} 具有相同键的关联列表 matrix 数值矩阵 - 如果列 ncoli 已经存在,则用新创建的列替换它. 否则,在现有列后添加一个新列.
- TransformColumns[tab,{col,ncolf}] 在现有列 col 后添加一个名为 ncol 的新列,而不是直接追加到末尾.
- 对于没有列键的表格数据 atab,TransformColumns[atab,{f1,f2,…,fn}] 通过对各行连续应用函数 fi 追加 n 个匿名新列.
- 函数 fi 应用于输入表格数据 tab 的各个行,如果 tab 有列键,则该行是一个关联 <|col1val1,…|>;如果 tab 没有列键,则该行是一个列表{val1,…}.
- 语法 colNothing 可用于删除名为 col 的现有列. »
- TransformColumns[transfs][tab] 等价于 TransformColumns[tab,transfs].
范例
打开所有单元 关闭所有单元基本范例 (3)
tab = Tabular[{{2, 2.78}, {1, 3.14}, {3, 1.68}}, {"a", "b"}]TransformColumns[tab, "c" -> Function[#b - #a]]TransformColumns[tab, {"a" -> (2#a&), "b" -> (#b / 2&)}]tab = Tabular[{{2004, 4, 1}, {2005, 4, 3}, {2006, 4, 5}}, {"a", "b", "c"}]TransformColumns[tab, "date" -> Function[DateObject[{#a, #b, #c}, "Day"]]]获取中美洲国家的人口和面积,以 Tabular 形式表示:
tab = EntityValue[EntityClass["Country", "CentralAmerica"], {"Population", "Area"}, "Tabular"]TransformColumns[tab, "Density" -> Function[#Population / #Area]]范围 (18)
转换 (7)
转换 Tabular 对象中的现有列:
Tabular[{{1, 2}, {3, 4}}, {"a", "b"}]TransformColumns[%, "a" -> Function[#a ^ 2]]拆分 Tabular 对象中的现有列:
Tabular[{{1, {2004, 1}}, {3, {2005, 3}}, {5, {2006, 2}}}, {"a", "b"}]TransformColumns[%, {"year" -> (First[#b]&), "month" -> (Last[#b]&), "b" -> Nothing}]如果列有名称,则 TransformColumns 与函数 f 将作为关联作用于整行:
Tabular[{<|"c1" -> Subscript[x, 11], "c2" -> Subscript[x, 12]|>, <|"c1" -> Subscript[x, 21], "c2" -> Subscript[x, 22]|>, <|"c1" -> Subscript[x, 31], "c2" -> Subscript[x, 32]|>}]TransformColumns[%, "new" -> f]在具有匿名列的 Tabular 对象上,行表示为列表:
Tabular[{{Subscript[x, 11], Subscript[x, 12]}, {Subscript[x, 21], Subscript[x, 22]}, {Subscript[x, 31], Subscript[x, 32]}}]TransformColumns[%, f]使用 TransformColumns 的运算符形式:
tab = Tabular[{{1, 2}, {3, 4}, {5, 6}}, {"a", "b"}]op = TransformColumns["b" -> Function[#b + 10]];op[tab]使用 "a"Nothing 从结果中删除列 "a":
tab = Tabular[{<|"a" -> 1, "b" -> 2, "c" -> 3, "d" -> 4|>}];
TransformColumns[tab, {"e" -> (50&), "f" -> (60&), "a" -> Nothing}]TransformColumns[tab, {"e" -> (50&), "f" -> (60&), {"a", "c", "d"} -> Nothing}]tab = Tabular[{{1, 2, 3, 5}, {8, 7, 6, 4}}];
TransformColumns[tab, #1[[2]] + #1[[4]]&]使用 Apply 函数时,每列都有一个参数:
TransformColumns[tab, Apply[#2 + #4&]]当键是一般表达式时,在 Tabular 转换的 Function 主体中使用 Key:
tab = ToTabular[{f[x] -> Power[Sin[x] ^ Range[5]]}, "Columns"]TransformColumns[tab, f'[x] -> Function[D[#[Key[f[x]]], x]]]TransformColumns[tab, f'[x] -> Function[D[Slot[Key[f[x]]], x]]]输入数据 (3)
data = {<|"a" -> 1, "b" -> 2|>, <|"a" -> 3, "b" -> 4|>};TransformColumns[data, "a" -> Function[#a ^ 2]]TransformColumns[data, "c" -> Function[#a + #b]]转换 Dataset 对象:
dataset = Dataset[{<|"a" -> 2, "b" -> "foo"|>, <|"a" -> 3, "b" -> "bar"|>}]TransformColumns[dataset, "a" -> Function[#a ^ 2]]MatrixForm[matrix = {{1, "one"}, {2, "two"}, {3, "three"}}]TransformColumns[matrix, Total]TransformColumns[matrix, {f, g}]列操作 (4)
使用 ColumnwiseValue 从列值中减去该列的平均值:
tab = ToTabular[<|"c" -> {3.71, -2.7, -5.29, 9.33, 6.26}|>, "Columns"];
TransformColumns[tab, "c-μ" -> (#c - ColumnwiseValue[Mean[#c]]&)]tab = ToTabular[<|"c" -> {4.24, 1.14, -7.38, 6.74, 6.22, 7.5}|>, "Columns"];TransformColumns[tab, "above median" -> (#c > ColumnwiseValue[Median[#c]]&)]TransformColumns[tab, {"median" -> (ColumnwiseValue[Median[#c]]&), "above median" -> (#c > ColumnwiseValue[Median[#c]]&)}](TransformColumns["median" -> (ColumnwiseValue[Median[#c]]&)] /* TransformColumns["above_median" -> (#c > #median&)])[tab]使用 ColumnwiseThread 对整个列进行向量值变换:
tab = ToTabular[<|"v" -> {2.07, -0.75, 4.16, 7.28, 8.63, 7.93}|>, "Columns"];
TransformColumns[tab, "a" -> (ColumnwiseThread[Accumulate[#v]]&)]使用 ColumnwiseValue,可以获得每行的相同列表:
TransformColumns[tab, "alist" -> (ColumnwiseValue[Accumulate[#v]]&)]取一个 Tabular 对象:
tab = ToTabular[{"old" -> {a, b, c}}, "Columns"]默认情况下,TransformColumns 按顺序对每一行进行操作:
TransformColumns[tab, "new" -> Function[Echo[#old, "row: "] + Echo[RandomInteger[5], " random: "]]]TransformColumns 与 ColumnwiseValue[expr] 合用,首先计算 expr 一次,然后作用于每一行:
TransformColumns[tab, "new" -> Function[Echo[#old, "row: "] + ColumnwiseValue[Echo[Total[#old], "total: "]]]]TransformColumns 与 ColumnwiseThread[expr] 合用,对 expr 计算一次,作用于整个列:
TransformColumns[tab, "new" -> Function[ColumnwiseThread[Echo[#old, "column: "] + Echo[RandomInteger[5], " random: "]]]]列的放置位置 (2)
取一个 Tabular 对象:
tab = Tabular[{<|"a" -> 1, "b" -> 2, "c" -> 3|>, <|"a" -> 10, "b" -> 20, "c" -> 30|>}]默认情况下,TransformColumns 将新列放置在末尾:
TransformColumns[tab, "new" -> Function[#b + #c]]TransformColumns[tab, {"b", "new" -> Function[#b + #c]}]TransformColumns[tab, {"a", "new" -> Function[#b + #c]}]TransformColumns[tab, {"new" -> Function[#b + #c], "a"}]tab = Tabular[{<|"a" -> 1, "b" -> 2, "c" -> 3, "d" -> 4|>}];
TransformColumns[tab, {"e" -> (50&), "f" -> (60&), "a"}]TransformColumns[tab, {"e" -> (50&), "f" -> (60&)}]将 "e" 放在 "a" 之前,将 "f" 放在 "b" 之后:
TransformColumns[tab, {"e" -> (50&), "a", "b", "f" -> (60&)}]将 "e" 放在前面,将 "f" 放在 "b" 之后,并从结果中删除 "a":
TransformColumns[tab, {"e" -> (50&), "a", "b", "f" -> (60&), "a" -> Nothing}]缺少备用选项 (2)
在转换 Tabular 对象时,使用 MissingFallback 中的列函数来填充缺失值:
TransformColumns[tab, "b" -> Function[MissingFallback[#b, #a]]]TransformColumns[tab, "b" -> Function[MissingFallback[#b, #c]]]TransformColumns[tab, "b" -> Function[MissingFallback[#b, -99]]]TransformColumns[tab, "b" -> Function[MissingFallback[#b, -99]]]在转换 Tabular 对象时,用 MissingFallback 中的列函数来填充缺失值:
tab = Tabular[{{1, 3, 5}, {2, Missing[], 6}, {7, 8, 9}}, {"a", "b", "c"}]TransformColumns[tab, "b" -> Function[MissingFallback[#b, #a + #c]]]TransformColumns[tab, "b" -> Function[MissingFallback[#b, Mean[{#a, #c}]]]]应用 (4)
医疗数据 (1)
该数据包含有关肾移植患者在给定年龄进行移植后距死亡的时间(以天计)或在研究时间的信息:
name = {"Statistics", "KidneyTransplant"};
ExampleData[name, "ColumnDescriptions"]Tabular[ExampleData[name], ExampleData[name, "ColumnHeadings"]]使用 TransformColumns 为数值编码数据赋予意义:
transplants = TransformColumns[%, {"Delta" -> (#Delta /. {0 -> "dead", 1 -> "alive"}&), "Gender" -> (#Gender /. {1 -> "male", 2 -> "female"}&), "Race" -> (#Race /. {1 -> "white", 2 -> "black"}&)}]现在,使用这些类别通过 PivotTable 来计算年平均生存时间:
PivotTable[transplants, UnitConvert[Quantity[Mean[#Time], "Days"], "Years"]&, "Race", "Gender", IncludeGroupAggregates -> True]气象数据 (1)
来自肯尼迪(JFK)机场的气象数据(单位:摄氏度、毫巴和公里/小时):
data = Tabular[IconizedObject[«JFK weather»]]data1 = Discard[data, Count[#, _Missing] > 0&]chill[t_, v_] := If[t > 10 || v < 5, t, 13.12 + 0.6215 * t + (0.3965 * t - 11.37) * (v ^ 0.16), Missing[]];创建一个带有新列的 Tabular 对象:
TransformColumns[data1, {"date", "temperature", "wind_chill" -> Function[chill[#temperature, #"wind_speed"]]}]DateListPlot[% -> {{"date", "temperature"}, {"date", "wind_chill"}}, PlotLegends -> {"temperature", "wind_chill"}]米德湖水位 (1)
ts = TemporalData[TimeSeries, {{{Missing[], Quantity[708.7, "Feet"], Quantity[701.7, "Feet"],
Quantity[752.4, "Feet"], Quantity[806.6, "Feet"], Quantity[909.1, "Feet"],
Quantity[928.4, "Feet"], Quantity[925.9, "Feet"], Quantity[920.8, "Feet"], ... fication[DateObject[{1935, 1, 31}, "Day"], {2024, 6, 30, 0, 0, 0},
"EndOfMonth", "DayRange"]}, 1, {"Continuous", 1}, {"Discrete", 1}, 1,
{ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, ValueDimensions -> 1}}, True,
14.2];创建一个 Tabular 对象:
tab1 = ToTabular[ts, "TimeSeries"]使用 TransformColumns 将日期拆分为年份和月份列并删除 "Date" 列:
tab2 = TransformColumns[tab1, {"Year" -> Function[DateValue[#Date, "Year"]], "Month" -> Function[DateValue[#Date, "MonthName"]], "Date" -> Nothing}]使用 PivotToColumns 将数据转换为更紧凑的可视化形式:
tab3 = PivotToColumns[tab2, "Month" -> "Value"]树木数据 (1)
tab = ResourceData["Sample Tabular Data: NYC Trees"]ColumnKeys[tab]使用 TransformColumns 将列 "latitude" 和 "longitude" 合并为一列 GeoPosition 对象,并将其放置在列 "longitude" 之后:
newtab = TransformColumns[tab, {"longitude", "geoposition" -> Function[GeoPosition[{#latitude, #longitude}]]}]ColumnKeys[newtab]使用 "geoposition" 列来绘制前 1000 棵树的位置:
GeoGraphics[Point[Normal[newtab[ ;; 1000, "geoposition"]]]]属性和关系 (3)
TransformColumns 保持所有列不被转换:
tab = Tabular[{{1, 2}, {3, 4}, {5, 6}}, {"a", "b"}]TransformColumns[tab, "b" -> (#b^2&)]ConstructColumns 仅保留列出的列:
ConstructColumns[tab, "b" -> Function[#b ^ 2]]TransformColumns 可用于删除列:
tab = Tabular[{{1, 2}, {3, 4}, {5, 6}}, {"a", "b"}]TransformColumns[tab, "a" -> Nothing]使用 DeleteColumns 是等效的:
DeleteColumns[tab, "a"]取一个以年份和月份为列的 Tabular 对象:
data = {{2024, 10}, {2024, 11}, {2024, 12}};tab = Tabular[data, {"year", "month"}]TransformColumns 可以通过为每一行构建一个日期来添加新列:
TransformColumns[tab, "date" -> DateObject @* Values]TransformColumns[tab, "date" -> (DateObject[{#year, #month}, "Month"]&)]或者,首先构建日期列,然后使用 InsertColumns 将其追加:
InsertColumns[tab, "date" -> Map[DateObject, data]]文本
Wolfram Research (2025),TransformColumns,Wolfram 语言函数,https://reference.wolfram.com/language/ref/TransformColumns.html (更新于 2026 年).
CMS
Wolfram 语言. 2025. "TransformColumns." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2026. https://reference.wolfram.com/language/ref/TransformColumns.html.
APA
Wolfram 语言. (2025). TransformColumns. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/TransformColumns.html 年
BibTeX
@misc{reference.wolfram_2026_transformcolumns, author="Wolfram Research", title="{TransformColumns}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/TransformColumns.html}", note=[Accessed: 16-November-2026]}
BibLaTeX
@online{reference.wolfram_2026_transformcolumns, organization={Wolfram Research}, title={TransformColumns}, year={2026}, url={https://reference.wolfram.com/language/ref/TransformColumns.html}, note=[Accessed: 16-November-2026]}