代数的数体—Wolfram Documentation

代数的数体

Wolfram言語では代数的数をRootオブジェクトとして表現することができる．Rootオブジェクトは代数的数の最小多項式と根番号（Rootオブジェクトが最小多項式のどの根を表しているのかを示す整数）を含んでいる．これにより，任意の複素代数的数の表現が一意的となる．一方で，この表現での演算操作はコストが高いという問題もある．そのため，Wolfram言語では演算式の簡約化のために追加の関数RootReduceを使用することが必要となる．計算を固定された有理数の有限次代数拡大内に限定することで，その要素をの多項式としてより簡単に表現することができる．

AlgebraicNumber[θ,{c₀,c₁,…,c_n}]

で代数的数

を表す

有理数の有限拡大体の要素としての代数的数の表現

が次数

の最小多項式を持つ代数的整数であり，

，

，…，

が有理数ならば，AlgebraicNumber[θ,{c₀,…,c_l}]は不活性数値オブジェクトである：

Wolfram Language code: a = AlgebraicNumber[Root[#^3 - # + 1&, 1], {1, 2, 3}]

Nを使うと，AlgebraicNumberオブジェクトの数値的近似が求められる：

Wolfram Language code: N[a, 20]

任意の代数的数および任意の実数のリストに対して，AlgebraicNumber[θ,{c₀,…,c_l}]を評価すると，AlgebraicNumber[ξ,{d₀,…,d_m}]になる．ここでは，の最小多項式の主係数の任意の因子についてとなるような代数的整数，はの最小多項式の次数，そして以下が成り立つ．

AlgebraicNumberは代数的整数の拡大体の生成元と，その拡大体の次数の長さに等しい係数リストを自動的に作成する：

Wolfram Language code: AlgebraicNumber[Root[2 #^4 - 3 # + 2&, 1], {1, 2, 3, 4, 5, 6}]

有理数を表すAlgebraicNumberオブジェクトは自動的に数値に還元される：

Wolfram Language code: AlgebraicNumber[Root[#^5 - 7 # + 1&, 1], {0, 7, 0, 0, 0, -1}]

明らかに同じ体に存在する（つまり第1，第3要素が等しい）AlgebraicNumberオブジェクトの加算または乗算，有理数とAlgebraicNumberオブジェクトの加算または乗算，あるいはAlgebraicNumberオブジェクトの整数乗を行うと，AlgebraicNumberオブジェクトが得られる：

Wolfram Language code:

a = AlgebraicNumber[Root[#^4 + 7 # - 21&, 1], {1, 2, 3, 4}];
b = AlgebraicNumber[Root[#^4 + 7 # - 21&, 1], {9, 8, 7, 5}];
(2 a^2 - 3 a b + 5 b^5 - 3/a^8 - b^4 + (1/2)) + 9

RootReduceはAlgebraicNumberオブジェクトをRootオブジェクトに変換する：

Wolfram Language code: RootReduce[a]

ToNumberField[a,θ]	θ により生成された数体上で代数的数 a を表す
ToNumberField[{a₁,a₂,…},θ]	θ により生成された体上で a_i を表す
ToNumberField[{a₁,a₂,…}]	単独の代数的数により生成された共通の拡大体上で a_i を表す

任意の代数的数を代数体の要素として表す

ToNumberFieldを使うと，指定の代数的数を含む有理数の共通の有限拡大体を求めることができる：

Wolfram Language code: ToNumberField[{Sqrt[2], Sqrt[3]}]

次の式は

をRoot[1-10 #1²+#1⁴&,4]により生成された体の要素として表す：

Wolfram Language code: ToNumberField[Sqrt[6], Root[1 - 10 #^2 + #^4&, 4]]

有理数の固定の有限拡大体内での計算は，複素代数的数すべての体の中での計算より格段に速い．

{x,y,z}が代数的数{a,b,c}で置き換えられた有理関数fの値を求めるとする：

Wolfram Language code:

{a, b, c} = {I, Sqrt[2], Root[#^3 - 2 # + 3&, 1]};
f = (-2 y z (7 + x - y + z^2) + (6 + x^2 + 2 y) (-11 + x y + z^2)/2 y z (-4 - x + 3 y z) - (6 + x^2 + 2 y) (2 - 2 x + z^3));

{a,b,c}におけるfの値をRootReduceを使って直接計算すると，多少時間がかかる：

Wolfram Language code: RootReduce[f /. {x -> a, y -> b, z -> c}]//Timing

これをより速く行う別の方法として，{a,b,c}を含む共通の代数体で計算を行うというものがある：

Wolfram Language code: ({aa, bb, cc} = ToNumberField[{a, b, c}])//Timing

共通の数体の中での計算は格段に速い：

Wolfram Language code:

(d = (-2 y z (7 + x - y + z^2) + (6 + x^2 + 2 y) (-11 + x y + z^2)/2 y z (-4 - x + 3 y z) - (6 + x^2 + 2 y) (2 - 2 x + z^3)) /. {x -> aa, y -> bb, z -> cc})//Timing

結果のAlgebraicNumberオブジェクトをRootオブジェクトに変換するのも速い：

Wolfram Language code: RootReduce[d]//Timing

ToNumberField[{a₁,a₂,…}]はToNumberField[{a₁,a₂,…},Automatic]と等価であり，必ずしも最小共通拡大体は使わない．ToNumberField[{a₁,a₂,…},All]は常に最小共通拡大体を使う．

1つ目のAlgebraicNumberオブジェクトは

に等しいため，これが示す第四次体

(Root[1-10 #1²+#1⁴&,4])を生成しない．しかし，ToNumberFieldが求めた共通体には体すべて

(Root[1-10 #1²+#1⁴&,4])が含まれる：

Wolfram Language code: ToNumberField[{AlgebraicNumber[Root[1 - 10 #^2 + #^4&, 4], {0, -(9/2), 0, (1/2)}], Sqrt[5]}]

第2引数をAllと指定すると，ToNumberFieldは可能な限り最小の体を探す：

Wolfram Language code: ToNumberField[{AlgebraicNumber[Root[1 - 10 #^2 + #^4&, 4], {0, -(9/2), 0, (1/2)}], Sqrt[5]}, All]

MinimalPolynomial[a]	代数的数 a の整数の最小多項式の純関数表現を返す
MinimalPolynomial[a,x]	x の多項式として表された代数的数 a の最小多項式を返す
AlgebraicIntegerQ[a]	代数的数 a が代数的整数ならTrueを，さもなければFalseを返す
AlgebraicNumberDenominator[a]	na が代数的整数となるような最小の正の整数 n を返す
AlgebraicNumberTrace[a]	代数的数 a のトレースを返す
AlgebraicNumberNorm[a]	代数的数 a のノルムを返す
AlgebraicUnitQ[a]	代数的数 a が代数的単数ならばTrueを，それ以外ならFalseを返す
RootOfUnityQ[a]	代数的数 a が1のベキ根ならばTrueを，それ以外ならFalseを返す

代数的数の特性を計算するめる関数

代数的数の最小多項式は，整数係数を持ち，となる最小の正の主係数を持つ最低次の多項式である．

次の式は純関数として表された

の最小多項式を返す：

Wolfram Language code: MinimalPolynomial[Sqrt[2] + Sqrt[3]]

次はxの多項式として表されたRoot[#1⁵-2 #1+7&,1]²+1の最小多項式を返す：

Wolfram Language code: MinimalPolynomial[Root[#^5 - 2 # + 7&, 1]^2 + 1, x]

代数的数はそのMinimalPolynomialがモニックのとき，かつそのときに限り，代数的整数である．

が代数的整数であることを示す：

Wolfram Language code: AlgebraicIntegerQ[(1/2) (1 + Sqrt[5])]

が代数的整数ではないことを示す：

Wolfram Language code: AlgebraicIntegerQ[(1/4) (1 + Sqrt[5])]

が代数的整数となる最小の正の整数

を求める：

Wolfram Language code: AlgebraicNumberDenominator[(1/4) (1 + Sqrt[5])]

代数的数 a のトレースはMinimalPolynomial[a]のすべての根の和である．

のトレース：

Wolfram Language code: AlgebraicNumberTrace[(-1)^1 / 7]

代数的数a のノルムはMinimalPolynomial[a]のすべての根の積である．

のノルム：

Wolfram Language code: AlgebraicNumberNorm[Sqrt[3] + Sqrt[5]]

との両方が代数的整数の場合，言い換えるとAlgebraicNumberNorm[a]がまたはの場合かつその場合に限り，代数的数は代数的単位元となる．

GoldenRatioが代数的単位元であることを示す：

Wolfram Language code: AlgebraicUnitQ[GoldenRatio]

AlgebraicNumber[Root[#1³-4#1+17&,1],{1,2,3}]は代数的単位数ではない：

Wolfram Language code: AlgebraicUnitQ[AlgebraicNumber[Root[#^3 - 4 # + 17&, 1], {1, 2, 3}]]

整数についてである場合，かつその場合に限り，代数的数は1のベキ根である．

は1のベキ根である：

Wolfram Language code: RootOfUnityQ[(1/2) (Sqrt[2 + Sqrt[2]] + I Sqrt[2 - Sqrt[2]])]

MinimalPolynomial[s,x,Extension->a]
	体上の代数的数 s の特性多項式を返す
MinimalPolynomial[s,x,Extension->Automatic]
	第1引数により生成された数体上のAlgebraicNumberオブジェクト s の特性多項式を返す
AlgebraicNumberTrace[a,Extension->θ]
	体上の代数的数 a のトレースを返す
AlgebraicNumberTrace[a,Extension->Automatic]
	第1引数により生成された数体上のAlgebraicNumberオブジェクト a のトレースを返す
AlgebraicNumberNorm[a,Extension->θ]
	体上の代数的数 a のノルムを返す
AlgebraicNumberNorm[a,Extension->Automatic]
	第1引数により生成された数体上のAlgebraicNumberオブジェクト a のノルムを返す

代数適す謡の要素の特性を計算する関数

a がAlgebraicNumber[θ,coeffs]であるとすると，MinimalPolynomial[a,x,Extension->Automatic]はMinimalPolynomial[a,x]^d に等しい．ここで，d はの拡大次数である．

の特性多項式は次数4の有理拡大体の要素として表されるが，これは

のMinimalPolynomialの二乗である：

Wolfram Language code:

a = AlgebraicNumber[Root[1 - 10 #^2 + #^4&, 4], {0, -(9/2), 0, (1/2)}];
MinimalPolynomial[a, x]
MinimalPolynomial[a, x, Extension -> Automatic]//Factor

代数的数のトレースは，特性多項式の根の総和である．a がAlgebraicNumber[θ,coeffs]ならば，AlgebraicNumberTrace[a,Extension->Automatic]はd AlgebraicNumberTrace[a]と等しい．ここで d はの拡大次数である．

のトレースは次数4の有理拡大体の要素として表されるが，これは

のAlgebraicNumberTraceの2倍である：

Wolfram Language code:

a = AlgebraicNumber[Root[1 - 10 #^2 + #^4&, 4], {1, -(9/2), 0, (1/2)}];
AlgebraicNumberTrace[a]
AlgebraicNumberTrace[a, Extension -> Automatic]

代数的数のノルムは，特性多項式の根の総積である．a がAlgebraicNumber[θ,coeffs]なら，AlgebraicNumberNorm[a,Extension->Automatic]はAlgebraicNumberNorm[a]^dに等しい．ここで d はの拡大次数である．

のノルムは，次数4の有理拡大体の要素として表されるが，これは

のAlgebraicNumberNormの二乗に等しい：

Wolfram Language code:

a = AlgebraicNumber[Root[1 - 10 #^2 + #^4&, 4], {5, -(9/2), 0, (1/2)}];
AlgebraicNumberNorm[a]
AlgebraicNumberNorm[a, Extension -> Automatic]

NumberFieldIntegralBasis[a]	代数的数 a により生成された体の整数底を返す
NumberFieldRootsOfUnity[a]	代数的数 a により生成された体の1のベキ根を返す
NumberFieldFundamentalUnits[a]	代数的数 a により生成された体の基本単位元のリストを返す
NumberFieldNormRepresentatives[a,m]
	代数的数 a により生成された体におけるノルム±m の代数的整数のクラスの代表値を返す
NumberFieldSignature[a]	代数的数 a により生成された体のシグネチャを返す
NumberFieldDiscriminant[a]	代数的数 a により生成された体の判別式を返す
NumberFieldRegulator[a]	代数的数 a により生成された体の基準を返す
NumberFieldClassNumber[a]	代数的数 aにより生成された数体のクラス数

代数体の特性を計算する関数

代数体の整数底は，の代数的整数の‐加群の底を形成する代数的数のリストである．が代数的整数であり，すべての代数的整数が次のように一意的に表せるとき，かつその場合に限り，集合は代数体の整数底である．

ここでは整数係数である．

の整数底：

Wolfram Language code: NumberFieldIntegralBasis[18^1 / 3]

533+429 #1+18 #1²+#1³& の最初の根により生成された体の整数底を返す：

Wolfram Language code: NumberFieldIntegralBasis[Root[533 + 429 # + 18 #^2 + #^3&, 1]]

NumberFieldIntegralBasisを使うと，対抗式と根の数を与えることにより数体を指定することができる：

Wolfram Language code: NumberFieldIntegralBasis[533 + 429 # + 18 #^2 + #^3&, 1]

Root[9-2 #²+#⁴&,4]により生成された体における1のベキ根を返す：

Wolfram Language code: NumberFieldRootsOfUnity[Root[9 - 2 #^2 + #^4&, 4]]

体

における1のベキ根すべてである：

Wolfram Language code: NumberFieldRootsOfUnity[1 + I Sqrt[3]]

が代数的単位元であり，すべての代数的単位元が次のように一意的に表される場合，かつその場合に限り，は代数体の基本単位元である．

ここで，は1のベキ根，は整数の指数である．

#1⁴-10 #1²+1& の三次の根により生成された体の基本単位元の集合：

Wolfram Language code: NumberFieldFundamentalUnits[Root[#^4 - 10 #^2 + 1&, 3]]

二次体

の基本単位元：

Wolfram Language code: NumberFieldFundamentalUnits[Sqrt[21]]

#1²-7& の一次の根により生成された体のノルム9の要素の類の代表値一式：

Wolfram Language code: NumberFieldNormRepresentatives[Root[#^2 - 7&, 1], 9]

体

のノルム2の要素の類の代表値一式：

Wolfram Language code: NumberFieldNormRepresentatives[Sqrt[2] + Sqrt[3], 2]

多項式#⁵+#⁴+#³+#²+1& が実根1つと，2対の複素共役根を持つことを示す：

Wolfram Language code: NumberFieldSignature[Root[#^5 + #^4 + #^3 + #^2 + 1&, 1]]

体

には12個の実根と6対の複素共役根が埋め込まれている：

Wolfram Language code:

a = Sqrt[2] + Root[#^3 - 11 # - 2&, 1] + AlgebraicNumber[Root[#^4 - 3 # + 1&, 2], {1, 2, 3}];
NumberFieldSignature[a]

数体の判別式はの整数底の判別式，つまり要素がAlgebraicNumberTrace[a_i a_j,Extension->Automatic]である行列の判別式である．判別式の値は，整数底の値に依存しない．

の判別式：

Wolfram Language code: NumberFieldDiscriminant[2 - Sqrt[3] + 5^1 / 4]

多項式#⁵+#⁴+#³+#²+1&の根により生成された体の判別式を求める．判別式の値はどの根を用いるかに因らないため，NumberFieldDiscriminantで多項式だけを指定することができる：

Wolfram Language code: NumberFieldDiscriminant[#^5 + #^4 + #^3 + #^2 + 1&]

数体の基準は，次の対数埋込みにおいての単位元のグループの写像の格子体積である．

ここで , …, はのへの実数埋込みであり，, …, はのへの複素共役埋込みのなかの1つである．

の基準：

Wolfram Language code: NumberFieldRegulator[Sqrt[61]]

多項式#1³-3 #1²+1& の根により生成された体の基準を求める．単数基準の値は根の選択に因らないため，NumberFieldRegulatorで多項式だけを指定することができる：

Wolfram Language code: NumberFieldRegulator[#^3 - 3 #^2 + 1&]

のクラス数を与える：

Wolfram Language code: NumberFieldClassNumber[Sqrt[-71]]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

代数的数体