WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

WatsonUSquareTest[data]

Watsonの 検定を使い，data が正規分布に従っているかどうかを調べる．

WatsonUSquareTest[data,dist]

Watsonの 検定を使い，data が dist に従った分布かどうかを調べる．

WatsonUSquareTest[data,dist,"property"]

"property"の値を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
検定  
レポート  
オプション  
Method  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

WatsonUSquareTest

WatsonUSquareTest[data]

Watsonの 検定を使い，data が正規分布に従っているかどうかを調べる．

WatsonUSquareTest[data,dist]

Watsonの 検定を使い，data が dist に従った分布かどうかを調べる．

WatsonUSquareTest[data,dist,"property"]

"property"の値を返す．

詳細とオプション

  • WatsonUSquareTestは data が分布 dist に従う母集団から引き出されたという帰無仮説 とそうではないという対立仮説 でWatsonの適合度検定を行う．
  • デフォルトで，確率値つまり 値が返される．
  • 小さい 値は data が dist から来ている可能性が低いことを示す．
  • dist は，記号および数値の母数，またはデータ集合，を持つ任意の記号分布でよい．
  • data は一変量{x1,x2,…}でも多変量{{x1,y1,…},{x2,y2,…},…}でもよい．
  • Watsonの検定はデータが連続分布のものであると仮定する．
  • Watsonの 検定は，事実上 に基づく検定統計を使う．ただし，および で，は data の経験的累積分布関数⶧は dist の累積分布関数である．
  • 多変量検定では，一変量限界 値の総和が使われる．総和は のもとでUniformSumDistributionに従うものと想定される．
  • WatsonUSquareTest[data,dist,"HypothesisTestData"]はHypothesisTestDataオブジェクト htd を返す．これは htd["property"]として追加的な検定結果と特性の抽出に使うことができる．
  • WatsonUSquareTest[data,dist,"property"]を使って直接"property"の値を与えることができる．
  • 検定結果のレポートに関連する特性
  • "PValue" 値
    "PValueTable""PValue"のフォーマットされたバージョン
    "ShortTestConclusion"検定結果の簡単な説明
    "TestConclusion"検定結果の説明
    "TestData"検定統計と 値
    "TestDataTable""TestData"のフォーマットされたバージョン
    "TestStatistic"検定統計
    "TestStatisticTable""TestStatistic"のフォーマットされたバージョン
  • 次の特性はどの検定が行われているかに依存しない．
  • データ分布に関連する特性
  • "FittedDistribution"データのフィットした分布
    "FittedDistributionParameters"データの分布母数
  • 使用可能なオプション
  • Method Automatic 値を計算するメソッド
    SignificanceLevel0.05診断とレポートのための切捨て
  • 適合度検定では， のときにのみ が棄却されるような切捨て が選択される．特性"TestConclusion"および"ShortTestConclusion"で使われる の値はSignificanceLevelオプションで制御される．デフォルトで， は0.05に設定されている．
  • Method->"MonteCarlo"の設定では，入力 と同じ長さの 個のデータ集合がフィットされた分布を使って のもとで生成される．次に，WatsonUSquareTest[si,dist,"TestStatistic"]からのEmpiricalDistributionを使って 値が推定される．

例題

すべて開く すべて閉じる

例  (4)

正規性についてWatsonの 検定を行う：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10^4];
Wolfram Language code: WatsonUSquareTest[data]

あるデータが特定の分布にフィットするかどうかの検定を行う：

Wolfram Language code: data = RandomVariate[LaplaceDistribution[1, 2], 10^3];
Wolfram Language code: WatsonUSquareTest[data, LaplaceDistribution[1, 2]]

2つのデータ集合の分布を比較する：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: data2 = RandomVariate[NormalDistribution[], 150];
Wolfram Language code: WatsonUSquareTest[data1, data2]

Watsonの 検定から検定統計を抽出する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10^3];
Wolfram Language code: WatsonUSquareTest[data, NormalDistribution[], "TestStatistic"]

スコープ  (9)

検定  (6)

正規性についてWatsonの 検定を行う：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 10^4]; data2 = RandomVariate[StudentTDistribution[3], 10^4];

正規データの 値は，非正規データの 値と比べて大きい：

Wolfram Language code: WatsonUSquareTest[data1]
Wolfram Language code: WatsonUSquareTest[data2]

特定の分布に対して適合度検定を行う：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 10^3]; data2 = RandomVariate[CauchyDistribution[0, 1], 10^3];
Wolfram Language code: WatsonUSquareTest[data1, CauchyDistribution[0, 1]]
Wolfram Language code: WatsonUSquareTest[data2, CauchyDistribution[0, 1]]

2つのデータ集合の分布を比べる：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 10^3]; data2 = RandomVariate[NormalDistribution[], 10^3];
Wolfram Language code: WatsonUSquareTest[data1, data2]

2つのデータ集合は同じ分布に従わない：

Wolfram Language code: data3 = RandomVariate[NormalDistribution[0, 1.25], 10^3];
Wolfram Language code: WatsonUSquareTest[data1, data3]

多変量正規性について検定する：

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[.5], 10^3]; data2 = RandomVariate[LaplaceDistribution[1, 2], {10^3, 2}];
Wolfram Language code: WatsonUSquareTest[data1]
Wolfram Language code: WatsonUSquareTest[data2]

任意多変量分布について適合度検定を行う：

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[.5], 10^3]; data2 = RandomVariate[𝒹 = LaplaceDistribution[1, 2], {10^3, 2}];
Wolfram Language code: 𝒟 = ProductDistribution[𝒹, 𝒹];
Wolfram Language code: WatsonUSquareTest[data1, 𝒟]
Wolfram Language code: WatsonUSquareTest[data2, 𝒟]

繰り返し特性を抽出するためにHypothesisTestDataオブジェクトを作成する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10^5];
Wolfram Language code: ℋ = WatsonUSquareTest[data, Automatic, "HypothesisTestData"]

抽出に使用できる特性：

Wolfram Language code: ℋ["Properties"]

レポート  (3)

Watsonの 検定の結果を表にする：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: ℋ = WatsonUSquareTest[data, Automatic, "HypothesisTestData"];

完全な検定表：

Wolfram Language code: ℋ["TestDataTable"]

値の表：

Wolfram Language code: ℋ["PValueTable"]

検定統計：

Wolfram Language code: ℋ["TestStatisticTable"]

カスタマイズされたレポート用にWatsonの 検定表から項目を取り出す：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 100]; data2 = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: ℋ1 = WatsonUSquareTest[data1, Automatic, "TestData"]
Wolfram Language code: ℋ2 = WatsonUSquareTest[data2, Automatic, "TestData"]
Wolfram Language code: BarChart[{Labeled[ℋ1, "Set 1"], Labeled[ℋ2, "Set 2"]}, ChartLabels -> {"SubscriptBox[D, n]", "p‐value"}]

"ShortTestConclusion"と"TestConclusion"を使って検定の結論をレポートする：

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[ParetoDistribution[1.05, 2], 100]];
Wolfram Language code: ℋ = WatsonUSquareTest[data, ParetoDistribution[1, 2], "HypothesisTestData"];
Wolfram Language code: ℋ["ShortTestConclusion"]
Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

有意水準が異なると，結論も異なることがある：

Wolfram Language code: ℋ = WatsonUSquareTest[data, ParetoDistribution[1, 2], "HypothesisTestData", SignificanceLevel -> .001];
Wolfram Language code: ℋ["ShortTestConclusion"]
Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

オプション  (3)

Method  (3)

計算式にモンテカルロ法に基づくメソッドを使う：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: WatsonUSquareTest[data, NormalDistribution[], Method -> "MonteCarlo"]
Wolfram Language code: WatsonUSquareTest[data, NormalDistribution[], Method -> Automatic]

モンテカルロ法に基づくメソッドで使うサンプル数を設定する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: pts = Table[{i, WatsonUSquareTest[data, NormalDistribution[], Method -> {"MonteCarlo", "MonteCarloSamples" -> i}]}, {i, Range[5, 100, 5]}];

モンテカルロ推定は，サンプルを増やすと，真の 値に収束する：

Wolfram Language code: pval = WatsonUSquareTest[data, NormalDistribution[]];
Wolfram Language code: Show[ListLinePlot[pts, PlotRange -> {0, 1}, FrameLabel -> {"Samples", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}], Graphics[{Dashed, Line[{{0, pval}, {100, pval}}]}]]

モンテカルロ法に基づくメソッドで使われるランダムなシードを設定する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: pts = Table[{i, WatsonUSquareTest[data, NormalDistribution[], Method -> {"MonteCarlo", "RandomSeed" -> i, "MonteCarloSamples" -> 50}]}, {i, Range[1, 10]}];

シードは生成器の状態に影響を与え，結果の 値にもいくらか影響を与える：

Wolfram Language code: pval = WatsonUSquareTest[data, NormalDistribution[]];
Wolfram Language code: Show[ListLinePlot[pts, PlotRange -> {Min[pts[[All, 2]]], Max[pts[[All, 2]]]}, FrameLabel -> {"Seed", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}], Graphics[{Dashed, Line[{{0, pval}, {100, pval}}]}]]

アプリケーション  (2)

Watsonの 検定の検出力曲線：

Wolfram Language code: data = Table[RandomVariate[UniformDistribution[{-4, 4}], {500, i}], {i, n = {5, 7, 10, 15, 20, 25, 30}}];
Wolfram Language code: ℋ = Table[WatsonUSquareTest[data[[i, j]], NormalDistribution[]], {i, Length[data]}, {j, Length[data[[i]]]}];
Wolfram Language code: pC = Interpolation[Transpose[{n, Table[Probability[x ≤ 0.05, xi], {i, ℋ}]}], InterpolationOrder -> 1];

近似検出力曲線を可視化する：

Wolfram Language code: Plot[pC[x], {x, 5, 30}, PlotRange -> {0, 1}, Ticks -> {n, Automatic}, AxesOrigin -> {0, 0}]

基礎となる分布がUniformDistribution[{-4,4}]であり，検定サイズが0.05，サンプルサイズが12である場合に，Watsonの 検定の検出力を推定する：

Wolfram Language code: pC[12.]

統計の授業でボードゲームのスピナーのバイアスについて検定を行うことになった．クラスの50人の学生それぞれがスピナーを1度回す．スピンごとにデバイスを使って回転の角度をラジアンで記録した：

Wolfram Language code: data = {25.1, 28.51, 15.58, 7.98, 7.87, 28.9, 28.72, 10.64, 27.33, 23.86, 6.49, 11.02, 8.66, 28.84, 31.14, 24.05, 15.92, 12.66, 20.31, 17.06, 17.45, 21.94, 9.8, 7.26, 11.44, 23.78, 18.83, 13.17, 23.12, 18.06, 21.79, 26.57, 22.11, 21.12, 13.24, 24.26, 18.48, 28.63, 20.51, 8.21, 21.82, 17.09, 30.67, 14.99, 28.42, 21.64, 16.75, 8.06, 9.5, 30.55};
Wolfram Language code: ListPlot[Table[{Cos[x], Sin[x]}, {x, data}], AspectRatio -> 1]

各測定値をにおける値に変換する：

Wolfram Language code: conv[d_] := With[{r = d / 2π}, 2π(r - IntegerPart[r])]
Wolfram Language code: cData = conv /@ data;

円上の一様性を検定すると，スピナーのバイアスがないことが分かる：

Wolfram Language code: WatsonUSquareTest[cData, UniformDistribution[{0, 2π}], "TestDataTable"]

特性と関係  (8)

デフォルトで一変量データはNormalDistributionと比べられる：

Wolfram Language code: data = RandomVariate[NormalDistribution[2, 3], 10^4];
Wolfram Language code: ℋ = WatsonUSquareTest[data, Automatic, "HypothesisTestData"];
Wolfram Language code: ℋ["TestDataTable"]

母数はデータから推定されている：

Wolfram Language code: ℋ["FittedDistribution"]

多変量データは，デフォルトでMultinormalDistributionと比べられる：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{1, 2, 3}, IdentityMatrix[3]], 1000];
Wolfram Language code: ℋ = WatsonUSquareTest[data, Automatic, "HypothesisTestData"];
Wolfram Language code: ℋ["TestDataTable"]
Wolfram Language code: ℋ["FittedDistribution"]//TraditionalForm

検定分布の母数は，指定されない場合にはデータから推測される：

Wolfram Language code: data = RandomVariate[NormalDistribution[1, 2], 1000];
Wolfram Language code: WatsonUSquareTest[data, NormalDistribution[μ, σ], "FittedDistribution"]

指定された母数は推測されない：

Wolfram Language code: WatsonUSquareTest[data, NormalDistribution[μ, 2], "FittedDistribution"]
Wolfram Language code: WatsonUSquareTest[data, NormalDistribution[1, 2], "FittedDistribution"]

最尤推定値は，検定分布の指定されていない母数に使われる：

Wolfram Language code: data = RandomVariate[ExponentialDistribution[3], 10^3];
Wolfram Language code: ℋ = WatsonUSquareTest[data, ExponentialDistribution[λ], "FittedDistribution"]
Wolfram Language code: WatsonUSquareTest[data, ExponentialDistribution[λ]]

母数が未知の場合，WatsonUSquareTestは可能であれば修正を適用する：

Wolfram Language code: data = RandomVariate[NormalDistribution[3, 4], 10^4];
Wolfram Language code: est = EstimatedDistribution[data, NormalDistribution[μ, σ]]

母数は推定されるが，修正は適用されない：

Wolfram Language code: WatsonUSquareTest[data, est]
Wolfram Language code: ℋ = WatsonUSquareTest[data, NormalDistribution[μ, σ], "HypothesisTestData"];

フィットされた分布は前と同じであり， 値は修正される：

Wolfram Language code: ℋ["FittedDistribution"]
Wolfram Language code: ℋ["PValue"]

独立周辺密度が多変量の適合度検定では仮定される：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{0, 0}, {{0.118, 0.252}, {0.252, 0.665}}], 100];
Wolfram Language code: WatsonUSquareTest[data, MultinormalDistribution[{0, 0}, {{0.118, 0.252}, {0.252, 0.665}}], "TestStatistic"]

独立性が仮定されると，検定統計は同一である：

Wolfram Language code: WatsonUSquareTest[data, MultinormalDistribution[{0, 0}, {{0.118, 0}, {0, 0.665}}], "TestStatistic"]

Watson 検定統計はNExpectationを使って定義することができる：

Wolfram Language code: n = 10; h0 = NormalDistribution[1, 2]; data = RandomVariate[h0, n];
Wolfram Language code: f[x_] := CDF[h0, x] Overscript[f, ^ ][x_] := CDF[EmpiricalDistribution[data], x]
Wolfram Language code: d[x_] := Overscript[f, ^ ][x] - f[x] Overscript[d, _] = NExpectation[d[x], xh0];
Wolfram Language code: n NExpectation[(d[x] - Overscript[d, _]) ^ 2, xh0]
Wolfram Language code: WatsonUSquareTest[data, h0, "TestStatistic"]

Watsonの 検定は，入力がTimeSeriesのときにのみ値に使うことができる：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{1.224578634529677, 0.47929635789978015, 0.6572781300178168, 0.21496048742669355, 0.7299608014554928, -0.2495111111278263, -1.3286551762002712, 0.552725018274874, 0.19272112205837066, 1.1809144012420882, -1.1671 ... 40938613662046, 1.052394590214582, 0.9345044123980388, 0.38537803109557855, -0.48660931166089394, -0.71203560340161}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: WatsonUSquareTest[ts]
Wolfram Language code: WatsonUSquareTest[ts["Values"]]

考えられる問題  (3)

Watsonの 検定は，離散分布には使えない：

Wolfram Language code: data = RandomVariate[DiscreteUniformDistribution[{-10, 10}], 35];
Wolfram Language code: WatsonUSquareTest[data, DiscreteUniformDistribution[{-10, 10}]]

一般に連続性の訂正は検定サイズの保全の点からするとうまくいく：

Wolfram Language code: sim = RandomVariate[DiscreteUniformDistribution[{-10, 10}], {500, 35}];
Wolfram Language code: p = Quiet[WatsonUSquareTest[#, DiscreteUniformDistribution[{-10, 10}]]]& /@ sim;
Wolfram Language code: Show[ListLinePlot[Table[{α, Probability[pv ≤ α, pvp]}, {α, .01, 1, .01}]], Plot[x, {x, 0, 1}, PlotStyle -> Dashed]]

しかし場合によってはこれが当て嵌まらないこともある：

Wolfram Language code: sim = RandomVariate[DiscreteUniformDistribution[{1, 3}], {500, 35}];
Wolfram Language code: p = Quiet[WatsonUSquareTest[#, DiscreteUniformDistribution[{1, 3}]]]& /@ sim;
Wolfram Language code: Show[ListLinePlot[Table[{α, Probability[pv ≤ α, pvp]}, {α, .01, 1, .01}]], Plot[x, {x, 0, 1}, PlotStyle -> Dashed]]

そのような場合にはモンテカルロ法またはPearsonChiSquareTestを使う：

Wolfram Language code: WatsonUSquareTest[sim[[1]], DiscreteUniformDistribution[{1, 3}], Method -> "MonteCarlo"]
Wolfram Language code: PearsonChiSquareTest[sim[[1]], DiscreteUniformDistribution[{1, 3}]]

母数がデータから推定される場合には，Watsonの 検定は，分布によっては有効ではないことがある：

Wolfram Language code: data = RandomVariate[BetaDistribution[1, 2], 100];
Wolfram Language code: WatsonUSquareTest[data, BetaDistribution[1, b]]

母数の値が既知である場合には与える：

Wolfram Language code: WatsonUSquareTest[data, BetaDistribution[1, 2]]

あるいは，モンテカルロ法を使って 値を近似する：

Wolfram Language code: WatsonUSquareTest[data, BetaDistribution[1, b], Method -> "MonteCarlo"]

データのタイは無視される：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 1000];
Wolfram Language code: WatsonUSquareTest[Join[data, {First[data]}]]
Wolfram Language code: PearsonChiSquareTest[Join[data, {First[data]}]]

差分はタイの数が大きくなると，より明らかであることもある：

Wolfram Language code: WatsonUSquareTest[Join[data, data]]
Wolfram Language code: PearsonChiSquareTest[Join[data, data]]

おもしろい例題  (1)

帰無仮説 が真であるときの統計量を計算する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {500, 100}];
Wolfram Language code: T1 = WatsonUSquareTest[#, NormalDistribution[], "TestStatistic"]& /@ data;

特定の対立仮説による検定統計：

Wolfram Language code: T2 = WatsonUSquareTest[#, LaplaceDistribution[1, 2], "TestStatistic"]& /@ data;

検定統計の分布を比較する：

Wolfram Language code: SmoothHistogram[{T1, T2}, Filling -> Axis, PlotLegends -> {"SubscriptBox[H, 0]は真", "SubscriptBox[H, 0]は偽"}, PlotRange -> All]
Wolfram Research (2010), WatsonUSquareTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/WatsonUSquareTest.html.

テキスト

Wolfram Research (2010), WatsonUSquareTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/WatsonUSquareTest.html.

CMS

Wolfram Language. 2010. "WatsonUSquareTest." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/WatsonUSquareTest.html.

APA

Wolfram Language. (2010). WatsonUSquareTest. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/WatsonUSquareTest.html

BibTeX

@misc{reference.wolfram_2026_watsonusquaretest, author="Wolfram Research", title="{WatsonUSquareTest}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/WatsonUSquareTest.html}", note=[Accessed: 09-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_watsonusquaretest, organization={Wolfram Research}, title={WatsonUSquareTest}, year={2010}, url={https://reference.wolfram.com/language/ref/WatsonUSquareTest.html}, note=[Accessed: 09-November-2026]}