PDESolve

関連項目
- 関数
- LinearSolve
- FindRoot
- NDSolve
- 関数
- InitializePDECoefficients
- PDECoefficientData
- InitializeBoundaryConditions
- BoundaryConditionData
- InitializePDEMethodData
- FEMMethodData
- DeployBoundaryConditions
- ProcessPDESolutions
関連するガイド
- 有限要素法
テクニカルノート

NDSolve`FEM`

PDESolve

PDESolve[cdata,bcdata,vd,sd,mdata]

係数データ cdata，境界条件データ bcdata，変数データ vd，解データ sd，メソッドデータ mdata に基づいて偏微分方程式を解き，新しい解のデータを返す．

詳細とオプション

PDESolveは，線形と非線形の定常偏微分方程式を解く．
PDESolveは，solution dataであるリストを返す．
係数データ cdata は，InitializePDECoefficientsによって生成されるPDECoefficientDataオブジェクトである．
境界条件データ bcdata は，InitializeBoundaryConditionsによって生成されるBoundaryConditionDataオブジェクトである．
変数データ vd と解データ sd は，変数と値の対応するリストである．vd と sd のテンプレートは，NDSolve`VariableDataとNDSolve`SolutionDataを使って生成され，コンポーネントはNDSolve`SetSolutionDataComponentを使って設定されることがある．
メソッドデータ mdata は，InitializePDEMethodDataを通して生成されるFEMMethodDataのような偏微分方程式のメソッドデータオブジェクトである．
PDESolveは以下のオプションを取る．

	"FindRootOptions"	Automatic	FindRootのオプションを指定する
	"LinearSolver"	Automatic	線形ソルバおよびそのオプションを指定する

PDESolveに与えられるオプションは，"PDESolveOptions"を指定することによってNDSolveに与えることができる． »
NDSolveおよび関連の関数からオプションを設定することについては，有限要素のためのNDSolveオプションに説明がある．

例題

すべて開くすべて閉じる

例 (3)

有限要素パッケージをロードする：

Wolfram Language code: Needs["NDSolve`FEM`"]

NumericalRegionを設定する：

Wolfram Language code: nRegion = ToNumericalRegion[Rectangle[{0, 0}, {1, 1 / 2}]]

変数データと解データを設定する：

Wolfram Language code:

vd = NDSolve`VariableData[{"DependentVariables", "Space"} -> {{u}, {x, y}}];
sd = NDSolve`SolutionData[{"Space"} -> {nRegion}];

偏微分方程式データを初期化する：

Wolfram Language code: methodData = InitializePDEMethodData[vd, sd]

線形偏微分方程式の解を設定する．線形係数を初期化する：

Wolfram Language code: pdeData = InitializePDECoefficients[vd, sd, "DiffusionCoefficients" -> {{-IdentityMatrix[2]}}]

線形境界条件データを初期化する：

Wolfram Language code: bcData = InitializeBoundaryConditions[vd, sd, {{DirichletCondition[u[x, y] == 0., x == 0]}}]

偏微分方程式を解く：

Wolfram Language code: sdNew = PDESolve[pdeData, bcData, vd, sd, methodData];

偏微分方程式の後処理を行う：

Wolfram Language code: ProcessPDESolutions[methodData, sdNew]

非線形偏微分方程式の解を設定する．非線形係数を初期化する：

Wolfram Language code: npdeData = InitializePDECoefficients[vd, sd, "DiffusionCoefficients" -> {{-Sqrt[u[x, y]] * IdentityMatrix[2]}}]

非線形境界条件データを初期化する：

Wolfram Language code:

nbcData = InitializeBoundaryConditions[vd, sd, {{DirichletCondition[u[x, y] == 0., x == 0], NeumannValue[u[x, y] ^ 2, x == 1]}}]

最初の推測を指定する：

Wolfram Language code: NDSolve`SetSolutionDataComponent[sd, "Dependent", {1}]

非線形偏微分方程式を解く：

Wolfram Language code: sdnew = PDESolve[npdeData, nbcData, vd, sd, methodData];

偏微分方程式の後処理を行う：

Wolfram Language code: ProcessPDESolutions[methodData, sdNew]

オプション (8)

"FindRootOptions" (5)

関数の呼出し，ステップ，関数行列式の評価の必要な数を調べる：

Wolfram Language code:

Block[{e = 0, s = 0, j = 0}, 
	PDESolve[npdeData, nbcData, vd, sd, methodData, 
	"FindRootOptions" -> {
	Jacobian -> {Automatic, EvaluationMonitor :> j++}
	, EvaluationMonitor :> e++, StepMonitor :> s++}
	];
	Print["Function Evaluations = ", e, "
Steps = ", s, "
Jacobian Evaluations = ", j];
	]

PDESolveがデフォルトのFindRoot の求根アルゴリズムを使うように指定する：

Wolfram Language code:

Block[{e = 0, s = 0, j = 0}, 
	PDESolve[npdeData, nbcData, vd, sd, methodData, 
	"FindRootOptions" -> {
	Method -> {"Newton"}
	, Jacobian -> {Automatic, EvaluationMonitor :> j++}
	, EvaluationMonitor :> e++, StepMonitor :> s++}
	];
	Print["Function Evaluations = ", e, "
Steps = ", s, "
Jacobian Evaluations = ", j];
	]

PDESolveがデフォルトのアフィン共変ニュートン法を使うように指定する：

Wolfram Language code:

Block[{e = 0, s = 0, j = 0}, 
	PDESolve[npdeData, nbcData, vd, sd, methodData, 
	"FindRootOptions" -> {
	Method -> {"AffineCovariantNewton"}
	, Jacobian -> {Automatic, EvaluationMonitor :> j++}
	, EvaluationMonitor :> e++, StepMonitor :> s++}
	];
	Print["Function Evaluations = ", e, "
Steps = ", s, "
Jacobian Evaluations = ", j];
	]

PDESolveがブロイデン法のアップデートを使わないように設定する：

Wolfram Language code:

Block[{e = 0, s = 0, j = 0}, 
	PDESolve[npdeData, nbcData, vd, sd, methodData, 
	"FindRootOptions" -> {
	Method -> {"AffineCovariantNewton", "BroydenUpdates" -> False}
	, Jacobian -> {Automatic, EvaluationMonitor :> j++}
	, EvaluationMonitor :> e++, StepMonitor :> s++}
	];
	Print["Function Evaluations = ", e, "
Steps = ", s, "
Jacobian Evaluations = ", j];
	]

デフォルトのPDESolve FindRootメソッド用にPrecisionGoalを設定する：

Wolfram Language code:

Block[{e = 0, s = 0, j = 0}, 
	PDESolve[npdeData, nbcData, vd, sd, methodData, 
	"FindRootOptions" -> {PrecisionGoal -> 4, 
	Jacobian -> {Automatic, EvaluationMonitor :> j++}, 
	EvaluationMonitor :> e++, StepMonitor :> s++}
	];
	Print["Function Evaluations = ", e, "
Steps = ", s, "
Jacobian Evaluations = ", j];
	]

"LinearSolver" (3)

PDESolveがLinearSolveに直接法を使うように指定する：

Wolfram Language code:

Block[{e = 0, s = 0, j = 0}, 
	PDESolve[npdeData, nbcData, vd, sd, methodData, 
	"LinearSolver" -> {LinearSolve, "Method" -> "Direct"}, 
	"FindRootOptions" -> {Jacobian -> {Automatic, EvaluationMonitor :> j++}, 
	EvaluationMonitor :> e++, StepMonitor :> s++}
	];
	Print["Function Evaluations = ", e, "
Steps = ", s, "
Jacobian Evaluations = ", j];
	]

PDESolveがLinearSolveにKeylovメソッドを使うように指定する：

Wolfram Language code:

Block[{e = 0, s = 0, j = 0}, 
	PDESolve[npdeData, nbcData, vd, sd, methodData, 
	"LinearSolver" -> {Automatic, "Method" -> "Krylov"}, 
	"FindRootOptions" -> {
	Jacobian -> {Automatic, EvaluationMonitor :> j++}
	, EvaluationMonitor :> e++, StepMonitor :> s++}
	];
	Print["Function Evaluations = ", e, "
Steps = ", s, "
Jacobian Evaluations = ", j];
	]

MaxIterations PDESolveがLinearSolveにKeylovメソッドを使うように指定する：

Wolfram Language code:

Block[{e = 0, s = 0, j = 0}, 
	PDESolve[npdeData, nbcData, vd, sd, methodData, 
	"LinearSolver" -> {(Print["LinearSolverCall"];LinearSolve[#])&}, 
	"FindRootOptions" -> {
	Jacobian -> {Automatic, EvaluationMonitor :> j++}, 
	EvaluationMonitor :> e++, StepMonitor :> s++}
	];
	Print["Function Evaluations = ", e, "
Steps = ", s, "
Jacobian Evaluations = ", j];
	]

特性と関係 (1)

PDESolveに与えられたオプションは，"PDESolveOptions"を指定することで NDSolveに与えることができる：

Wolfram Language code:

Block[{e = 0, s = 0, j = 0}, 
	NDSolve[{-Inactive[Div][(1/Sqrt[1 + Grad[u[x, y], {x, y}] . Grad[u[x, y], {x, y}]])*
  Inactive[Grad][u[x, y], {x, y}], {x, y}] == 0, DirichletCondition[u[x, y] == Sin[2π * (x + y)], True]}, u, {x, y}∈Disk[], Method -> {"FiniteElement", "PDESolveOptions" -> "FindRootOptions" -> {
	Jacobian -> {Automatic, EvaluationMonitor :> j++}
	, EvaluationMonitor :> e++, StepMonitor :> s++}}];
	Print["Function Evaluations = ", e, "
Steps = ", s, "
Jacobian Evaluations = ", j];
	]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

PDESolve

詳細とオプション

例題

例 (3)

オプション (8)

"FindRootOptions" (5)

"LinearSolver" (3)

特性と関係 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

PDESolve

詳細とオプション

例題

例 (3)

オプション (8)

"FindRootOptions" (5)

"LinearSolver" (3)

特性と関係 (1)

関連項目

テクニカルノート

関連するガイド

テキスト

CMS

APA

BibTeX

BibLaTeX