WOLFRAM

Wolfram 语言与系统参考资料中心

WindSpeedData[]

给出靠近当前位置的风速的最新测量值.

WindSpeedData[datespec]

给出靠近当前位置的指定时间的风速值.

WindSpeedData[locationspec]

给出靠近指定位置的风速的最新测量值.

WindSpeedData[locationspec,datespec]

给出指定日期和地点的值.

WindSpeedData[{{location1,date1},{location2,date2},…}]

给出指定日期的所有指定地点的值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
位置规范  
气象站属性  
日期规范  
位置列表  
格式规范  
关联规范  
选项  
UnitSystem  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

WindSpeedData

WindSpeedData[]

给出靠近当前位置的风速的最新测量值.

WindSpeedData[datespec]

给出靠近当前位置的指定时间的风速值.

WindSpeedData[locationspec]

给出靠近指定位置的风速的最新测量值.

WindSpeedData[locationspec,datespec]

给出指定日期和地点的值.

WindSpeedData[{{location1,date1},{location2,date2},…}]

给出指定日期的所有指定地点的值.

更多信息和选项

  • WindSpeedData 给出全世界标准气象站当前和历史的风速数据.
  • WindSpeedData[] 使用 $GeoLocation 和 $TimeZone 来确定你的位置和时区. 返回离由 $GeoLocation 指定的位置最近的具有高可靠度的气象站的最新测量值.
  • 位置可以被指定为 ICAO 代码如："KNYC"，或 WMO 代码如："WMO12345"，业余气象站代码如： "C1234"，或其他标准气象站识别符.
  • 位置可以由纬度/经度对指定，假设度为单位，一个 GeoPosition 规范或 Entity 对象，假设它们代表具有地理坐标的对象. 它们也可以是 GeoGraphics 基元，例如 GeoDisk 或用在 CityData 类型中的城市规范. WindSpeedData 给出最靠近位置的高度可靠气象站的结果.
  • locationspec 可以是单个位置或位置列表.
  • datespec 可以 DateString 格式或一个 DateObject 形式指定为一个日期列表、一个字符串.
  • 默认情况下，WindSpeedData[locationspec,datespec] 认定 datespec 是按当地时间给定的，并在输出中使用 UTC 时间.
  • 当给定特定时间，会返回该时间的内插结果. 一天或更长时间的 datespec 规范返回风速测量的区间.
  • datespec 可被指定为 {start,end,step} 以便与 DateRange 规范相兼容. step 可以是 All、"Day"、"Week"、"Month" 或 "Year". All 给出所有观察记录. 如果省略，step 被假设为具有值 All.
  • 位置和日期也可以通过 Association["Location"->locationspec,"Date"datespec] 一起指定.
  • 当位置被指定时，WindSpeedData[locationspec,datespec,func] 被用于指定输出的格式.
  • func 可能的设置包括：
  • All返回延伸位置和时间的所有值
    Automatic返回延伸位置和不确定时间的区间
    Interval返回延伸位置和时间的区间
    Max返回延伸位置和时间的最大值
    Mean返回延伸位置和时间的均值
    Min返回延伸位置和时间的最小值
    StandardDeviation返回延伸位置和时间的标准偏差
    "Stations"返回所有值连同它们的源气象站
  • 风速以 Quantity 返回，可以是千米每小时或者英里每小时.
  • 选项 UnitSystem 控制输出单位. 由 $UnitSystem 设置缺省值. 可以使用下列设置：
  • "Imperial"以英制单位返回结果
    "Metric"以公制单位返回结果
  • WindSpeedData[locationspec,"property"] 返回对应于 locationspec 位置的指定气象站的属性.
  • 识别气象站的相关属性包括：
  • "Coordinates"作为 GeoPosition 的气象站坐标
    "Memberships"WMO、NCDC 和 CWOP 报告网络隶属关系
    "NearestStation"最近的气象站
    "StationDistance"指定位置与给定气象站之间的距离（km）
    "StationName"气象站名称
  • WindSpeedData 可以检索来自世界各地气象站观测的空气温度数据.

范例

打开所有单元 关闭所有单元

基本范例  (1)

找到靠近你当前位置的最新的风速测量值：

Wolfram Language code: WindSpeedData[]

风速可以千米每小时或英里每小时返回：

Wolfram Language code: WindSpeedData[UnitSystem -> "Imperial"]

获取指定气象站的风速读数：

Wolfram Language code: WindSpeedData["KMCI"]

求靠近指定位置在指定日期的插值风速：

Wolfram Language code: WindSpeedData["KSAC", DateObject[{2012, 1, 2}, TimeObject[{13, 0, 0}]]]

范围  (19)

位置规范  (6)

来自于 "KBOS" 近似坐标处高度可靠气象站的当前风速测量值：

Wolfram Language code: WindSpeedData["KBOS"]

坐标可以作为一个位置：

Wolfram Language code: WindSpeedData[{40.67, -73.94}]
Wolfram Language code: WindSpeedData[GeoPosition[{40.67, -73.94}]]

可使用 Entity 对象：

Wolfram Language code: WindSpeedData[Entity["Building", "SearsTower"]]

使用自由格式输入（）获取合适的 Entity：

Wolfram Language code: WindSpeedData[Entity["Building", "SearsTower"]]

探索离伦敦东部180度圆弧中风速读数的范围：

Wolfram Language code: WindSpeedData[GeoDisk[EntityValue[Entity["City", {"Paris", "IleDeFrance", "France"}], "Coordinates"], Quantity[100, "Miles"], {0, 180}]]

求跨越地理区域的风速的测量范围：

Wolfram Language code: WindSpeedData[Polygon[Entity["Country", "Germany"]]]

使用 "StationName" 属性，根据坐标或城市名返回气象站名称：

Wolfram Language code: WindSpeedData[{42.3, -71.0}, "StationName"]

气象站属性  (3)

找到使用的气象站名称和坐标：

Wolfram Language code: WindSpeedData["StationName"]
Wolfram Language code: WindSpeedData["Coordinates"]

探索指定位置与使用的气象站的相对距离：

Wolfram Language code: WindSpeedData[{40.67, -73.94}, "StationDistance"]

了解气象站的高度：

Wolfram Language code: WindSpeedData["KCMI", "Elevation"]

日期规范  (3)

使用 DateObject 输入日期：

Wolfram Language code: WindSpeedData["KSAC", DateObject[{2012, 1, 2}, TimeObject[{13, 0, 0}]]]

日期也可以用 DateList 格式指定：

Wolfram Language code: WindSpeedData["KSAC", {2012, 1, 2, 13, 0, 0}]

以 {start,end} 为格式的日期范围会返回所有在该范围内的数据：

Wolfram Language code: data = WindSpeedData["KMCI", {DateObject[{2012, 1, 1}], DateObject[{2012, 1, 2}]}]
Wolfram Language code: DateListPlot[data]

对于长于1个小时的时间段，日期规范会返回此时间段风速的 Interval：

Wolfram Language code: WindSpeedData["KSAC", DateObject[{2012, 1, 1}]]

位置列表  (3)

可以提供位置列表：

Wolfram Language code: WindSpeedData[{"KSAC", Entity["Building", "EmpireStateBuilding"], {40.11, -88.24}}]

搜索在指定时间，多个位置的插值风速：

Wolfram Language code: WindSpeedData[{"KSAC", Entity["Building", "EmpireStateBuilding"], {40.11, -88.24}}, DateObject[{2012, 6, 17}, TimeObject[{17}]]]

求多个位置和日期的风速插值：

Wolfram Language code: WindSpeedData[{{"KCMI", DateObject[{2008, 8, 4}, TimeObject[{12}]]}, {"KSAC", DateObject[{2008, 8, 4}, TimeObject[{12}]]}, {"KISP", DateObject[{2012, 6, 6}, TimeObject[{13}]]}}]

格式规范  (2)

求延伸位置的风速：

Wolfram Language code: WindSpeedData[GeoDisk[{40, -90}, Quantity[25, "Miles"]], DateObject[{2011, 9, 4}, TimeObject[{12}]]]

获取最大或最小压强：

Wolfram Language code: WindSpeedData[GeoDisk[{40, -90}, Quantity[25, "Miles"]], DateObject[{2011, 9, 4}, TimeObject[{12}]], Max]
Wolfram Language code: WindSpeedData[GeoDisk[{40, -90}, Quantity[25, "Miles"]], DateObject[{2011, 9, 4}, TimeObject[{12}]], Min]

使用设置 Mean 获取平均风速：

Wolfram Language code: WindSpeedData[GeoDisk[{40, -90}, Quantity[25, "Miles"]], DateObject[{2011, 9, 4}, TimeObject[{12}]], Mean]

对所有显示的值返回气象站：

Wolfram Language code: WindSpeedData[Polygon[{{-99.24, 39.11}, {-99.24, 41.11}, {-101.24, 41.11}, {-101.24, 39.11}}], DateObject[{2011, 8, 4}, TimeObject[{12}]], "Stations"]

关联规范  (2)

日期和位置可以使用 Association 一起指定：

Wolfram Language code: WindSpeedData[Association["Location" -> "KISP", "Date" -> DateObject[{2012, 1, 2}]]]

Association 规范适用于格式参数：

Wolfram Language code: WindSpeedData[Association["Location" -> "KSAC", "Date" -> DateObject[{2012, 1, 1}]], Mean]

选项  (2)

UnitSystem  (2)

默认情况下，结果会使用由 $UnitSystem 给出的格式：

Wolfram Language code: $UnitSystem

设置 UnitSystem 为 "Imperial" 指定英里每小时：

Wolfram Language code: WindSpeedData[UnitSystem -> "Imperial"]

或设置 UnitSystem 为 "Metric" 指定千米每小时：

Wolfram Language code: WindSpeedData[UnitSystem -> "Metric"]

UnitConvert 也可用于调整单位：

Wolfram Language code: UnitConvert[WindSpeedData[], "Meters" / "Seconds"]

应用  (2)

绘制风速和时间：

Wolfram Language code: data = WindSpeedData["KISP", {{2012, 10, 28}, {2012, 10, 30}}, UnitSystem -> "Imperial"];
Wolfram Language code: DateListPlot[data, Joined -> True, FrameLabel -> Automatic]

检查一年中每天的平均风速测量值：

Wolfram Language code: data = WindSpeedData["KCMI", {{2012, 1, 1}, {2012, 12, 31}}]

计算特定日期所有值的平均值：

Wolfram Language code: averaged = TimeSeriesAggregate[data, "Day", Mean]
Wolfram Language code: DateListPlot[averaged]

属性和关系  (4)

默认情况下，位置由 $GeoLocation 指定：

Wolfram Language code: WindSpeedData[]
Wolfram Language code: WindSpeedData[$GeoLocation]

使用 IconData 中的 WindSpeedData 输出：

Wolfram Language code: IconData["WindSpeed", WindSpeedData[]]

使用 GeoGraphics 和 IconData 绘制选中的德国城市的风速：

Wolfram Language code: cities = {Entity["City", {"Berlin", "Berlin", "Germany"}], Entity["City", {"Hamburg", "Hamburg", "Germany"}], Entity["City", {"Munich", "Bavaria", "Germany"}], Entity["City", {"Cologne", "NorthRhineWestphalia", "Germany"}], Entity["City", {"Frankfurt", "Hesse", "Germany"}], Entity["City", {"Stuttgart", "BadenWurttemberg", "Germany"}], Entity["City", {"Dortmund", "NorthRhineWestphalia", "Germany"}], Entity["City", {"Bremen", "Bremen", "Germany"}], Entity["City", {"Dresden", "Saxony", "Germany"}], Entity["City", {"Hanover", "LowerSaxony", "Germany"}], Entity["City", {"Nuremberg", "Bavaria", "Germany"}]};
Wolfram Language code: data = {CityData[#, "Coordinates"], CityData[#, "Name"], WindSpeedData[#]}& /@ cities;
Wolfram Language code: GeoGraphics[{GeoStyling["ReliefMap"], EdgeForm[Thin], Opacity[0.5], Polygon[Entity["Country", "Germany"]], PointSize[Large], Opacity[1], {Black, Text[#[[2]], GeoPosition[#[[1]]], {-1.5, 0}], Red, Point[GeoPosition[#[[1]]]], Inset[IconData["WindSpeed", #[[3]]], GeoPosition[#[[1]]], Bottom, 2]}& /@ data}]

找到具有 GeoEntities 区域的所有气象站：

Wolfram Language code: stations = GeoEntities[Entity["AdministrativeDivision", {"Delaware", "UnitedStates"}], "WeatherStation"]

找出所有气象站的风速：

Wolfram Language code: WindSpeedData /@ stations

巧妙范例  (2)

基于最新测量值，找出堪萨斯风力最大的位置：

Wolfram Language code: stations = WindSpeedData[Polygon[Entity["AdministrativeDivision", {"Kansas", "UnitedStates"}]], "StationName"];
Wolfram Language code: data = Last@SortBy[DeleteCases[{#, WindSpeedData[#]}& /@ stations, {_, Missing[_]}], Last]

给出风力机的典型值，确定在该位置会产生多少能量：

Wolfram Language code: FormulaData["WindTurbine", {A -> Quantity[100, "Meters" ^ 2], V -> data[[2]], μ -> 0.4, ρ -> Quantity[1.257, "Kilograms" / "Meters" ^ 3]}]

把丹佛记载的风速拟合进 VarianceGammaDistribution：

Wolfram Language code: data = WindSpeedData[Entity["City", {"Denver", "Colorado", "UnitedStates"}], {{2000, 1, 1}, {2009, 12, 31}}][ "Values"];
Wolfram Language code: hg = Histogram[data, Automatic, "PDF"]; ed = EstimatedDistribution[data, VarianceGammaDistribution[α, β, b, μ], ParameterEstimator -> "MethodOfMoments"]
Wolfram Language code: Show[{hg, Plot[PDF[ed, Quantity[x, "Miles"/"Hours"]], {x, 0, 100}, PlotRange -> All]}]
Wolfram Research (2014)，WindSpeedData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/WindSpeedData.html.

文本

Wolfram Research (2014)，WindSpeedData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/WindSpeedData.html.

CMS

Wolfram 语言. 2014. "WindSpeedData." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/WindSpeedData.html.

APA

Wolfram 语言. (2014). WindSpeedData. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/WindSpeedData.html 年

BibTeX

@misc{reference.wolfram_2026_windspeeddata, author="Wolfram Research", title="{WindSpeedData}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/WindSpeedData.html}", note=[Accessed: 04-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_windspeeddata, organization={Wolfram Research}, title={WindSpeedData}, year={2014}, url={https://reference.wolfram.com/language/ref/WindSpeedData.html}, note=[Accessed: 04-November-2026]}