WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

VideoStream[source]

新たなVideoStreamオブジェクトをソースから作成する．

VideoStream[id]

一意的な動画ストリームを表すオブジェクトである．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
特性  
オプション  
AudioOutputDevice  
ImageSize  
Looping  
RasterSize  
SoundVolume  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

VideoStream

VideoStream[source]

新たなVideoStreamオブジェクトをソースから作成する．

VideoStream[id]

一意的な動画ストリームを表すオブジェクトである．

詳細とオプション

  • VideoStreamは，動画の再生または録画をプログラムで制御するためのVideoオブジェクトまたはデバイスへのハンドルである．
  • source は以下のいずれでもよい．
  • videoVideoオブジェクトからの再生ストリーム
    "camera"$ImagingDevicesのカメラからの録画ストリーム
    {"Screen",n}n 番目の接続スクリーンからの録画ストリーム
    {"Screen",n,bbox}n 番目のスクリーンの領域 bbox からの録画ストリーム
    NotebookObject[…]スクリーンに描画されたノートブックからの録画ストリーム
    "livestream"HTTPまたはHTTPSのライブストリームから生成されたストリーム
  • VideoPlayを使って動画ストリームの再生を開始する．
  • VideoRecordを使ってストリームの録画を開始する．
  • VideoPauseとVideoStopを使って録音の再生を一時停止したり中止したりする．
  • Video[vstream]を使って録画されたストリームからVideoオブジェクトを作る．
  • 次は使用可能なオプションである．
  • AudioOutputDevice Automatic再生に使用する音声出力デバイス
    ImageSize Automatic動画フレームの表示サイズ
    Looping False再生をループにするかどうか
    RasterSize Automatic動画フレームの次元
    SoundVolume Automatic音量
  • vstream["prop"]を使って動画ストリーム vstream の特性が入手できる．
  • vstream["prop"]=val で特性の値が設定できる．
  • 次は，大域的特性である．
  • "Duration"全体的な継続時間
    "ID"ストリームID
    "ImageSize"動画の再生サイズ
    "Location"リンクされた動画ファイルの位置
    "Looping"再生をループにするかどうか
    "Position"時間Quantityとして与えられた再生位置
    "Status"ストリームの状態
    "AudioTrackCount"音声トラック数
    "VideoTrackCount"動画トラック数
    "SubtitleTrackCount"字幕トラック数
  • "Status"の可能な設定値には，"Playing"，"Recording"，"Paused"，"Stopped"がある．
  • 次は，VideoStream[dev]のその他の特性である．
  • "AudioInputDevice"録音に使う音声入力デバイス
    "GeneratedAssetLocation"録音された音声を保存するファイルのパス
    "RecordedVideo"録音のための動画オブジェクト
    "RecordedDuration"録音された動画の継続時間
  • 次は，現行のトラック特性である．
  • "CurrentAudioTrack"現行音声トラックのインデックス
    "CurrentAudio"現行音声の断片
    "CurrentVideoTrack"現行動画トラックのインデックス
    "CurrentFrame"現行動画の1フレーム
    "CurrentSubtitleTrack"現行字幕トラックのインデックス
    "CurrentSubtitle"現行字幕の断片
  • 次は，現行音声トラックの特性である．
  • "AudioOutputDevice"再生に使用する音声出力デバイス
    "AudioChannels"音声チャンネル数
    "SampleRate"音声サンプルレート
    "SoundVolume"音量
    "AudioEncoding"音声コーデック
  • 次は，現行動画トラックの特性である．
  • "FrameChannels"色チャンネルの数
    "FrameRate"動画フレームレート
    "RasterSize"フレームの次元
    "VideoEncoding"動画コーデック
  • 次は，現行字幕トラックの特性である．
  • "SubtitleEncoding"字幕コーデック

例題

すべて開く すべて閉じる

例  (1)

ローカルの動画ファイルにリンクしたVideoStreamオブジェクトを作成する：

Wolfram Language code: stream = VideoStream["ExampleData/Caminandes.mp4"]
Wolfram Language code: Dynamic[stream["CurrentFrame"]]

動画ストリームを再生する：

Wolfram Language code: VideoPlay[stream]

ストリームを一時停止する：

Wolfram Language code: VideoPause[stream]

スコープ  (10)

基本的な用法  (6)

直接ファイルからの動画ストリーム：

Wolfram Language code: stream = VideoStream["ExampleData/Caminandes.mp4"]
Wolfram Language code: Dynamic[stream["CurrentFrame"]]

Videoオブジェクトからの動画ストリーム：

Wolfram Language code: v = Video["ExampleData/Caminandes.mp4"]
Wolfram Language code: stream = VideoStream[v]
Wolfram Language code: stream["Duration"]

URLからのストリーム：

Wolfram Language code: stream = VideoStream["http://exampledata.wolfram.com/agent327.mp4"];
Wolfram Language code: stream["Position"] = 60;
Wolfram Language code: stream["CurrentFrame"]

ライブストリーム動画からのストリーム：

Wolfram Language code: stream = VideoStream[URL[...]]; VideoPlay[stream]
Wolfram Language code: stream["CurrentFrame"]

ライブストリームの継続時間はIndeterminateである：

Wolfram Language code: stream["Duration"]

接続された画像デバイスからの録画ズトリーム：

Wolfram Language code: stream = VideoStream[$DefaultImagingDevice]

ストリームからフレームを録画する：

Wolfram Language code: VideoRecord[stream] Pause[5]; VideoStop[stream];

録音された動画を取り出す：

Wolfram Language code: Video[stream]
Wolfram Language code: Information[%]

スクリーンからストリームを録画する：

Wolfram Language code: stream = VideoStream["Screen"]

ストリームからフレームを録画する：

Wolfram Language code: VideoRecord[stream] Pause[5]; VideoStop[stream];

録画した動画を取り出す：

Wolfram Language code: Video[stream]
Wolfram Language code: Information[%]

特性  (4)

使用可能なストリームの特性をチェックする：

Wolfram Language code: stream = VideoStream["ExampleData/Caminandes.mp4"]; stream["Properties"]

動画ストリームの特性値を得る：

Wolfram Language code: AssociationMap[stream, stream["Properties"]]//Dataset

録音可能なストリームの使用可能な特性をチェックする：

Wolfram Language code: stream = VideoStream[$DefaultImagingDevice]; stream["Properties"]

動画ストリームの特性値を得る：

Wolfram Language code: AssociationMap[stream, stream["Properties"]]//Dataset

"Position"特性を設定する：

Wolfram Language code: stream = VideoStream["ExampleData/Caminandes.mp4"];
Wolfram Language code: stream["Position"] = 30;

現行位置のフレームを抽出する：

Wolfram Language code: stream["CurrentFrame"]

ストリームを再生しながら特性を変更する：

Wolfram Language code: stream = VideoStream["ExampleData/Caminandes.mp4"]
Wolfram Language code: VideoPlay[stream]; Pause[5]; stream["SoundVolume"] = .1; Pause[5]; stream["SoundVolume"] = 1;

オプション  (5)

AudioOutputDevice  (1)

デフォルトで，AudioOutputDeviceは対応するVideoオブジェクトから継承される：

Wolfram Language code: v = Video["ExampleData/rule30.mp4", AudioOutputDevice -> $DefaultAudioOutputDevice]; stream = VideoStream[v];
Wolfram Language code: AudioOutputDevice /. Options[v]
Wolfram Language code: stream["AudioOutputDevice"]

AudioOutputDeviceオブションを使ってVideoStreamを別のデバイスに設定することもできる：

Wolfram Language code: stream = VideoStream[v, AudioOutputDevice -> $AudioOutputDevices[[2]]];
Wolfram Language code: stream["AudioOutputDevice"]

ImageSize  (1)

デフォルトで，画像の次元とウィンドウサイズに基づいてスケールする自動画像サイズが使われる：

Wolfram Language code: str = VideoStream["ExampleData/bullfinch.mkv"]
Wolfram Language code: str["CurrentFrame"]

別の画像サイズを指定する：

Wolfram Language code: str = VideoStream["ExampleData/bullfinch.mkv", ImageSize -> 200]; str["CurrentFrame"]

画像の次元は影響されない点に注意のこと：

Wolfram Language code: ImageDimensions[%]

"ImageSize"特性を変更する：

Wolfram Language code: str["ImageSize"] = 400; str["CurrentFrame"]

Looping  (1)

デフォルトで，動画ストリームはループされない：

Wolfram Language code: str = VideoStream["ExampleData/bullfinch.mkv"]
Wolfram Language code: str["Looping"]

ループストリームを作成する：

Wolfram Language code: str = VideoStream["ExampleData/bullfinch.mkv", Looping -> True]; str["Looping"]

2回ループするストリームを作成する：

Wolfram Language code: str = VideoStream["ExampleData/bullfinch.mkv", Looping -> 2]; str["Looping"]

RasterSize  (1)

デフォルトで，もとのラスタサイズが使われる：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];
Wolfram Language code: Information[v]["VideoTracks"]
Wolfram Language code: str = VideoStream[v]; str["CurrentFrame"]//ImageDimensions

別のラスタサイズを指定する：

Wolfram Language code: str = VideoStream[v, RasterSize -> 320]; str["CurrentFrame"]//ImageDimensions

縦と横の両方を指定する：

Wolfram Language code: str = VideoStream[v, RasterSize -> {320, 100}]; str["CurrentFrame"]//ImageDimensions

SoundVolume  (1)

デフォルトで，SoundVolumeは対応するVideoオブジェクトから継承される：

Wolfram Language code: v = Video["ExampleData/rule30.mp4", SoundVolume -> .5]; stream = VideoStream[v];
Wolfram Language code: SoundVolume /. Options[v]
Wolfram Language code: stream["SoundVolume"]

SoundVolumeオプションを使ってVideoStreamを異なる音量に設定することもできる：

Wolfram Language code: stream = VideoStream[v, SoundVolume -> .1];
Wolfram Language code: stream["SoundVolume"]

アプリケーション  (3)

簡単な動画GUIを作成する：

Wolfram Language code: stream = VideoStream["ExampleData/bullfinch.mkv"]
Wolfram Language code: Panel@Column[{ Dynamic[stream["CurrentFrame"]], Slider[Dynamic[QuantityMagnitude[stream["Position"], "Seconds"], (stream["Position"] = #)&], {0, QuantityMagnitude[stream["Duration"], "Seconds"]}], Button[ Dynamic[If[stream["Status"] === "Playing", "Pause", "Play"]], If[stream["Status"] === "Playing", VideoPause[stream], VideoPlay[stream]] ] }, Alignment -> Center]

ニューラルネットワークに基づいた関数をリアルタイムで現行フレームに適用する：

Wolfram Language code: stream = VideoStream["ExampleData/bullfinch.mkv"]

ImageCasesの結果を動的にハイライトする：

Wolfram Language code: VideoPlay[stream];HighlightImage[stream["CurrentFrame"], ImageCases[stream["CurrentFrame"], All -> "BoundingBox"]]//Dynamic
Wolfram Language code: VideoPause[]

画像処理関数を現行フレームに動的に適用する：

Wolfram Language code: stream = VideoStream["ExampleData/bullfinch.mkv"]

ImageSaliencyFilterの結果を計算する：

Wolfram Language code: VideoPlay[stream];Dynamic@ImageSaliencyFilter[stream["CurrentFrame"]]
Wolfram Language code: VideoPause[]

特性と関係  (1)

VideoPlayを使って動画ストリームを作成し，これの再生を開始する：

Wolfram Language code: v = Import["ExampleData/Caminandes.mp4"]; stream = VideoPlay[v]
Wolfram Language code: Dynamic[Quiet@stream["CurrentFrame"] /. Except[_Image] -> None]

VideoPauseを使って再生を一時停止する：

Wolfram Language code: VideoPause[stream];

VideoStopを使って再生を中止して再設定する：

Wolfram Language code: VideoStop[stream];

VideoStreamsを使ってシステム中のすべての動画ストリームをリストにする：

Wolfram Language code: VideoStreams[]

RemoveVideoStreamを使ってストリームと関連するリソースを削除する：

Wolfram Language code: RemoveVideoStream[stream];
Wolfram Research (2020), VideoStream, Wolfram言語関数， https://reference.wolfram.com/language/ref/VideoStream.html （2021年に更新）.

テキスト

Wolfram Research (2020), VideoStream, Wolfram言語関数， https://reference.wolfram.com/language/ref/VideoStream.html （2021年に更新）.

CMS

Wolfram Language. 2020. "VideoStream." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/VideoStream.html.

APA

Wolfram Language. (2020). VideoStream. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/VideoStream.html

BibTeX

@misc{reference.wolfram_2026_videostream, author="Wolfram Research", title="{VideoStream}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/VideoStream.html}", note=[Accessed: 02-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_videostream, organization={Wolfram Research}, title={VideoStream}, year={2021}, url={https://reference.wolfram.com/language/ref/VideoStream.html}, note=[Accessed: 02-November-2026]}