Wolfram 语言与系统参考资料中心

XMLTemplate

XMLTemplate["string"]

产生一个 TemplateObject，表示可被诸如 TemplateApply 这样的函数应用的 XML 模板.

XMLTemplate[src]

用 File[…]、URL[…] 或 CloudObject[…] 作为字符串模板的来源.

XMLTemplate[form,args]

产生一个有参数的 TemplateObject，可用于云部署或其他运算.

范例

打开所有单元关闭所有单元

基本范例 (2)

应用一个带有名为 a 和 b 插槽的 XML 模板：

Wolfram Language code: XMLTemplate["first <wolfram:slot id='a'/> then <wolfram:slot id='b'/>"][<|"a" -> 1234, "b" -> 5678|>]

用 TemplateApply 来做同样的事情：

Wolfram Language code:

TemplateApply[XMLTemplate["first <wolfram:slot id='a'/> then <wolfram:slot id='b'/>"], 
	<|"a" -> 1234, "b" -> 5678|>]

XMLTemplate 支持和 StringTemplate 一样的语法；当模板被运用的时候，对 <*…*> 中的表达式进行计算：

Wolfram Language code: TemplateApply @ XMLTemplate["Values: <* Range[5] *>."]

在模板字符串中包含模板插槽和一个表达式：

Wolfram Language code:

TemplateApply[
	XMLTemplate["Range of `a`: <* Range[#a] *>."], 
	<|"a" -> 5|>
	]

用 XML 标签的、有同等效用的语法：

Wolfram Language code:

TemplateApply[
	XMLTemplate["Range of <wolfram:slot id='a'/>: <wolfram:expr>Range[#a]</wolfram:expr>."], 
	<|"a" -> 5|>
	]

当你需要将数据注入 XML 属性中时，字符串模板语法会很有用：

Wolfram Language code:

TemplateApply[
	XMLTemplate["link: <a href='`url`'><wolfram:slot id='name'/></a>"], 
	<|"url" -> "http://wolfram.com", "name" -> "wolfram"|>
	]

范围 (4)

完全支持 File：

Wolfram Language code: XMLTemplate[File["Examples/XML/Sequence.html"]]

可将模板置于 Wolfram 云中：

Wolfram Language code: template = CloudDeploy[XMLTemplate["My name is <wolfram:slot id='Name'/>."]]

Wolfram Language code: FileTemplate[template]

XMLTemplate 的第二个参数可用来把数据绑定到模板上：

Wolfram Language code:

t = XMLTemplate["a is <wolfram:slot id='a'/>, b is <wolfram:slot id='b'/>", <|"a" :> RandomReal[]|>];
TemplateApply[t]

Wolfram Language code: TemplateApply[t, <|"b" :> RandomReal[]|>]

可以使用 URL 提取模板：

Wolfram Language code: template = URL @@ CloudExport["hello <wolfram:slot id='Name'/>", "String"]

Wolfram Language code: URLRead[template, "Body"]

Wolfram Language code: XMLTemplate[template]

选项 (2)

InsertionFunction (1)

插入（inserter）属性可以是一个函数或者是 $ExportFormats 之间选中的字符串：

Wolfram Language code:

t = "
<script type='text/javascript'>
	var planets= <wolfram:slot id='planets'>#planets</wolfram:slot>;
</script>
";
data = <| "planets" -> {
	"Jupiter", 
	"Mars", 
	"Earth"
} |>;
	
TemplateApply[XMLTemplate[t, InsertionFunction -> "JSON"], data]

上面的代码等价于：

Wolfram Language code: TemplateApply[XMLTemplate[t, InsertionFunction -> Function[body, ExportString[body, "JSON"]]], data]

InsertionFunction 可以是任何内容：

Wolfram Language code:

TemplateApply[
	XMLTemplate[
	"<h1>Planet</h1>
   <p><wolfram:slot id='planet'/> is beautiful</p>", 
	InsertionFunction -> ToUpperCase
	], 
	<| "planet" -> "Jupiter"|>
	]

CombinerFunction (1)

结合器（combiner）函数也接受格式：

Wolfram Language code:

t = "<h1>Template</h1>
This is my <strong>html</strong>.
In javascript everything will be \"escaped\"
";
TemplateApply[XMLTemplate[t, CombinerFunction -> "JSON"]]

结合器（combiner）函数可以是任何内容：

Wolfram Language code: TemplateApply[XMLTemplate[t, CombinerFunction -> Composition[StringJoin, ToUpperCase]]]

应用 (9)

<wolfram:slot id='...' inserter='...'>...</wolfram:slot>

简单的使用方法：

Wolfram Language code: XMLTemplate["value: <wolfram:slot id='1'/>"][1]

使用默认值和插入器：

Wolfram Language code:

ToMean[s_String] := StringTrim[s];
ToMean[l_List] := ToString @ N[Mean[l]];
	
t = XMLTemplate["
slot data: <wolfram:slot id='data' inserter='ToMean'>
    No data found.
</wolfram:slot>
"];
TemplateApply[t]

Wolfram Language code: TemplateApply[t, <|"data" -> Range[10, 15]|>]

<wolfram:expr inserter='...'>...</wolfram:expr>

简单的使用方法：

Wolfram Language code: XMLTemplate["mean: <wolfram:expr>Mean[#1]</wolfram:expr>"][Range[10]]

使用数据和插入器：

Wolfram Language code:

ToJSON[Missing] := "null";
ToJSON[expr_] := ExportString[expr, "JSON"];
	
t = XMLTemplate["
<script type='text/javascript'>
	var planets = <wolfram:expr inserter=ToJSON>Rule @@@ Transpose[
		{#planets, #colors}
	]</wolfram:expr>;
</script>
"];
TemplateApply[t, <|"planets" -> {"Mercury", "Earth", "Mars"}, "colors" -> {"Grey", "Light Blue", "Red"}|>]

<wolfram:if test='...'>...</wolfram:if>

Wolfram Language code:

t = XMLTemplate["This is planet <wolfram:slot id='planet'/>. <wolfram:if test='#beautiful'>It's so beautiful to me.</wolfram:if>"];
TemplateApply[t, <|"planet" -> "Venus"|>]

Wolfram Language code: TemplateApply[t, <|"planet" -> "Mars", "beautiful" -> True|>]

测试可以是任何表达式：

Wolfram Language code:

t = XMLTemplate["This is planet <wolfram:slot id='planet'/>. <wolfram:if test='#planet === #home'>It's our home planet.</wolfram:if>"];
TemplateApply[t, <|"planet" -> "Earth", "home" -> "Earth"|>]

<wolfram:which><wolfram:if test='...'>...</wolfram:if></wolfram:which>

使用 which 来对多个 else if 语句进行嵌套：

Wolfram Language code:

t = XMLTemplate["<wolfram:which>
  <wolfram:if test='StringQ[#planets]'>This is a single planet.</wolfram:if>
  <wolfram:if test='ListQ[#planets]'>This is a list of planets.</wolfram:if> 
  <wolfram:if test='MatchQ[#planets, Missing|_Missing]'>This planet is missing.</wolfram:if>
  <wolfram:else>This is not a planet.</wolfram:else>
</wolfram:which>"];
	
TemplateApply[t]

Wolfram Language code: TemplateApply[t, <|"planets" -> {"Jupiter", "Mars", "Earth"}|>]

Wolfram Language code: TemplateApply[t, <|"planets" -> JustAnotherSymbol|>]

<wolfram:sequence values='...' ...>...</wolfram:sequence>

基本的使用方法：

Wolfram Language code:

t = XMLTemplate["<ul>
<wolfram:sequence values='#planets'>
   <li><wolfram:slot id='1'/></li>
 </wolfram:sequence>
</ul>"];
TemplateApply[t, <|"planets" -> {"jupiter", "mars", "earth"}|>]

使用已命名的变量：

Wolfram Language code:

t = XMLTemplate["<ul>
<wolfram:sequence values='#planets' slot='planet' index='counter'>
   <li><wolfram:slot id='counter'/>: <wolfram:slot id='planet'/></li>
 </wolfram:sequence>
</ul>"];
TemplateApply[t, <|"planets" -> {"jupiter", "mars", "earth"}|>]

使用插入函数：

Wolfram Language code:

CapFirst[a_String] := With[
	{chars = Characters[a]}, 
	StringJoin[ToUpperCase[First[chars]], Rest[chars]]
	];
CapFirst[a_] := ToString[a];
	
t = XMLTemplate["<ul>
<wolfram:sequence values='#planets' index='counter' inserter='CapFirst'>
   <li><wolfram:slot id='counter'/>: <wolfram:slot id='1'/></li>
 </wolfram:sequence>
</ul>"];
TemplateApply[t, <|"planets" -> {"jupiter", "mars", "earth"}|>]

使用默认数值（StringTemplate）：

Wolfram Language code:

t = XMLTemplate["<ul>
<wolfram:sequence values='#results' index='counter' default='<li>No results for: `query`</li>'>
   <li><wolfram:slot id='counter'/>: <wolfram:slot id='1'/></li>
 </wolfram:sequence>
</ul>"];
TemplateApply[t, <| "query" -> "alpha centauri", "results" -> {} |>]

使用分隔符：

Wolfram Language code:

t = XMLTemplate["Insert one of the following planets: <wolfram:sequence values='#1' delimiters=', '><wolfram:slot id='1'/></wolfram:sequence>."];
TemplateApply[t, {{"jupiter", "mars", "earth"}}]

<wolfram:with key$1='val$1' ...>...</wolfram:with>

Wolfram Language code:

t = XMLTemplate["<wolfram:with mean='Round @ Mean[#data]' total='Total[#data]'>
Mean: <wolfram:slot id='mean'/>
Total: <wolfram:slot id='total'/>
</wolfram:with>
Data: <wolfram:slot id='data'/>"];
	
TemplateApply[t, <|"data" -> Fibonacci /@ Range[10, 15]|>]

<wolfram:get path='...'><wolfram:slot id='...'/>...</wolfram:get>

包括路径的模板. 路径是一个 StringTemplate：

Wolfram Language code:

t = XMLTemplate["<wolfram:get path='Examples/XML/with.html' />"];

TemplateApply[t, <|"data" -> Range[10]|>]

改变输出的插入和结合器函数：

Wolfram Language code:

capitalize = Composition[ToUpperCase, ToString];
strip[body_] := StringReplace[StringJoin[body], WhitespaceCharacter -> ""];

t = XMLTemplate["<wolfram:get combiner='strip' inserter='capitalize' path='Examples/XML/sequence.html'/>"];
TemplateApply[t, <|"data" -> {"jupiter", "mars", "earth"}|>]

扩展一个模板. HTML 页面的模板范例：

Wolfram Language code: Import["Examples/XML/Inheritance/main.html", "String", Path -> $TemplatePath]

使用 get 来覆盖插口（slot）：

Wolfram Language code:

TemplateApply @ XMLTemplate["
<wolfram:get path='Examples/XML/Inheritance/main.html'>
	<wolfram:slot id='pageTitle'>Earth</wolfram:slot>
	<wolfram:slot id='pageHeader'>Planet earth</wolfram:slot>
	<wolfram:slot id='pageContent'>Read all about earth on <a href='http://en.wikipedia.org/wiki/Earth'>Wikipedia</a></wolfram:slot>
	<wolfram:slot id='pageFooter'>Thanks for visiting our home planet</wolfram:slot>
</wolfram:get>"]

<wolfram:template ...>...</wolfram:template>

使用“模板”来创建片断，以覆盖插入和结合器函数：

Wolfram Language code:

capitalize = Composition[ToUpperCase, StringJoin];
	
TemplateApply @ XMLTemplate["
<wolfram:template combiner='capitalize'>
	<p>this is a block of text and <wolfram:slot>slots</wolfram:slot></p>
</wolfram:template>
"]

结合模板和编辑外部模板：

Wolfram Language code:

capitalize = Composition[ToUpperCase, StringJoin];
	
TemplateApply[
	XMLTemplate["
<wolfram:template combiner='capitalize'>
	<p>All text is capitalized</p>
	<wolfram:get path='Examples/XML/if.html'/>
</wolfram:template>
"], 
	<| "data" -> "Earth" |>
	]

<wolfram:comment>...</wolfram:comment>

Wolfram Language code:

TemplateApply @ XMLTemplate["
<h1>About planet Mars</h1>
<wolfram:comment>
	Insert planet mass here
</wolfram:comment>
<p>Mars is red</p>
"]

Wolfram Language code:

TemplateApply @ XMLTemplate["
<h1>About planet Jupiter</h1>
<wolfram:comment>
	Maybe we should improve this description
</wolfram:comment>
<p>Jupiter is big</p>
"]

<wolfram:verbatim>...</wolfram:verbatim>

使用“verbatim”来避免语义分析. 允许可选的插入函数：

Wolfram Language code:

capitalize = Composition[ToUpperCase, StringJoin];
	
TemplateApply @ XMLTemplate["
Sample usage of comment tag:
<wolfram:verbatim inserter='capitalize'>
    <wolfram:comment>
        This comment will (not) be deleted
    </wolfram:comment>
</wolfram:verbatim>
"]

属性和关系 (1)

XMLTemplate 的运算结果为 TemplateObject:

Wolfram Language code: XMLTemplate["My name is <wolfram:slot id='Name'/>."]

可能存在的问题 (1)

XMLTemplate 的第二个参数中的数据比 TemplateApply 中的参数的优先级要高：

Wolfram Language code:

t = XMLTemplate["My name is <wolfram:slot id='a'/>.", <|"a"  ->   1|>];
TemplateApply[t, <|"a"  ->   2|>]

巧妙范例 (1)

可以把 XMLTemplate 部署到云端. 每一次访问 URL 时，TemplateApply 将渲染模板：

Wolfram Language code:

CloudDeploy[
	XMLTemplate[
	"now is: `Now`", 
	<|"Now" :> Now|>
	]]

Top

	<wolfram:slot>	TemplateSlot
	<wolfram:expr>	TemplateExpression
	<wolfram:if>	TemplateIf
	<wolfram:which>	多个 TemplateIf
	<wolfram:sequence>	TemplateSequence
	<wolfram:with>	TemplateWith
	<wolfram:template>	TemplateObject
	<wolfram:get>	Get
	<wolfram:comment>	需要忽略的评论
	<wolfram:verbatim>	verbatim XML

values	(required)	重复 body 的列表或者关联性
slot	1	提供给 body 的模板插口的名称
index	2	提供给 body 的位置索引名称
delimiters	Sequence[]	在 body 的重复之间插入的分隔符
default	Sequence[]	若无数值时应使用的格式
inserter	Inherited	InsertionFunction 选项的设置

	inserter	Inherited	InsertionFunction 选项的设置
	combiner	Inherited	CombinerFunction 选项的设置

path	(required)	文件或者 URL 路径
inserter	Inherited	InsertionFunction 选项的设置
combiner	Inherited	CombinerFunction 选项的设置

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

XMLTemplate

更多信息和选项

范例

基本范例 (2)

范围 (4)

选项 (2)

InsertionFunction (1)

CombinerFunction (1)

应用 (9)

属性和关系 (1)

可能存在的问题 (1)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

	InsertionFunction	"HTMLFragment"	在插入表达式前应用的函数或者格式
	CombinerFunction	StringJoin	在返回结果前用于合并各个部分的函数

XMLTemplate

更多信息和选项

范例

基本范例 (2)

范围 (4)

选项 (2)

InsertionFunction (1)

CombinerFunction (1)

应用 (9)

属性和关系 (1)

可能存在的问题 (1)

巧妙范例 (1)

参见

相关指南

相关的工作流程

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX