WOLFRAM

Wolfram 语言与系统参考资料中心

e1&&e2&&…

是逻辑 AND 函数. 它按照顺序对其参数进行计算，当它们中任意一个是 False 时立即返回 False，如果它们都是 True 则返回 True.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

And

e1&&e2&&…

是逻辑 AND 函数. 它按照顺序对其参数进行计算，当它们中任意一个是 False 时立即返回 False，如果它们都是 True 则返回 True.

更多信息

  • And[e1,e2,…] 在 StandardForm 和 InputForm 中可以按 e1∧e2∧… 输入. 字符 ∧ 可以输入为 &&、and 或 \[And]. »
  • And 具有属性 HoldAll，明确控制其自变量的计算. 在 e1&&e2&&… 中按顺序计算 ei，如果其中出现 False 则停止. »
  • And 在必要时给出符号结果，去除为 True 的初始参数. »

范例

打开所有单元 关闭所有单元

基本范例  (4)

利用 && 结合断定：

Wolfram Language code: 2 > 1 && Pi > 3

符号合取：

Wolfram Language code: a && b && !c

方程组：

Wolfram Language code: x + 2y == 3 && 4x + 5y == 6

利用和输入：

Wolfram Language code: p∧q

范围  (5)

And 的参数可以为任意个：

Wolfram Language code: And[x, y, z]

And 具有结合性：

Wolfram Language code: And[x, And[y, z]]//FullForm

具有显式 True 或 False 参数的 And 将简化：

Wolfram Language code: And[x, True, z]
Wolfram Language code: And[x, False, z]

And 按顺序计算其参数，当一个参数计算为 False 时停止：

Wolfram Language code: And[Print[1];False, Print[2];True]
Wolfram Language code: And[Print[1];True, Print[2];True]

参数的次序可能很重要：

Wolfram Language code: x ≠ 0 && y == 1 / x /. x -> 0
Wolfram Language code: y == 1 / x && x ≠ 0 /. x -> 0

符号变换将不保持参数顺序：

Wolfram Language code: z && y && y && x
Wolfram Language code: Simplify[%]

TraditionalForm 格式输出：

Wolfram Language code: x && y && z//TraditionalForm

应用  (6)

组合 Wolfram 语言代码中的条件：

Wolfram Language code: PositiveNumberQ[x_] := NumberQ[x] && Head[x] =!= Complex && x > 0
Wolfram Language code: PositiveNumberQ[1]

如果 And 的一个参数计算为 False，随后的任意参数将不再计算：

Wolfram Language code: PositiveNumberQ[I]

And 中参数的次序很重要，如果我们倒换最后两个参数，则计算为 I>0：

Wolfram Language code: PositiveNumberQ2[x_] := NumberQ[x] && x > 0 && Head[x] =!= Complex
Wolfram Language code: PositiveNumberQ2[I]

组合假定：

Wolfram Language code: Refine[(a ^ b) ^ c, a ≥ 0 && Element[b, Reals]]

组合方程及不等式；And 既用于输入也用于输出：

Wolfram Language code: Reduce[x ^ 2 + y ^ 2 == 1 && x ≥ y, {x, y}]

利用 And 组合各种条件：

Wolfram Language code: RegionPlot[x ^ 2 + y ^ 2 < 1 && x + y > 0, {x, -2, 2}, {y, -2, 2}]
Wolfram Language code: RegionPlot3D[x ^ 2 + y ^ 2 + z ^ 2 < 1 && x ^ 2 + y ^ 2 < z ^ 2, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

基于 And 的元胞自动机：

Wolfram Language code: ArrayPlot[Boole[CellularAutomaton[{And@@#&, {}}, RandomChoice[{True, False}, 40], 20]]]

求出由代数条件给定的集的相交面积：

Wolfram Language code: Integrate[Boole[x ^ 2 + y ^ 2 < 1 && (x - 1) ^ 2 + y ^ 2 < 2], {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]

显示该集合：

Wolfram Language code: RegionPlot[x ^ 2 + y ^ 2 < 1 && (x - 1) ^ 2 + y ^ 2 < 2, {x, -1.5, 2.5}, {y, -2, 2}]

属性和关系  (8)

二元 And 的真值表：

Wolfram Language code: BooleanTable[{x, y, And[x, y]}, {x, y}]//Grid

三元 And：

Wolfram Language code: BooleanTable[{x, y, z, And[x, y, z]}, {x, y, z}]//Grid

零参数 And 为 True：

Wolfram Language code: And[]

具有单一参数的 And 将返回运算后的参数，无论值如何：

Wolfram Language code: And[2 + 2]

&& 比 || 具有更高优先级：

Wolfram Language code: p || q && r//FullForm

利用 BooleanConvert 相对于 Or 展开 And：

Wolfram Language code: (a || b) && (c || d || e)
Wolfram Language code: BooleanConvert[%]

德·摩根定律关联 And、Or 和 Not：

Wolfram Language code: BooleanConvert[!(a && b)]
Wolfram Language code: BooleanConvert[!(a || b || c)]

条件的合取与积或 Boole 函数的 Min 一致：

Wolfram Language code: Boole[a]Boole[b] - Boole[a && b]
Wolfram Language code: Simplify[%]
Wolfram Language code: Min[Boole[a], Boole[b]] - Boole[a && b]
Wolfram Language code: Simplify[%]

利用 Thread 线性作用于列表：

Wolfram Language code: {p, q} && {r, s}
Wolfram Language code: Thread[%]
Wolfram Research (1988)，And，Wolfram 语言函数，https://reference.wolfram.com/language/ref/And.html （更新于 1996 年）.

文本

Wolfram Research (1988)，And，Wolfram 语言函数，https://reference.wolfram.com/language/ref/And.html （更新于 1996 年）.

CMS

Wolfram 语言. 1988. "And." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 1996. https://reference.wolfram.com/language/ref/And.html.

APA

Wolfram 语言. (1988). And. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/And.html 年

BibTeX

@misc{reference.wolfram_2026_and, author="Wolfram Research", title="{And}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/And.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_and, organization={Wolfram Research}, title={And}, year={1996}, url={https://reference.wolfram.com/language/ref/And.html}, note=[Accessed: 17-August-2026]}