WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

e1&&e2&&…

各要素の論理積を表す．与えられた引数を順に評価し，これらのいずれかがFalseであれば直ちにFalseを与え，すべてがTrueの場合にはTrueを与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

And

e1&&e2&&…

各要素の論理積を表す．与えられた引数を順に評価し，これらのいずれかがFalseであれば直ちにFalseを与え，すべてがTrueの場合にはTrueを与える．

詳細

  • And[e1,e2,…]は，StandardFormおよびInputFormでは，e1∧e2∧… とも入力できる．∧は&&，andまたは\[And]でも入力可能である． »
  • Andは属性HoldAllを持ち，引数の評価を明示的に制御する．e1&&e2&&… では，eiは順番に評価され，その中のいずれかがFalseと判明した時点で評価が中止される． »
  • Andの評価では，必要ならば記号代数的な処理を行い，True指定の引数を取り除く． »

例題

すべて開く すべて閉じる

例  (4)

アサーションを&&で繋ぐ：

Wolfram Language code: 2 > 1 && Pi > 3

記号結合：

Wolfram Language code: a && b && !c

方程式系：

Wolfram Language code: x + 2y == 3 && 4x + 5y == 6

andを使って入力する：

Wolfram Language code: p∧q

スコープ  (5)

Andでは任意数の引数が使える：

Wolfram Language code: And[x, y, z]

Andには結合律である：

Wolfram Language code: And[x, And[y, z]]//FullForm

明示的なTrueまたはFalse引数を伴うAndは簡約される：

Wolfram Language code: And[x, True, z]
Wolfram Language code: And[x, False, z]

Andは引数を順序通りに評価し，評価の結果がFalseになったところで停止する：

Wolfram Language code: And[Print[1];False, Print[2];True]
Wolfram Language code: And[Print[1];True, Print[2];True]

引数の順序が重要なことがある：

Wolfram Language code: x ≠ 0 && y == 1 / x /. x -> 0
Wolfram Language code: y == 1 / x && x ≠ 0 /. x -> 0

記号変換は引数順序を保存しない：

Wolfram Language code: z && y && y && x
Wolfram Language code: Simplify[%]

TraditionalFormによる表示：

Wolfram Language code: x && y && z//TraditionalForm

アプリケーション  (6)

Wolfram言語コードで条件を結合する：

Wolfram Language code: PositiveNumberQ[x_] := NumberQ[x] && Head[x] =!= Complex && x > 0
Wolfram Language code: PositiveNumberQ[1]

Andの引数を評価するとFalseになる場合，続く引数は評価されない：

Wolfram Language code: PositiveNumberQ[I]

Andにおける引数順は重要である．最後の2つの引数順序を逆にするとI>0が評価される：

Wolfram Language code: PositiveNumberQ2[x_] := NumberQ[x] && x > 0 && Head[x] =!= Complex
Wolfram Language code: PositiveNumberQ2[I]

仮定を結合する：

Wolfram Language code: Refine[(a ^ b) ^ c, a ≥ 0 && Element[b, Reals]]

方程式と不等式を結合する．Andは入力と出力の両方に使われる：

Wolfram Language code: Reduce[x ^ 2 + y ^ 2 == 1 && x ≥ y, {x, y}]

Andを使って条件を結合する：

Wolfram Language code: RegionPlot[x ^ 2 + y ^ 2 < 1 && x + y > 0, {x, -2, 2}, {y, -2, 2}]
Wolfram Language code: RegionPlot3D[x ^ 2 + y ^ 2 + z ^ 2 < 1 && x ^ 2 + y ^ 2 < z ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

Andに基づいたセルオートマトン：

Wolfram Language code: ArrayPlot[Boole[CellularAutomaton[{And@@#&, {}}, RandomChoice[{True, False}, 40], 20]]]

代数条件で与えられる集合の共通部分の面積を求める：

Wolfram Language code: Integrate[Boole[x ^ 2 + y ^ 2 < 1 && (x - 1) ^ 2 + y ^ 2 < 2], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]

集合を示す：

Wolfram Language code: RegionPlot[x ^ 2 + y ^ 2 < 1 && (x - 1) ^ 2 + y ^ 2 < 2, {x, -1.5, 2.5}, {y, -2, 2}]

特性と関係  (8)

2引数のAndの真理値表：

Wolfram Language code: BooleanTable[{x, y, And[x, y]}, {x, y}]//Grid

3引数のAnd：

Wolfram Language code: BooleanTable[{x, y, z, And[x, y, z]}, {x, y, z}]//Grid

引数がないAndはTrueである：

Wolfram Language code: And[]

1引数のAndは，値にかかわらず，評価された引数を返す：

Wolfram Language code: And[2 + 2]

&&は||よりも優先順位が高い：

Wolfram Language code: p || q && r//FullForm

BooleanConvertを使ってAndをOrについて展開する：

Wolfram Language code: (a || b) && (c || d || e)
Wolfram Language code: BooleanConvert[%]

ド・モルガン(De Morgan)の法則はAnd，Or，Notを関連付ける：

Wolfram Language code: BooleanConvert[!(a && b)]
Wolfram Language code: BooleanConvert[!(a || b || c)]

積またはBoole関数のMinに対応する条件の結合：

Wolfram Language code: Boole[a]Boole[b] - Boole[a && b]
Wolfram Language code: Simplify[%]
Wolfram Language code: Min[Boole[a], Boole[b]] - Boole[a && b]
Wolfram Language code: Simplify[%]

Threadを使ってリストに縫い込む：

Wolfram Language code: {p, q} && {r, s}
Wolfram Language code: Thread[%]
Wolfram Research (1988), And, Wolfram言語関数， https://reference.wolfram.com/language/ref/And.html （1996年に更新）.

テキスト

Wolfram Research (1988), And, Wolfram言語関数， https://reference.wolfram.com/language/ref/And.html （1996年に更新）.

CMS

Wolfram Language. 1988. "And." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 1996. https://reference.wolfram.com/language/ref/And.html.

APA

Wolfram Language. (1988). And. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/And.html

BibTeX

@misc{reference.wolfram_2026_and, author="Wolfram Research", title="{And}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/And.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_and, organization={Wolfram Research}, title={And}, year={1996}, url={https://reference.wolfram.com/language/ref/And.html}, note=[Accessed: 12-August-2026]}