Wolfram 语言与系统参考资料中心

AndersonDarlingTest

AndersonDarlingTest[data]

利用 Anderson–Darling 检验检测data 是否服从正态分布.

AndersonDarlingTest[data,dist]

利用 Anderson–Darling 检验检测data 是否服从分布 dist.

AndersonDarlingTest[data,dist,"property"]

返回 "property" 的值.

范例

打开所有单元关闭所有单元

基本范例 (3)

进行 Anderson–Darling 的正态性检验：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10^3];

Wolfram Language code: AndersonDarlingTest[data]

Wolfram Language code: Show[SmoothHistogram[data, PlotStyle -> {Dashed, Red}], Plot[PDF[NormalDistribution[], x], {x, -4, 4}]]

检测对某些数据的拟合是否符合某特定分布：

Wolfram Language code: data = RandomVariate[PowerDistribution[1, 2], 10^4];

Wolfram Language code: AndersonDarlingTest[data, PowerDistribution[1, 2]]

Wolfram Language code:

Show[Histogram[data, Automatic, "PDF"], Plot[PDF[PowerDistribution[1, 2], x], {x, 0, 1}, PlotStyle -> Thick, PlotRange -> All]]

比较两组数据的分布：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 100];

Wolfram Language code: data2 = RandomVariate[NormalDistribution[.1, 1], 150];

Wolfram Language code: AndersonDarlingTest[data1, data2]

Wolfram Language code: SmoothHistogram[{data1, data2}]

范围 (9)

检验 (6)

进行 Anderson–Darling 的正态性检验：

Wolfram Language code:

data1 = RandomVariate[NormalDistribution[], 10^4];
data2 = RandomVariate[StudentTDistribution[3], 10^4];

正态数据的值与非正态数据的值相比较大：

Wolfram Language code: AndersonDarlingTest[data1]

Wolfram Language code: AndersonDarlingTest[data2]

检验对一种特定分布的拟合优度：

Wolfram Language code:

data1 = RandomVariate[NormalDistribution[], 10^3];
data2 = RandomVariate[CauchyDistribution[0, 1], 10^3];

Wolfram Language code: AndersonDarlingTest[data1, CauchyDistribution[0, 1]]

Wolfram Language code: AndersonDarlingTest[data2, CauchyDistribution[0, 1]]

比较两组数据的分布：

Wolfram Language code:

data1 = RandomVariate[NormalDistribution[], 10^3];
data2 = RandomVariate[NormalDistribution[], 10^3];

Wolfram Language code: AndersonDarlingTest[data1, data2]

Wolfram Language code: data3 = RandomVariate[NormalDistribution[0, 1.25], 10^3];

Wolfram Language code: AndersonDarlingTest[data1, data3]

多变量正态性检验：

Wolfram Language code:

data1 = RandomVariate[BinormalDistribution[.5], 10^3];
data2 = RandomVariate[LaplaceDistribution[1, 2], {10^3, 2}];

Wolfram Language code: AndersonDarlingTest[data1]

Wolfram Language code: AndersonDarlingTest[data2]

任意多变量分布的拟合优度检验：

Wolfram Language code:

data1 = RandomVariate[BinormalDistribution[.5], 10^3];
data2 = RandomVariate[𝒹 = LaplaceDistribution[1, 2], {10^3, 2}];

Wolfram Language code: 𝒟 = ProductDistribution[𝒹, 𝒹];

Wolfram Language code: AndersonDarlingTest[data1, 𝒟]

Wolfram Language code: AndersonDarlingTest[data2, 𝒟]

创建一个 HypothesisTestData 对象以进行重复属性提取：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10^5];

Wolfram Language code: ℋ = AndersonDarlingTest[data, Automatic, "HypothesisTestData"]

可用于提取的属性：

Wolfram Language code: ℋ["Properties"]

报告 (3)

将 Anderson–Darling 检验的结果制作成表格：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];

Wolfram Language code: ℋ = AndersonDarlingTest[data, Automatic, "HypothesisTestData"];

完全检验表：

Wolfram Language code: ℋ["TestDataTable"]

一个值表：

Wolfram Language code: ℋ["PValueTable"]

检验统计量：

Wolfram Language code: ℋ["TestStatisticTable"]

从 Anderson–Darling 检验表中提取项目，用于生成定制的报告：

Wolfram Language code:

data1 = RandomVariate[NormalDistribution[], 100];
data2 = RandomVariate[NormalDistribution[], 100];

Wolfram Language code: ℋ1 = AndersonDarlingTest[data1, Automatic, "TestData"]

Wolfram Language code: ℋ2 = AndersonDarlingTest[data2, Automatic, "TestData"]

Wolfram Language code:

BarChart[{Labeled[ℋ1, "Set 1"], Labeled[ℋ2, "Set 2"]}, ChartLabels -> {"SuperscriptBox[A, 2]", "p‐value"}]

使用 "ShortTestConclusion" 和 "TestConclusion" 报告检验结论：

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[ParetoDistribution[1.05, 2], 100]];

Wolfram Language code: ℋ = AndersonDarlingTest[data, ParetoDistribution[1, 2], "HypothesisTestData"];

Wolfram Language code: ℋ["ShortTestConclusion"]

Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

结论在不同的显著性水平上可能是不同的：

Wolfram Language code: ℋ = AndersonDarlingTest[data, ParetoDistribution[1, 2], "HypothesisTestData", SignificanceLevel -> .001];

Wolfram Language code: ℋ["ShortTestConclusion"]

Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

选项 (4)

Method (3)

对一个可计算的公式使用基于蒙特卡罗的方法：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];

Wolfram Language code: AndersonDarlingTest[data, NormalDistribution[], Method -> "MonteCarlo"]

Wolfram Language code: AndersonDarlingTest[data, NormalDistribution[], Method -> Automatic]

对于基于蒙特卡罗的方法，设置样本数：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];

Wolfram Language code:

pts = Table[{i, AndersonDarlingTest[data, NormalDistribution[], Method -> {"MonteCarlo", "MonteCarloSamples" -> i}]}, {i, Range[5, 250, 15]}];

当样本数增加时，蒙特卡罗估计量收敛到真实的值：

Wolfram Language code: pval = AndersonDarlingTest[data, NormalDistribution[]];

Wolfram Language code:

Show[ListLinePlot[pts, PlotRange -> {0, 1}, FrameLabel -> {"Samples", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}], Graphics[{Dashed, Line[{{0, pval}, {250, pval}}]}]]

设置用于蒙特卡洛方法的随机种子：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];

Wolfram Language code:

pts = Table[{i, AndersonDarlingTest[data, NormalDistribution[], Method -> {"MonteCarlo", "RandomSeed" -> i, "MonteCarloSamples" -> 50}]}, {i, Range[1, 10]}];

种子对产生器的状态有影响，而且对所得的值也有一定影响：

Wolfram Language code: pval = AndersonDarlingTest[data, NormalDistribution[]];

Wolfram Language code:

Show[ListLinePlot[pts, PlotRange -> {Min[pts[[All, 2]]], Max[pts[[All, 2]]]}, FrameLabel -> {"Seed", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}], Graphics[{Dashed, Line[{{0, pval}, {100, pval}}]}]]

SignificanceLevel (1)

设置用于 "TestConclusion" 和 "ShortTestConclusion" 的显著性水平：

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[NormalDistribution[], 100]];

Wolfram Language code: AndersonDarlingTest[data, NormalDistribution[0, 1.5], "ShortTestConclusion", SignificanceLevel -> .05]

Wolfram Language code: AndersonDarlingTest[data, NormalDistribution[0, 1.5], "ShortTestConclusion", SignificanceLevel -> .01]

默认情况下，使用：

Wolfram Language code: AndersonDarlingTest[data, NormalDistribution[0, 1.5], "TestConclusion"]//TraditionalForm

应用 (4)

可以证明 GammaDistribution[1,1/λ] 等价于 ExponentialDistribution[λ]. 该结论被模拟实验支持：

Wolfram Language code: λvect = {2, 4, 6, 8, 10};

Wolfram Language code: data = Table[RandomVariate[GammaDistribution[1, (1/λ)], {1000, 100}], {λ, λvect}];

执行 Anderson–Darling 检验，把每个数据集根据的期望值分组：

Wolfram Language code: p = Table[(AndersonDarlingTest[#1, ExponentialDistribution[λvect[[i]]]]&) /@ data[[i]], {i, Length[λvect]}];

所得的值分布近似服从均匀分布，这支持我们的推断：

Wolfram Language code: And@@(AndersonDarlingTest[#, UniformDistribution[], "PValue"] > 0.05& /@ p)

Anderson–Darling 检验的效能曲线：

Wolfram Language code: data = Table[RandomVariate[UniformDistribution[{-4, 4}], {500, i}], {i, n = {5, 7, 10, 15, 20, 25, 30}}];

Wolfram Language code: ℋ = Table[AndersonDarlingTest[data[[i, j]], NormalDistribution[]], {i, Length[data]}, {j, Length[data[[i]]]}];

Wolfram Language code: pC = Interpolation[Transpose[{n, Table[Probability[x ≤ 0.05, xi], {i, ℋ}]}], InterpolationOrder -> 1];

将近似效能曲线可视化：

Wolfram Language code: Plot[pC[x], {x, 5, 30}, PlotRange -> {.6, 1}, Ticks -> {n, Automatic}, AxesOrigin -> {0, 0.6}]

当内在分布是 UniformDistribution[{-4,4}]，检验大小为 0.05，并且样本大小为 6 时，估计 Anderson–Darling 检验的效能：

Wolfram Language code: pC[6.]

一组测量数据从来自3个物种、每个物种50个样本中采集. 据观察，物种 setosa 容易识别，但是另外两种，versicolor 和 virginica，经常被混淆：

Wolfram Language code: data = ExampleData[{"Statistics", "FisherIris"}];

Wolfram Language code: petalLen = data[[All, 3]];

Wolfram Language code: species = data[[All, -1]];

每个物种的花瓣长度的分布：

Wolfram Language code: SmoothHistogram[Pick[petalLen, species, #], PlotLabel -> #, Filling -> Axis]& /@ DeleteDuplicates[species]

对于 versicolor 和 virginica 的分布是一致的，但是与 setosa 有很大不同：

Wolfram Language code: AndersonDarlingTest[Pick[petalLen, species, "versicolor"], Pick[petalLen, species, "viginica"]]

Wolfram Language code: AndersonDarlingTest[Pick[petalLen, species, "setosa"], Pick[petalLen, species, "virginica" | "versicolor"]]

假设对于总体来说，下列花瓣长度度量是已知的：

Wolfram Language code: Subscript[μ, s] = 1.5;Subscript[μ, vv] = 4.9;Subscript[σ, s] = .2;Subscript[σ, vv] = .8;

Wolfram Language code:

𝒟 = MixtureDistribution[{50 / 150, 100 / 150}, {NormalDistribution[Subscript[μ, s], Subscript[σ, s]], NormalDistribution[Subscript[μ, vv], Subscript[σ, vv]]}];

Wolfram Language code: 𝒟data = SmoothKernelDistribution[petalLen, {"Adaptive", Automatic, .5}];

Wolfram Language code: Plot[{PDF[𝒟, x], PDF[𝒟data, x]}, {x, 0, 8}, PlotLegends -> {"𝒟", "𝒟data"}]

正态混合看上去对花瓣长度分布的拟合相当良好：

Wolfram Language code: AndersonDarlingTest[petalLen, 𝒟, "TestDataTable"]

通过最小化 Anderson-Darling 检验统计量来估计分布的参数：

Wolfram Language code: data = RandomVariate[StudentTDistribution[6.4], 500];

Wolfram Language code: adDistance[df_Real] := AndersonDarlingTest[data, StudentTDistribution[df], "TestStatistic"]

Wolfram Language code: Plot[adDistance[ν], {ν, 1, 10}]

Wolfram Language code: νMinAD = NArgMin[{adDistance[ν], ν > 0}, ν]

与用 MLE 计算所得的值进行比较

Wolfram Language code: νMLE = ν /. FindDistributionParameters[data, StudentTDistribution[ν]]

比较采用这两个最优参数时的 Anderson-Darling 检验统计量：

Wolfram Language code: {adDistance[νMinAD], adDistance[νMLE]}

属性和关系 (9)

默认情况下，单变量数据与 NormalDistribution 相比较：

Wolfram Language code: data = RandomVariate[NormalDistribution[2, 3], 10^4];

Wolfram Language code: ℋ = AndersonDarlingTest[data, Automatic, "HypothesisTestData"];

Wolfram Language code: ℋ["TestDataTable"]

参数已经由数据估计得到：

Wolfram Language code: ℋ["FittedDistribution"]

默认情况下，多变量数据与 MultinormalDistribution 相比较：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{1, 2, 3}, IdentityMatrix[3]], 1000];

Wolfram Language code: ℋ = AndersonDarlingTest[data, Automatic, "HypothesisTestData"];

Wolfram Language code: ℋ["TestDataTable"]

Wolfram Language code: ℋ["FittedDistribution"]//TraditionalForm

若未指明，则检验分布的参数由数据中估计得到：

Wolfram Language code: data = RandomVariate[NormalDistribution[1, 2], 1000];

Wolfram Language code: AndersonDarlingTest[data, NormalDistribution[μ, σ], "FittedDistribution"]

若未指明，则检验分布的参数由数据中估计得到：

Wolfram Language code: AndersonDarlingTest[data, NormalDistribution[μ, 2], "FittedDistribution"]

Wolfram Language code: AndersonDarlingTest[data, NormalDistribution[1, 2], "FittedDistribution"]

若未指明，则检验分布的参数由数据中估计得到：

Wolfram Language code: data = RandomVariate[ExponentialDistribution[3], 10^3];

Wolfram Language code: ℋ = AndersonDarlingTest[data, ExponentialDistribution[λ], "FittedDistribution"]

Wolfram Language code: EstimatedDistribution[data, ExponentialDistribution[λ]]

如果参数未知，则当可能的情况下，AndersonDarlingTest 应用一次校正：

Wolfram Language code: data = RandomVariate[NormalDistribution[3, 4], 10^4];

Wolfram Language code: est = EstimatedDistribution[data, NormalDistribution[μ, σ]]

应用一次校正：

Wolfram Language code: AndersonDarlingTest[data, est]

Wolfram Language code: ℋ = AndersonDarlingTest[data, NormalDistribution[μ, σ], "HypothesisTestData"];

拟合分布与之前的相同，而且值被校正：

Wolfram Language code: ℋ["FittedDistribution"]

Wolfram Language code: ℋ["PValue"]

在多变量拟合优度的检验中，假设边缘密度是独立的：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{0, 0}, {{0.118, 0.252}, {0.252, 0.665}}], 100];

Wolfram Language code: AndersonDarlingTest[data, MultinormalDistribution[{0, 0}, {{0.118, 0.252}, {0.252, 0.665}}], "TestStatistic"]

假设独立的情况下，检验统计量是相同的：

Wolfram Language code: AndersonDarlingTest[data, MultinormalDistribution[{0, 0}, {{0.118, 0}, {0, 0.665}}], "TestStatistic"]

Anderson–Darling 检验统计量：

Wolfram Language code: n = 100;

Wolfram Language code: data = Sort@RandomVariate[StudentTDistribution[3], n];

Wolfram Language code: F[x_] := CDF[NormalDistribution[], x];

Wolfram Language code: -n - Underoverscript[∑, k, n](2 k - 1/n) (Log[1 - F[data[[n - k + 1]]]] + Log[F[data[[k]]]])

Wolfram Language code: AndersonDarlingTest[data, NormalDistribution[], "TestStatistic"]

Anderson–Darling 统计量可以使用 NExpectation 定义：

Wolfram Language code:

n = 10;
h0 = NormalDistribution[1, 2];
data = RandomVariate[h0, n];

Wolfram Language code:

f[x_] := CDF[h0, x]
Overscript[f,  ^ ][x_] := CDF[EmpiricalDistribution[data], x]

Wolfram Language code: n NExpectation[((Overscript[f, ^ ][t] - f[t])^2/f[t] (1 - f[t])), th0]

Wolfram Language code: AndersonDarlingTest[data, h0, "TestStatistic"]

仅当输入为 TimeSeries 时，Anderson–Darling 检验适用于值：

Wolfram Language code:

ts = TemporalData[TimeSeries, {{{0., -0.11029234344648474, 0.0345779635879646, 0.1743666051306928, 
    0.16967400225598006, 0.1411114639333355, 0.23851991945192513, 0.26921448263698, 
    0.24027115738328042, 0.17492509184799315, 0.2781622872829057, 0. ... 276577, -0.45856201940681207, -0.4228641161946517, 
    -0.21228762599990375}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, 
  {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1];

Wolfram Language code: AndersonDarlingTest[ts]

Wolfram Language code: AndersonDarlingTest[ts["Values"]]

可能存在的问题 (2)

Anderson–Darling检验不用于离散分布：

Wolfram Language code: data = RandomVariate[PoissonDistribution[30], 35];

Wolfram Language code: AndersonDarlingTest[data, PoissonDistribution[30]]

连续性检验对于保持检验的大小非常有用：

Wolfram Language code: sim = RandomVariate[PoissonDistribution[30], {500, 35}];

Wolfram Language code: p = Quiet[AndersonDarlingTest[#, PoissonDistribution[30]]]& /@ sim;

Wolfram Language code:

Show[ListLinePlot[Table[{α, Probability[pv ≤ α, pvp]}, {α, .01, 1, .01}]], Plot[x, {x, 0, 1}, PlotStyle -> {Gray, Dashed}]]

但是在有些情况下，并非如此：

Wolfram Language code: sim = RandomVariate[DiscreteUniformDistribution[{1, 3}], {500, 35}];

Wolfram Language code: p = Quiet[AndersonDarlingTest[#, DiscreteUniformDistribution[{1, 3}]]]& /@ sim;

Wolfram Language code:

Show[ListLinePlot[Table[{α, Probability[pv ≤ α, pvp]}, {α, .01, 1, .01}]], Plot[x, {x, 0, 1}, PlotStyle -> {Gray, Dashed}]]

在这些情况下，使用蒙特卡罗方法或者 PearsonChiSquareTest：

Wolfram Language code: AndersonDarlingTest[sim[[1]], DiscreteUniformDistribution[{1, 3}], Method -> "MonteCarlo"]

Wolfram Language code: PearsonChiSquareTest[sim[[1]], DiscreteUniformDistribution[{1, 3}]]

当参数已经从数据中估计得到时，对于某些分布， Anderson-Darling 检验是无效的：

Wolfram Language code: data = RandomVariate[BetaDistribution[1, 2], 100];

Wolfram Language code: AndersonDarlingTest[data, BetaDistribution[1, b]]

提供已知的参数值：

Wolfram Language code: AndersonDarlingTest[data, BetaDistribution[1, 2]]

或者，使用蒙特卡罗方法来求近似值：

Wolfram Language code: AndersonDarlingTest[data, BetaDistribution[1, b], Method -> "MonteCarlo"]

巧妙范例 (1)

计算零假设为真时的统计量：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2500, 100}];

Wolfram Language code: T1 = AndersonDarlingTest[#, NormalDistribution[], "TestStatistic"]& /@ data;

检验统计量给出特定的选择：

Wolfram Language code: T2 = AndersonDarlingTest[#, NormalDistribution[1, 2], "TestStatistic"]& /@ data;

比较检验统计量的分布：

Wolfram Language code:

SmoothHistogram[{T1, T2}, Filling -> Axis, PlotLegends -> {"SubscriptBox[H, 0] is True", "SubscriptBox[H, 0] is False"}, PlotStyle -> Thick]

Top

	"FittedDistribution"	数据的拟合分布
	"FittedDistributionParameters"	数据的分布参数

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

AndersonDarlingTest

更多信息和选项

范例

基本范例 (3)

范围 (9)

检验 (6)

报告 (3)

选项 (4)

Method (3)

SignificanceLevel (1)

应用 (4)

属性和关系 (9)

可能存在的问题 (2)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

	"PValue"	值
	"PValueTable"	"PValue" 的格式化形式
	"ShortTestConclusion"	一个检验结论的简短描述
	"TestConclusion"	一个检验结论的描述
	"TestData"	检验统计量与值
	"TestDataTable"	"TestData" 的格式化形式
	"TestStatistic"	检验统计量
	"TestStatisticTable"	格式化的 "TestStatistic"

	Method	Automatic	计算值所用的方法
	SignificanceLevel	0.05	诊断和报告的分界点

AndersonDarlingTest

更多信息和选项

范例

基本范例 (3)

范围 (9)

检验 (6)

报告 (3)

选项 (4)

Method (3)

SignificanceLevel (1)

应用 (4)

属性和关系 (9)

可能存在的问题 (2)

巧妙范例 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX