WOLFRAM

Wolfram 语言与系统参考资料中心

f@@expr 或 Apply[f,expr]

用 f 替换 expr的头部.

Apply[f,expr,levelspec]

替换 expr 中使用 levelspec 指定的部分的头部.

Apply[f]

表示可应用于表达式的 Apply 的算符形式.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
层的指定  
表达式的类型  
选项  
Heads  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关的工作流程
相关链接
历史
按以下格式引用：

Apply

f@@expr 或 Apply[f,expr]

用 f 替换 expr的头部.

Apply[f,expr,levelspec]

替换 expr 中使用 levelspec 指定的部分的头部.

Apply[f]

表示可应用于表达式的 Apply 的算符形式.

更多信息和选项

  • Apply 使用标准层指定：
  • n层 1 到 n
    Infinity层 1 到 Infinity
    {n}只有层 n
    {n1,n2}层 n1 到 n2
  • levelspec 的缺省值在 Apply 中为 {0}.
  • Apply[f,expr,{1}] 等价于 MapApply[f,expr] 或 f@@@expr. »
  • 正层 n 由指标 n 指定的 expr 所有部分组成.
  • 负层 -n 由深度为 n 的 expr 所有部分组成.
  • 层 -1 由不带次级部分的数值、符号和其它对象组成.
  • 层 0 对应于整个表达式.
  • 使用选项设置 Heads->True，Apply 将应用于除了部分本身之外的部分头部的内部. »
  • Apply 通常很有效地构成全新表达式然后进行计算.
  • Apply 对 SparseArray 对象和结构化数组进行运算的方式就像对相应的普通列表一样. »
  • Association 对象上的 Apply 仅对值进行运算. »
  • Apply[f][expr] 等价于 Apply[f,expr].
  • Parallelize[Apply[f,expr,levelspec]] 在所有子核上并行运行 Apply[f,expr,levelspec]. »

范例

打开所有单元 关闭所有单元

基本范例  (6)

用 f 替换列表的头部：

Wolfram Language code: Apply[f, {a, b, c, d}]

等价运算：

Wolfram Language code: f@@{a, b, c, d}

通过用 Plus 替换头部来对列表求和：

Wolfram Language code: Plus@@{1, 2, 3, 4}

Apply 去掉了一层列表：

Wolfram Language code: f@@{{a, b}, {c}, d}

使用 Apply 的运算符形式：

Wolfram Language code: Apply[f][{{a, b}, {c}, d}]

将 f 应用于 Association，只保留数值：

Wolfram Language code: Apply[f, <|1 -> a, 2 -> b, 3 -> c|>]

将 List 应用于一个 Association，该效果等价于 Values：

Wolfram Language code: Apply[List, <|1 -> a, 2 -> b, 3 -> c, 4 -> {d}|>]
Wolfram Language code: Values[<|1 -> a, 2 -> b, 3 -> c, 4 -> {d}|>]

范围  (15)

层的指定  (10)

在层 0 应用(缺省)：

Wolfram Language code: Apply[f, {{a, b, c}, {d, e}}]
Wolfram Language code: f@@{{a, b, c}, {d, e}}

在层 1 应用：

Wolfram Language code: Apply[f, {{a, b, c}, {d, e}}, {1}]

在层 0 和 1 应用：

Wolfram Language code: Apply[f, {{a, b, c}, {d, e}}, {0, 1}]

向下应用至层 2 (层 0 除外)：

Wolfram Language code: Apply[f, {{{{{a}}}}}, 2]

在层 0 至 2 应用：

Wolfram Language code: Apply[f, {{{{{a}}}}}, {0, 2}]

在所有层应用，从层 1 开始：

Wolfram Language code: Apply[f, {{{{{a}}}}}, Infinity]

也在层 0 应用：

Wolfram Language code: Apply[f, {{{{{a}}}}}, {0, Infinity}]

负层：

Wolfram Language code: Apply[f, {{{{{a}}}}}, -1]
Wolfram Language code: Apply[f, {{{{{a}}}}}, -2]
Wolfram Language code: Apply[f, {{{{{a}}}}}, -3]

正层和负层可以混合：

Wolfram Language code: Apply[f, {{{{{a}}}}}, {2, -3}]

各层的不同头部：

Wolfram Language code: Apply[f, h0[h1[h2[h3[h4[a]]]]], {2, -3}]

也在指定层的头部内使用：

Wolfram Language code: Apply[f, p[x][q[y]], {1}, Heads -> True]

表达式的类型  (5)

Apply 可用于任何头部，而不仅仅是 List：

Wolfram Language code: Apply[Plus, g[x, y, z]]

Apply 可用于稀疏数组：

Wolfram Language code: SparseArray[{1 -> 1, 2 -> 2, 10 -> 10}]
Wolfram Language code: Apply[List, %]

将 Apply 用于结构化数组，如 SymmetrizedArray：

Wolfram Language code: SymmetrizedArray[{{1, 2} -> 1, {1, 3} -> 2, {2, 3} -> 3}, {3, 3}, Antisymmetric[All]]
Wolfram Language code: f@@%

使用 Apply 将函数应用于 QuantityArray 类型的结构化数组的行：

Wolfram Language code: QuantityArray[{{1, 2}, {3, 4}, {5, 6}}, "Meters"]
Wolfram Language code: Apply[g, %, {1}]

在关联关系的第二层应用 f；保留关联的头部：

Wolfram Language code: Apply[f, <|1 -> a, 2 -> b, 3 -> c, 4 -> {d, {e}}|>, {2}]

在多层应用 f：

Wolfram Language code: Apply[f, <|1 -> a, 2 -> b, 3 -> c, 4 -> {d, {e}}|>, {0, 2}]

选项  (2)

Heads  (2)

在头部内以及参数上应用：

Wolfram Language code: Apply[f, p[x][q[y]], {1}, Heads -> True]
Wolfram Language code: Apply[f, p[x][q[y]], {1}]

如果包含零层，则该选项无效：

Wolfram Language code: Apply[f, p[x][q[y][r[z]]], {0, 1}, Heads -> True]
Wolfram Language code: Apply[f, p[x][q[y][r[z]]], {0, 1}, Heads -> False]

应用  (4)

使用上标表示一个整数的因数分解：

Wolfram Language code: FactorInteger[20!]
Wolfram Language code: CenterDot@@Apply[Superscript, %, {1}]

由一个范围指定的列表，创建一个表：

Wolfram Language code: Table[i ^ j, ##]&@@{{i, 3}, {j, 4}}

将函数的几个参数，转换成一个参数列表：

Wolfram Language code: cplus[list_] := Plus@@list
Wolfram Language code: cplus[{a, b, c}]

求随机互质的整数：

Wolfram Language code: Select[RandomInteger[10, {20, 2}], Apply[CoprimeQ]]

属性和关系  (5)

Total 实际上与将 Plus 应用到一个列表的效果相同：

Wolfram Language code: Total[{a, b, c, d}]
Wolfram Language code: Plus@@{a, b, c, d}

在纯函数中使用 ## 与应用 Apply 的效果相同：

Wolfram Language code: Plus@@{1, 2, 3, 4}
Wolfram Language code: Plus[##]&[1, 2, 3, 4]

在第 1 层应用函数的三种方式：

Wolfram Language code: Apply[f, {{a, b}, {c, d}}, {1}]

使用 Map：

Wolfram Language code: Apply[f, #]& /@ {{a, b}, {c, d}}

使用 MapApply：

Wolfram Language code: f@@@{{a, b}, {c, d}}

一般函数应用将列表当作一个单一参数:

Wolfram Language code: f@{a, b, c}

Apply 视列表的元素为单独的参数:

Wolfram Language code: f@@{a, b, c}

并行运行 Apply：

Wolfram Language code: Parallelize[Apply[f, {{a, b, c}, {u, v, w}, {x, y}}, 1]]

可能存在的问题  (1)

如果应用于不可再分的对象，则没有效果：

Wolfram Language code: Apply[f, a]
Wolfram Language code: Apply[f, {a, "string", 3}, {-1}]
Wolfram Research (1988)，Apply，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Apply.html （更新于 2014 年）.

文本

Wolfram Research (1988)，Apply，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Apply.html （更新于 2014 年）.

CMS

Wolfram 语言. 1988. "Apply." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/Apply.html.

APA

Wolfram 语言. (1988). Apply. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Apply.html 年

BibTeX

@misc{reference.wolfram_2026_apply, author="Wolfram Research", title="{Apply}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Apply.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_apply, organization={Wolfram Research}, title={Apply}, year={2014}, url={https://reference.wolfram.com/language/ref/Apply.html}, note=[Accessed: 15-August-2026]}