WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ActionMenu[name,{lbl1:>act1,lbl2:>act2,…}]

対応する項目が選ばれると式 actiを評価する lbliというラベルの付いた項目を含む，name というラベルの付いたアクションメニューを表す．

ActionMenu[name,{…,lbli{sublbl1:>subact1,sublbl2:>subact2,…},…}]

アクションが subactiの項目 sublbliを含む，ラベル lbliが付いたサブメニューを含むアクションメニューを表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Appearance  
ContentPadding  
Enabled  
Show More Show More
Evaluator  
FrameMargins  
ImageMargins  
ImageSize  
Method  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

ActionMenu

ActionMenu[name,{lbl1:>act1,lbl2:>act2,…}]

対応する項目が選ばれると式 actiを評価する lbliというラベルの付いた項目を含む，name というラベルの付いたアクションメニューを表す．

ActionMenu[name,{…,lbli{sublbl1:>subact1,sublbl2:>subact2,…},…}]

アクションが subactiの項目 sublbliを含む，ラベル lbliが付いたサブメニューを含むアクションメニューを表す．

詳細とオプション

  • name，サブメニュー，項目ラベルは任意の式でよい．
  • ActionMenuは，デフォルトで name と lbliを"ActionMenu"スタイルで表示する．通常はシステムのメニューフォントが使われる．
  • ActionMenu[name,list]では，list の要素としてDelimiterを使い，表示されたメニューの水平デリミタを指定することができる．
  • サブメニューはデリミタおよび他のサブメニューを含むことができる．
  • 次のオプションを与えることができる．
  • Appearance Automaticメニューの全体的な外観
    BaselinePositionAutomatic周囲のテキストのベースラインと何を揃えるか
    BaseStyle{}メニューのベーススタイル指定
    ContentPadding True余白をコンテンツの周囲ぎりぎりまで縮めるかどうか
    Enabled Automaticメニューを有効にするか，灰色（無効）にするか
    Evaluator Automaticactiを評価するカーネル
    FrameMargins Automaticメニューの枠の中に残す余白
    ImageMargins 0表示されたメニューの画像周囲の余白
    ImageSize Automatic表示されたメニューの全体的な画像サイズ
    MenuStyle{}メニュー項目のスタイル指定
    Method "Preemptive"使用する評価メソッド
  • Appearanceが取り得る値には次のようなものがある．
  • None編集を加えずに name だけを表示する
    Automatic特別のアクションメニュー形式で表示する（デフォルト）
    "PopupMenu"初期値を name とし，ポップアップメニューのように表示する
    "Button"ボタンのように表示する
  • Methodオプションの一般的な設定値には"Preemptive"，"Queued"等がある．
  • BaseStyleの設定値は，一般に現行スタイルシートの"ActionMenu"スタイルで与えられるデフォルトスタイルに付加される．

例題

すべて開く すべて閉じる

例  (3)

評価結果を出力するアクションメニューを作る：

Wolfram Language code: ActionMenu["階乗の表示", {"4!" :> Print[4!], "7!" :> Print[7!], "10!" :> Print[10!]}]

簡単な割当て操作を行うアクションメニューを作る：

Wolfram Language code: {ActionMenu["xの設定", {"x = 1" :> (x = 1;), "x = 2" :> (x = 2;)}], Dynamic[x]}

サブメニューがあるアクションメニューを作る：

Wolfram Language code: ActionMenu["出力", {"階乗の出力" -> {"4!" :> Print[4!], "7!" :> Print[7!], "10!" :> Print[10!]}, "二重階乗の出力" -> {"4!!" :> Print[4!!], "7!!" :> Print[7!!], "10!!" :> Print[10!!]}}]

スコープ  (3)

Delimiterを使ってメニュー項目を分離する：

Wolfram Language code: {ActionMenu["xの設定", {"x = 1" :> (x = 1;), Delimiter, "x = 2" :> (x = 2;)}], Dynamic[x]}

ラベルは任意の式でよい：

Wolfram Language code: {ActionMenu["xの設定", {Graphics[Disk[], ImageSize -> 20] :> (x = 1;), Delimiter, Expand[(a + b) ^ 4] :> (x = 2;)}], Dynamic[x]}

リストを使ってネストしたメニュー構造を構築する：

Wolfram Language code: ActionMenu["Help", { "Version Information" -> {"Kernel" :> Print[$Version], "All" :> NotebookPut[SystemInformation[]]}, "Documentation" -> { "Home" :> FrontEndTokenExecute[EvaluationNotebook[], "OpenHelpLink"], Delimiter, "$Version" :> SystemOpen["paclet:ref/$Version"], "SystemInformation" :> SystemOpen["paclet:ref/SystemInformation"]} }]

オプション  (10)

Appearance  (1)

メニューに異なる外観を用いる：

Wolfram Language code: Table[ActionMenu["階乗", {"4!" :> Print[4!], "7!" :> Print[7!], "10!" :> Print[10!]}, Appearance -> a], {a, {None, Automatic, "PopupMenu", "Button"}}]

ContentPadding  (1)

アセンダやディセンダがないラベルの周囲の余分な余白を除去する：

Wolfram Language code: ActionMenu["xxx", {"4!" :> Print[4!], "7!" :> Print[7!], "10!" :> Print[10!]}, ContentPadding -> False, FrameMargins -> 0]

Enabled  (2)

デフォルトで，ActionMenuは有効になっている：

Wolfram Language code: ActionMenu["階乗", {"4!" :> Print[4!], "7!" :> Print[7!], "10!" :> Print[10!]}]

Enabled->Falseと設定すると，このメニュー項目は無効になる：

Wolfram Language code: ActionMenu["階乗", {"4!" :> Print[4!], "7!" :> Print[7!], "10!" :> Print[10!]}, Enabled -> False]

Evaluator  (2)

デフォルトで，ボタン関数は評価のためにカーネルに送られる：

Wolfram Language code: ActionMenu["カーネル", {"$ProcessID" :> Print[$ProcessID], "$SessionID" :> Print[$SessionID]}]

Evaluatorを設定すると，ボタン関数を別のカーネルで評価することができる：

Wolfram Language code: ActionMenu["フロントエンド", {"$ProcessID" :> Print[$ProcessID], "$SessionID" :> Print[$SessionID]}, Evaluator -> "System"]

FrameMargins  (1)

メニュー内に余白を加える：

Wolfram Language code: Table[ActionMenu["階乗", {"4!" :> Print[4!], "7!" :> Print[7!], "10!" :> Print[10!]}, FrameMargins -> m], {m, {0, 5, 10}}]

ImageMargins  (1)

メニューの外側に余白を加える：

Wolfram Language code: Table[Framed[ActionMenu["階乗", {"4!" :> Print[4!], "7!" :> Print[7!], "10!" :> Print[10!]}, ImageMargins -> m]], {m, {0, 5, 10}}]

ImageSize  (1)

全体的な画像サイズを指定する：

Wolfram Language code: Grid[Table[ActionMenu["階乗", {"4!" :> Print[4!], "7!" :> Print[7!], "10!" :> Print[10!]}, ImageSize -> {w, h}], {h, {20, 30, 50}}, {w, {50, 100, 200}}]]

Method  (1)

デフォルトで，アクションメニュー関数は5秒でタイムアウトになるプリエンプティブリンクで評価される：

Wolfram Language code: DynamicModule[{a = "開始"}, {ActionMenu["タイムアウト", {"時間がかかるタスク" :> (Pause[10];a = "end long task"), "もっと時間がかかるタスク" :> (Pause[20];a = "end longer task")} ], Dynamic[a]}]

Method->"Queued"を使ってボタン関数をタイムアウトがないメインリンクで評価するようにする：

Wolfram Language code: DynamicModule[{a = "開始"}, {ActionMenu["タイムアウトなし", {"時間がかかるタスク" :> (Pause[10];a = "end long task"), "もっと時間がかかるタスク" :> (Pause[20];a = "end longer task")}, Method -> "Queued" ], Dynamic[a]}]

アプリケーション  (2)

さまざまなグラフィックスオブジェクトから選ぶ：

Wolfram Language code: {g1, g2, g3, g4} = {Graphics[Disk[], ImageSize -> 20], Graphics[Circle[], ImageSize -> 20], Graphics[Rectangle[], ImageSize -> 20], Graphics[Polygon[{{-1, 0}, {1, 0}, {0, Sqrt[3]}}], ImageSize -> 20]};
Wolfram Language code: DynamicModule[{x = {}}, {ActionMenu["Graphics", {g1 :> (x = Disk[];), g2 :> (x = Circle[];), g3 :> (x = Rectangle[];), g4 :> (x = Polygon[{{-1, 0}, {1, 0}, {0, Sqrt[3]}}];)}], Dynamic[Graphics[{Pink, x}]]}]

グラフィックスの範囲を制御する：

Wolfram Language code: DynamicModule[{range = 1}, Column[{ActionMenu["ズーム", {"イン" :> (range = range 3 / 4), "アウト" :> (range = range 4 / 3), "リセット" :> (range = 1)}], Graphics[{Circle[{0, 0}, #]& /@ {1 / 5, 1 / 2, 1, 5, 10}}, Axes -> True, PlotRange -> Dynamic[range]]}]]

特性と関係  (1)

ActionMenuは一連のButtonと同じ効果を持つ：

Wolfram Language code: {ActionMenu["xの設定", {"x = 1" :> (x = 1;), "x = 2" :> (x = 2;)}], Dynamic[x]}
Wolfram Language code: {Button["y = 1", (y = 1;)], Button["y = 2", (y = 2;)], Dynamic[y]}

おもしろい例題  (1)

システムレイアウトからメインメニューを取得する：

Wolfram Language code: menus = Get[FileNameJoin[{$InstallationDirectory, "SystemFiles/FrontEnd/TextResources/Japanese", $InterfaceEnvironment, "MenuSetup.tr"}]][[2]];

メニューをActionMenuで配備可能な形式に変換する：

Wolfram Language code: menus = menus //. {MenuItem[lbl_, action_String, ___] :> (lbl :> FrontEndTokenExecute[action]), MenuItem[lbl_, action_, ___] :> (lbl :> action), (HelpMenu | Menu)[lbl_, submenu_List, ___] :> (lbl -> submenu), LinkedItems[{name_ :> _, ___}] :> (name :> Null), AlternateItems[{first_, ___}] :> first}; ActionMenu["Main menu", menus]
Wolfram Research (2007), ActionMenu, Wolfram言語関数， https://reference.wolfram.com/language/ref/ActionMenu.html （2023年に更新）.

テキスト

Wolfram Research (2007), ActionMenu, Wolfram言語関数， https://reference.wolfram.com/language/ref/ActionMenu.html （2023年に更新）.

CMS

Wolfram Language. 2007. "ActionMenu." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/ActionMenu.html.

APA

Wolfram Language. (2007). ActionMenu. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ActionMenu.html

BibTeX

@misc{reference.wolfram_2026_actionmenu, author="Wolfram Research", title="{ActionMenu}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/ActionMenu.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_actionmenu, organization={Wolfram Research}, title={ActionMenu}, year={2023}, url={https://reference.wolfram.com/language/ref/ActionMenu.html}, note=[Accessed: 11-September-2026]}